QB64 vs same coded C/C++ program

[Ryster]

So out of curiosity, i compiled the code on my computer, result: 1847296 (1.76 MB)

[Petr]

Thank for reply, Pete, i think, with library is none problem if you add all to row 35 as .BI file and all from row 48 to end as .BM file. 

I would just recommend using long specific names of variables and fields so that their names indicate that they belong to this library and do not interfere with variables that could be the same in other code while keeping the current names.  I do that so, and it always help me, if write some library.

[Pete]

@Ashish: That's what Steve thought, it's the difference between your 32-bit and my 64 bit version. Thanks for getting back to us.

@Ryster: What version are you using, 32-bit or 64 bt, and what's the version number? Also, are you using Windows or another OS?

@Petr: Thanks for posting all those tests with various versions on your Windows 7. It's about a MB in range between all of those systems. Apparently, the newer versions and the 64-bit ones need to link more libraries, larger libraries, or some additional support information to the finished exe. Also, below is my beginnings into making what I initially posted int a usable library. Yes, I had that same thought about changing the variable names. I usually make programs with global variables, so this library, as currently written, would bite me in the ascii! Anyway, I may start another thread for this, as I'm curious if I could get away with fewer parameters to pass if I made my library variables into TYPES? Oh, and you can try this program, and turn on or off the variable displays. With the variable dispay off, you can see the cursor just fine.
------------------------------------------------------------

Here is the updated code, with some bug fixes and what I hope is the correct variable passing between subs. It compiled on my win 10 64-bit system running QB64 64-bit V1.3 @ 2,487 KB. Again, approx 2.5 MB.

Code: QB64: [Select]

