elliptic hyperboloid

[STxAxTIC]

5G... jfc lol

[Petr]

Answer for BPlus: It's all determined by the point of view PERSPECTIVE. A circle, seen from the side is as an ellipse. When correctly rotated (viewed from the top) you can see a circle. My program just counts on the side view, so it creates an ellipse and it does a 3D effect.

Answer to Ashish: Again, it's not 3D mathematics. It's 2D mathematics, with a 3D perspective.

This show it:

Code: QB64: [Select]

1. _TITLE "Elliptic Hyperboloid"
2. SCREEN _NEWIMAGE(600, 600, 32)
3.  
4. TYPE V3D
5.     X AS SINGLE
6.     Z AS SINGLE
7. END TYPE
8.  
9. DIM SHARED V(30) AS V3D
10. 'create points for circle:
11. FOR c = 0 TO _PI(2) STEP _PI(2) / 31
12.     V(i).X = SIN(c) * 3
13.     V(i).Z = COS(c) * 3
14.     i = i + 1
15. NEXT
16.  
17. DO
18.     _LIMIT 30
19. LOOP
20.  
21. SUB _GL ()
22.  
23.     _glMatrixMode _GL_PROJECTION
24.     _gluPerspective 50, 1, 0.1, 100
25.  
26.     _glMatrixMode _GL_MODELVIEW
27.     a = 1
28.     b = 1
29.     c = 1
30.     STATIC rotY
31.     _glTranslatef 0, 0, -10
32.     _glRotatef rotY, 1, 0, 0
33.     rotY = rotY + 1
34.  
35.  
36.  
37.     '    _glPointSize 2
38.     _glLineWidth 5
39.     _glBegin _GL_LINES
40.     FOR u = 0 TO 29 STEP 1
41.         _glVertex3f V(u).X, 1, V(u).Z
42.         _glVertex3f V(u + 1).X, 1, V(u + 1).Z
43.     NEXT
44.     _glVertex3f V(0).X, 1, V(0).Z
45.     _glVertex3f V(30).X, 1, V(30).Z
46.  
47.     _glEnd
48. END SUB
49.  

So real 3D solution can be something as this:

Code: QB64: [Select]

1. _TITLE "Elliptic Hyperboloid"
2. SCREEN _NEWIMAGE(600, 600, 32)
3.  
4. TYPE V3D
5.     X AS SINGLE
6.     Z AS SINGLE
7. END TYPE
8.  
9. DIM SHARED V(30) AS V3D
10. DIM SHARED roto AS SINGLE
11. 'create points for circle:
12. FOR c = 0 TO _PI(2) STEP _PI(2) / 31
13.     V(i).X = SIN(c) * 3
14.     V(i).Z = COS(c) * 3
15.     i = i + 1
16. NEXT
17.  
18. DO
19.     _LIMIT 30
20. LOOP
21.  
22. SUB _GL ()
23.  
24.     _glMatrixMode _GL_PROJECTION
25.     _gluPerspective 50, 1, 0.1, 100
26.  
27.     _glMatrixMode _GL_MODELVIEW
28.     a = 1
29.     b = 1
30.     c = 1
31.     STATIC rotY
32.     _glTranslatef 0, 0, -10
33.     _glRotatef rotY, 1, 0, 0
34.     _glRotatef rotY, 0, 1, 0
35.  
36.     rotY = rotY + .5
37.  
38.  
39.  
40.     '    _glPointSize 2
41.     _glLineWidth 5
42.     _glBegin _GL_LINES
43.  
44.     'circle 1
45.     FOR u = 0 TO 29 STEP 1
46.         _glVertex3f V(u).X, -1, V(u).Z
47.         _glVertex3f V(u + 1).X, -1, V(u + 1).Z
48.     NEXT
49.     'circle 1 last area
50.     _glVertex3f V(0).X, -1, V(0).Z
51.     _glVertex3f V(30).X, -1, V(30).Z
52.  
53.  
54.     'circle 2
55.     FOR u = 0 TO 29 STEP 1
56.         _glVertex3f V(u).X, 1, V(u).Z
57.         _glVertex3f V(u + 1).X, 1, V(u + 1).Z
58.     NEXT
59.     'circle 2 last area
60.     _glVertex3f V(0).X, 1, V(0).Z
61.     _glVertex3f V(30).X, 1, V(30).Z
62.  
63.     'lines between circles:
64.     f = _PI(2) / 31
65.     FOR i2 = 0 TO 30
66.         _glVertex3f V(i2).X, 1, V(i2).Z
67.         _glVertex3f COS((i2 * f) + roto) * 3, -1, SIN((i2 * f) + roto) * 3
68.     NEXT
69.     roto = roto + .3
70.     _glEnd
71. END SUB
72.  

