Who wants duplicate my experience with COMMON SHARED?

[TempodiBasic]

Hi QB64 community
Hi QB64 friends

I have tried to build up a little program that runs another that runs another... and all these little programs have a COMMON SHARED area to exchange  some values....

Well, nothing to do is my result!

To get the same experience
1. copy these 3 codes, compile without running (F11)
2. open the folder of .EXE and run the first file...
3. don't hurt yourself! Quickly close all those windows that are popping up!

file1: Save this file as  multipleinstances 1.BAS

Code: QB64: [Select]

1. Common Shared iOne
2. Print " Hi ", iOne
3. Sleep 2
4.  
5. If iOne = 0 Then
6.     iOne = 1
7.     _Title " First"
8. End If
9. Print "Now ione = "; iOne
10.  
11. Sleep 1
12. If iOne < 2 Then Shell _DontWait "multipleinstances 2.exe" Else Print "Goodbye"
13. End
14.  

file2: Save this file as multipleinstances 2.BAS

Code: QB64: [Select]

1. Common Shared iOne
2. Print " Hi ", iOne
3. Sleep 2
4.  
5. If iOne = 1 Then
6.     iOne = iOne + 1
7.     _Title "Second "
8. End If
9.  
10. Print "Now iOne = "; iOne
11. Sleep 1
12. If iOne < 2 Then Shell _DontWait "multipleinstances 3.exe" Else Print "Goodbye"
13. End

file3:Save  this file as multipleinstances 3.BAS

Code: QB64: [Select]

1. Common Shared iOne
2. Print " Hi ", iOne
3. Sleep 2
4.  
5. If iOne = 2 Then
6.     iOne = iOne + 1
7.     _Title " Third"
8. End If
9. Print "Now iOne is "; iOne
10.  
11. Sleep 1
12. If iOne < 2 Then Shell _DontWait "multipleinstances 3.exe" Else Print "Goodbye"
13. End
14.  

Waiting your suggestions. Thanks

[George McGinn]

I have an old program that was written in QB45 that uses COMMON SHARED and works fine.

