Bordersize and Titlebar Height

[SMcNeill]

Looking over a few old programs on my drive, I came across one which gave me the border size and title bar height for my program, and I thought I'd share:

Code: QB64: [Select]

1. DECLARE LIBRARY
2.     FUNCTION glutGet& (BYVAL what&)
3. END DECLARE
4.  
5. _SCREENMOVE 200, 200 'We moved our screen to 200,200 so we know these values are correct
6. BorderWidth = glutGet(506)
7. TitleBarHeight = glutGet(507)
8. ActualScreenX = glutGet(100)
9. ActualScreenY = glutGet(101)
10.  
11. PRINT "Actual Top Left of screen is at ("; _SCREENX; ","; _SCREENY; ")"
12. PRINT "The border is "; BorderWidth; "pixels"
13. PRINT "And the title bar is"; TitleBarHeight; " pixels"
14. PRINT "So your actual display starts at ("; ActualScreenX; ","; ActualScreenY; ")"

I'm guessing since this is a glut command, it should work cross-platform for all the Linux/Mac folks, but I won't swear to it.  I've only got a Win 10 PC available ATM to test things on, and it works as advertised for me...

I honestly have no idea where I got the 100, 101, 506, 507 values, or what they actually represent here -- all I know is they seem to work and give me the relevant information which I'd want back.

For folks who use _SCREENCLICK and _MOUSEMOVE and such (like Pete and Cobolt), this might help you guys calculate where your actual buttons are on a screen and make it easier to interact with them, so I thought I'd share, even though it's basically still a mystery to me what the heck those values represent.  :P

[RhoSigma]

I honestly have no idea where I got the 100, 101, 506, 507 values, or what they actually represent here -- all I know is they seem to work and give me the relevant information which I'd want back.

You probably got 100/101 out of qb64\internal\c\parts\core\src\freeglut_std.h and 506/507 out of freeglut_ext.h in the same folder, there's also a html documentation here qb64\internal\c\parts\core\download\freeglut-2.8.0\doc\freeglut_user_interface.html. Function glutGet and it's respective constants are frequently used by the SCREEN related functions in libqb.cpp

BTW - Steve, you've fixed the _SCREENMOVE _MIDDLE thing a while ago, maybe you can go in again and take the border size / title height into account, so that the actual display area would be centered rather than the entire window. By doing so, we would finally restore the same _SCREENMOVE _MIDDLE behavior as it was in the old SDL version (just in the sake of backward compatibility).

[SMcNeill]

Expanded these little routines to also give us the Taskbar Height and Width, as well as to toss my little ScreenMove routines in there which actually position the screen itself and not the title bar at the position you specify.

Code: QB64: [Select]