Code: QB64: [Select]

1. _TITLE "Elliptic Hyperboloid"
2. SCREEN _NEWIMAGE(1024, 768, 32)
3.  
4. TYPE V3D
5.     X AS SINGLE
6.     Z AS SINGLE
7. END TYPE
8.  
9. DIM SHARED V(30) AS V3D
10. DIM SHARED roto AS SINGLE
11. 'create points for circle:
12. FOR c = 0 TO _PI(2) STEP _PI(2) / 31
13.     V(i).X = SIN(c) * 3
14.     V(i).Z = COS(c) * 3
15.     i = i + 1
16. NEXT
17.  
18. DO
19.     _LIMIT 30
20. LOOP
21.  
22. SUB _GL ()
23.  
24.     _glMatrixMode _GL_PROJECTION
25.     _gluPerspective 50, 1, 0.1, 100
26.  
27.     _glMatrixMode _GL_MODELVIEW
28.     a = 1
29.     b = 1
30.     c = 1
31.     STATIC rotY
32.     _glTranslatef 0, 0, -15
33.     _glRotatef rotY, 1, 0, 0
34.     _glRotatef rotY, 0, 1, 0
35.  
36.     rotY = rotY + .5
37.  
38.  
39.  
40.     '    _glPointSize 2
41.     _glLineWidth 5
42.     _glBegin _GL_LINES
43.  
44.     'circle 1
45.     FOR u = 0 TO 29 STEP 1
46.         _glVertex3f V(u).X, -5, V(u).Z
47.         _glVertex3f V(u + 1).X, -5, V(u + 1).Z
48.     NEXT
49.     'circle 1 last area
50.     _glVertex3f V(0).X, -5, V(0).Z
51.     _glVertex3f V(30).X, -5, V(30).Z
52.  
53.  
54.     'circle 2
55.     FOR u = 0 TO 29
56.         _glVertex3f V(u).X, 5, V(u).Z
57.         _glVertex3f V(u + 1).X, 5, V(u + 1).Z
58.     NEXT
59.     'circle 2 last area
60.     _glVertex3f V(0).X, 5, V(0).Z
61.     _glVertex3f V(30).X, 5, V(30).Z
62.  
63.     'lines between circles:
64.     f = _PI(2) / 31
65.     FOR i2 = 0 TO 30
66.         _glVertex3f V(i2).X, 5, V(i2).Z
67.         _glVertex3f COS((i2 * f) + roto) * 3, -5, SIN((i2 * f) + roto) * 3
68.     NEXT
69.     roto = roto + .3
70.     _glEnd
71. END SUB
72.  

[bplus]

Thanks Petr, according to this video you can can both:

[Pete]

It's a popular design for TV towers, like the Canton Tower. 
Also used for a lighthouse in 1910.

It also looks like the Holy Grail.  I offerred Ashish a shrubbery
for it.

The Canton Tower looks like an upside down golf tee to me, but thanks for posting a real-life architectural example. Hey, maybe if I can buy it, flip it, and put the Times square New Years Eve Ball on top of it, I can finally get the Jolly Green Giant to pay me a Jolly green greens fee for a round of golf.