1. main:
2. ' The next two lines can be removed to use this library with other programs.
3. LINE INPUT "Input 1 for debug mode with variable display, any other to turn debug off. "; a$
4. IF a$ = "1" THEN DIM SHARED debug: debug = -1
5.  
6. ' Place the routine that will use this library above and/or inside this loop...
7. WHILE (1)
8.     CALL UserInput
9. WEND
10.  
11. '=============================CONSOLE INPUT LIBRARY===========================
12.  
13. SUB UserInput
14.     STATIC UserInputSetup AS INTEGER
15.     STATIC MAX_SIZE AS INTEGER, prompt_column AS INTEGER, startpos AS INTEGER, vertpos AS INTEGER, endpos AS INTEGER, yyseparator AS INTEGER, ins AS INTEGER
16.     STATIC entry$(), xntry$(), prompt$(), entryrow() AS INTEGER
17.     STATIC xx AS INTEGER, yy AS INTEGER
18.  
19.     IF UserInputSetup = 0 THEN
20.  
21.         CONST prompt_length = 17 'Length of the longest prompt.
22.         CONST vmax = 4 'Number of prompts. Must not exceed rows of screen.
23.         CONST c1f = 0: CONST c1b = 7 'Default foreground and background text/screen colors.
24.         CONST c2f = 7: CONST c2b = 1 'Text highlighting color.
25.  
26.         DIM entry$(vmax) 'Text entry array.
27.         DIM prompt$(vmax) 'Prompt array.
28.         DIM entryrow(vmax) AS INTEGER 'Tracks row location of each prompt.
29.  
30.         MAX_SIZE = 36
31.         prompt_column = 10 'Number of columns to indent prompts.
32.         startpos = prompt_column + prompt_length - 1
33.         vertpos = 5
34.         endpos = startpos + MAX_SIZE
35.         yyseparator = 2 'Number of blank rows, less 1, between prompts. Do not set lower than 1.
36.         ins = 7 'Cursor vertical height for default insert text mode.
37.  
38.         CALL SetTitle
39.  
40.         CALL SetConsole(c1f, c1b)
41.  
42.         CALL GetPrompts(startpos, vertpos, vmax, yyseparator, xx, yy, prompt_column, entryrow(), prompt$())
43.  
44.         CALL SetCursor(ins)
45.  
46.         UserInputSetup = -1
47.     END IF
48.  
49.     CALL GetConsoleInput(startpos, endpos, vertpos, vmax, yyseparator, xx, yy, ins, MAX_SIZE, c1f, c1b, c2f, c2b, prompt_column, entryrow(), entry$())
50.  
51. END SUB
52.  
53. SUB SetTitle
54.     title$ = "Pete's Custom Keyboard Input App"
55.     _TITLE title$
56. END SUB
57.  
58. SUB SetConsole (c1f AS INTEGER, c1b AS INTEGER)
59.     PALETTE 7, 63
60.     COLOR c1f, c1b
61.     CLS
62. END SUB
63.  
64. SUB GetPrompts (startpos AS INTEGER, vertpos AS INTEGER, vmax AS INTEGER, yyseparator AS INTEGER, xx AS INTEGER, yy AS INTEGER, prompt_column AS INTEGER, entryrow() AS INTEGER, prompt$())
65.     DIM ii AS INTEGER
66.  
67.     xx = startpos
68.     yy = vertpos
69.  
70.     prompt$(0) = "Name..........: "
71.     prompt$(1) = "Address.......: "
72.     prompt$(2) = "City/State/Zip: "
73.     prompt$(3) = "Phone.........: "
74.  
75.     yy = vertpos
76.  
77.     FOR ii = 0 TO vmax - 1
78.         LOCATE yy, prompt_column
79.         PRINT prompt$(ii);
80.         entryrow(ii) = yy
81.         yy = yy + yyseparator
82.     NEXT
83.  
84.     LOCATE vertpos, startpos
85.     xx = startpos
86.     yy = vertpos
87. END SUB
88.  
89. SUB SetCursor (ins AS INTEGER)
90.     LOCATE , , 1, 7, ins
91. END SUB
92.  
93. SUB copy (startpos AS INTEGER, vertpos AS INTEGER, yyseparator AS INTEGER, xx AS INTEGER, yy AS INTEGER, hmrk AS INTEGER, entry$(), xntry$)
94.     DIM m1 AS INTEGER, m2 AS INTEGER
95.  
96.     IF xx - startpos + 1 < hmrk THEN
97.         m2 = hmrk
98.         m1 = xx - startpos + 1
99.     ELSE
100.         m1 = hmrk
101.         m2 = xx - startpos + 1
102.     END IF
103.     xntry$ = MID$(entry$((yy - vertpos) / yyseparator), m1, m2 - m1)
104. END SUB
105.  
106. SUB replace (startpos AS INTEGER, vertpos AS INTEGER, yyseparator AS INTEGER, xx AS INTEGER, yy AS INTEGER, entry$(), hmrk AS INTEGER, highlighton AS INTEGER, dir AS INTEGER, c1f AS INTEGER, c1b AS INTEGER)
107.     DIM j AS INTEGER, m1 AS INTEGER, m2 AS INTEGER
108.  
109.     j = LEN(entry$((yy - vertpos) / yyseparator))
110.     COLOR c1f, c1b
111.     IF xx - startpos + 1 < hmrk THEN
112.         m2 = hmrk
113.         m1 = xx - startpos
114.     ELSE
115.         m1 = hmrk - 1
116.         m2 = xx - startpos + 1
117.     END IF
118.     entry$((yy - vertpos) / yyseparator) = MID$(entry$((yy - vertpos) / yyseparator), 1, m1) + MID$(entry$((yy - vertpos) / yyseparator), m2)
119.     LOCATE yy, startpos
120.     PRINT entry$((yy - vertpos) / yyseparator);
121.     PRINT STRING$(j - LEN(entry$((yy - vertpos) / yyseparator)), 32);
122.     IF xx - startpos + 1 > hmrk THEN
123.         xx = hmrk - 1 + startpos
124.     END IF
125.     LOCATE yy, xx
126.     hmrk = 0
127.     highlighton = 0
128.     dir = 0
129. END SUB
130.  
131. SUB GetConsoleInput (startpos AS INTEGER, endpos AS INTEGER, vertpos AS INTEGER, vmax AS INTEGER, yyseparator AS INTEGER, xx AS INTEGER, yy AS INTEGER, ins AS INTEGER, MAX_SIZE AS INTEGER, c1f AS INTEGER, c1b AS INTEGER, c2f AS INTEGER, c2b AS INTEGER, prompt_column AS INTEGER, entryrow() AS INTEGER, entry$())
132.     STATIC drag AS INTEGER, dir AS INTEGER, highlighton AS INTEGER, hmrk AS INTEGER, xntry$, shift AS INTEGER
133.     DIM ii AS INTEGER, oldyy AS INTEGER
134.     DIM xntry$(MAX_SIZE) 'Cut/Copy array.
135.  
136.     IF ctrl THEN ctrl = 0
137.     IF shift < 0 THEN shift = 0
138.     DEF SEG = 0
139.     ii = PEEK(&H417) MOD 16
140.     SELECT CASE ii
141.         CASE 1, 2
142.             shift = -1
143.         CASE 4
144.             ctrl = -1
145.     END SELECT
146.     DEF SEG
147.  
148.     oldyy = yy
149.  
150.     IF drag = 0 THEN
151.         IF highlighton AND shift = 0 AND hmrk = 0 THEN
152.             highlighton = 0 ' Disable highlighton so character value isn't printed after a shift / release event without highlighting.
153.         END IF
154.     END IF
155.  
156.     CALL mouse(startpos, vmax, xx, yy, vertpos, yyseparator, hmrk, dir, highlighton, c1f, c1b, c2f, c2b, drag, prompt_column, MAX_SIZE, shift, ch$, entry$(), entryrow())
157.  
158.     IF drag = 0 THEN
159.         IF ch$ = "" THEN ch$ = INKEY$
160.         IF ch$ <> "" THEN
161.             IF ctrl THEN
162.                 SELECT CASE LCASE$(ch$)
163.                     CASE CHR$(1) ' Select All
164.                         LOCATE yy, startpos
165.                         COLOR c2f, c2b
166.                         PRINT entry$((yy - vertpos) / yyseparator);
167.                         COLOR c1f, c1b
168.                         hmrk = 1
169.                         highlighton = -1
170.                         dir = LEN(entry$((yy - vertpos) / yyseparator))
171.                         xx = startpos + dir
172.                         LOCATE yy, xx
173.  
174.                     CASE CHR$(3) ' Copy
175.                         IF hmrk THEN
176.                             CALL copy(startpos, vertpos, yyseparator, xx, yy, hmrk, entry$(), xntry$)
177.                         END IF
178.  
179.                     CASE CHR$(24) ' Cut
180.                         IF hmrk THEN
181.                             CALL copy(startpos, vertpos, yyseparator, xx, yy, hmrk, entry$(), xntry$)
182.                             CALL replace(startpos, vertpos, yyseparator, xx, yy, entry$(), hmrk, highlighton, dir, c1f, c1b)
183.                         END IF
184.  
185.                     CASE CHR$(22) ' Paste
186.                         IF xntry$ <> "" THEN
187.                             IF hmrk THEN
188.                                 CALL replace(startpos, vertpos, yyseparator, xx, yy, entry$(), hmrk, highlighton, dir, c1f, c1b)
189.                             END IF
190.                             m1 = xx - startpos
191.                             m2 = m1 + 1
192.                             IF LEN(xntry$) + LEN(entry$((yy - vertpos) / yyseparator)) - (m2 - m1) <= MAX_SIZE - 1 THEN
193.                                 entry$((yy - vertpos) / yyseparator) = MID$(entry$((yy - vertpos) / yyseparator), 1, m1) + xntry$ + MID$(entry$((yy - vertpos) / yyseparator), m2)
194.                                 LOCATE yy, startpos
195.                                 COLOR c1f, c1b
196.                                 PRINT entry$((yy - vertpos) / yyseparator);
197.                                 xx = xx + LEN(xntry$)
198.                                 LOCATE yy, xx
199.                             ELSE
200.                                 BEEP ' Contents too large to paste.
201.                             END IF
202.                         END IF
203.                 END SELECT
204.             ELSE
205.                 SELECT CASE ch$
206.                     CASE CHR$(8) ' Backspace
207.                         ch$ = CHR$(0)
208.                         IF hmrk > 0 THEN
209.                             CALL replace(startpos, vertpos, yyseparator, xx, yy, entry$(), hmrk, highlighton, dir, c1f, c1b)
210.                         ELSE
211.                             IF xx > startpos THEN
212.                                 xx = xx - 1
213.                                 LOCATE yy, xx
214.                                 PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 2); " ";
215.                                 entry$((yy - vertpos) / yyseparator) = MID$(entry$((yy - vertpos) / yyseparator), 1, xx - startpos) + MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 2)
216.                                 LOCATE yy, xx
217.                             END IF
218.                         END IF
219.                     CASE CHR$(0) + "S" ' Delete
220.                         IF shift THEN
221.                             IF hmrk THEN
222.                                 CALL copy(startpos, vertpos, yyseparator, xx, yy, hmrk, entry$(), xntry$)
223.                                 CALL replace(startpos, vertpos, yyseparator, xx, yy, entry$(), hmrk, highlighton, dir, c1f, c1b)
224.                             END IF
225.                         ELSE
226.                             ch$ = CHR$(0)
227.                             IF hmrk > 0 THEN
228.                                 CALL replace(startpos, vertpos, yyseparator, xx, yy, entry$(), hmrk, highlighton, dir, c1f, c1b)
229.                             ELSE
230.                                 IF LEN(entry$((yy - vertpos) / yyseparator)) > 0 AND xx - startpos <= LEN(entry$((yy - vertpos) / yyseparator)) THEN
231.                                     PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 2); " ";
232.                                     entry$((yy - vertpos) / yyseparator) = MID$(entry$((yy - vertpos) / yyseparator), 1, xx - startpos) + MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 2)
233.                                     LOCATE yy, xx
234.                                 END IF
235.                             END IF
236.                         END IF
237.  
238.                     CASE CHR$(0) + "H" ' Arrow up
239.                         ch$ = CHR$(0)
240.                         IF yy > vertpos THEN
241.                             yy = yy - yyseparator
242.                             xx = startpos
243.                             LOCATE yy, xx
244.                         END IF
245.  
246.                     CASE CHR$(0) + "P", CHR$(13) ' Arrow down, Enter
247.                         ch$ = CHR$(0)
248.                         IF (yy - vertpos) / yyseparator + 1 < vmax THEN
249.                             yy = yy + yyseparator
250.                             xx = startpos
251.                             LOCATE yy, xx
252.                         END IF
253.  
254.                     CASE CHR$(0) + "K" ' Arrow left
255.                         ch$ = CHR$(0)
256.                         IF xx > startpos THEN
257.                             IF shift THEN
258.                                 IF dir <= 0 THEN
259.                                     IF dir = 0 THEN
260.                                         hmrk = xx - startpos + 1
261.                                         highlighton = -1
262.                                     END IF
263.                                     xx = xx - 1
264.                                     LOCATE yy, xx
265.                                     COLOR c2f, c2b
266.                                     PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1)
267.                                     dir = dir - 1
268.                                     LOCATE yy, xx
269.                                 ELSE
270.                                     xx = xx - 1
271.                                     LOCATE yy, xx
272.                                     COLOR c1f, c1b
273.                                     PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1)
274.                                     dir = dir - 1
275.                                     IF dir = 0 THEN
276.                                         hmrk = 0
277.                                     END IF
278.                                     LOCATE yy, xx
279.                                 END IF
280.  
281.                             ELSE
282.                                 xx = xx - 1
283.                                 LOCATE yy, xx
284.                             END IF
285.                         END IF
286.  
287.                     CASE CHR$(0) + "M" ' Arrow right
288.                         ch$ = CHR$(0)
289.                         IF xx < endpos - 1 AND xx - startpos < LEN(entry$((yy - vertpos) / yyseparator)) THEN
290.                             IF shift THEN
291.                                 IF dir >= 0 THEN
292.                                     IF dir = 0 THEN
293.                                         hmrk = xx - startpos + 1
294.                                         highlighton = -1
295.                                     END IF
296.                                     COLOR c2f, c2b
297.                                     PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1)
298.                                     xx = xx + 1
299.                                     LOCATE yy, xx
300.                                     dir = dir + 1
301.                                     LOCATE yy, xx
302.                                 ELSE
303.                                     COLOR c1f, c1b
304.                                     PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1)
305.                                     xx = xx + 1
306.                                     dir = dir + 1
307.                                     IF dir = 0 THEN
308.                                         hmrk = 0
309.                                         highlighton = 0
310.                                     END IF
311.                                     LOCATE yy, xx
312.                                 END IF
313.                             ELSE
314.                                 xx = xx + 1
315.                                 LOCATE yy, xx
316.                             END IF
317.                         END IF
318.  
319.                     CASE CHR$(0) + "G" ' Home
320.                         ch$ = CHR$(0)
321.                         IF xx > startpos THEN
322.                             IF shift THEN
323.                                 WHILE xx > startpos
324.                                     IF dir <= 0 THEN
325.                                         IF dir = 0 THEN
326.                                             hmrk = xx - startpos + 1
327.                                             ' highlighton is already set.
328.                                         END IF
329.                                         xx = xx - 1
330.                                         LOCATE yy, xx
331.                                         COLOR c2f, c2b
332.                                         PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1);
333.                                         dir = dir - 1
334.                                         LOCATE yy, xx
335.                                     ELSE
336.                                         xx = xx - 1
337.                                         LOCATE yy, xx
338.                                         COLOR c1f, c1b
339.                                         PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1);
340.                                         dir = dir - 1
341.                                         IF dir = 0 THEN
342.                                             hmrk = 0
343.                                             highlighton = 0
344.                                         END IF
345.                                         LOCATE yy, xx
346.                                     END IF
347.                                 WEND
348.                             ELSE
349.                                 xx = startpos
350.                                 LOCATE yy, xx
351.                             END IF
352.                         END IF
353.  
354.                     CASE CHR$(0) + "O" ' End
355.                         ch$ = CHR$(0)
356.                         IF xx < endpos - 1 THEN
357.                             IF shift THEN
358.                                 WHILE xx - startpos < LEN(entry$((yy - vertpos) / yyseparator))
359.                                     IF dir >= 0 THEN
360.                                         IF dir = 0 THEN
361.                                             hmrk = xx - startpos + 1
362.                                             highlighton = -1
363.                                         END IF
364.                                         COLOR c2f, c2b
365.                                         PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1);
366.                                         xx = xx + 1
367.                                         LOCATE yy, xx
368.                                         dir = dir + 1
369.                                         LOCATE yy, xx
370.                                     ELSE
371.                                         COLOR c1f, c1b
372.                                         PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1);
373.                                         xx = xx + 1
374.                                         dir = dir + 1
375.                                         IF dir = 0 THEN
376.                                             hmrk = 0
377.                                         END IF
378.                                         LOCATE yy, xx
379.                                     END IF
380.                                 WEND
381.                             ELSE
382.                                 xx = startpos + LEN(entry$((yy - vertpos) / yyseparator))
383.                                 LOCATE yy, xx
384.                             END IF
385.                         END IF
386.  
387.                     CASE CHR$(27)
388.                         ch$ = CHR$(0)
389.                         SYSTEM
390.  
391.                     CASE CHR$(0) + CHR$(82) ' Insert
392.                         ch$ = CHR$(0)
393.                         IF ins = 7 THEN ins = 30 ELSE ins = 7
394.                         SetCursor ins
395.  
396.                     CASE CHR$(32) TO CHR$(126)
397.                         IF hmrk > 0 THEN
398.                             CALL replace(startpos, vertpos, yyseparator, xx, yy, entry$(), hmrk, highlighton, dir, c1f, c1b)
399.                         END IF
400.                         IF ins = 30 THEN
401.                             IF xx - startpos < MAX_SIZE - 1 THEN
402.                                 MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1) = ch$
403.                                 LOCATE yy, xx
404.                                 PRINT ch$;
405.                                 xx = xx + 1
406.                                 LOCATE yy, xx
407.                             END IF
408.                         ELSE
409.                             IF LEN(entry$((yy - vertpos) / yyseparator)) < MAX_SIZE - 1 THEN
410.                                 PRINT ch$ + MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1);
411.                                 entry$((yy - vertpos) / yyseparator) = MID$(entry$((yy - vertpos) / yyseparator), 1, xx - startpos) + ch$ + MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1)
412.                                 xx = xx + 1
413.                                 LOCATE yy, xx
414.                             END IF
415.                         END IF
416.                 END SELECT
417.             END IF
418.         END IF
419.  
420.         IF shift THEN
421.             IF highlighton = 0 AND dir <> 0 THEN
422.                 highlighton = -1 ' When dir <> 0 the first character has been highlighted.
423.             END IF
424.         ELSE
425.             IF ch$ <> "" THEN
426.                 IF highlighton AND shift = 0 AND LCASE$(ch$) <> "x" AND ctrl = 0 AND ch$ <> CHR$(8) AND ch$ <> CHR$(0) + "S" THEN
427.                     ' ROutine to remove highlighting from text.
428.                     COLOR c1f, c1b
429.                     LOCATE oldyy, startpos
430.                     IF ch$ <> CHR$(0) THEN
431.                         PRINT ch$;
432.                     END IF
433.                     PRINT entry$((oldyy - vertpos) / yyseparator);
434.                     LOCATE yy, xx
435.                     hmrk = 0
436.                     highlighton = 0
437.                     dir = 0
438.                 END IF
439.             END IF
440.         END IF
441.         ch$ = ""
442.     END IF
443. END SUB
444.  
445. SUB mouse (startpos AS INTEGER, vmax AS INTEGER, xx AS INTEGER, yy AS INTEGER, vertpos AS INTEGER, yyseparator AS INTEGER, hmrk AS INTEGER, dir AS INTEGER, highlighton AS INTEGER, c1f AS INTEGER, c1b AS INTEGER, c2f AS INTEGER, c2b AS INTEGER, drag AS INTEGER, prompt_column AS INTEGER, MAX_SIZE AS INTEGER, shift AS INTEGER, ch$, entry$(), entryrow() AS INTEGER)
446.     STATIC doubleclick AS INTEGER, lb AS INTEGER, lbdn AS INTEGER, z1, oldmx AS INTEGER, oldmy AS INTEGER, mhl AS INTEGER
447.     STATIC mx AS INTEGER, my AS INTEGER
448.     DIM ii AS INTEGER
449.  
450.     IF debug THEN
451.         LOCATE 20, 1
452.         COLOR c1f, c1b
453.         PRINT " oldmx"; oldmx; "  oldmy"; oldmy; "  mx"; mx; "  my"; my; "  xx"; xx; "  yy"; yy; "  lb"; lb; "  lbdn"; lbdn; "      "
454.         PRINT " shift"; shift; "  drag"; drag; "  mhl"; mhl; "  hmrk"; hmrk; "  dir"; dir; "  dblclk"; doubleclick; "  startpos"; startpos; "        "
455.         PRINT " mx"; mx - startpos + 1; "  my"; (my - vertpos) / yyseparator; "  xx"; xx - startpos + 1; "  yy"; (yy - vertpos) / yyseparator; "        "
456.         PRINT " highlighton"; highlighton; "     ";
457.         LOCATE yy, xx
458.     END IF
459.  
460.     WHILE _MOUSEINPUT: WEND
461.     mx = _MOUSEX
462.     my = _MOUSEY
463.     lb = _MOUSEBUTTON(1)
464.  
465.     IF lb AND highlighton AND shift = 0 AND drag = 0 AND mhl = 0 THEN ' Allows highlighting caused by mouse click to be removed in parent sub.
466.         ch$ = CHR$(0)
467.         EXIT SUB
468.     END IF
469.  
470.     IF shift AND lb AND drag = 0 OR mhl THEN
471.         IF mhl = 0 THEN ' Shift + click highlighting.
472.             IF my = yy AND mx <> xx AND mx >= startpos AND mx - startpos <= LEN(entry$((yy - vertpos) / yyseparator)) THEN
473.                 mhl = mx - startpos + 1
474.             END IF
475.         ELSE ' Terminal point reached, end highlighting.
476.             IF mhl = xx - startpos + 1 THEN mhl = 0: drag = 0: EXIT SUB
477.         END IF
478.     END IF
479.  
480.     IF LEN(entry$((yy - vertpos) / yyseparator)) THEN
481.         IF lbdn AND xx <> mx AND shift = 0 OR mhl THEN ' Combined drag and shift + click highlighting.
482.             IF my = yy THEN ' Restrict to active text line.
483.                 IF lb OR mhl THEN
484.                     IF xx > mx THEN
485.                         drag = -1
486.                     ELSE
487.                         drag = 1
488.                     END IF
489.                     GOSUB mousedrag
490.                     EXIT SUB
491.                 ELSE
492.                     drag = 0
493.                 END IF
494.             END IF
495.         END IF
496.     END IF
497.  
498.     IF lb THEN
499.         IF debug THEN COLOR c1f, c1b: LOCATE 2, 1: PRINT "left button down    "
500.         IF lbdn = 0 THEN lbdn = -1
501.         IF my = yy THEN
502.             IF mx >= startpos AND mx - startpos <= LEN(entry$((yy - vertpos) / yyseparator)) THEN
503.                 IF drag = 0 AND shift = 0 THEN yy = my ' Prevents changing rows if a drag is in progress.
504.                 xx = mx
505.                 LOCATE yy, xx
506.                 oldmx = mx: oldmy = my
507.             END IF
508.         ELSEIF shift = 0 THEN
509.             FOR ii = 0 TO vmax - 1
510.                 IF my = entryrow(ii) THEN EXIT FOR
511.             NEXT
512.  
513.             IF my = entryrow(ii) AND drag = 0 THEN
514.                 IF mx >= prompt_column AND mx - startpos <= MAX_SIZE THEN
515.                     IF mx - startpos > 0 AND mx - startpos <= LEN(entry$(ii)) THEN
516.                         yy = my: xx = mx
517.                     ELSE
518.                         yy = my: xx = startpos
519.                     END IF
520.                     LOCATE yy, xx
521.                 END IF
522.             END IF
523.         END IF
524.     ELSE
525.         IF lbdn THEN
526.             z1 = TIMER
527.             IF debug THEN COLOR c1f, c1b: LOCATE 2, 1: PRINT "left button released"
528.             doubleclick = doubleclick + 1
529.             lbdn = 0
530.             drag = 0
531.         END IF
532.     END IF
533.  
534.     IF doubleclick = 1 THEN
535.         IF ABS(z1 - TIMER) > .33 THEN doubleclick = 0
536.     END IF
537.  
538.     IF doubleclick = 2 THEN
539.         ' Any double click events go here...
540.         IF debug THEN LOCATE 2, 1: PRINT "double click         ";
541.         doubleclick = 0
542.     END IF
543.     LOCATE yy, xx
544.  
545.     EXIT SUB
546.  
547.     mousedrag:
548.     SELECT CASE drag
549.         CASE IS < 0
550.             IF dir <= 0 THEN ' highlight to left
551.                 IF dir = 0 THEN
552.                     hmrk = xx - startpos + 1
553.                     ' Do not emulate shift here. shift remains 0.
554.                     highlighton = -1
555.                 END IF
556.                 xx = xx - 1
557.                 LOCATE yy, xx
558.                 COLOR c2f, c2b
559.                 PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1)
560.                 dir = dir - 1
561.                 LOCATE yy, xx
562.             ELSE ' unhighlight to left
563.                 xx = xx - 1
564.                 dir = dir - 1
565.                 LOCATE yy, xx
566.                 COLOR c1f, c1b
567.                 PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1)
568.                 IF dir = 0 THEN
569.                     hmrk = 0
570.                     highlighton = 0
571.                     shift = 0
572.                 END IF
573.                 LOCATE yy, xx
574.             END IF
575.         CASE IS > 0
576.             IF dir >= 0 THEN
577.                 COLOR c2f, c2b
578.                 PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1)
579.                 IF dir = 0 THEN
580.                     hmrk = xx - startpos + 1
581.                     highlighton = -1
582.                     ' Do not emulate shift here. shift remains 0.
583.                 END IF
584.                 xx = xx + 1
585.                 dir = dir + 1
586.                 LOCATE yy, xx
587.             ELSE
588.                 COLOR c1f, c1b
589.                 PRINT MID$(entry$((yy - vertpos) / yyseparator), xx - startpos + 1, 1)
590.                 xx = xx + 1
591.                 dir = dir + 1
592.                 IF dir = 0 THEN
593.                     hmrk = 0
594.                     highlighton = 0
595.                     shift = 0
596.                 END IF
597.                 LOCATE yy, xx
598.             END IF
599.     END SELECT
600.     RETURN
601. END SUB
602.  

Pete

[Ryster]

The result of the compilation: 1847296 (1.76 MB)
Windows 10 - 1903, 64-bit. >>> QB64 1.2 - 32-bit.

[Pete]

Thank you. It seems there is a pattern emerging that 64-bit versions of QB64 compile to larger exe files than the 32-bit versions, and that the higher versions (more recent versions) likewise, compile larger exe files.

Pete

[SMcNeill]

Thank you. It seems there is a pattern emerging that 64-bit versions of QB64 compile to larger exe files than the 32-bit versions, and that the higher versions (more recent versions) likewise, compile larger exe files.

Pete

Remember: V1.3 swapped out to the latest MinGW compiler.  Prior versions used an old version of mingw which probably dated back to the Stone Age when LET was still in use by primitive programmers.

[Ryster]

SMcNeill.
It's nice to see that now you've come to the conclusion that previous versions were from the age of the splitting spit. As I wrote once, that the previous versions are unusable (at least in my case) that a lot of epithets rushed on my head, and that was what Clippy was leading. The only version that can meet my code is version 1.3 of December 2018 and I use it every day. Other non-useable ones.