CLOCK.BAS

[Colonel_Panic]

CLOCK.BAS
---------------

my first program post on QB64... CLOCK.BAS

its, well... its yet another CLOCK program.
I wanted to "learn graphics" as I have always been a "business programmer".

NOTE:  I cut and pasted example HELP code, because the DRAW command impressed me with the TA thing.
           then I wasn't happy until I did "ghetto 360 degrees" fake-LED rotating numbers

apologies for the 'code style' which is "did not know I would eventually post it"

PS: screenshot... http://i.imgur.com/EkNLjfN.png

Code: QB64: [Select]

1. maxx = 420
2. maxy = 420
3. x = INT(maxx / 2)
4. y = INT(maxy / 2)
5. SCREEN _NEWIMAGE(maxx, maxy, 32)
6. _title "Clock"
7. _DISPLAY
8. GOSUB draw_clock:
9.  
10. again:
11. 'LOCATE 1, 1: PRINT "hours:";: LINE INPUT hour$: hour = VAL(hour$)
12. 'LOCATE 1, 1: PRINT STRING$(64, " ")
13. 'LOCATE 1, 1: PRINT "minutes:";: LINE INPUT minute$: minute = VAL(minute$)
14.  
15. CLS
16. z$ = TIME$
17. GOSUB draw_digital: ': PRINT z$
18. hour = VAL(LEFT$(z$, 2))
19. IF hour > 12 THEN hour = hour - 12
20. minute = VAL(MID$(z$, 4, 2))
21. second = VAL(MID$(z$, 7, 2))
22. 'IF second = 0 THEN _SCREENCLICK _SCREENX, _SCREENY
23. GOSUB draw_clock:
24. GOSUB draw_hands:
25. _DISPLAY
26. loop1:
27. IF TIME$ <> z$ THEN GOTO again: ELSE GOTO loop1:
28.  
29.  
30. 'draw hands
31. draw_hands:
32. DRAW "TA0"
33. 'hour hand (thicker little hand)
34. 'IF hour = 0 THEN SYSTEM
35. PSET (x, y), colr&
36. DRAW "TA " + STR$((-30 * hour) + INT(minute / -2))
37. DRAW "U15L1D15R2U15L1 L7U100R14D100L7 L6U99R12D98L12"
38.  
39. 'minute hand (thinner big hand)
40. DRAW "TA0"
41. PSET (x, y), colr&
42. DRAW "TA " + STR$(-6 * minute)
43. DRAW "U20L1D20R2U20L1 L5U120R10D120L5 L6U121R12D120L12"
44.  
45. 'second hand
46. DRAW "TA0"
47. PSET (x, y), colr&
48. DRAW "TA " + STR$(-6 * second)
49. DRAW "U145L1D145R2U145"
50. 'try rotating seconds display
51. DRAW "TA0"
52. PSET (x, y), _RGB32(255, 0, 0) 'colr&
53. DRAW "TA " + STR$(-6 * second)
54. DRAW "bU183 bL15bU10"
55. zecs$ = RIGHT$(STR$(100 + second), 2)
56. zecs$ = LTRIM$(zecs$)
57. zecs$ = RTRIM$(zecs$)
58. ch$ = LEFT$(zecs$, 1): GOSUB draw_digit:
59. DRAW "TA0"
60. PSET (x, y), _RGB32(255, 0, 0) 'colr&
61. DRAW "TA " + STR$(-6 * second)
62. DRAW "bU183 bR5bU10"
63. ch$ = RIGHT$(zecs$, 1): GOSUB draw_digit
64.  
65. RETURN
66.  
67. draw_clock:
68. 'colr& = _RGB32(128, 128, 128)
69. colr& = _RGB32(95, 95, 95)
70. FOR csize = 150 TO 152
71.   CIRCLE (x, y), csize, colr&
72. NEXT csize
73. FOR csize = 158 TO 160
74.   CIRCLE (x, y), csize, colr&
75. NEXT csize
76. FOR csize = 197 TO 202
77.   CIRCLE (x, y), csize, colr&
78. NEXT csize
79. CIRCLE (x, y), 7, colr&
80. PAINT (x, y), colr&
81. 'DRAW "U10D20U10R10L20"
82. colr& = _RGB32(128, 128, 55)
83. FOR Ang = 0 TO 360 STEP 6
84.   PSET (x, y), colr&
85.   DRAW "TA " + STR$(Ang) + "BU150" + "U10L1D10R2U10"
86. NEXT Ang
87.  
88. colr& = _RGB32(128, 188, 61)
89. FOR Ang = 0 TO 360 STEP 30
90.   PSET (x, y), colr&
91.   DRAW "TA " + STR$(Ang) + "BU150" + "U20L1D20R2U20L1" + "BU15"
92.   FOR csize = 4 TO 5
93.     CIRCLE STEP(0, 0), csize, colr&
94.   NEXT csize
95. NEXT Ang
96.  
97. FOR csize = 1 TO 3
98.   CIRCLE (x, y), csize, _RGB32(0, 0, 0)
99. NEXT csize
100. 'face numbers
101. COLOR _RGB32(6, 255, 255)
102. _PRINTSTRING (x - 8, y - 140), "12"
103. _PRINTSTRING (x + 62, y - 122), "1"
104. _PRINTSTRING (x + 62, y + 106), "5"
105. _PRINTSTRING (x - 70, y + 106), "7"
106. _PRINTSTRING (x - 74, y - 122), "11"
107. _PRINTSTRING (x + 112, y - 71), "2"
108. _PRINTSTRING (x + 112, y + 62), "4"
109. _PRINTSTRING (x - 120, y + 62), "8"
110. _PRINTSTRING (x - 120, y - 71), "10"
111. _PRINTSTRING (x - 4, y + 130), "6"
112. _PRINTSTRING (x + 130, y - 8), "3"
113. _PRINTSTRING (x - 138, y - 8), "9"
114.  
115. RETURN
116.  
117.  
118. draw_digital:
119. PSET (0, 0), _RGB32(255, 0, 0)
120. DRAW "BR10BD10"
121. ch$ = LEFT$(z$, 1): GOSUB draw_digit:
122. PSET (0, 0), _RGB32(255, 0, 0)
123. DRAW "BR30BD10"
124. ch$ = MID$(z$, 2, 1): GOSUB draw_digit:
125. PSET (0, 0), _RGB32(255, 0, 0)
126. DRAW "BR50BD10"
127. ch$ = MID$(z$, 4, 1): GOSUB draw_digit:
128. PSET (0, 0), _RGB32(255, 0, 0)
129. DRAW "BR70BD10"
130. ch$ = MID$(z$, 5, 1): GOSUB draw_digit:
131. PSET (0, 0), _RGB32(255, 0, 0)
132. DRAW "BR340BD10"
133. ch$ = MID$(z$, 7, 1): GOSUB draw_digit:
134. PSET (0, 0), _RGB32(255, 0, 0)
135. DRAW "BR360BD10"
136. ch$ = RIGHT$(z$, 1): GOSUB draw_digit:
137.  
138.  
139. RETURN
140.  
141. draw_digit:
142. IF ch$ = "0" THEN DRAW "R10D10D10L10U10U10"
143. IF ch$ = "1" THEN DRAW "BR10D10D10"
144. IF ch$ = "2" THEN DRAW "R10D10L10D10R10"
145. IF ch$ = "3" THEN DRAW "R10D10L10R10D10L10"
146. IF ch$ = "4" THEN DRAW "D10R10U10D10D10"
147. IF ch$ = "5" THEN DRAW "R10L10D10R10D10L10"
148. IF ch$ = "6" THEN DRAW "R10L10D10D10R10U10L10"
149. IF ch$ = "7" THEN DRAW "R10D10D10"
150. IF ch$ = "8" THEN DRAW "R10D10L10U10D10D10R10U10"
151. IF ch$ = "9" THEN DRAW "R10D10L10U10R10D20L10"
152. RETURN
153.  
154.  
155.  