1. DH = _DesktopHeight: DW = _DesktopWidth
2. TBH = TaskbarHeight: TBW = TaskbarWidth
3. TH = TitleBarHeight: BW = BorderWidth
4. If TBH = DH Then TBH = 0 'Users taskbar is configured vertical, not hortizonal.
5. If TBW = DW Then TBW = 0
6.  
7.  
8. Screen _NewImage(DW, DH, 32)
9.  
10.  
11. Print "This screen is the size of your desktop, but it has some inherent issues."; _Width, _Height
12. Print
13. Print "Hit the <SPACE BAR> and watch as we position it in different manners:"
14. Sleep
15. _ScreenMove 0, 0
16. Print
17. Print "To start with, this is a _SCREENMOVE 0,0 call.  It places the TITLEBAR's top left corner at position 0,0."
18. Print "If you notice, the bottom of the screen is now hidden as the titlebar has shifted us down below the max resolution our screen will display."
19. Sleep
20. ScreenMove 0, 0
21. Print
22. Print "Now, this is a Steve Approved(tm) ScreenMove method to move the screen itself to position 0,0."
23. Print "Now, as you can tell (if your taskbar is set to hide itself), the program window now covers the screen perfectly."
24. Print "The only problem with this method is that we are now hiding the title bar over the top of the screen!"
25. Sleep
26.  
27.  
28. Screen _NewImage(DW - TBW - 2 * BW, DH - TBH - TH - BW * 2, 32)
29.  
30.  
31. Print
32. Print "To fix these issues, we use the functions here to figure out EXACTLY what size our screen needs to be."
33. Print
34. Print "Title Bar Height = "; TH
35. Print "Screen Border ="; BW; "on each side."
36. Print "Task Bar Height ="; TBH
37. Print "Task Bar Height ="; TBW
38. Print
39. Print "This is a screen perfectly sized to fit on your screen."; _Width, _Height
40. Print "See how it fits your visible screen perfectly?"
41. Print
42. Print "Note: If you have transparent borders, or if your theme has them set to opaque, it may appear to be a gap around your screen.  That transparent gap IS the screen border.  Set it a solid color and you can see it."
43. Print "Note2: You may have to move the program window manually, if your taskbar isn't at the bottom of your screen."
44. Print
45. Print "At this point, you should have your title bar up top.  You screen shouldn't cover, or be covered, by the task bar."
46. Print "Everything should be visible and accessable for you."
47. Print
48. Print "To my way of thinking, THIS is the maximum resolution that your screen should run in with a program.  ;)"
49.  
50.  
51. _ScreenMove 0, 0
52.  
53. Sub ScreenMove (x, y)
54.     Do Until _Width <> 0 And _ScreenExists = -1: Loop
55.     _ScreenMove x - BorderWidth, y - BorderWidth - TitleBarHeight
56. End Sub
57.  
58. Sub ScreenMove_Middle
59.     Do Until _Width <> 0 And _ScreenExists = -1: Loop
60.     _ScreenMove (_DesktopWidth - _Width - BorderWidth) / 2 + 1, (_DesktopHeight - _Height - BorderWidth) / 2 - TitleBarHeight + 1
61. End Sub
62.  
63. Function TaskbarHeight
64.     Do Until _Width <> 0 And _ScreenExists = -1: Loop
65.     $If WIN Then
66.         $If TASKBARDEC = UNDEFINED Then
67.             $Let TASKBARDEC = TRUE
68.             Declare Library "taskbar"
69.                 Function taskbar_height& ()
70.                 Function taskbar_width& ()
71.             End Declare
72.         $End If
73.         TaskbarHeight = taskbar_height&
74.     $Else
75.         TaskbarHeight = 0 'no function to get the value for Linux/Mac, so return 0 instead of an error
76.     $End If
77. End Function
78.  
79. Function TaskbarWidth
80.     Do Until _Width <> 0 And _ScreenExists = -1: Loop
81.     $If WIN Then
82.         $If TASKBARDEC = UNDEFINED Then
83.             $Let TASKBARDEC = TRUE
84.  
85.             Declare Library "taskbar"
86.             Function taskbar_height& ()
87.             Function taskbar_width& ()
88.             End Declare
89.         $End If
90.         TaskbarWidth = taskbar_width&
91.     $Else
92.         TaskbarWidth = 0 'no function to get the value for Linux/Mac, so return 0 instead of an error
93.     $End If
94. End Function
95.  
96.  
97. Function TitleBarHeight
98.     Do Until _Width <> 0 And _ScreenExists = -1: Loop
99.     $If BORDERDEC = UNDEFINED Then
100.         $Let BORDERDEC = TRUE
101.         Declare Library
102.             Function glutGet& (ByVal what&)
103.         End Declare
104.     $End If
105.     TitleBarHeight = glutGet(507)
106. End Function
107.  
108. Function BorderWidth
109.     Do Until _Width <> 0 And _ScreenExists = -1: Loop
110.     $If BORDERDEC = UNDEFINED Then
111.         $Let BORDERDEC = TRUE
112.         Declare Library
113.         Function glutGet& (ByVal what&)
114.         End Declare
115.     $End If
116.     BorderWidth = glutGet(506)
117. End Function

