Moving into the Matrix Rain by Ashish

[Qwerkey]

Author: @Ashish
Source: qb64.org Forum
URL: https://www.qb64.org/forum/index.php?topic=1453
Version: 1
Tags: [3D], [Graphics]

Description:
I was just inspired by Bplus's Matrix rain on this topic - https://www.qb64.org/forum/index.php?topic=1152.msg106362
So, I decided to create a similar matrix rain having depth effect.

Source Code:

Code: QB64: [Select]

1. 'Moving into the Matrix Rain
2. 'By Ashish Kushwaha
3. '23 Jun, 2019
4. '
5. 'Inspire by B+ Matrix Rain.
6. _TITLE "Moving into the Matrix Rain"
7.  
8. RANDOMIZE TIMER
9.  
10. SCREEN _NEWIMAGE(800, 600, 32)
11.  
12. TYPE matRain
13.     x AS SINGLE 'x location
14.     y AS SINGLE 'y location
15.     z AS SINGLE 'z location
16.     ay AS SINGLE 'rain velocity
17.     strData AS STRING 'string data of each matrix rain
18. END TYPE
19.  
20. DIM SHARED charImg(74) AS LONG, matRainWidth, matRainHeight 'ascii char from 48 to 122, i.e, total 75 type of chars
21. DIM SHARED glAllow AS _BYTE, matrixRain(700) AS matRain, matrixRainTex(74) AS LONG, mov
22. matRainWidth = _FONTWIDTH * 0.005
23. matRainHeight = _FONTHEIGHT * 0.005
24. CLS , _RGB32(255)
25. tmp& = _NEWIMAGE(_FONTWIDTH - 1, _FONTHEIGHT, 32)
26. FOR i = 0 TO 74
27.     charImg(i) = _NEWIMAGE(_FONTWIDTH * 5, _FONTHEIGHT * 5, 32)
28.     _DEST tmp&
29.     CLS , _RGBA(0, 0, 0, 0)
30.     COLOR _RGB32(0, 255, 0), 1
31.     _PRINTSTRING (0, 0), CHR$(i + 48)
32.     _DEST charImg(i)
33.     _PUTIMAGE , tmp&
34.     _DEST 0
35. NEXT
36.  
37.  
38. glAllow = -1
39. DO
40.     FOR i = 0 TO UBOUND(matrixRain)
41.         matrixRain(i).y = matrixRain(i).y - matrixRain(i).ay
42.         IF RND > 0.9 THEN
43.             d$ = ""
44.             FOR k = 1 TO LEN(matrixRain(i).strData)
45.                 d$ = d$ + CHR$(48 + p5random(0, 74)) 'change the character of rain randomly by a chance of 10%
46.             NEXT
47.             matrixRain(i).strData = d$
48.         END IF
49.         matrixRain(i).z = matrixRain(i).z + 0.00566 'move into the rain
50.         IF matrixRain(i).z > 0.1 THEN 'when behind screen
51.             matrixRain(i).x = p5random(-2, 2)
52.             matrixRain(i).y = p5random(2, 3.7)
53.             matrixRain(i).z = map((i / UBOUND(matrixRain)), 0, 1, -8, -0.2)
54.             matrixRain(i).ay = p5random(0.006, 0.02)
55.         END IF
56.     NEXT
57.     _LIMIT 60
58. LOOP
59.  
60. SUB _GL ()
61.     STATIC glInit
62.     mov = mov + 0.01
63.     IF NOT glAllow THEN EXIT SUB
64.  
65.     IF glInit = 0 THEN
66.         glInit = 1
67.  
68.         FOR i = 0 TO UBOUND(matrixRainTex) 'create texture for each ascii character
69.             _glGenTextures 1, _OFFSET(matrixRainTex(i))
70.  
71.             DIM m AS _MEM
72.             m = _MEMIMAGE(charImg(i))
73.  
74.             _glBindTexture _GL_TEXTURE_2D, matrixRainTex(i)
75.             _glTexImage2D _GL_TEXTURE_2D, 0, _GL_RGBA, _WIDTH(charImg(i)), _HEIGHT(charImg(i)), 0, _GL_BGRA_EXT, _GL_UNSIGNED_BYTE, m.OFFSET
76.  
77.             _MEMFREE m
78.  
79.             _glTexParameteri _GL_TEXTURE_2D, _GL_TEXTURE_MAG_FILTER, _GL_NEAREST
80.             _glTexParameteri _GL_TEXTURE_2D, _GL_TEXTURE_MIN_FILTER, _GL_NEAREST
81.             _FREEIMAGE charImg(i)
82.         NEXT
83.  
84.         FOR i = 0 TO UBOUND(matrixRain) 'initialization
85.             n = p5random(1, 15)
86.             FOR j = 1 TO n
87.                 v$ = CHR$(p5random(48, 122))
88.                 matrixRain(i).strData = matrixRain(i).strData + v$
89.             NEXT
90.             matrixRain(i).x = p5random(-2, 2)
91.             matrixRain(i).y = p5random(2, 3.7)
92.             matrixRain(i).z = map((i / UBOUND(matrixRain)), 0, 1, -8, -0.2)
93.             matrixRain(i).ay = p5random(0.006, 0.02)
94.         NEXT
95.  
96.         _glViewport 0, 0, _WIDTH, _HEIGHT
97.     END IF
98.  
99.     _glEnable _GL_BLEND 'enabling necessary stuff
100.     _glEnable _GL_DEPTH_TEST
101.     _glEnable _GL_TEXTURE_2D
102.  
103.  
104.     _glClearColor 0, 0, 0, 1
105.     _glClear _GL_COLOR_BUFFER_BIT OR _GL_DEPTH_BUFFER_BIT
106.  
107.  
108.     _glMatrixMode _GL_PROJECTION
109.     _glLoadIdentity
110.     _gluPerspective 60, _WIDTH / _HEIGHT, 0.01, 10.0
111.  
112.     _glRotatef SIN(mov) * 20, 1, 0, 0 'rotating x-axis a bit, just to get Depth effect.
113.  
114.  
115.     _glMatrixMode _GL_MODELVIEW
116.     _glLoadIdentity
117.  
118.     'rendering the rain
119.     FOR i = 0 TO UBOUND(matrixRain)
120.         n = LEN(matrixRain(i).strData)
121.         FOR j = 1 TO n
122.             ca$ = MID$(matrixRain(i).strData, j, 1)
123.             'selecting texture on the basis of ascii code.
124.             _glBindTexture _GL_TEXTURE_2D, matrixRainTex(ASC(ca$) - 48)
125.             _glBegin _GL_QUADS
126.             _glTexCoord2f 0, 1
127.             _glVertex3f matrixRain(i).x - matRainWidth, matrixRain(i).y - matRainHeight + 2 * (j - 1) * matRainHeight, matrixRain(i).z
128.             _glTexCoord2f 0, 0
129.             _glVertex3f matrixRain(i).x - matRainWidth, matrixRain(i).y + matRainHeight + 2 * (j - 1) * matRainHeight, matrixRain(i).z
130.             _glTexCoord2f 1, 0
131.             _glVertex3f matrixRain(i).x + matRainWidth, matrixRain(i).y + matRainHeight + 2 * (j - 1) * matRainHeight, matrixRain(i).z
132.             _glTexCoord2f 1, 1
133.             _glVertex3f matrixRain(i).x + matRainWidth, matrixRain(i).y - matRainHeight + 2 * (j - 1) * matRainHeight, matrixRain(i).z
134.             _glEnd
135.         NEXT
136.     NEXT
137.  
138.     _glFlush
139. END SUB
140.  
141. 'taken from p5js.bas
142. 'https://bit.ly/p5jsbas
143. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
144.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
145. END FUNCTION
146.  
147.  
148. FUNCTION p5random! (mn!, mx!)
149.     IF mn! > mx! THEN
150.         SWAP mn!, mx!
151.     END IF
152.     p5random! = RND * (mx! - mn!) + mn!
153. END FUNCTION
154.