[Colonel_Panic]

I'm kind of 'anal' sometimes, and will over-do-it...

here, I wasn't happy until:

1) hour hand and minute hand was *not* going to satisfy me, I had to have a seconds hand
2) color? once i hit the "color picking" phase... I was going for one of those "old BIG BEN luminescent, real radium, old-timey clocks"
3) I had to get the mathematical angles of the hour hand "creeping" correct. (six degrees per minute, BTW)
4) Once i saw example DRAW stuff? and the TA thing? "rotating seconds LED"

PS - in screenshot? you can see, I can run as many CLOCKs as I like; I was always wanting to make one of those
"17 clocks like important businessmen in movies always have kind of clocks", with each clock in a 1-hour different time zone...

...you know, random city and countries printed on them? LMAO...

[bplus]

Hey I like what you did with the seconds, nice looking clock!

[Colonel_Panic]

thanks guy.

PS - I always *did* wonder:

"now, WHY does the NAME come up on all but one of the CLOCKs I bring up, eh?"

then? one day? HELP manual, found on accident that's because I am not
"loop waiting until" the window is formed and reported back.
(I just learned in HELP to DO that a few days ago, only reason i know about it now)
if memory serves without checking, maybe it was the _SCREENEXISTS COMMAND?

[johnno56]

Such a cool looking clock! Nicely done!

[Petr]

Nice work, welcome to the forum, Colonel_Panic!

[euklides]

Very nice clock !

[Richard Frost]

Ran yours - always nice to see unique clocks.  Since you mentioned the airport type:
 

Code: QB64: [Select]

