Earth-browser in maptriangle

[bplus]

Just out of curiosity, why can't standard mouse detection work for this program?

Ah maybe I should say "standard QB64 mouse detection". ;-))

[MasterGy]

to this day i write in qb 1.3 because it makes exe faster. _MOUSEMOVEMENT still works fine here, but not in later versions. _Mousemoment detects when you leave the screen, but _MOUSEX does not. this can be confusing. I'm about to rewrite the source code to use _MOUSEX instead of _MOUSEMOVEMENTX. Or: start in 1.3

[Petr]

@bplus wrote:

Just out of curiosity, why can't standard mouse detection work for this program?

Because _MOUSEMOVEMENT is far more convenient for the OpenGL coordinate system that uses _MAPTRIANGLE 3D. This does not mean that it cannot be written with _MOUSEX and _MOUSEY, but simply the _MOUSEMOVEMENT solution takes into account the OpenGL coordinate system.

[MasterGy]

the two things have nothing to do with each other

[MasterGy]

in principle, this will work for everyone

Code: QB64: [Select]

1. ' settings ---------------------------------
2.  
3. map_pic_c = 8 'how many maps available ?
4. map_pic$(0) = "need/physical-world-map.jpg": mp_t$(0) = "earth"
5. map_pic$(1) = "need/outline-world-map.jpg": mp_t$(1) = "earth"
6. map_pic$(2) = "need/map_hd.bmp": mp_t$(2) = "earth"
7. map_pic$(3) = "need/geological-world-map.jpg": mp_t$(3) = "earth"
8. map_pic$(4) = "need/continental-world-map.jpg": mp_t$(4) = "earth"
9. map_pic$(5) = "need/moon_map_mercator.jpg": mp_t$(5) = "moon"
10. map_pic$(6) = "need/mars_map.jpg": mp_t$(6) = "mars"
11. map_pic$(7) = "need/squares.bmp": mp_t$(7) = ""
12.  
13. da = 70 'resolution 360/da degree horisontal
14. db = 70 'resolution 360/db degree vertical
15.  
16. zoom_xy = 100
17. zoom_distance = 50
18. stepping = .08
19. monx = _DESKTOPWIDTH
20. mony = _DESKTOPHEIGHT
21. msenx = .05
22. msenz = .05
23. max_couch = 70
24.  
25. 'pre ---------------------------------------
26. fnt = _LOADFONT("need/cyberbit.ttf", monx / 50)
27. pip180 = _PI / 180: points = da * db: sqs = points
28. DIM points(points - 1, 9), sq(sqs - 1, 7, map_pic_c - 1), cam(9), me(19)
29. FOR t = 0 TO map_pic_c - 1: wmap(t) = _LOADIMAGE(map_pic$(t), 33): NEXT t
30.  
31. 'creating 3d points
32. FOR da2 = 0 TO da - 1: dega = 360 / (da - 1) * da2 * pip180: FOR db2 = 0 TO db - 1: degb = 180 / (db - 1) * db2 * pip180
33. ap = da2 * db + db2: points(ap, 0) = SIN(degb) * COS(dega): points(ap, 1) = SIN(degb) * SIN(dega): points(ap, 2) = COS(degb): NEXT db2, da2
34.  
35. 'creating squares
36. FOR map = 0 TO map_pic_c - 1: FOR da2 = 0 TO da - 2: FOR db2 = 0 TO db - 2: sqa = da2 * db + db2 'actual square
37.             sq(sqa, 0, map) = sqa: sq(sqa, 1, map) = sq(sqa, 0, map) + 1: sq(sqa, 2, map) = sq(sqa, 0, map) + db: sq(sqa, 3, map) = sq(sqa, 2, map) + 1 '3d points ser
38.             sq(sqa, 4, map) = _WIDTH(wmap(map)) - (_WIDTH(wmap(map)) / (da - 1) * da2) - 1
39.             sq(sqa, 5, map) = _WIDTH(wmap(map)) - (_WIDTH(wmap(map)) / (da - 1) * (da2 + 1)) - 1
40.             sq(sqa, 6, map) = INT(_HEIGHT(wmap(map)) / (db - 1) * db2): sq(sqa, 7, map) = INT(_HEIGHT(wmap(map)) / (db - 1) * (db2 + 1))
41. NEXT db2, da2, map
42.  
43. mon = _NEWIMAGE(monx, mony, 32): SCREEN mon: _DISPLAYORDER _HARDWARE , _SOFTWARE: _FULLSCREEN _SQUAREPIXELS , _SMOOTH: _MOUSEHIDE: _FONT fnt
44. me(0) = -1.31: me(1) = .575: me(2) = 1.5: me(10) = 1.94: me(11) = 2.05 'start position
45.  
46. 'boss cycle -----------------------------------------------
47. DO: _LIMIT 30
48.  
49.     IF INKEY$ = " " THEN act_map = act_map + 1: IF act_map > map_pic_c - 1 THEN act_map = 0
50.  
51.     'control
52.     kw = _KEYDOWN(119) OR _MOUSEBUTTON(1): ks = _KEYDOWN(115) OR _MOUSEBUTTON(2): ka = _KEYDOWN(97): kd = _KEYDOWN(100): et_ir = (ABS(ka OR kd OR kw) OR -ABS(ks))
53.     ir = 0: IF inv_me10 = -1 THEN SWAP ka, kd
54.     FOR elt1 = 0 TO max_couch STEP 2: FOR elt2 = 0 TO 360 STEP 12: IF ir = 0 THEN
55.                 elt_xy = SIN(elt2 * pip180) * elt1: elt_z = COS(elt2 * pip180) * elt1
56.                 szog_xy_elt = -90 * ABS(ka) + 90 * ABS(kd): szog_xy = me(10) + (szog_xy_elt + elt_xy) * pip180: szog_z = me(11) + pip180 * (90 + elt_z)
57.                 irx = -SIN(szog_xy) * COS(szog_z): iry = -COS(szog_xy) * COS(szog_z): irz = SIN(szog_z): ir = et_ir: multi = stepping * ir * pre_calc * 2
58.                 multi = stepping * ir / max_couch * (max_couch - elt1): me(0) = me(0) + irx * multi: me(1) = me(1) + iry * multi
59.     me(2) = me(2) + irz * multi: END IF: NEXT elt2, elt1
60.     'mousex = 0: mousey = 0
61.     WHILE _MOUSEINPUT: WEND
62.     me(11) = me(11) + mousey / 7 * msenz
63.     mousex = _MOUSEX - mousex_last
64.     mousey = _MOUSEY - mousey_last
65.     mousex_last = _MOUSEX: mousey_last = _MOUSEY
66.  
67.     me(11) = me(11) - 2 * _PI * ABS(me(11) > 2 * _PI): me(11) = me(11) + 2 * _PI * ABS(me(11) < 0): inv_me10 = 1: IF me(11) < _PI THEN inv_me10 = -1
68.     me(10) = me(10) + mousex / 5 * msenx * inv_me10
69.  
70.     'calculating points
71.     cam(0) = me(0) - SIN(me(10) - 180 * pip180) * me(3) / 2: cam(1) = me(1) - COS(me(10) - 180 * pip180) * me(3) / 2
72.     cam(2) = me(2) + me(5) / 4: cam(3) = me(10): cam(4) = me(11): cosrotz = COS(cam(3)): sinrotz = SIN(cam(3)): cosrotx = COS(cam(4)): sinrotx = SIN(cam(4))
73.     FOR actual_point = 0 TO points - 1
74.         px = points(actual_point, 0) - cam(0): py = points(actual_point, 1) - cam(1): pz2 = points(actual_point, 2) - cam(2)
75.         px3 = px * cosrotz - py * sinrotz: py2 = px * sinrotz + py * cosrotz: py3 = py2 * cosrotx - pz2 * sinrotx: pz3 = py2 * sinrotx + pz2 * cosrotx
76.         points(actual_point, 4) = -px3 * zoom_xy: points(actual_point, 5) = -py3 * zoom_xy: points(actual_point, 6) = -pz3 * zoom_distance
77.     NEXT actual_point
78.  
79.     'draw
80.     FOR asq = 0 TO sqs - 1
81.         wx0 = points(sq(asq, 0, act_map), 4): wy0 = points(sq(asq, 0, act_map), 5): wz0 = points(sq(asq, 0, act_map), 6)
82.         wx1 = points(sq(asq, 1, act_map), 4): wy1 = points(sq(asq, 1, act_map), 5): wz1 = points(sq(asq, 1, act_map), 6)
83.         wx2 = points(sq(asq, 2, act_map), 4): wy2 = points(sq(asq, 2, act_map), 5): wz2 = points(sq(asq, 2, act_map), 6)
84.         wx3 = points(sq(asq, 3, act_map), 4): wy3 = points(sq(asq, 3, act_map), 5): wz3 = points(sq(asq, 3, act_map), 6)
85.         sy0 = sq(asq, 6, act_map): sx0 = sq(asq, 4, act_map): sy1 = sq(asq, 7, act_map): sx1 = sq(asq, 4, act_map)
86.         sy2 = sq(asq, 6, act_map): sx2 = sq(asq, 5, act_map): sy3 = sq(asq, 7, act_map): sx3 = sq(asq, 5, act_map)
87.         _MAPTRIANGLE (sx0, sy0)-(sx1, sy1)-(sx2, sy2), wmap(act_map) TO(wx0, wy0, wz0)-(wx1, wy1, wz1)-(wx2, wy2, wz2), , _SMOOTH
88.         _MAPTRIANGLE (sx3, sy3)-(sx1, sy1)-(sx2, sy2), wmap(act_map) TO(wx3, wy3, wz3)-(wx1, wy1, wz1)-(wx2, wy2, wz2), , _SMOOTH
89.     NEXT asq
90.  
91.     'view
92.     _DISPLAY: _PUTIMAGE , wmap(act_map)
93.     rdis = _FONTHEIGHT * 1.2
94.     _PRINTSTRING (0, 0), "MOVING:WASD+mouse         NEXT MAP:space key           "
95.     _PRINTSTRING (0, rdis), "Type:  " + UCASE$(mp_t$(act_map)) + "  " + map_pic$(act_map) + "             "
96.     distance = SQR(me(0) * me(0) + me(1) * me(1) + me(2) * me(2)): diam = 0
97.     SELECT CASE mp_t$(act_map)
98.         CASE "earth": diam = 12742
99.         CASE "moon": diam = 3474
100.         CASE "mars": diam = 6779
101.     END SELECT
102.     distance_km = -(1 - distance) * diam / 2
103.     IF diam THEN _PRINTSTRING (0, rdis * 2), "distance from the surface " + STR$(INT(distance_km)) + "km   ," + STR$(INT(distance_km / 1.6)) + "mp                    "
104.  
105. LOOP
106.  
107.  
108.  
109.  
110.  
111.  