Note that you'll need the taskbar.h file in your qb64 folder for this to work on Windows to actually get the taskbar dimensions for you.  Linux/Mac users, you get a 0 for your sizes as I'm not a Linux/Mac user and don't know which library to use to get those dimensions for you.  If someone wants to add that, let me know and I'll be happy to add it into the code here, but I'm basically just a pure Windows guy anymore.  I don't have enough free time anymore to bother with looking up libraries for OSes which I'll never use or anything personally.  Sorry.  :P

And there's probably a way to do this without the header file for Windows users.  Only problem is, I'm lazy and got it working this way first and said, "Good enough for my needs!"  LOL.  ;D

[bplus]

Feedback image on how your screen centering worked:
https://www.qb64.org/forum/index.php?topic=4381.msg138084#msg138084

Looks like screen height & width is just right but not the locate to right of the taskbar I have on the left side.

[SMcNeill]

Feedback image on how your screen centering worked:
https://www.qb64.org/forum/index.php?topic=4381.msg138084#msg138084

Looks like screen height & width is just right but not the locate to right of the taskbar I have on the left side.

Print "Note2: You may have to move the program window manually, if your taskbar isn't at the bottom of your screen."

[Dav]

Very interesting. Works well here.  By the way, I was playing around with the glutget function in that, and for some reason when I run the function by itself the QB64 IDE won't do anything when I try to compile the code.  Like in below, nothing happens. What am I missing here?  Running the latest QB64 version 32-bit.

Code: QB64: [Select]

1. DECLARE LIBRARY
2.     FUNCTION glutGet& (BYVAL what&)
3. END DECLARE
4.  
5. PRINT glutGet(506)
6.  
7.  

- Dav

[SMcNeill]

Very interesting. Works well here.  By the way, I was playing around with the glutget function in that, and for some reason when I run the function by itself the QB64 IDE won't do anything when I try to compile the code.  Like in below, nothing happens. What am I missing here?  Running the latest QB64 version 32-bit.

Code: QB64: [Select]

1. DECLARE LIBRARY
2.     FUNCTION glutGet& (BYVAL what&)
3. END DECLARE
4.  
5. PRINT glutGet(506)
6.  
7.  

- Dav

Try adding this in there before your PRINT statement:


    Do Until _Width <> 0 And _ScreenExists = -1: Loop

[Dav]

Yes, now it compiles.  Thanks.  But why won't it compile without adding it?

EDIT: Oh, maybe it is compiling, but I just don't notice it because the screen never shows.  Looks like it's closing by itself.

- Dav

[SMcNeill]

Feedback image on how your screen centering worked:
https://www.qb64.org/forum/index.php?topic=4381.msg138084#msg138084

Looks like screen height & width is just right but not the locate to right of the taskbar I have on the left side.

@bplus:

Give this version a go.  I added in 4 more functions for you so you can get to know all you'd ever want to know about your taskbar:

Code: QB64: [Select]