1. _Title " World Clock"
2. $Color:32
3. Dim p$(30), zo(30), t$(30) '                     place, zone, time
4. Screen _NewImage(800, 600, 32)
5. _ScreenMove (_DesktopWidth - _Width) \ 2, 20
6. For i = 1 To 30: Read p$(i), zo(i): Next i
7. d = 35 '                                         diameter of clocks
8. Do
9.     Cls: t$ = Time$
10.     h = (Val(Mid$(t$, 1, 2)) + 7) Mod 24 '       GMT = my time + 7
11.     m = Val(Mid$(t$, 4, 2))
12.     For i = 1 To 30 '                            actual time for each place
13.         th = h + Int(zo(i))
14.         z! = Abs(zo(i)) - Abs(Int(zo(i)))
15.         tm = m + z! * 60 * Sgn(zo(i))
16.         If tm < Val("00") Then tm = tm + 60: th = th - 1
17.         If tm > Val("59") Then tm = tm - 60: th = th + 1
18.         th = (th + 24) Mod 24
19.         th$ = Right$("0" + LTrim$(Str$(th)), 2)
20.         tm$ = Right$("0" + LTrim$(Str$(tm)), 2)
21.         t$(i) = th$ + tm$
22.     Next i
23.     p = 0 '                                      place index
24.     For yi = 0 To 4
25.         For xi = 0 To 5
26.             xc = xi * _Width \ 6 + (_Width \ 6) * .5
27.             yc = yi * _Height / 5.4 + 60
28.             p = p + 1 '                          place index
29.             _PrintString (xc - _PrintWidth(p$(p)) \ 2, yc + d + 4), p$(p)
30.             Circle (xc, yc), d + 2, Green
31.             If Val(Left$(t$(p), 2)) < 12 Then Paint (xc, yc), Green, Green ' am/pm
32.             For a = 0 To 330 Step 30 '           clock tick marks
33.                 x1 = xc + (d - 3) * Cos(_D2R(a))
34.                 y1 = yc + (d - 3) * Sin(_D2R(a))
35.                 Circle (x1, y1), 1, White '      ticks
36.             Next a
37.             th = Val(Mid$(t$(p), 1, 2)) '        hour
38.             tm = Val(Mid$(t$(p), 3, 2)) '        minute
39.             ra = _D2R(tm * 6 - 90) '             minute hand
40.             x(0) = xc + (d - 8) * Cos(ra)
41.             y(0) = yc + (d - 8) * Sin(ra)
42.             ra = _D2R((th + tm / 60) * 30 - 90) 'hour hand
43.             x(1) = xc + (d - 16) * Cos(ra)
44.             y(1) = yc + (d - 16) * Sin(ra)
45.             For zz = 0 To 1 '                    draw hands
46.                 For zx = -1 To 1
47.                     For zy = -1 To 1
48.                         Line (xc + zx, yc + zy)-(x(zz), y(zz)), White
49.                     Next zy
50.                 Next zx
51.             Next zz
52.         Next xi
53.     Next yi
54.     Do: _Limit 10 '                              wait for new minute
55.         x = 20 + Val(Right$(Time$, 2)) / 60 * (_Width - 40)
56.         Line (20, _Height - 20)-(x, _Height - 21), Green, B
57.         _Display
58.         If Len(InKey$) Then System '             any key exits
59.     Loop Until Left$(t$, 5) <> Left$(Time$, 5)
60. Loop
61.  
62. Data Amsterdam,1
63. Data Beijing,8
64. Data Berlin,1
65. Data Brasilia,-3
66. Data Cairo,2
67. Data Chicago,-6
68. Data Delhi,5.5
69. Data Denver,-7
70. Data Detroit,-5
71. Data Edmonton,-7
72. Data Gander,-3.5
73. Data Hawaii,-10
74. Data Hong Kong,8
75. Data Houston,-6
76. Data Istanbul,2
77. Data London,0
78. Data Los Angeles,-9
79. Data Madrid,1
80. Data Mexico City,-6
81. Data Moscow,3
82. Data New York,-5
83. Data Paris,1
84. Data Perth,8
85. Data Phoenix,-8
86. Data Rome,1
87. Data Seoul,9
88. Data Singapore,8
89. Data Sydney,10
90. Data Tehran,3.5
91. Data Tokyo,9
92.  

[Dav]

Nice look clock, @Colonel_Panic!  And welcome to the forum. 

Nice looking clocks too, @Richard Frost.

- Dav

[TempodiBasic]

Hi boys and girls
Welcome to Colonel_Panic

This is a pleasure that you coder of QB64 have done something with my half name

here your screenshot
 

Waiting other your applications...

[Colonel_Panic]

to everyone: thanks for the warm welcome.
@frost: YES... you have the "airport clocks".

very attractive "airport clocks".

[bplus]

@Colonel_Panic My clock says it Christmas what are you doing here ;-))

[Colonel_Panic]

@Colonel_Panic My clock says it Christmas what are you doing here ;-))

Its Christmas, I can do ANYTHING I WANT to do, right?

---I dont really "drink" drink...
---and I use my laptop the way most people use their PHONES, so...
---I dont want to go date some tinder roastie anyways

what more fun could i be having? I cant picture it.

[bplus]

Ya! Merry Christmas!