[OldMoses]

As Petr indicated, I downloaded the 32 bit build and it will work with 32 bit version, on my system. Is everyone else running 32, or does my rig just not play nice with 64? Can't say I've ever had other issues with it.

[bplus]

Code: QB64: [Select]

1. _Mousemoment detects when you leave the screen, but _MOUSEX does not.

Ah! good reason, thank you very much, MasterGy!

@Petr I hope you idea for fixing, works out for us.

Oh say, I just had thought, actually another question:
What does _Mousemovement return when the mouse is off screen?

[MasterGy]

I may be wrong, but I noticed this:
_MOUSEMOVEMENT - it can also detect when you leave the window, but it doesn't work above 1.3, and there may be problems with non-windows
_MOUSEX - universal for all operating systems and qb - versions, but if you exit the window, it does not detect it.
To this day, I prefer qb 1.3 because of the compiler speed, and for that reason too.

[OldMoses]

Oh say, I just had thought, actually another question:
What does _Mousemovement return when the mouse is off screen?

It just returns the relative offset from the last time the position was polled as far as I can tell.

[bplus]

It just returns the relative offset from the last time the position was polled as far as I can tell.

This sounds the same as the regular QB64 mouse detection system, when you go off screen it just stops reporting mx my until you are back on again, nothing jumps to 0, 0 or disappears except mouse.

[Galleon]

FYI - I've been exclusively using the 32bit version just because of the bug in _MOUSEMOVEMENTX/Y on the 64bit version. It would be great if it got fixed at some point. No I'm not gonna fix it sorry.

[luke]

Version under which it works is 1.5 488c4a1 from git.  HA! In 32 bit version it works, but in 64 bit version with the same version number it works not! Now tested!

This is good to know!

Apologies to MasterGy for hijacking the thread.

[MasterGy]

it doesn't bother me, just feel free! educational thoughts are voiced. interesting to me too.

[bplus]

And we got it fixed! :)

[MasterGy]

I am very happy with the fix, thank you for the fix on my behalf!