Cartesian Coordinate System Setup for QB64

[bplus]

All the tools are already there, just need a decent demo, try something along lines of STxAxTIC's recent work of art:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Test Using Window for Cartesian Coordinate System x = -100 to 100, y = -100 to 100"
3. 'It seems all graphics commands convert x, y to window system BUT...
4. 'Mouse and _PrintString do not convert! BUT...
5. 'Somebody setup a PMAP system that will do these conversions both to graphics coordinate system and back
6. ' convert mouse qbx, qby to graphics x, y use
7. ' PMAP(qbx, 2), PMAP(qby, 3)
8. ' And to print something at the graphics location use
9. ' PMAP(graphicsX, 0), PMAP(graphicsY, 1) to _PRINTSTRING to a graphics location
10.  
11. CONST xmax = 700, ymax = 700, red = &HFFFF0000, grn = &HFF009900, blu = &HFF0000AA
12. CONST tlx = -100, tly = 100, brx = 100, bry = -100 ' Cartesian Coordinate System corners for WINDOW command
13. SCREEN _NEWIMAGE(xmax, ymax, 32)
14. _SCREENMOVE 300, 40
15.  
16. DIM mx, my, a, r, s$
17.  
18. WINDOW (tlx, tly)-(brx, bry) ' converts QB screen to Cartesian Coodianate System
19. WHILE _KEYDOWN(27) = 0
20.     CLS
21.     WHILE _MOUSEINPUT: WEND
22.     mx = INT(PMAP(_MOUSEX, 2)): my = INT(PMAP(_MOUSEY, 3)) 'covert mouse to Cart Cood using PMAP
23.     a = atan360(my, mx) 'mouse angle to origin
24.     r = INT((mx * mx + my * my) ^ .5)
25.     LINE (0, 0)-(mx, my), grn 'hypotenuse = radius
26.     LINE (0, 0)-(mx, 0), blu ' r*cos
27.     LINE (mx, 0)-(mx, my), red ' r*sin
28.     arc 0, 0, 10, 0, _R2D(a), &HFFFFFF00 'yellow arc
29.     s$ = "Mouse (" + _TRIM$(STR$(mx)) + ", " + _TRIM$(STR$(my)) + "), Radius: "
30.     s$ = s$ + _TRIM$(STR$(r)) + ", Degrees: " + _TRIM$(STR$(_R2D(a) \ 1))
31.     _PRINTSTRING (PMAP(0, 0), PMAP(-1, 1)), s$
32.     _PRINTSTRING (PMAP(-95, 0), PMAP(95, 1)), "COS = x/r = " + _TRIM$(STR$(mx / r))
33.     _PRINTSTRING (PMAP(-95, 0), PMAP(89, 1)), "SIN = y/r = " + _TRIM$(STR$(my / r))
34.      IF mx <> 0 THEN _PRINTSTRING (PMAP(-95, 0), PMAP(83, 1)), "TAN = y/x = " + _TRIM$(STR$(my / mx))  'EDIT
35.     _DISPLAY
36.     _LIMIT 60
37. WEND
38.  
39. ' A regular graphic draw still works correctly in a Cartesian Window System! even the angle goes Counter-Clockwise.
40. 'note: degrees start due East = 0 and go clockwise: South = 90, West = 180, North = 270
41. SUB arc (x, y, r, degStart, degStop, c~&)
42.  
43.     DIM rs, re, a, ax, ay, lastx, lasty
44.     'x, y origin, r = radius, c = color
45.  
46.     'degStart is first angle clockwise from due East = 0 degrees
47.     ' arc will start drawing there and clockwise until degStop angle reached, unless in Cartesain Window
48.  
49.     IF degStop < degStart THEN
50.         arc x, y, r, degStart, 360, c~&
51.         arc x, y, r, 0, degStop, c~&
52.     ELSE
53.         rs = _D2R(degStart): re = _D2R(degStop)
54.         FOR a = rs TO re STEP 1 / (7 * r)
55.             ax = x + r * COS(a)
56.             ay = y + r * SIN(a)
57.             IF a <> rs THEN LINE (lastx, lasty)-(ax, ay), c~&
58.             lastx = ax: lasty = ay
59.         NEXT
60.     END IF
61. END SUB
62.  
63. 'Do need to match degrees going around clockwise up to full circle to avoid negative angles
64. FUNCTION atan360 (y, x)
65.     DIM test
66.     test = _ATAN2(y, x)
67.     IF test < 0 THEN atan360 = _PI(2) + test ELSE atan360 = test
68. END FUNCTION
69.  
70.  

EDIT: I had the ratio for tangent wrong, it is rise over run just like slope of a line, sin/cos or y/x here.

[Petr]

Excellent!

[STxAxTIC]

My only beef is this comment:

Code: QB64: [Select]

1. 'note: degrees start due East = 0 and go clockwise: South = 90, West = 180, North = 270
2.  

I believe north and south are flipped good sir. Angles should go counterclockwise, which I think is correct in the actual code.

[bplus]

My only beef is this comment:

Code: QB64: [Select]

1. 'note: degrees start due East = 0 and go clockwise: South = 90, West = 180, North = 270
2.  

I believe north and south are flipped good sir. Angles should go counterclockwise, which I think is correct in the actual code.

Hi STxAxTIC,

That comment was leftover from the original arc code, explaining how normal QB64 graphics go. The amazing thing is that it works with the Cartesian system such that the angles do increase in Counter-Clockwise direction without any change of the drawing code! I thought the comment above it, that applies to the demo would over-ride it.

' A regular graphic draw still works correctly in a Cartesian Window System! even the angle goes Counter-Clockwise.

[STxAxTIC]

Ah, that clears it up. You da man.

[Jack002]

Very cool. Excellent work!

[TempodiBasic]

Cool!
It is clear trigonometry in this way :-) You can see directly it!