I forgot to wipe the IDE when I did this. It combined the code contributed by Petr and Ashish. I didn't even realize that, until I ran the routine.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(1024, 768, 256)
2. x = _WIDTH / 2
3. y = _HEIGHT / 2
4. radiusX = 50
5. radiusY = 50
6.  
7. CIRCLE (x, y), 10
8.  
9.  
10. DO UNTIL angle = 360
11.  
12.     angle = angle + 1
13.     t = _D2R(angle)
14.  
15.     '    Pt.x = x * COS(t) - y * SIN(t)
16.     '    Pt.y = x * SIN(t) + y * COS(t)
17.  
18.     Pt.x = x + COS(t) * radiusX
19.     Pt.y = y + SIN(t) * radiusY
20.  
21.     CIRCLE (Pt.x, Pt.y), 10
22.     _LIMIT 100
23. LOOP
24.  
25.  
26. PRINT "Press key..."
27. SLEEP
28.  
29. CLS
30. radiusX = 75
31. radiusY = 25
32.  
33.  
34. DO
35.     angle = 0
36.     DO UNTIL angle = 360
37.         a2 = a2 + _D2R(15) 'rotate up to 15 degrees
38.  
39.         angle = angle + 360 / 20
40.         t = _D2R(angle)
41.         t2 = _D2R(angle + 360 / 20)
42.         DO WHILE _MOUSEINPUT
43.             an3 = an3 + _MOUSEWHEEL
44.         LOOP
45.         a3 = _D2R(an3)
46.  
47.         'ellipse 1
48.         Pt.x = _MOUSEX + COS(t + a2) * radiusX
49.         Pt.y = _MOUSEY + SIN(t + a2) * radiusY
50.  
51.         'ellipse 2
52.         Pt.x2 = x + COS(t + a2 + a3) * radiusX
53.         Pt.y2 = y + SIN(t + a2 + a3) * radiusY
54.  
55.  
56.         '   PSET (Pt.x, Pt.y)
57.         '   PSET (Pt.x2, Pt.y2), 14
58.  
59.         LINE (Pt.x, Pt.y)-(Pt.x2, Pt.y2)
60.  
61.  
62.         'for ellipse1 circuit:
63.         Pt.x3 = _MOUSEX + COS(t2 + a2) * radiusX
64.         Pt.y3 = _MOUSEY + SIN(t2 + a2) * radiusY
65.  
66.  
67.         'for ellipse2 circuit:
68.         Pt.x4 = x + COS(t2 + a2 + a3) * radiusX
69.         Pt.y4 = y + SIN(t2 + a2 + a3) * radiusY
70.  
71.         'draw elipses circuit
72.         LINE (Pt.x3, Pt.y3)-(Pt.x, Pt.y), 9
73.         LINE (Pt.x4, Pt.y4)-(Pt.x2, Pt.y2), 10
74.  
75.     LOOP
76.     _DISPLAY
77.     _LIMIT 25
78.     CLS
79. LOOP
80.  
81.  
82. _TITLE "Elliptic Hyperboloid"
83. SCREEN _NEWIMAGE(600, 600, 32)
84.  
85. DO
86.     _LIMIT 30
87. LOOP
88.  
89. SUB _GL ()
90.     'using parametric equations
91.     'x(u,v) = a*sqrt(1+u^2)*cos(v)
92.     'y(u,v)=b*sqrt(1+u^2)*sin(v)
93.     'z(u,v)=c*u
94.     'for v in [0, 2ã]
95.     'from https://mathworld.wolfram.com/EllipticHyperboloid.html
96.  
97.     _glMatrixMode _GL_PROJECTION
98.     _gluPerspective 50, 1, 0.1, 100
99.  
100.     _glMatrixMode _GL_MODELVIEW
101.     a = 1
102.     b = 1
103.     c = 1
104.     STATIC rotY
105.     _glTranslatef 0, 0, -10
106.     _glRotatef rotY, 0, 1, 0
107.     rotY = rotY + 1
108.  
109.     _glPointSize 2
110.     _glBegin _GL_POINTS
111.     FOR u = 0 TO 3 STEP 0.1
112.         FOR v = 0 TO _PI(2) STEP 0.1
113.             x = a * SQR(1 + u ^ 2) * COS(v)
114.             y = c * u
115.             z = b * SQR(1 + u ^ 2) * SIN(v) 'you see, I swap the expression for y and z 'cause in 3D graphics, Y-axis upward
116.  
117.             _glVertex3f x, y, z
118.             _glVertex3f x, -y, z 'creating mirror image
119.         NEXT
120.     NEXT
121.     _glEnd
122. END SUB
123.  

Anyway, I get the feeling the O.P. can't use the GL example, because it is calling internal functions, which he wouldn't be able to explain. There should be ways to draw this out along a 2-D x,y,z projection axis I liked Vince's parallel projection code. I modified it just a bit to draw one line at a time. Very cool...

Code: QB64: [Select]