1. DH = _DesktopHeight: DW = _DesktopWidth
2. TBH = TaskbarHeight: TBW = TaskbarWidth
3. TH = TitleBarHeight: BW = BorderWidth
4. If TBH = DH Then TBH = 0 'Users taskbar is configured vertical, not hortizonal.
5. If TBW = DW Then TBW = 0
6.  
7.  
8. Screen _NewImage(DW, DH, 32)
9.  
10. Print "This screen is the size of your desktop, but it has some inherent issues."; _Width, _Height
11. Print
12. Print "Hit the <SPACE BAR> and watch as we position it in different manners:"
13. Sleep
14. _ScreenMove 0, 0
15. Print
16. Print "To start with, this is a _SCREENMOVE 0,0 call.  It places the TITLEBAR's top left corner at position 0,0."
17. Print "If you notice, the bottom of the screen is now hidden as the titlebar has shifted us down below the max resolution our screen will display."
18. Sleep
19. ScreenMove 0, 0
20. Print
21. Print "Now, this is a Steve Approved(tm) ScreenMove method to move the screen itself to position 0,0."
22. Print "Now, as you can tell (if your taskbar is set to hide itself), the program window now covers the screen perfectly."
23. Print "The only problem with this method is that we are now hiding the title bar over the top of the screen!"
24. Sleep
25.  
26.  
27. Screen _NewImage(DW - TBW - 2 * BW, DH - TBH - TH - BW * 2, 32)
28. If taskbar_top > 0 Then ScreenX = 0 Else ScreenX = TBH
29. If taskbar_left > 0 Then Screeny = 0 Else Screeny = TBW
30. ScreenMove ScreenX, Screeny
31.  
32. Print
33. Print "To fix these issues, we use the functions here to figure out EXACTLY what size our screen needs to be."
34. Print
35. Print "Title Bar Height = "; TH
36. Print "Screen Border ="; BW; "on each side."
37. Print "Task Bar Height ="; TBH
38. Print "Task Bar Width ="; TBW
39. Print "Task Bar Top = "; taskbar_top
40. Print "Task Bar Left = "; taskbar_left
41. Print "Task Bar Bottom = "; taskbar_bottom
42. Print "Task Bar Right = "; taskbar_right
43. Print
44. Print "This is a screen perfectly sized to fit on your screen."; _Width, _Height
45. Print "See how it fits your visible screen perfectly?"
46. Print
47. Print "Note: If you have transparent borders, or if your theme has them set to opaque, it may appear to be a gap around your screen.  That transparent gap IS the screen border.  Set it a solid color and you can see it."
48. Print
49. Print "At this point, you should have your title bar up top.  You screen shouldn't cover, or be covered, by the task bar."
50. Print "Everything should be visible and accessable for you."
51. Print
52. Print "To my way of thinking, THIS is the maximum resolution that your screen should run in with a program.  ;)"
53.  
54.  
55. Sub ScreenMove (x, y)
56.     Do Until _Width <> 0 And _ScreenExists = -1: Loop
57.     _ScreenMove x - BorderWidth, y - BorderWidth - TitleBarHeight
58. End Sub
59.  
60. Sub ScreenMove_Middle
61.     Do Until _Width <> 0 And _ScreenExists = -1: Loop
62.     _ScreenMove (_DesktopWidth - _Width - BorderWidth) / 2 + 1, (_DesktopHeight - _Height - BorderWidth) / 2 - TitleBarHeight + 1
63. End Sub
64.  
65. Function TaskbarHeight
66.     Do Until _Width <> 0 And _ScreenExists = -1: Loop
67.     $If WIN Then
68.         $If TASKBARDEC = UNDEFINED Then
69.             $Let TASKBARDEC = TRUE
70.             Declare Library "taskbar"
71.                 Function taskbar_height& ()
72.                 Function taskbar_width& ()
73.                 Function taskbar_top& ()
74.                 Function taskbar_left& ()
75.                 Function taskbar_bottom& ()
76.                 Function taskbar_right& ()
77.             End Declare
78.         $End If
79.         TaskbarHeight = taskbar_height&
80.     $Else
81.         TaskbarHeight = 0 'no function to get the value for Linux/Mac, so return 0 instead of an error
82.     $End If
83. End Function
84.  
85. Function TaskbarWidth
86.     Do Until _Width <> 0 And _ScreenExists = -1: Loop
87.     $If WIN Then
88.         $If TASKBARDEC = UNDEFINED Then
89.             $Let TASKBARDEC = TRUE
90.  
91.             Declare Library "taskbar"
92.             Function taskbar_height& ()
93.             Function taskbar_width& ()
94.             Function taskbar_top& ()
95.             Function taskbar_left& ()
96.             Function taskbar_bottom& ()
97.             Function taskbar_right& ()
98.             End Declare
99.         $End If
100.         TaskbarWidth = taskbar_width&
101.     $Else
102.         TaskbarWidth = 0 'no function to get the value for Linux/Mac, so return 0 instead of an error
103.     $End If
104. End Function
105.  
106.  
107. Function TitleBarHeight
108.     Do Until _Width <> 0 And _ScreenExists = -1: Loop
109.     $If BORDERDEC = UNDEFINED Then
110.         $Let BORDERDEC = TRUE
111.         Declare Library
112.             Function glutGet& (ByVal what&)
113.         End Declare
114.     $End If
115.     TitleBarHeight = glutGet(507)
116. End Function
117.  
118. Function BorderWidth
119.     Do Until _Width <> 0 And _ScreenExists = -1: Loop
120.     $If BORDERDEC = UNDEFINED Then
121.         $Let BORDERDEC = TRUE
122.         Declare Library
123.         Function glutGet& (ByVal what&)
124.         End Declare
125.     $End If
126.     BorderWidth = glutGet(506)
127. End Function
128.  

