What would Pythagoras think of computers and programming? He would love QB64!

Alright, here are some things that I would like you to improve in this game:
You can't press the upper arrow key? Like come on! I don't know if it is because of the fault in your code but PLEASE FIX IT!
And the transition is REALLY REALLY LONG!!!

Those are my only complaints! But still, really nice game I would say! Keep working on it!

Oh, you mean like this?

Code: QB64: [Select]

1. DEFINT I
2. DECLARE SUB instructions ()
3. DECLARE SUB qbide ()
4. DECLARE SUB mship (imothership)
5. REM Adds multiple bullets (5) max.
6. REM Adds firing delay and ship turns red while reloading.
7. REM Adds aliens.
8. REM Adds collision for bullets from base to aliens.
9. REM Adds Mouse support.
10. REM Adds alien motion.
11. REM Adds 3 progressive levels.
12. REM Adds aliens move all the way to both sides.
13. REM Adds Aliens shoot back.
14. REM Adds sub-routines.
15. REM Adds counter.
16. REM Adds alien bullets finish before moving on to next level.
17. REM Adds mothership.
18.  
19. DECLARE SUB alienattack (ialiencolstat, ialiencol)
20. DECLARE SUB alienmissile (iresults)
21. DECLARE SUB checkcollision (ihitaliens, ialiencol, i4, i)
22. DECLARE SUB mdriver (ex%, key$, tankx%)
23. DECLARE SUB marchdown (ialiencol, ialiencolstat, imotion, iresults)
24. DECLARE SUB movealiens (ialiencol, ialiencolstat, iresults)
25. DECLARE SUB reprintaliens (ialiencol, ihitaliens, iresults, i4, i, imothership)
26.  
27. TYPE RegType
28.     AX AS INTEGER
29.     BX AS INTEGER
30.     CX AS INTEGER
31.     DX AS INTEGER
32.     BP AS INTEGER
33.     SI AS INTEGER
34.     DI AS INTEGER
35.     FLAGS AS INTEGER
36.     DS AS INTEGER
37.     ES AS INTEGER
38. END TYPE
39.  
40. DIM SHARED MOUSE$
41. DIM SHARED Registers AS RegType
42. DIM SHARED LB%, RB%, MB%, DX, CX
43. DIM SHARED lmargin%, rmargin%, topmargin%, screenwidth%, level, ibk, ileadingrow
44. DIM SHARED irow, icol, inextrnd, imaxalienmissiles, alienforce%, ileadingmax, imaxalienforce, ihits
45.  
46. imaxalienforce = 6
47. imaxalienmissiles = 3
48. lmargin% = 2
49. rmargin% = 79
50. topmargin% = 3
51. ialiencolstat = 6
52. iwin = 3
53. screenwidth% = rmargin% - lmargin% + 1
54. ibk = 1
55.  
56. DIM SHARED a(imaxalienforce) AS STRING * 68
57.  
58. RANDOMIZE TIMER
59. SCREEN 0, 0, 0, 0
60. COLOR 7, 1: CLS
61.  
62. REM Make aliens
63. a1$ = "-<" + CHR$(237) + ">-  "
64. a$ = a1$ + a1$ + a1$ + a1$ + a1$ + a1$ + a1$ + a1$ + a1$ + a1$
65.  
66. CALL qbide
67. CALL instructions
68.  
69. DO
70.     IF inextrnd = -1 THEN PCOPY 3, 0
71.     tank$ = CHR$(218) + CHR$(127) + CHR$(191): icolor = 7
72.     REDIM SHARED bullet%(5), bulletcol%(5), bulletdelay%(5), iltalien(imaxalienforce)
73.     REDIM SHARED ia(imaxalienmissiles), iy(imaxalienmissiles), ix(imaxalienmissiles)
74.     REDIM SHARED matrix(imaxalienforce) AS STRING * 10
75.     alienforce% = imaxalienforce
76.     level = .65
77.     iround = iround + 1
78.     level = level - iround / 15
79.     inextrnd = -1
80.     COLOR 7, ibk
81.  
82.     REM Set up aliens
83.     ialiencol = ialiencolstat
84.     LOCATE 2, ialiencol
85.     FOR i = 1 TO imaxalienforce
86.         IF i MOD 1 = 0 THEN PRINT
87.         LOCATE , ialiencol
88.         IF i = imaxalienforce THEN ileadingrow = CSRLIN: ileadingmax = ileadingrow
89.         a(i) = a$
90.         PRINT a(i)
91.     NEXT
92.  
93.     REM Station
94.     LOCATE 24, 40, 1, 7, 7
95.     PRINT tank$;: LOCATE , POS(1) - 2: tanky% = CSRLIN: tankx% = POS(1) + 1
96.     key$ = INKEY$: SLEEP 1
97.     ex% = 1: CALL mdriver(ex%, key$, tankx%)
98.     DO
99.         z1 = TIMER
100.         DO
101.             IF topmargin% + ileadingmax - (imaxalienforce * 2) >= topmargin% + 2 THEN
102.                 IF imothership <> 0 THEN CALL mship(imothership)
103.             END IF
104.             IF ABS(TIMER - z1aliens) > level THEN
105.                 CALL movealiens(ialiencol, ialiencolstat, iresults)
106.                 z1aliens = TIMER
107.             END IF
108.             IF iresults < 0 THEN EXIT DO
109.             IF ABS(TIMER - z1ia) > .3 THEN CALL alienmissile(iresults): z1ia = TIMER
110.             key$ = INKEY$
111.             IF key$ = "" THEN ex% = 2: CALL mdriver(ex%, key$, tankx%)
112.             SELECT CASE key$
113.                 CASE CHR$(0) + "K"
114.                     IF POS(1) > lmargin% + 1 THEN COLOR icolor, ibk: LOCATE , POS(1) - 2: PRINT tank$ + " ";: LOCATE , POS(1) - 3
115.                     tanky% = CSRLIN: tankx% = POS(1)
116.                     IF SCREEN(tanky%, tankx% - 2) = 25 OR SCREEN(tanky%, tankx% + 2) = 25 THEN result = -1: EXIT DO
117.                 CASE CHR$(0) + "M"
118.                     IF POS(1) < screenwidth% THEN COLOR icolor, ibk: LOCATE , POS(1) - 1: PRINT " " + tank$;: LOCATE , POS(1) - 2
119.                     tanky% = CSRLIN: tankx% = POS(1)
120.                     IF SCREEN(tanky%, tankx% - 2) = 25 OR SCREEN(tanky%, tankx% + 2) = 25 THEN result = -1: EXIT DO
121.                 CASE CHR$(32)
122.                     IF icolor = 7 THEN
123.                         FOR i2 = 1 TO 5
124.                             IF bullet%(i2) = 0 THEN
125.                                 icolor = 12: COLOR icolor, ibk: GOSUB redraw
126.                                 bullet%(i2) = -1: reload = TIMER: EXIT FOR
127.                             END IF
128.                         NEXT
129.                     END IF
130.                 CASE CHR$(27): SYSTEM
131.             END SELECT
132.  
133.             IF ABS(z1 - reload) > .7 AND reload <> 0 THEN
134.                 GOSUB redraw
135.                 icolor = 7: reload = 0
136.             END IF
137.  
138.             REM Fire
139.             FOR i = 1 TO 5
140.                 SELECT CASE bullet%(i)
141.                     CASE -1: bullet%(i) = tanky% - 1: bulletcol%(i) = tankx%
142.                     CASE IS > 0
143.                         IF bulletdelay%(i) = -1 OR bullet%(i) = tanky% - 1 THEN
144.                             CALL checkcollision(ihitaliens, ialiencol, i4, i)
145.                             z2bullet = TIMER: bulletdelay%(i) = 0
146.                             COLOR 7, ibk
147.                             LOCATE bullet%(i), bulletcol%(i)
148.                             IF bullet%(i) = topmargin% AND imothership <> 0 THEN
149.                                 IF SCREEN(ABS(bullet%(i)), bulletcol%(i)) <> 32 THEN
150.                                     SOUND 1000, .75
151.                                     LOCATE topmargin%, lmargin%: PRINT SPACE$(screenwidth%);
152.                                     imothership = 0
153.                                 END IF
154.                             END IF
155.                             PRINT CHR$(24)
156.                             IF CSRLIN <> 24 THEN LOCATE , bulletcol%(i): PRINT " ";
157.                             IF ihitaliens <> 0 THEN CALL reprintaliens(ialiencol, ihitaliens, iresults, i4, i, imothership)
158.                             LOCATE tanky%, tankx%
159.                             IF bullet%(i) > topmargin% THEN
160.                                 bullet%(i) = bullet%(i) - 1
161.                             ELSE
162.                                 GOSUB erasebullet
163.                             END IF
164.                         END IF
165.                 END SELECT
166.             NEXT
167.  
168.             REM Bullet timer delay
169.             IF z2bullet <> 0 THEN
170.                 IF z1 < z2bullet THEN z2bullet = z2bullet - 86400
171.                 IF z1 - z2bullet >= .06 THEN
172.                     FOR i2 = 1 TO 5
173.                         IF bullet%(i2) <> 0 THEN bulletdelay%(i2) = -1
174.                     NEXT i2
175.                 END IF
176.                 EXIT DO
177.             END IF
178.         LOOP
179.         IF iresults < 0 THEN EXIT DO
180.         IF alienforce% = 0 OR iresults = iwin THEN
181.             FOR i = 1 TO imaxalienmissiles
182.                 IF ia(i) <> 0 THEN EXIT FOR
183.             NEXT
184.             IF i > imaxalienmissiles THEN iwait = -1
185.             IF iwait = -1 THEN
186.                 EXIT DO
187.             END IF
188.         ELSE
189.             iwait = 1
190.         END IF
191.     LOOP
192.     ex% = -1: CALL mdriver(ex%, key$, tankx%)
193.     key$ = INKEY$
194.     SLEEP 2
195.     IF iresults = iwin OR iresults < 0 THEN
196.         REM end game
197.         EXIT DO
198.     END IF
199.     inextrnd = -1
200. LOOP
201. SELECT CASE iresults
202.     CASE IS < 0
203.         COLOR 7, ibk
204.         LOCATE tanky% - 1, lmargin%
205.         PRINT SPACE$(screenwidth%);
206.         LOCATE tanky%, lmargin%
207.         PRINT SPACE$(screenwidth%);
208.         key$ = INKEY$
209.         SOUND 140, 2
210.         SLEEP 2
211. END SELECT
212. CALL qbide
213. CALL instructions
214. SYSTEM
215.  
216. erasebullet:
217. LOCATE ABS(bullet%(i)), bulletcol%(i): PRINT " ";
218. bullet%(i) = 0: bulletcol%(i) = 0: bulletdelay%(i) = 0
219. LOCATE tanky%, tankx%
220. RETURN
221.  
222. redraw:
223. COLOR , ibk: LOCATE tanky%, tankx% - 1: PRINT tank$;: LOCATE tanky%, tankx%: COLOR 7, ibk
224. RETURN
225.  
226. DATA "Well, I better get busy and finish the compiler..."
227. DATA "Or... I'll just do some more work on this IDE, instead..."
228. DATA ""
229. DATA " Loading..."
230. DATA "EOF"
231. DATA "Game Over. Thanks for playing..."
232. DATA ""
233. DATA "Now finish the compiler!"
234. DATA "EOF2"
235.  
236. SUB alienattack (ialiencolstat, ialiencol)
237. z2alienfire = TIMER
238.  
239. i3 = INT(RND * 10)
240. FOR i = 1 TO imaxalienmissiles
241.     IF ia(i) = 0 THEN
242.         FOR i2 = imaxalienforce TO 1 STEP -1
243.             IF RTRIM$(a(i2)) <> "" THEN
244.                 IF MID$(matrix(i2), i3 + 1, 1) <> "0" THEN
245.                     i4 = INSTR(i3 * 7 + 1, a(i2), CHR$(237)) + ialiencol
246.                     EXIT FOR
247.                 END IF
248.             END IF
249.         NEXT i2
250.         IF i4 <> 0 THEN
251.             ia(i) = (ileadingmax - (imaxalienforce - i2) * 2) * 80 + i4
252.             EXIT FOR
253.         END IF
254.     END IF
255. NEXT i
256.  
257. END SUB
258.  
259. SUB alienmissile (iresults)
260. irow = CSRLIN: icol = POS(1)
261. FOR i = 1 TO imaxalienmissiles
262.     IF ia(i) <> 0 THEN
263.         IF iy(i) = 0 THEN
264.             iy(i) = ia(i) \ 80: ix(i) = ia(i) MOD 80
265.             IF ix(i) = 0 THEN ix(i) = screenwidth%
266.         END IF
267.         LOCATE iy(i) + 1, ix(i)
268.         COLOR 7, ibk
269.         IF CSRLIN <= 24 THEN
270.             IF CSRLIN = 24 THEN IF SCREEN(CSRLIN, ix(i)) <> 32 THEN iresults = -1
271.             PRINT CHR$(25);
272.         ELSE
273.             ia(i) = 0
274.             LOCATE iy(i), ix(i)
275.             PRINT " ";: iy(i) = 0
276.             ia(i) = 0
277.             LOCATE irow, icol
278.             EXIT SUB
279.         END IF
280.         LOCATE iy(i), ix(i): PRINT " ";
281.         iy(i) = iy(i) + 1
282.     END IF
283. NEXT
284. LOCATE irow, icol
285.  
286. END SUB
287.  
288. SUB checkcollision (ihitaliens, ialiencol, i4, i)
289. ihitaliens = 0
290. IF ileadingmax MOD 2 = bullet%(i) MOD 2 THEN
291.     i4 = imaxalienforce - (ileadingmax - bullet%(i)) \ 2
292.     IF bullet%(i) <= ileadingrow AND i4 > 0 AND i4 <= imaxalienforce THEN
293.         IF RTRIM$(a(i4)) <> "" THEN
294.             IF bulletcol%(i) >= iltalien(i4) AND bulletcol%(i) - ialiencol <= LEN(RTRIM$(a(i4))) THEN
295.                 IF MID$(a(i4), bulletcol%(i) - ialiencol, 1) > CHR$(32) THEN
296.                     ihitaliens = bulletcol%(i) - ialiencol + 1
297.                     i3 = ihitaliens - 7 + 1: IF i3 < 1 THEN i3 = 1: REM count from the "<" symbol.
298.                     i2 = INSTR(i3 + 1, a(i4), "<") - 1
299.                     MID$(a(i4), i2, 7) = SPACE$(7)
300.                     MID$(matrix(i4), (i2 + 1) \ 7 + 1, 1) = "0"
301.                 END IF
302.             END IF
303.         END IF
304.     END IF
305. END IF
306.  
307. FOR i2 = 1 TO imaxalienmissiles
308.     IF ia(i2) <> 0 THEN
309.         IF iy(i2) >= bullet%(i) AND ix(i2) = bulletcol%(i) THEN
310.             ihitaliens = -i2
311.             EXIT FOR
312.         END IF
313.     END IF
314. NEXT
315.  
316. END SUB
317.  
318. SUB instructions
319.  
320. ''in$ = "EOF"
321. IF in$ = "" THEN
322.     key$ = INKEY$
323.     LOCATE 3, 3, 1, 7, 7: COLOR 7, ibk
324.     SLEEP 2
325.     DO
326.         READ in$
327.         IF MID$(in$, 1, 3) = "EOF" THEN EXIT DO
328.         FOR i = 1 TO LEN(in$)
329.             SOUND 400, .1
330.             LOCATE , 2 + i
331.             PRINT MID$(in$, i, 1);
332.             z = TIMER
333.             DO
334.                 IF ABS(z - TIMER) > .1 THEN EXIT DO
335.             LOOP
336.         NEXT
337.         LOCATE , , 0, 7, 0
338.         key$ = INKEY$
339.         SLEEP 1
340.         PRINT
341.         LOCATE , 3
342.     LOOP
343.     key$ = INKEY$
344.     SLEEP 1
345. END IF
346.  
347. IF in$ = "EOF" THEN
348.     COLOR 7, 1
349.     FOR i = 1 TO 5
350.         LOCATE 2 + i, 2: PRINT SPACE$(78)
351.     NEXT
352.     FOR i = 3 TO 24
353.         LOCATE i, 80: PRINT CHR$(179);
354.     NEXT
355.     LOCATE 21, 2: PRINT STRING$(78, " ");
356.     LOCATE 22, 1: PRINT CHR$(179);
357.     LOCATE 22, 80: PRINT CHR$(179);
358.     LOCATE 22, 2: PRINT STRING$(78, " ");
359. ELSE
360.     COLOR 0, 3
361. END IF
362.  
363. COLOR 0, 3
364. yy% = CSRLIN: xx% = POS(1)
365. LOCATE 25, 76 - LEN(LTRIM$(STR$(ihits)))
366. PRINT LTRIM$(STR$(ihits));
367. LOCATE 25, 80 - LEN(LTRIM$(STR$(imaxalienforce - alienforce%)))
368. PRINT "0";
369. LOCATE yy%, xx%
370.  
371. PCOPY 0, 3: REM save skin
372.  
373. END SUB
374.  
375. SUB marchdown (ialiencol, ialiencolstat, imotion, iresults)
376. COLOR 7, ibk
377. ileadingrow = ileadingrow + 1
378. ileadingmax = ileadingmax + 1
379. COLOR 7, ibk
380. FOR i = 1 TO imaxalienforce
381.     IF RTRIM$(a(i)) <> "" THEN
382.         ialiencol = ialiencolstat + imotion
383.         LOCATE ileadingmax - (imaxalienforce * 2) + i * 2 - 1, lmargin%
384.         PRINT STRING$(screenwidth%, " ")
385.         LOCATE , ialiencol + INSTR(a(i), "-")
386.         iltalien(i) = POS(1)
387.         PRINT LTRIM$(RTRIM$(a(i)))
388.     END IF
389. NEXT
390. LOCATE irow, icol
391. level = level - .025
392. IF ileadingrow = 22 THEN iresults = -2
393. END SUB
394.  
395. DEFSNG I
396. SUB mdriver (ex%, key$, tankx%)
397. STATIC MOUSEACT%
398.  
399. REM INITIATE MOUSE
400. IF MOUSEACT% = 0 OR ex% = -1 THEN
401.     Registers.AX = 0: GOSUB CALLI
402.     MOUSEACT% = 1
403. END IF
404.  
405. IF ex% = 1 THEN
406.     Registers.AX = 4: Registers.DX = 184: Registers.CX = 304
407.     Registers.AX = 8: Registers.DX = 184: Registers.CX = 184
408.     GOSUB CALLI
409.     EXIT SUB
410. END IF
411.  
412. Registers.AX = 3: GOSUB CALLI
413.  
414. DX = Registers.DX
415. CX = Registers.CX
416. y% = DX \ 8 + 1: x% = CX \ 8 + 1
417.  
418. REM MOUSE BUTTONS
419. LB% = Registers.BX AND 1
420. RB% = (Registers.BX AND 2) \ 2
421. MB% = (Registers.BX AND 4) \ 4
422.  
423. IF LB% <> 0 THEN
424.     key$ = CHR$(32)
425. ELSE
426.     IF x% > tankx% THEN key$ = CHR$(0) + "M"
427.     IF x% < tankx% THEN key$ = CHR$(0) + "K"
428. END IF
429. EXIT SUB
430.  
431. CALLI:
432. CALL INTERRUPT(&H33, Registers, Registers)
433. RETURN
434.  
435. END SUB
436.  
437. DEFINT I
438. SUB movealiens (ialiencol, ialiencolstat, iresults)
439. STATIC imotion, imarch, imotiondir
440. IF inextrnd = -1 THEN inextrnd = 0: imotion = 0: imarch = 0: imotiondir = 0
441. irow = CSRLIN: icol = POS(1)
442. yy% = CSRLIN: xx% = POS(1)
443. PCOPY 0, 1: SCREEN 0, 0, 1, 0: LOCATE yy%, xx%, 0, 7, 0
444. IF imotiondir = 0 THEN imotion = imotion - 1 ELSE imotion = imotion + 1
445. COLOR 7, ibk
446.  
447. FOR i = imaxalienforce TO 1 STEP -1
448.     IF RTRIM$(a(i)) <> "" THEN
449.         i2 = i2 + 2
450.         SOUND 400, .03
451.         ialiencol = ialiencolstat + imotion
452.         LOCATE ileadingmax - (imaxalienforce - i) * 2, ialiencol + INSTR(a(i), "-")
453.         IF POS(1) = lmargin% THEN imarch = 1
454.         iltalien(i) = POS(1)
455.         IF imotiondir = 0 THEN
456.             PRINT LTRIM$(RTRIM$(a(i))); " "
457.         ELSE
458.             LOCATE , POS(1) - 1
459.             PRINT " "; LTRIM$(RTRIM$(a(i)))
460.         END IF
461.         IF ialiencol + LEN(RTRIM$(a(i))) = screenwidth% THEN imarch = -1
462.     END IF
463. NEXT
464.  
465. IF imarch = 1 THEN imotiondir = 1: CALL marchdown(ialiencol, ialiencolstat, imotion, iresults)
466. IF imarch = -1 THEN imotiondir = 0: CALL marchdown(ialiencol, ialiencolstat, imotion, iresults)
467. IF imarch = 0 THEN
468.     IF ABS(TIMER - z2alienfire) > firerate THEN
469.         firerate = (INT(RND * 10) + 1) / 20
470.         IF iwait = 0 THEN CALL alienattack(ialiencolstat, ialiencol)
471.     END IF
472. ELSE
473.     imarch = 0
474. END IF
475. PCOPY 1, 0: SCREEN 0, 0, 0, 0
476. LOCATE irow, icol, 1, 7, 7
477. END SUB
478.  
479. SUB mship (imothership)
480. STATIC x%, mov%, z4, mothership$
481.  
482. yy% = CSRLIN: xx% = POS(1): COLOR 7, ibk
483. IF imothership = -1 THEN
484.     imothership = 1
485.     x% = lmargin%
486.     mothership$ = CHR$(254) + CHR$(254) + "O" + CHR$(254) + CHR$(254)
487.     mov% = 1
488. END IF
489.  
490. IF ABS(TIMER - z4) > .05 THEN GOSUB mothership: z4 = TIMER: LOCATE yy%, xx%: EXIT SUB
491. ''IF ABS(TIMER - z2) > .2 THEN GOSUB bullets: z2 = TIMER
492. LOCATE yy%, xx%
493. EXIT SUB
494.  
495. mothership:
496. IF x% + LEN(mothership$) = screenwidth% + lmargin% THEN mov% = -1 ELSE IF x% = lmargin% THEN mov% = 1
497. x% = x% + mov%
498. LOCATE topmargin%, x%
499. PRINT mothership$;
500. IF x% > 1 AND mov% = 1 THEN
501.     LOCATE , POS(1) - LEN(mothership$) - 1: PRINT " ";
502. END IF
503. IF mov% = -1 THEN PRINT " ";
504. RETURN
505.  
506. END SUB
507.  
508. DEFINT A-H, J-Z
509. SUB qbide
510. PALETTE 2, 59
511. COLOR 15, 1
512. CLS
513.  
514. COLOR 0, 7
515. LOCATE 1, 1
516. PRINT SPACE$(80)
517. LOCATE 1, 1: PRINT "   File  Edit  View  Search  Run  Debug  Calls  Options                   Help"
518.  
519. COLOR 7, 1
520.  
521. LOCATE 2, 1: PRINT CHR$(218)
522. LOCATE 2, 2: PRINT STRING$(78, CHR$(196))
523. LOCATE 2, 80: PRINT CHR$(191)
524.  
525. LOCATE 2, 76: PRINT CHR$(180)
526. LOCATE 2, 78: PRINT CHR$(195)
527.  
528. COLOR 1, 7
529. LOCATE 2, 77: PRINT CHR$(24)
530. LOCATE 2, 36: PRINT " Untitled "
531.  
532. COLOR 7, 1
533. FOR Rows = 3 TO 24
534.     LOCATE Rows, 1: PRINT CHR$(179);
535.     LOCATE Rows, 80: PRINT CHR$(179);
536. NEXT Rows
537.  
538. LOCATE 22, 1: PRINT CHR$(195)
539. LOCATE 22, 80: PRINT CHR$(180)
540. LOCATE 22, 2: PRINT STRING$(78, CHR$(196))
541. LOCATE 22, 35
542. PRINT " Immediate "
543.  
544. COLOR 0, 7
545. LOCATE 21, 3: PRINT STRING$(76, CHR$(176))
546. LOCATE 21, 2: PRINT CHR$(27)
547. LOCATE 21, 3: PRINT CHR$(219)
548. LOCATE 21, 79: PRINT CHR$(26)
549. FOR Rows = 4 TO 19
550.     LOCATE Rows, 80: PRINT CHR$(176)
551. NEXT Rows
552. LOCATE 3, 80: PRINT CHR$(24)
553. LOCATE 4, 80: PRINT CHR$(219)
554. LOCATE 20, 80: PRINT CHR$(25)
555.  
556. COLOR 0, 3: LOCATE 25, 1: PRINT " <Shift+F1=Help> <F6=Window> <F2=Subs> <F5=Run> <F8=Step> ";
557. LOCATE 25, 59: PRINT SPACE$(4);
558. COLOR 0, 3
559. LOCATE 25, 63: PRINT CHR$(179);
560. LOCATE 25, 64: PRINT SPACE$(6);
561. LOCATE 25, 68: PRINT "C  00001:001 ";
562.  
563. END SUB
564.  
565. DEFSNG A-H, J-Z
566. SUB reprintaliens (ialiencol, ihitaliens, iresults, i4, i, imothership)
567. IF ihitaliens > 0 THEN
568.     ihits = ihits + 1
569.     IF (ihits + 15) MOD 20 = 0 AND imothership = 0 THEN imothership = -1
570.     LOCATE bullet%(i), lmargin%: PRINT SPACE$(screenwidth%);
571.     iltalien(i4) = POS(1)
572.  
573.     IF RTRIM$(a(i4)) = "" THEN
574.         alienforce% = alienforce% - 1
575.         IF alienforce% = 0 THEN iresults = iresults + 1
576.         IF bullet%(i) = ileadingrow THEN ileadingrow = ileadingrow - 2
577.     ELSE
578.         LOCATE bullet%(i), ialiencol + INSTR(a(i4), "-"): PRINT LTRIM$(RTRIM$(a(i4)))
579.     END IF
580. ELSE
581.     i2 = ABS(ihitaliens)
582.     LOCATE iy(i2), ix(i2)
583.     PRINT " ";: iy(i2) = 0
584.     ia(i2) = 0
585.     LOCATE irow, icol
586.     SOUND 1000, .5
587. END IF
588.  
589. ihitaliens = 0
590. bullet%(i) = -bullet%(i)
591.  
592. COLOR 0, 3
593. yy% = CSRLIN: xx% = POS(1)
594. LOCATE 25, 76 - LEN(LTRIM$(STR$(ihits)))
595. PRINT LTRIM$(STR$(ihits));
596. LOCATE 25, 80 - LEN(LTRIM$(STR$(imaxalienforce - alienforce%)))
597. PRINT LTRIM$(STR$(imaxalienforce - alienforce%));
598. LOCATE yy%, xx%
599. COLOR 7, ibk
600. END SUB
601.  

Edit: Hey, I found the mother ship version! Mouse to move, left click to shoot.