Ball Breaker

[SMcNeill]

Code: QB64: [Select]

1. CONST Blue = &HFF0000FF~& ' _RGB32(0,0,255)
2. CONST Brown = &HFFA52A2A~& ' _RGB32(165,42,42)
3. CONST BrickRed = &HFFCB4154~& '_RGB32(203,65,84)
4. CONST Red = &HFFFF0000~&
5. CONST SkyBlue = &HFF87CEEB~& ' _RGB32(135,206,235)
6.  
7.  
8. DEFLNG A-Z
9. RANDOMIZE TIMER
10. WS = _NEWIMAGE(640, 480, 32)
11. SCREEN WS
12. _SCREENMOVE _MIDDLE
13.  
14. TYPE BulletInfo
15.     valid AS INTEGER
16.     x AS INTEGER
17.     y AS INTEGER
18. END TYPE
19.  
20. TYPE BallInfo
21.     valid AS INTEGER
22.     originalsize AS INTEGER
23.     size AS INTEGER
24.     x AS INTEGER
25.     y AS INTEGER
26.     movex AS INTEGER
27.     movey AS INTEGER
28. END TYPE
29.  
30. DIM SHARED Ball(100) AS BallInfo
31. DIM SHARED Bullet(100) AS BulletInfo
32. DIM SHARED ROF AS INTEGER
33. DIM SHARED Ammo AS LONG
34. DIM SHARED GameOver AS LONG
35. DIM SHARED score
36.  
37. CLS , SkyBlue
38. LINE (0, 479)-(639, 460), Brown, BF
39. PCOPY 0, 1 'Save as the background
40. x = 290
41. ROF = 50
42. Ammo = 1000
43.  
44. DO
45.     PCOPY 1, 0
46.     _LIMIT 180
47.     IF _KEYDOWN(19200) THEN
48.         x = x - 1
49.     ELSEIF _KEYDOWN(19712) THEN
50.         x = x + 1
51.     END IF
52.     IF x < 0 THEN x = 0
53.     IF x > 570 THEN x = 570
54.     IF _KEYDOWN(27) THEN GameOver = -1
55.     IF _KEYDOWN(32) THEN Shoot x
56.  
57.     GenerateBall
58.  
59.     DrawBalls
60.     DrawPlayer x
61.     DrawBullets
62.  
63.     DrawStatus
64.     _DISPLAY
65. LOOP UNTIL GameOver
66.  
67. DO
68.     _LIMIT 30
69. LOOP UNTIL _KEYDOWN(27)
70. END
71.  
72. SUB DrawBalls
73.     FOR i = 1 TO 100
74.         IF Ball(i).valid THEN
75.             Ball(i).x = Ball(i).x - Ball(i).movex
76.             Ball(i).y = Ball(i).y - Ball(i).movey
77.             IF Ball(i).x < Ball(i).size THEN Ball(i).x = Ball(i).size: Ball(i).movex = -Ball(i).movex
78.             IF Ball(i).y < -Ball(i).size THEN Ball(i).y = -Ball(i).size: Ball(i).movey = -Ball(i).movey
79.             IF Ball(i).x > 640 - Ball(i).size THEN Ball(i).x = 640 - Ball(i).size: Ball(i).movex = -Ball(i).movex
80.             IF Ball(i).y > 460 - Ball(i).size THEN Ball(i).y = 460 - Ball(i).size: Ball(i).movey = -Ball(i).movey
81.             CircleFill Ball(i).x, Ball(i).y, Ball(i).size, _RGB32(0, 0, 255 - i * 2)
82.         END IF
83.     NEXT
84. END SUB
85.  
86.  
87. SUB GenerateBall
88.     STATIC Spawn AS _FLOAT
89.     IF ExtendedTimer > Spawn + 2 THEN
90.         Spawn = ExtendedTimer
91.         FOR i = 1 TO 100
92.             IF Ball(i).valid = 0 THEN
93.                 Ball(i).valid = -1
94.                 Ball(i).x = RND * 640 + 1
95.                 Ball(i).size = RND * 91 + 10
96.                 Ball(i).y = -Ball(i).size
97.                 Ball(i).originalsize = Ball(i).size
98.                 Ball(i).movey = -RND * 3 + 1
99.                 Ball(i).movex = 1 - RND * 3
100.                 EXIT SUB
101.             END IF
102.         NEXT
103.     END IF
104. END SUB
105.  
106.  
107. SUB DrawStatus
108.     _PRINTSTRING (10, 462), "AMMO:" + STR$(Ammo)
109.     _PRINTSTRING (560, 462), TIME$
110.     _PRINTSTRING (200, 462), "SCORE:" + STR$(score)
111. END SUB
112.  
113. SUB DrawPlayer (x)
114.     FOR x1 = x TO x + 69
115.         FOR y1 = 445 TO 459
116.             IF POINT(x1, y1) <> SkyBlue THEN GameOver = -1
117.         NEXT
118.     NEXT
119.     FOR x1 = x + 10 TO x + 59
120.         FOR y1 = 425 TO 444
121.             IF POINT(x1, y1) <> SkyBlue THEN GameOver = -1
122.         NEXT
123.     NEXT
124.     FOR x1 = x + 30 TO x + 39
125.         FOR y1 = 415 TO 424
126.             IF POINT(x1, y1) <> SkyBlue THEN GameOver = -1
127.         NEXT
128.     NEXT
129.     LINE (x, 445)-STEP(70, 15), Red, BF
130.     LINE (x + 10, 425)-STEP(50, 20), Red, BF
131.     LINE (x + 30, 415)-STEP(10, 10), Red, BF
132. END SUB
133.  
134. SUB DrawBullets
135.     DIM P AS _UNSIGNED LONG
136.     FOR i = 1 TO 100
137.         IF Bullet(i).valid THEN
138.             Bullet(i).y = Bullet(i).y - 1
139.             IF Bullet(i).y < 0 THEN Bullet(i).valid = 0: _CONTINUE
140.             P = POINT(Bullet(i).x, Bullet(i).y)
141.             IF P <> SkyBlue THEN
142.                 Bullet(i).valid = 0
143.                 B = (255 - _BLUE32(P)) / 2
144.                 Ball(B).size = Ball(B).size - 1: score = score + 1
145.                 IF Ball(B).size < 10 THEN Ball(B).valid = 0: Ammo = Ammo + Ball(B).originalsize
146.                 _CONTINUE
147.             END IF
148.  
149.             LINE (Bullet(i).x, Bullet(i).y)-STEP(3, 5), BrickRed, BF
150.         END IF
151.     NEXT
152.     IF Ammo = 0 THEN
153.         FOR i = 1 TO 100
154.             IF Bullet(i).valid THEN EXIT SUB
155.         NEXT
156.         GameOver = -1 'once you're out of bullets and there's none left on the screen, the game is over.
157.     END IF
158. END SUB
159.  
160.  
161. SUB Shoot (x)
162.     STATIC Delay AS _FLOAT
163.     IF ExtendedTimer > Delay + ROF / 1000 THEN 'only shoot once every Rate Of Fire
164.         FOR i = 1 TO 100
165.             IF Bullet(i).valid = 0 THEN
166.                 Bullet(i).valid = -1
167.                 Bullet(i).x = x + 33
168.                 Bullet(i).y = 410
169.                 Ammo = Ammo - 1
170.                 Delay = ExtendedTimer
171.                 EXIT SUB
172.             END IF
173.         NEXT
174.     END IF
175. END SUB
176.  
177.  
178. FUNCTION ExtendedTimer##
179.     d$ = DATE$
180.     l = INSTR(d$, "-")
181.     l1 = INSTR(l + 1, d$, "-")
182.     m = VAL(LEFT$(d$, l))
183.     d = VAL(MID$(d$, l + 1))
184.     y = VAL(MID$(d$, l1 + 1)) - 1970
185.     FOR i = 1 TO m
186.         SELECT CASE i 'Add the number of days for each previous month passed
187.             CASE 1: d = d 'January doestn't have any carry over days.
188.             CASE 2, 4, 6, 8, 9, 11: d = d + 31
189.             CASE 3: d = d + 28
190.             CASE 5, 7, 10, 12: d = d + 30
191.         END SELECT
192.     NEXT
193.     FOR i = 1 TO y
194.         d = d + 365
195.     NEXT
196.     FOR i = 2 TO y STEP 4
197.         IF m > 2 THEN d = d + 1 'add an extra day for leap year every 4 years, starting in 2016
198.     NEXT
199.     s~&& = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
200.     ExtendedTimer## = (s~&& + TIMER)
201. END FUNCTION
202.  
203. SUB CircleFill (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
204.     ' CX = center x coordinate
205.     ' CY = center y coordinate
206.     '  R = radius
207.     '  C = fill color
208.     DIM Radius AS INTEGER, RadiusError AS INTEGER
209.     DIM X AS INTEGER, Y AS INTEGER
210.     Radius = ABS(R)
211.     RadiusError = -Radius
212.     X = Radius
213.     Y = 0
214.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
215.     LINE (CX - X, CY)-(CX + X, CY), C, BF
216.     WHILE X > Y
217.         RadiusError = RadiusError + Y * 2 + 1
218.         IF RadiusError >= 0 THEN
219.             IF X <> Y + 1 THEN
220.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
221.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
222.             END IF
223.             X = X - 1
224.             RadiusError = RadiusError - X * 2
225.         END IF
226.         Y = Y + 1
227.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
228.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
229.     WEND
230. END SUB
231.  
232.  

A little shooter game which I was playing around with making, though it seems a little too difficult with the current settings.  Spawn timer may need to be reduced to create new balls at a slightly slower rate, and ball move speed might need to be decreased a bit to keep the game going, but as it is, it's a nice workable game already -- just not one where you can play for more than a few moments at a time.  :P

Move left/right with the arrow keys.
Shoot with the space bar.
Bullets use Ammo, but each successful hit on a ball shrinks it in size.  Once the ball "pops" and you destroy it, you get the ball's original size back to increase your ammo.
You get hit with a ball and it's game over.
Run out of ammo and it's game over.
You earn 1 point for each bullet which hits the target balls.

And that's it!  :P

[SMcNeill]

A slightly tweaked version which spawns balls at an ever increasing rate as you play, and in which the player shooter is a little more responsive to movements.

Code: QB64: [Select]

1. CONST Blue = &HFF0000FF~& ' _RGB32(0,0,255)
2. CONST Brown = &HFFA52A2A~& ' _RGB32(165,42,42)
3. CONST BrickRed = &HFFCB4154~& '_RGB32(203,65,84)
4. CONST Red = &HFFFF0000~&
5. CONST SkyBlue = &HFF87CEEB~& ' _RGB32(135,206,235)
6.  
7.  
8. DEFLNG A-Z
9. RANDOMIZE TIMER
10. WS = _NEWIMAGE(640, 480, 32)
11. SCREEN WS
12. _SCREENMOVE _MIDDLE
13.  
14. TYPE BulletInfo
15.     valid AS INTEGER
16.     x AS INTEGER
17.     y AS INTEGER
18. END TYPE
19.  
20. TYPE BallInfo
21.     valid AS INTEGER
22.     originalsize AS INTEGER
23.     size AS INTEGER
24.     x AS _FLOAT
25.     y AS _FLOAT
26.     movex AS _FLOAT
27.     movey AS _FLOAT
28. END TYPE
29.  
30. DIM SHARED Ball(100) AS BallInfo
31. DIM SHARED Bullet(100) AS BulletInfo
32. DIM SHARED ROF AS INTEGER
33. DIM SHARED Ammo AS LONG
34. DIM SHARED GameOver AS LONG
35. DIM SHARED score
36.  
37. CLS , SkyBlue
38. LINE (0, 479)-(639, 460), Brown, BF
39. PCOPY 0, 1 'Save as the background
40. x = 290
41. ROF = 50
42. Ammo = 1000
43.  
44. DO
45.     PCOPY 1, 0
46.     _LIMIT 180
47.     IF _KEYDOWN(19200) THEN
48.         x = x - 3
49.     ELSEIF _KEYDOWN(19712) THEN
50.         x = x + 3
51.     END IF
52.     IF x < 0 THEN x = 0
53.     IF x > 570 THEN x = 570
54.     IF _KEYDOWN(27) THEN GameOver = -1
55.     IF _KEYDOWN(32) THEN Shoot x
56.  
57.     GenerateBall
58.     DrawBalls
59.     DrawPlayer x
60.     DrawBullets
61.  
62.     DrawStatus
63.     _DISPLAY
64. LOOP UNTIL GameOver
65.  
66. DO
67.     _LIMIT 30
68. LOOP UNTIL _KEYDOWN(27)
69. END
70.  
71. SUB DrawBalls
72.     FOR i = 1 TO 100
73.         IF Ball(i).valid THEN
74.             Ball(i).x = Ball(i).x - Ball(i).movex
75.             Ball(i).y = Ball(i).y - Ball(i).movey
76.             IF Ball(i).x < Ball(i).size THEN Ball(i).x = Ball(i).size: Ball(i).movex = -Ball(i).movex
77.             IF Ball(i).y < -Ball(i).size THEN Ball(i).y = -Ball(i).size: Ball(i).movey = -Ball(i).movey
78.             IF Ball(i).x > 640 - Ball(i).size THEN Ball(i).x = 640 - Ball(i).size: Ball(i).movex = -Ball(i).movex
79.             IF Ball(i).y > 460 - Ball(i).size THEN Ball(i).y = 460 - Ball(i).size: Ball(i).movey = -Ball(i).movey
80.             CircleFill Ball(i).x, Ball(i).y, Ball(i).size, _RGB32(0, 0, 255 - i * 2)
81.         END IF
82.     NEXT
83. END SUB
84.  
85.  
86. SUB GenerateBall
87.     STATIC Spawn AS _FLOAT
88.     STATIC StartTime AS _FLOAT
89.     DIM SpawnTime AS _FLOAT
90.     IF Spawn = 0 THEN
91.         StartTime = ExtendedTimer
92.     END IF
93.     SELECT CASE ExtendedTimer - StartTime
94.         CASE IS < 30: SpawnTime = 8
95.         CASE IS < 60: SpawnTime = 6.5
96.         CASE IS < 120: SpawnTime = 5
97.         CASE IS < 300: SpawnTime = 3
98.         CASE IS < 600: SpawnTime = 2
99.         CASE ELSE: SpawnTime = 1
100.     END SELECT
101.     IF ExtendedTimer > Spawn + SpawnTime THEN
102.         Spawn = ExtendedTimer
103.         FOR i = 1 TO 100
104.             IF Ball(i).valid = 0 THEN
105.                 Ball(i).valid = -1
106.                 Ball(i).x = RND * 640 + 1
107.                 Ball(i).size = RND * 91 + 10
108.                 Ball(i).y = -Ball(i).size
109.                 Ball(i).originalsize = Ball(i).size
110.                 DO
111.                     Ball(i).movey = -RND * 3 + 1
112.                 LOOP UNTIL Ball(i).movey <> 0
113.                 Ball(i).movex = 1 - RND * 3
114.                 EXIT SUB
115.             END IF
116.         NEXT
117.     END IF
118. END SUB
119.  
120.  
121. SUB DrawStatus
122.     _PRINTSTRING (10, 462), "AMMO:" + STR$(Ammo)
123.     _PRINTSTRING (560, 462), TIME$
124.     _PRINTSTRING (200, 462), "SCORE:" + STR$(score)
125. END SUB
126.  
127. SUB DrawPlayer (x)
128.     FOR x1 = x TO x + 69
129.         FOR y1 = 445 TO 459
130.             IF POINT(x1, y1) <> SkyBlue THEN GameOver = -1
131.         NEXT
132.     NEXT
133.     FOR x1 = x + 10 TO x + 59
134.         FOR y1 = 425 TO 444
135.             IF POINT(x1, y1) <> SkyBlue THEN GameOver = -1
136.         NEXT
137.     NEXT
138.     FOR x1 = x + 30 TO x + 39
139.         FOR y1 = 415 TO 424
140.             IF POINT(x1, y1) <> SkyBlue THEN GameOver = -1
141.         NEXT
142.     NEXT
143.     LINE (x, 445)-STEP(70, 15), Red, BF
144.     LINE (x + 10, 425)-STEP(50, 20), Red, BF
145.     LINE (x + 30, 415)-STEP(10, 10), Red, BF
146. END SUB
147.  
148. SUB DrawBullets
149.     DIM P AS _UNSIGNED LONG
150.     FOR i = 1 TO 100
151.         IF Bullet(i).valid THEN
152.             Bullet(i).y = Bullet(i).y - 1
153.             IF Bullet(i).y < 0 THEN Bullet(i).valid = 0: _CONTINUE
154.             P = POINT(Bullet(i).x, Bullet(i).y)
155.             IF P <> SkyBlue THEN
156.                 Bullet(i).valid = 0
157.                 B = (255 - _BLUE32(P)) / 2
158.                 Ball(B).size = Ball(B).size - 1: score = score + 1
159.                 IF Ball(B).size < 10 THEN Ball(B).valid = 0: Ammo = Ammo + Ball(B).originalsize
160.                 _CONTINUE
161.             END IF
162.  
163.             LINE (Bullet(i).x, Bullet(i).y)-STEP(3, 5), BrickRed, BF
164.         END IF
165.     NEXT
166.     IF Ammo = 0 THEN
167.         FOR i = 1 TO 100
168.             IF Bullet(i).valid THEN EXIT SUB
169.         NEXT
170.         GameOver = -1 'once you're out of bullets and there's none left on the screen, the game is over.
171.     END IF
172. END SUB
173.  
174.  
175. SUB Shoot (x)
176.     STATIC Delay AS _FLOAT
177.     IF ExtendedTimer > Delay + ROF / 1000 THEN 'only shoot once every Rate Of Fire
178.         FOR i = 1 TO 100
179.             IF Bullet(i).valid = 0 THEN
180.                 Bullet(i).valid = -1
181.                 Bullet(i).x = x + 33
182.                 Bullet(i).y = 410
183.                 Ammo = Ammo - 1
184.                 Delay = ExtendedTimer
185.                 EXIT SUB
186.             END IF
187.         NEXT
188.     END IF
189. END SUB
190.  
191.  
192. FUNCTION ExtendedTimer##
193.     d$ = DATE$
194.     l = INSTR(d$, "-")
195.     l1 = INSTR(l + 1, d$, "-")
196.     m = VAL(LEFT$(d$, l))
197.     d = VAL(MID$(d$, l + 1))
198.     y = VAL(MID$(d$, l1 + 1)) - 1970
199.     FOR i = 1 TO m
200.         SELECT CASE i 'Add the number of days for each previous month passed
201.             CASE 1: d = d 'January doestn't have any carry over days.
202.             CASE 2, 4, 6, 8, 9, 11: d = d + 31
203.             CASE 3: d = d + 28
204.             CASE 5, 7, 10, 12: d = d + 30
205.         END SELECT
206.     NEXT
207.     FOR i = 1 TO y
208.         d = d + 365
209.     NEXT
210.     FOR i = 2 TO y STEP 4
211.         IF m > 2 THEN d = d + 1 'add an extra day for leap year every 4 years, starting in 2016
212.     NEXT
213.     s~&& = d * 24 * 60 * 60 'Seconds are days * 24 hours * 60 minutes * 60 seconds
214.     ExtendedTimer## = (s~&& + TIMER)
215. END FUNCTION
216.  
217. SUB CircleFill (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
218.     ' CX = center x coordinate
219.     ' CY = center y coordinate
220.     '  R = radius
221.     '  C = fill color
222.     DIM Radius AS INTEGER, RadiusError AS INTEGER
223.     DIM X AS INTEGER, Y AS INTEGER
224.     Radius = ABS(R)
225.     RadiusError = -Radius
226.     X = Radius
227.     Y = 0
228.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
229.     LINE (CX - X, CY)-(CX + X, CY), C, BF
230.     WHILE X > Y
231.         RadiusError = RadiusError + Y * 2 + 1
232.         IF RadiusError >= 0 THEN
233.             IF X <> Y + 1 THEN
234.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
235.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
236.             END IF
237.             X = X - 1
238.             RadiusError = RadiusError - X * 2
239.         END IF
240.         Y = Y + 1
241.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
242.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
243.     WEND
244. END SUB
245.  

[Pete]

And that's it!  :P

I hope, for your sake, the name isn't based on your marital experience. If so, I'd recommend LOCATE apostrophe, +2 to the quoted line above.

Hey, nice game! I also liked the scoring. I've always thought more shooting games should incorporate a conservation of ammo instead of games like Defender, where you could just paste the trigger lever down and concentrate all day on just flying and positioning the spaceship. I've considered models where you have a certain amount of ammo per a time period. Run out before the reload time, and you're left dodging opponents until that time elapses. A reload vehicle could even appear on the scene, but if you can't get to it, or it gets destroyed, you have to wait for the next shipment. Although I don't make games anymore, I do get that the best ideas are usually ones that are simple. In other words a bare bones version is still lots of fun to play, you don't need to tweak or add much to have a winner like Pac Man, etc.

Pete

 

[qb4ever]

A slightly tweaked version which spawns balls at an ever increasing rate as you play, and in which the player shooter is a little more responsive to movements.

Great mix between space invaders and breakout.
Very nice idea !
Have a nice day.

[Ashish]

Nice job! But it is a bit hard to play this game. :D

[johnno56]

Reminds of the little game called Pang... Cool...

[TempodiBasic]

Yes it remembers to me this one https://www.youtube.com/watch?v=kE-jzDmt1SI called SuperPang