You can now find your taskbar_top, taskbar_left, taskbar_bottom, taskbar_right positions, and move accordingly to suit your screen.

Unfortunately, I can't actually test to see if this works.  The taskbar *DOES NOT* move from the bottom in the newest versions of Windows.  Win 11 has this to say about the taskbar:  https://www.microsoft.com/en-us/windows/windows-11-specifications#primaryR4

Taskbar is changed including:

• People is no longer present on the Taskbar.
• Some icons may no longer appear in the System Tray (systray) for upgraded devices including previous customizations.
• Alignment to the bottom of the screen is the only location allowed.
• Apps can no longer customize areas of the Taskbar.

[SMcNeill]

Yes, now it compiles.  Thanks.  But why won't it compile without adding it?

- Dav

It's the same type of race conditions which we end up seeing with _SCREENMOVE and _TITLE sometimes.  You're trying to grab the information from the screen before it's fully initialized and registered to begin win. 

A delay before the call will fix it at start up, or I've found   "Do Until _Width <> 0 And _ScreenExists = -1: Loop" to be a good test for a delay for me, as well.  ;)

[Dav]

Yes, that makes sense, and I see a delay is needed to get valid info, but I find it puzzling that the program appears to not even compile and start without it. Shouldn’t the program still try to run? Maybe a failed glutget call terminates programs instantly I’m wondering.

- Dav

[SMcNeill]

Yes, that makes sense, and I see a delay is needed to get valid info, but I find it puzzling that the program appears to not even compile and start without it. Shouldn’t the program still try to run? Maybe a failed glutget call terminates programs instantly I’m wondering.

- Dav

It compiles (look in the QB64 folder for an untitled.exe if you're curious about it).  The problem is it generates a seg fault as soon as you run it, crashing before it even finishes initializing properly.  The program is running and dying in the blink of a nanosecond -- probably faster than your monitors 60 FPS refresh rate.  You'll want a *really* fast display to catch the try-but-die flicker you're generating.  ;)

[bplus]

Hi @SMcNeill

The last screen is loading under the taskbar and down from top of screen. When I drag it to see entire screen it fits well.

[SMcNeill]

Hi @SMcNeill

The last screen is loading under the taskbar and down from top of screen. When I drag it to see entire screen it fits well.

There's a glitch in my logic here then:

If taskbar_top > 0 Then ScreenX = 0 Else ScreenX = TBH
If taskbar_left > 0 Then Screeny = 0 Else Screeny = TBW

The above determines if we're in the top left corner, but it doesn't tell us horizontal or vertical. 

If taskbar_bottom = TBH Then 'bar is at top
    ScreenY = TBH
Else
    ScreenY = 0
END IF

If taskbar_right = TBW THEN 'bar is on left
   ScreenX = TBW
ELSE
    ScreenX = 0
END IF

Replace those two lines with the above and see if it corrects the logic.

[bplus]

The taskbar location are listed correctly left, top = 0,0 and right, bottom = 63, 768 (the screen height available to view), so if you  drew a rectangle with those dimensions you would have taskbar outlined.