1. pi = 4 * ATN(1)
2. sw = 640
3. sh = 480
4.  
5. SCREEN 12
6.  
7. t = t + 0.05
8. a = 0
9. b = pi * COS(t) / 3
10. ox = 120 * COS(a - b)
11. oz = 120 * SIN(a - b)
12. oy = -150
13. oxx = 120 * COS(a + b)
14. ozz = 120 * SIN(a + b)
15. oyy = 150
16. LINE (0, 0)-(sw, sh), 0, BF
17. FOR a = 2 * pi / 30 TO 2 * pi STEP 2 * pi / 30
18.     x = 120 * COS(a - b)
19.     z = 120 * SIN(a - b)
20.     y = -150
21.     LINE (sw / 2 + ox + 0.707 * oz, sh / 2 + oy + 0.707 * oz)-(sw / 2 + x + 0.707 * z, sh / 2 + y + 0.707 * z)
22.     ox = x
23.     oy = y
24.     oz = z
25.  
26.     x = 120 * COS(a + b)
27.     z = 120 * SIN(a + b)
28.     y = 150
29.     LINE -(sw / 2 + x + 0.707 * z, sh / 2 + y + 0.707 * z)
30.     LINE -(sw / 2 + oxx + 0.707 * ozz, sh / 2 + oyy + 0.707 * ozz)
31.     oxx = x
32.     oyy = y
33.     ozz = z
34.     SLEEP
35. NEXT
36.  
37. _DISPLAY
38. DO: _LIMIT 10: LOOP UNTIL INKEY$ = CHR$(27)

Pete

I have a mind like a steel trap. Once it's shut, nothing gets in!

[ngr888]

put a string or wire through holes and tie to make circle, then angle them all in same direction.

Much better than strings or wires, for a studio model it is to use rubbers. The 3 axis flexibility is very instructive.

The use of rubbers for the edges would allow the construction to be manipulated so that the 'bases' were more or less separated.
As well as that those bases were not parallel, originating lateral surfaces with different parabolas.
(Sorry, it is difficult to explain without the support of a couple of drawings, but I still do not know how to add them to my post.)

[_vince]

Ok, last one from me, this is an exact clone of that video minus some minor perspective and proportion adjustment

Code: [Select]

dim shared pi, sw, sh
pi = 4*atn(1)
sw = 640
sh = 480

rr = 500
h = 1200

screen 12

do
        for t=0 to h step 10
                line (0,0)-(sw,sh),0,bf
                hyperb rr, t, 0, 0

                _display
                _limit 100
        next

        for b=0 to 0.80*pi/2 step 0.008
                line (0,0)-(sw,sh),0,bf
                hyperb rr, h, b, 0

                _display
                _limit 100
        next

        _delay 0.5

        for rot = 0 to 0.9*pi/2 step 0.01
                line (0,0)-(sw,sh),0,bf
                hyperb rr, h, 0.80*pi/2, rot

                _display
                _limit 100
        next

        _delay 0.5

        for i=0 to 1 step 0.005
                line (0,0)-(sw,sh),0,bf
                hyperb rr, h, (1 - i)*0.80*pi/2, (1 - i)*0.9*pi/2

                _display
                _limit 100
        next

        for t=0 to h step 10
                line (0,0)-(sw,sh),0,bf
                hyperb rr, h-t, 0, 0

                _display
                _limit 100
        next
loop
system

'radius, height, twist, rotate
sub hyperb (r, h, b, rot)
        a = 0
        x = r*cos(a - b)
        z = r*sin(a - b)
        y = -h/2 + 200

        yy = y*cos(rot) - z*sin(rot)
        zz = y*sin(rot) + z*cos(rot)
        y = yy
        z = zz

        ox = x
        oz = z
        oy = y


        x = r*cos(a + b)
        z = r*sin(a + b)
        y = h/2 + 200

        yy = y*cos(rot) - z*sin(rot)
        zz = y*sin(rot) + z*cos(rot)
        y = yy
        z = zz

        oxx = x
        oyy = y
        ozz = z


        for a = 2*pi/30 to 2*pi step 2*pi/30
                x = r*cos(a - b)
                z = r*sin(a - b)
                y = -h/2 + 200

                yy = y*cos(rot) - z*sin(rot)
                zz = y*sin(rot) + z*cos(rot)
                y = yy
                z = zz

                pset  (sw/2 + ox*700/(oz + 2500), sh/2 - 50 + oy*700/(oz + 2500))
                line -(sw/2 +  x*700/( z + 2500), sh/2 - 50 +  y*700/( z + 2500))

                ox = x
                oy = y
                oz = z


                x = r*cos(a + b)
                z = r*sin(a + b)
                y = h/2 + 200

                yy = y*cos(rot) - z*sin(rot)
                zz = y*sin(rot) + z*cos(rot)
                y = yy
                z = zz

                line -(sw/2 +   x*700/(  z + 2500), sh/2 - 50 +   y*700/(  z + 2500))
                line -(sw/2 + oxx*700/(ozz + 2500), sh/2 - 50 + oyy*700/(ozz + 2500))

                oxx = x
                oyy = y
                ozz = z
        next
end sub


edit: fixed

[Pete]

--------->APPLAUSE<--------

[Petr]

Perfect!

[bplus]

Yep, nailed it.