DIM SHARED Array Does Not Transfer Into/Out Of Subroutine Correctly

[Qwerkey]

In my latest project, I ran into problems with an array not updating properly when put through a subroutine: all the array elements returned zeroes when they should have had non-zero values.

In the code here, Positions!() is a DIM SHARED Array which in the subroutine SetData has its elements set.

If you run the code as is, you will see that the displayed elements have non-zero values.

If you then comment out lines 44 to 53 and uncomment lines 39 to 42, then all the array elements end up zero.  In lines 39 to 42, the subroutine Angle is called: this subroutine performs the same operations as in lines 44 to 53.

It seems that a DIM SHARED Array does not like to be put through a subroutine (is this an expected property of a shared array?).  The subroutine works properly (of course) with stand-alone variables and with non-shared arrays.

I don't believe that I'm doing something stupid here (I've checked it out thrice), but that is a possibility.

Code: QB64: [Select]

1. CONST Pi! = 3.141592, Hours! = -Pi! / 6, ZOffset% = -398, XImage% = 182, YImage% = 252
2. CONST Halfwidth%% = 50, Halfheight%% = Halfwidth%% * YImage% / XImage%, Radius% = 320, Tucked%% = 7
3. DIM SHARED Positions!(4, 12, 1, 4), Phi!(12)
4.  
5. CALL SetData
6.  
7. FOR N%% = 0 TO 11
8.     FOR S%% = 0 TO 3
9.         PRINT N%%, S%%, Positions!(S%%, N%%, 0, 0); Positions!(S%%, N%%, 1, 0)
10.     NEXT S%%
11. NEXT N%%
12.  
13. END
14.  
15. SUB SetData
16.     FOR N%% = 0 TO 6
17.         Phi!(N%%) = N%% * Hours!
18.     NEXT N%%
19.     FOR N%% = 7 TO 11
20.         Phi!(N%%) = (N%% - 12) * Hours!
21.     NEXT N%%
22.     FOR S%% = 0 TO 4
23.         Positions!(S%%, 0, 0, 4) = 0
24.         Positions!(S%%, 0, 1, 4) = Radius% - Tucked%% * S%%
25.         Positions!(S%%, 0, 0, 3) = Positions!(S%%, 0, 0, 4) + Halfwidth%%
26.         Positions!(S%%, 0, 1, 3) = Positions!(S%%, 0, 1, 4) - Halfheight%%
27.         Positions!(S%%, 0, 0, 2) = Positions!(S%%, 0, 0, 4) - Halfwidth%%
28.         Positions!(S%%, 0, 1, 2) = Positions!(S%%, 0, 1, 4) - Halfheight%%
29.         Positions!(S%%, 0, 0, 1) = Positions!(S%%, 0, 0, 4) + Halfwidth%%
30.         Positions!(S%%, 0, 1, 1) = Positions!(S%%, 0, 1, 4) + Halfheight%%
31.         Positions!(S%%, 0, 0, 0) = Positions!(S%%, 0, 0, 4) - Halfwidth%%
32.         Positions!(S%%, 0, 1, 0) = Positions!(S%%, 0, 1, 4) + Halfheight%%
33.     NEXT S%%
34.     FOR S%% = 0 TO 4
35.         FOR N%% = 1 TO 11
36.  
37.             'CALL Angle doesn't work with Positions!()
38.             'CALL Angle(Positions!(S%%, 0, 0, 0), Positions!(S%%, 0, 1, 0), Positions!(S%%, N%%, 0, 0), Positions!(S%%, N%%, 1, 0), Phi!(N%%))
39.             'CALL Angle(Positions!(S%%, 0, 0, 1), Positions!(S%%, 0, 1, 1), Positions!(S%%, N%%, 0, 1), Positions!(S%%, N%%, 1, 1), Phi!(N%%))
40.             'CALL Angle(Positions!(S%%, 0, 0, 2), Positions!(S%%, 0, 1, 2), Positions!(S%%, N%%, 0, 2), Positions!(S%%, N%%, 1, 2), Phi!(N%%))
41.             'CALL Angle(Positions!(S%%, 0, 0, 3), Positions!(S%%, 0, 1, 3), Positions!(S%%, N%%, 0, 3), Positions!(S%%, N%%, 1, 3), Phi!(N%%))
42.  
43.             Positions!(S%%, N%%, 0, 0) = CINT(Positions!(S%%, 0, 0, 0) * COS(Phi!(N%%)) - Positions!(S%%, 0, 1, 0) * SIN(Phi!(N%%)))
44.             Positions!(S%%, N%%, 1, 0) = CINT(Positions!(S%%, 0, 0, 0) * SIN(Phi!(N%%)) + Positions!(S%%, 0, 1, 0) * COS(Phi!(N%%)))
45.             Positions!(S%%, N%%, 0, 1) = CINT(Positions!(S%%, 0, 0, 1) * COS(Phi!(N%%)) - Positions!(S%%, 0, 1, 1) * SIN(Phi!(N%%)))
46.             Positions!(S%%, N%%, 1, 1) = CINT(Positions!(S%%, 0, 0, 1) * SIN(Phi!(N%%)) + Positions!(S%%, 0, 1, 1) * COS(Phi!(N%%)))
47.             Positions!(S%%, N%%, 0, 2) = CINT(Positions!(S%%, 0, 0, 2) * COS(Phi!(N%%)) - Positions!(S%%, 0, 1, 2) * SIN(Phi!(N%%)))
48.             Positions!(S%%, N%%, 1, 2) = CINT(Positions!(S%%, 0, 0, 2) * SIN(Phi!(N%%)) + Positions!(S%%, 0, 1, 2) * COS(Phi!(N%%)))
49.             Positions!(S%%, N%%, 0, 3) = CINT(Positions!(S%%, 0, 0, 3) * COS(Phi!(N%%)) - Positions!(S%%, 0, 1, 3) * SIN(Phi!(N%%)))
50.             Positions!(S%%, N%%, 1, 3) = CINT(Positions!(S%%, 0, 0, 3) * SIN(Phi!(N%%)) + Positions!(S%%, 0, 1, 3) * COS(Phi!(N%%)))
51.             Positions!(S%%, N%%, 0, 4) = CINT(Positions!(S%%, 0, 0, 4) * COS(Phi!(N%%)) - Positions!(S%%, 0, 1, 4) * SIN(Phi!(N%%)))
52.             Positions!(S%%, N%%, 1, 4) = CINT(Positions!(S%%, 0, 0, 4) * SIN(Phi!(N%%)) + Positions!(S%%, 0, 1, 4) * COS(Phi!(N%%)))
53.  
54.         NEXT N%%
55.     NEXT S%%
56.     FOR S%% = 0 TO 4
57.         Positions!(S%%, 12, 0, 0) = Tucked%% * (3 - S%%) - Halfwidth%%
58.         Positions!(S%%, 12, 1, 0) = Halfheight%%
59.         Positions!(S%%, 12, 0, 1) = Positions!(S%%, 12, 0, 0) + 2 * Halfwidth%%
60.         Positions!(S%%, 12, 1, 1) = Halfheight%%
61.         Positions!(S%%, 12, 0, 2) = Tucked%% * (3 - S%%) - Halfwidth%%
62.         Positions!(S%%, 12, 1, 2) = -Halfheight%%
63.         Positions!(S%%, 12, 0, 3) = Positions!(S%%, 12, 0, 2) + 2 * Halfwidth%%
64.         Positions!(S%%, 12, 1, 3) = -Halfheight%%
65.         Positions!(S%%, 12, 0, 4) = Tucked%% * (3 - S%%)
66.         Positions!(S%%, 12, 1, 4) = 0
67.     NEXT S%%
68. END SUB
69.  
70. SUB Angle (Xin%, Yin%, Xout%, Yout%, Theta!)
71.     Xout% = CINT(Xin% * COS(Theta!) - Yin% * SIN(Theta!))
72.     Yout% = CINT(Xin% * SIN(Theta!) + Yin% * COS(Theta!))
73. END SUB
74.  
75.  

[FellippeHeitor]

Angle() expects integers and your array is of type single. Values enter the SUB but can’t be altered if types don’t match.

[Qwerkey]

Ah, I thought that integers and singles could swap freely (the single gets "integerised" in the process).  So it was incompetence, after all.

[Pete]

How did you miss it on try 3? That was supposed to be the "charm."

I'm just happy a shared array can be re-dimensioned in a sub when I need that done. What I've been caught on a couple of times is incorrect variable results because I'll declare a variable as an integer and expand my project to the point some functions surpass the limits of the integer declaration.

Well I see lots of numbers but even with the angle call corrected, I have no idea what this data will be used for. I'll guess a clock. Am I close?

Pete

[Qwerkey]

Well I see lots of numbers but even with the angle call corrected, I have no idea what this data will be used for. I'll guess a clock. Am I close?

Pete

Pete, the code I gave was just a demo of the problem I had.  In fact the original difficulty occurred in my Clock Patience program, so yes you were close.  I'm looking forward to that day when I actually know what I'm doing with this marvellous resource which is QB64.