(I would post the code, but it's just under 3,000 lines).

Here is the code I use with great success:

Code: QB64: [Select]

1. '*****************************************
2. '   DEFINE GLOBAL VARIABLES
3. '*****************************************
4. COMMON SHARED Number, RedBlack, OddEven, HighLow, Column, Dozen, BankRoll
5. COMMON SHARED Bets, Table, PayoffAmount, BetAmount, BetType$, LineOut$
6. COMMON SHARED NumberOfBets, BetNumber%, GoodBet, NumOut$, TypOut$
7. COMMON SHARED windowTop!, windowBottom!, windowLeft!, windowRight!, FColor%, BColor%, WLBL$
8. COMMON SHARED errWTop!, errWBottom!, errWLeft!, errWRight!, errWFClr%, errWBClr%
9. COMMON SHARED errWLBL$, errTClr%, NOERRORS, GreenBack%, BlackBack%, RedBack%
10. COMMON SHARED RowPointer%, ForeGroundColor%, BackGroundColor%
11. COMMON SHARED Amount$, FileName$, SplitOut$, HeadingColor%
12. COMMON SHARED IntroFColor1%, IntroFColor2%, IntroFColor3%, IntroFColor4%, IntroFColor5%
13. COMMON SHARED IntroBColor1$, IntroBColor2%
14. COMMON SHARED TableMinimum, TableMaximum, TotalInsideBets, TotalOutsideBets

[Cobalt]

Hi QB64 community
Hi QB64 friends

I have tried to build up a little program that runs another that runs another... and all these little programs have a COMMON SHARED area to exchange  some values....

Well, nothing to do is my result!

To get the same experience
1. copy these 3 codes, compile without running (F11)
2. open the folder of .EXE and run the first file...
3. don't hurt yourself! Quickly close all those windows that are popping up!

COMMON SHARED was used to keep variables across MODULEs. As QB64 does not support MODULEs anymore its not going to work how your thinking it should, if you need to keep variable value between programs you will have to PUT and GET them to and  from a file in between programs

[bplus]

Common Shared will work with arrays and variables in Include files.

[RhoSigma]

Just from looking at the code (didn't test it), I would say the problem is that Tempodi is SHELLing out the other instances, which executes every instance in its own context.

As far as I know COMMON SHARED does only pass the variables when CHAINing from one to the other module, or maybe RUNing too, but definitly not SHELLing.

EDIT:
Nope, as per the Wiki, only CHAIN will pass COMMON SHARED variables.

[TempodiBasic]

Hi QB64 community!
I love you!

Thanks for useful feedbacks!
thanks to:
@bplus  and @George McGinn  your informations have been useful to fix the search in my bad code.
@Cobalt  your workaround is good as true as SSD are faster then HDD of the past!
@RhoSigma  you have lighted me why my code is wrong, Yes I use SHELL _DONTWAIT and not CHAIN...

nevertheless I got my code running, but I got not 3 windows but one DOS window in which the output of the 3 different programs comes out!
So CHAIN is a good DOS emulator command and each module has been taken off of memory in the moment that the new module has been loaded into memory! .... No TSR program!

[SpriggsySpriggs]

@TempodiBasic

Don't forget; you can also use my new shared memory library in Windows!

Parent:

Code: QB64: [Select]

1. Option _Explicit
2.  
3. Dim As _MEM pShare 'You need to use a _MEM block
4. Dim As Long longtoShare: longtoShare = 500 'declaring a long variable to store in the _MEM block
5. pShare = _Mem(longtoShare) 'storing the long variable in the _MEM block
6.  
7. Print CommonShared("MySharedMem", pShare) 'initializing the shared memory object
8. _MemFree pShare
9.  
10. '$INCLUDE:'Win32 SharedMem.bas'

Child:

Code: QB64: [Select]

1. Option _Explicit
2.  
3. Dim As _MEM newMem: newMem = _MemNew(4) 'declaring the destination _MEM block
4.  
5. Print ReadShared("MySharedMem", newMem) 'reading the shared memory object into the new _MEM block
6.  
7. Dim As Long dest 'declaring a destination long variable
8. _MemGet newMem, newMem.OFFSET, dest 'storing the contents of the _MEM block into a new long variable
9. Print dest
10. _MemFree newMem
11.  
12. '$INCLUDE:'Win32 SharedMem.bas'

Full $INCLUDE, save as Win32 SharedMem.bas

Code: QB64: [Select]

1. Declare CustomType Library
2.     Function CreateFileMapping%& Alias "CreateFileMappingA" (ByVal hFile As _Offset, Byval lpFileMappingAttributes As _Offset, Byval flProtect As Long, Byval dwMaximumSizeHigh As Long, Byval dwMaximumSizeLow As Long, lpName As String)
3.     Function OpenFileMapping%& Alias "OpenFileMappingA" (ByVal dwDesiredAccess As Long, Byval bInheritHabndle As Long, lpName As String)
4.     Function MapViewOfFile%& (ByVal hFileMappingObject As _Offset, Byval dwDesiredAccess As Long, Byval dwFileOffsetHigh As Long, Byval dwFileOffsetLow As Long, Byval dwNumberOfBytesToMap As _Offset)
5.     Sub UnmapViewOfFile (ByVal lpBaseAddress As _Offset)
6.     Function GetLastError& ()
7.     Sub CloseHandle (ByVal hObject As _Offset)
8. End Declare
9.  
10. Function CommonShared%% (sharedName As String, pShared As _MEM)
11.     Const INVALID_HANDLE_VALUE = -1
12.     Const PAGE_READWRITE = &H04
13.     Const FILE_MAP_ALL_ACCESS = &HF001F
14.     Declare Dynamic Library "Kernel32"
15.         Sub CopyMemory Alias "RtlCopyMemory" (ByVal Destination As _Offset, Byval Source As _Offset, Byval Length As _Offset)
16.     End Declare
17.     Dim As _Offset hMapFile, pBuf
18.     Dim As Long sharedSize: sharedSize = Val(Str$(pShared.SIZE))
19.     hMapFile = CreateFileMapping(INVALID_HANDLE_VALUE, 0, PAGE_READWRITE, 0, sharedSize, sharedName)
20.     If hMapFile = 0 Then
21.         CommonShared = 0
22.         Exit Function
23.     End If
24.     pBuf = MapViewOfFile(hMapFile, FILE_MAP_ALL_ACCESS, 0, 0, sharedSize)
25.     If pBuf = 0 Then
26.         CloseHandle hMapFile
27.         CommonShared = 0
28.         Exit Function
29.     End If
30.     CopyMemory pBuf, pShared.OFFSET, sharedSize
31.     CommonShared = -1
32.     EndShare hMapFile, pBuf
33. End Function
34.  
35. Function ReadShared%% (sharedName As String, destVar As _MEM)
36.     Const FILE_MAP_ALL_ACCESS = &HF001F
37.     Dim As _Offset hMapFile, pBuf
38.     Dim As Long sharedSize: sharedSize = Val(Str$(destVar.SIZE))
39.     hMapFile = OpenFileMapping(FILE_MAP_ALL_ACCESS, 0, sharedName)
40.     If hMapFile = 0 Then
41.         ReadShared = 0
42.         Exit Function
43.     End If
44.     pBuf = MapViewOfFile(hMapFile, FILE_MAP_ALL_ACCESS, 0, 0, sharedSize)
45.     If pBuf = 0 Then
46.         ReadShared = 0
47.         Exit Function
48.     End If
49.     destVar = _Mem(pBuf, sharedSize)
50.     ReadShared = -1
51.     EndShare hMapFile, pBuf
52. End Function
53.  
54. Sub EndShare (hMap As _Offset, pMapBuf As _Offset)
55.     UnmapViewOfFile hMap
56.     CloseHandle pMapBuf
57. End Sub

[TempodiBasic]

@SpriggsySpriggs
Interesting workaround that can make working sharing variable by RAM between 2 SHELL programs

Sure it must manage manually the exchanges between 2 programs but it CAN DO IT!
I'll try ,as I get some time to spend for project, to build 2 different programs that talks between them.

Thanks

[TempodiBasic]

Here a first step using the workaroung of Spriggsy
Parent version (programA) in which pressing Enter you decide the new long value to pass to child (programB)

Code: QB64: [Select]

1.  Option _Explicit
2. Const space = 32, enter = 13
3. Dim K$, NamVar$
4. Dim As _MEM pShare 'You need to use a _MEM block
5. Dim As Long longtoShare, CountLong: longtoShare = 500 'declaring a long variable to store in the _MEM block
6. pShare = _Mem(longtoShare) 'storing the long variable in the _MEM block
7. Print CommonShared("MySharedMem", pShare) 'initializing the shared memory object
8.  
9. 'my mod
10. Locate 1, 1: Print "Press space to quit program"
11. View Print 3 To 24
12. While 1
13.     K$ = InKey$
14.     If K$ = Chr$(space) Then Exit While
15.     If K$ = Chr$(enter) Then
16.         Input "please enter new value:", longtoShare
17.         CountLong = CountLong + 1
18.         pShare = _Mem(longtoShare) 'storing the long variable in the _MEM block
19.         NamVar$ = Str$(CountLong)
20.         Print CommonShared(NamVar$, pShare), longtoShare 'initializing the shared memory object
21.     End If
22. Wend
23. _MemFree pShare
24.  
25. '$INCLUDE:'Win32 SharedMem.bas'
26.  

Child version (programB) in which you red the new value passed by Parent (programA)

Code: QB64: [Select]

1. Option _Explicit
2. Const space = 32, enter = 13
3.  
4. Dim K$, NamVar$
5. ReDim As _MEM newMem: newMem = _MemNew(4) 'declaring the destination _MEM block
6.  
7. Print ReadShared("MySharedMem", newMem) 'reading the shared memory object into the new _MEM block
8. Dim As Long dest, countRead 'declaring a destination long variable
9. _MemGet newMem, newMem.OFFSET, dest 'storing the contents of the _MEM block into a new long variable
10. Print dest
11.  
12.  
13. While 1
14.     K$ = InKey$
15.     If K$ = Chr$(space) Then Exit While
16.     If K$ = Chr$(enter) Then
17.         newMem = _MemNew(4)
18.         countRead = countRead + 1
19.         NamVar$ = Str$(countRead)
20.         Print ReadShared(NamVar$, newMem) 'reading the shared memory object into the new _MEM block
21.         _MemGet newMem, newMem.OFFSET, dest 'storing the contents of the _MEM block into a new long variable
22.         Print dest
23.     End If
24. Wend
25. _MemFree newMem
26.  
27. '$INCLUDE:'Win32 SharedMem.bas'
28.  

The 2 kind of operations can be used for talking between 2 programs stay resident like in this example using SHELL _DONTWAIT.

Waiting feedbacks, Thanks to read and try