the Latest from UniKorn ProDucKions: SIMON 64!

[Cobalt]

For my second release of 2019 I give you SIMON 64!
despite my best efforts I wasn't able to get the tones using SOUND like I wanted so there is an additional SFX file needed to play.
Also I wasn't able to get the images compact enough to store as DATA too, so we get another GFX file for that.

Code: QB64: [Select]

1. 'Simon Game
2. 'Cobalt 2019-01-13
3. 'INformation:
4. ' 4 levels:
5. '  1-8 count pattern
6. '  2-16 count pattern
7. '  3-24 count pattern
8. '  4-32 count pattern
9. ' Speed increase at 5,9,13,22,29 counts
10. ' Tones E,C#,A,E-O1 ????
11. 'Program actually adapts based off users screen size(upto 640vl anyway)
12.  
13. '------------------Types-------------------------
14. TYPE Game_Data
15.  Level AS _BYTE '1-4(easy,med,Norm,Hard)
16.  Speed AS _BYTE
17.  Length AS _BYTE
18.  ScrnHeight AS INTEGER 'computer's screen height
19.  Height AS INTEGER 'games screen height
20.  Factor AS SINGLE 'scale factor computer's height \640
21.  GamePlay AS _BYTE 'has player pressed START\GO! button?
22.  GO_GO_GO AS _BYTE 'game started flag\ displaying pattern flag
23.  Yellow_On AS _BYTE
24.  Last_Click AS _BYTE
25.  Display AS _BYTE 'flag to display sequence
26.  Time_It AS SINGLE 'after sequence display give player X# secs to enter each entry
27.  Current_Light AS _BYTE 'where is player in sequence
28.  Loser AS _BYTE
29.  '---these pertain to click area colors-----------
30.  Up_Arrow AS _UNSIGNED LONG
31.  Down_Arrow AS _UNSIGNED LONG
32.  Go_Button AS _UNSIGNED LONG
33.  Yellow_Button AS _UNSIGNED LONG
34.  Blue_Button AS _UNSIGNED LONG
35.  Green_Button AS _UNSIGNED LONG
36.  Red_Button AS _UNSIGNED LONG
37.  '------------------------------------------------
38. END TYPE
39. '------------------------------------------------
40.  
41. '-----------------Arrays and Consts--------------
42. DIM SHARED Sequence(32) AS _BYTE, G AS Game_Data, SFX(5) AS LONG
43. DIM SHARED Play_Back(32), Layer(7) AS LONG, Ti(5) AS LONG
44. DIM SHARED StartUp%%
45. CONST TRUE = -1, FALSE = NOT TRUE
46. CONST EASY = 1, MED = 2, NORM = 3, HARD = 4
47. CONST SLOWEST = 9, SLOWER = 7, SLOW = 6, FAST = 5, FASTER = 3, FASTEST = 1
48. CONST RED = 15, BLUE = 31, GREEN = 63, YELLOW = 127, LOSER = 1, GO = 69
49. '------------------------------------------------
50.  
51. '-------------Setup------------------------------
52. G.ScrnHeight = _DESKTOPHEIGHT
53. G.ScrnHeight = 640
54. IF G.ScrnHeight >= 640 THEN G.Factor = 1 ELSE G.Factor = G.ScrnHeight / 640 - .0125
55. '-------------layer loader-----------------------
56. DIM Size(64) AS LONG, FOffset&(64)
57. OPEN "simon.gfx" FOR BINARY AS #1
58. GET #1, , c~%% 'number of records
59. FOR w% = 1 TO c~%%
60.  GET #1, , FOffset&(w%)
61.  GET #1, , Size(w%)
62.  FOffset&(w%) = FOffset&(w%) + 1
63. NEXT
64. '------------------------------------------------
65. SCREEN _NEWIMAGE(640, 640 * G.Factor, 32)
66. Layer(0) = _NEWIMAGE(640, 640 * G.Factor, 32)
67. Layer(1) = LoadGFX&(FOffset&(4), Size(4))
68. Layer(2) = LoadGFX&(FOffset&(3), Size(3))
69. Layer(3) = LoadGFX&(FOffset&(5), Size(5))
70. Layer(4) = LoadGFX&(FOffset&(2), Size(2))
71. Layer(5) = LoadGFX&(FOffset&(1), Size(1))
72. CLOSE #1 'close GFX file
73. Layer(6) = _NEWIMAGE(640, 640 * G.Factor, 32)
74. Layer(7) = _NEWIMAGE(640, 640 * G.Factor, 32)
75. _CLEARCOLOR _RGB32(0, 0, 0), Layer(1)
76. _CLEARCOLOR _RGB32(0, 0, 0), Layer(2)
77. _CLEARCOLOR _RGB32(0, 0, 0), Layer(3)
78. _CLEARCOLOR _RGB32(0, 0, 0), Layer(4)
79. '--------------Sound Loader----------------------
80. OPEN "simon.SFX" FOR BINARY AS #1
81. GET #1, , c%%
82. FOR w% = 1 TO c%%
83.  GET #1, , FOffset&(w%)
84.  GET #1, , Size(w%)
85.  FOffset&(w%) = FOffset&(w%) + 1
86. NEXT
87. SFX(0) = LoadSFX&(FOffset&(3), Size(3)) '_SNDOPEN("RedTone.wav")
88. SFX(1) = LoadSFX&(FOffset&(1), Size(1)) '_SNDOPEN("BlueTone.wav")
89. SFX(2) = LoadSFX&(FOffset&(2), Size(2)) '_SNDOPEN("GreenTone.wav")
90. SFX(3) = LoadSFX&(FOffset&(4), Size(4)) '_SNDOPEN("YellowTone.wav")
91. SFX(4) = LoadSFX&(FOffset&(5), Size(5)) '_SNDOPEN("LoseTone.wav")
92. CLOSE #1 'Close SFX file
93.  
94. FOR i%% = 0 TO 3
95.  _SNDVOL SFX(i%%), .2
96. NEXT
97. _SNDVOL SFX(4), .5
98. RANDOMIZE TIMER
99. _DELAY .02
100. _SCREENMOVE 64, 16
101. G.Yellow_Button = _RGB32(255, 255, 0)
102. G.Blue_Button = _RGB32(0, 0, 255)
103. G.Green_Button = _RGB32(0, 255, 0)
104. G.Red_Button = _RGB32(255, 0, 0)
105. G.Up_Arrow = _RGB32(128, 0, 128)
106. G.Down_Arrow = _RGB32(160, 0, 160)
107. G.Go_Button = _RGB32(192, 0, 192)
108. Ti(0) = _FREETIMER
109. ON TIMER(Ti(0), .05) Start_Flash_Yellow
110. Simon_Base
111. Simon_Label
112. Setup_Click_Area
113. _TITLE "Simon 64! 2019 V0.8b"
114. '------------------------------------------------
115.  
116. Start_Up_Values
117.  
118. '------------------Main Loop---------------------
119. DO
120.  nul% = _MOUSEINPUT
121.  IF _MOUSEBUTTON(1) AND G.GO_GO_GO THEN
122.   Simon_Mouse
123.  END IF
124.  
125.  IF G.Display THEN _DELAY .75: G.GO_GO_GO = FALSE: Display_Sequence
126.  IF G.GamePlay AND (NOT StartUp%%) AND G.Last_Click THEN
127.   IF G.Last_Click = Sequence(G.Current_Light) THEN
128.    IF G.Current_Light = G.Level * 8 THEN Winner%% = TRUE: exitflag%% = TRUE: G.Current_Light = 0
129.    G.Current_Light = G.Current_Light + 1
130.    IF G.Current_Light > G.Length THEN Add_Color
131.   ELSE
132.    G.Loser = TRUE
133.    Start_Tone LOSER
134.    Build_Display
135.    LOCATE 1, 1: PRINT G.Last_Click; Sequence(G.Current_Light); G.Current_Light
136.    _DELAY 2.5
137.    Stop_Tone LOSER
138.    Start_Up_Values
139.   END IF
140.  END IF
141.  IF G.Length = 5 THEN G.Speed = SLOWER
142.  IF G.Length = 9 THEN G.Speed = SLOW
143.  IF G.Length = 14 THEN G.Speed = FAST
144.  IF G.Length = 22 THEN G.Speed = FASTER
145.  IF G.Length = 29 THEN G.Speed = FASTEST
146.  Build_Display
147.  
148.  _DELAY .05
149.  DO: LOOP WHILE _MOUSEINPUT 'clear mouse buffer
150.  IF INKEY$ = CHR$(27) THEN exitflag%% = TRUE
151.  G.Last_Click = FALSE
152. LOOP UNTIL exitflag%%
153. '------------------------------------------------
154. IF Winner%% THEN PRINT "YOU WIN!"
155.  
156. SUB Lose_Game_Sound
157.  FOR i%% = 0 TO 15
158.   SOUND 142, .8 'lose
159.   SOUND 72, .6 'lose
160.  NEXT
161. END SUB
162.  
163. SUB Red_Sound (t%%)
164.  FOR i%% = o TO t%%
165.   SOUND 440, 1 'Red
166.   _DELAY .015
167.  NEXT i%%
168. END SUB
169.  
170. SUB Blue_Sound (t%%)
171.  FOR i%% = o TO t%%
172.   SOUND 330, 1 'Blue
173.   _DELAY .015
174.  NEXT i%%
175. END SUB
176.  
177. SUB Green_Sound (t%%)
178.  FOR i%% = o TO t%%
179.   SOUND 294, 1 'Green
180.   _DELAY .015
181.  NEXT i%%
182. END SUB
183.  
184. SUB Yellow_Sound (t%%)
185.  FOR i%% = o TO t%%
186.   SOUND 277, 1 'Yellow
187.   _DELAY .015
188.  NEXT i%%
189. END SUB
190.  
191. SUB Yellow_Light
192.  _PUTIMAGE (0, 0)-STEP(320 * G.Factor, 320 * G.Factor), Layer(3), Layer(0), (0, 0)-(146, 146)
193. END SUB
194.  
195. SUB Green_Light
196.  _PUTIMAGE (320 * G.Factor, 320 * G.Factor)-STEP(320 * G.Factor, 320 * G.Factor), Layer(3), Layer(0), (147, 147)-(293, 293)
197. END SUB
198.  
199. SUB Blue_Light
200.  _PUTIMAGE (320 * G.Factor, 0)-STEP(320 * G.Factor, 320 * G.Factor), Layer(3), Layer(0), (147, 0)-(293, 146)
201. END SUB
202.  
203. SUB Red_Light
204.  _PUTIMAGE (0, 320 * G.Factor)-STEP(320 * G.Factor, 320 * G.Factor), Layer(3), Layer(0), (0, 147)-(146, 293)
205. END SUB
206.  
207. SUB Simon_Base
208.  _PUTIMAGE (0, 0)-STEP(640 * G.Factor, 640 * G.Factor), Layer(1), Layer(7)
209. END SUB
210.  
211. SUB Add_Color ()
212.  Result%% = INT(RND * 100)
213.  G.Length = G.Length + 1 'add one level to sequence
214.  G.Display = TRUE 'tell main loop to display new sequence
215.  G.Current_Light = 1 'start player at first entry
216.  SELECT CASE Result%%
217.   CASE 0 TO 24
218.    Sequence(G.Length) = YELLOW
219.   CASE 25 TO 49
220.    Sequence(G.Length) = BLUE
221.   CASE 50 TO 74
222.    Sequence(G.Length) = RED
223.   CASE 75 TO 99
224.    Sequence(G.Length) = GREEN
225.  END SELECT
226. END SUB
227.  
228. SUB Simon_Label
229.  x% = 170 * G.Factor
230.  y% = 158 * G.Factor
231.  _PUTIMAGE (x%, y%)-STEP(294 * G.Factor, 294 * G.Factor), Layer(2), Layer(7)
232. END SUB
233.  
234. SUB Level_LED
235.  x% = 170 * G.Factor
236.  y% = 284 * G.Factor
237.  _PUTIMAGE (x%, y%)-STEP(294 * G.Factor, 37 * G.Factor), Layer(4), Layer(0), (0, 32)-(127, 47)
238.  SELECT CASE G.Level
239.   CASE EASY
240.    _PUTIMAGE (x% + 60, y%)-STEP(45 * G.Factor, 37 * G.Factor), Layer(4), Layer(0), (3, 16)-(22, 31)
241.   CASE MED
242.    _PUTIMAGE (x% + 107, y%)-STEP(44 * G.Factor, 37 * G.Factor), Layer(4), Layer(0), (23, 16)-(42, 31)
243.   CASE NORM
244.    _PUTIMAGE (x% + 152, y%)-STEP(44 * G.Factor, 37 * G.Factor), Layer(4), Layer(0), (43, 16)-(62, 31)
245.   CASE HARD
246.    _PUTIMAGE (x% + 198, y%)-STEP(45 * G.Factor, 37 * G.Factor), Layer(4), Layer(0), (63, 16)-(82, 31)
247.  END SELECT
248. END SUB
249.  
250. SUB Level_Adjust_Arrows
251.  x% = 196 * G.Factor
252.  y% = 284 * G.Factor
253.  _PUTIMAGE (x%, y%)-STEP(22 * G.Factor, 32 * G.Factor), Layer(4), Layer(0), (85, 0)-(96, 15)
254.  _PUTIMAGE (x% + 224, y%)-STEP(22 * G.Factor, 32 * G.Factor), Layer(4), Layer(0), (85, 16)-(96, 31)
255.  _DEST Layer(6)
256.  LINE (x%, y%)-STEP(22 * G.Factor, 32 * G.Factor), G.Down_Arrow, BF
257.  LINE (x% + 224, y%)-STEP(22 * G.Factor, 32 * G.Factor), G.Up_Arrow, BF
258.  _DEST _DISPLAY
259. END SUB
260.  
261. SUB Start_Button (state%%)
262.  x% = 292 * G.Factor
263.  y% = 360 * G.Factor
264.  IF NOT state%% THEN
265.   _PUTIMAGE (x%, y%)-STEP(52 * G.Factor, 32 * G.Factor), Layer(4), Layer(0), (97, 0)-(123, 15)
266.  ELSE
267.   _PUTIMAGE (x%, y%)-STEP(52 * G.Factor, 32 * G.Factor), Layer(4), Layer(0), (97, 16)-(123, 31)
268.  END IF
269.  _DEST Layer(6)
270.  LINE (x%, y%)-STEP(52 * G.Factor, 32 * G.Factor), G.Go_Button, BF
271.  _DEST _DISPLAY
272. END SUB
273.  
274. SUB Button_Down_Lock
275.  ButtonDown%% = TRUE
276.  '--------lock mouse until button release---------
277.  'stops program progess but not timer progress
278.  'player could lose if they hold button down.
279.  'this IS ment to be.
280.  IF G.GO_GO_GO THEN Press_Color: Start_Tone G.Last_Click
281.  DO
282.   IF _MOUSEINPUT THEN
283.    IF NOT _MOUSEBUTTON(1) THEN ButtonDown%% = FALSE
284.   END IF
285.   _DELAY .001
286.  LOOP WHILE ButtonDown%%
287.  Stop_Tone G.Last_Click
288.  '------------------------------------------------
289.  Build_Display
290. END SUB
291.  
292. SUB Start_Flash_Yellow
293.  G.Yellow_On = G.Yellow_On + 1
294.  IF G.Yellow_On > 19 THEN G.Yellow_On = 1
295. END SUB
296.  
297. SUB Setup_Click_Area
298.  _PUTIMAGE (0, 0)-STEP(640 * G.Factor, 640 * G.Factor), Layer(5), Layer(6)
299. END SUB
300.  
301. SUB Simon_Mouse
302.  SELECT CASE POINT(_MOUSEX, _MOUSEY)
303.   CASE G.Up_Arrow
304.    IF G.Level < 4 AND (NOT G.GamePlay) THEN G.Level = G.Level + 1
305.   CASE G.Down_Arrow
306.    IF G.Level > 1 AND (NOT G.GamePlay) THEN G.Level = G.Level - 1
307.   CASE G.Go_Button
308.    IF NOT G.GamePlay THEN
309.     G.GamePlay = TRUE
310.     StartUp%% = TRUE
311.     TIMER(Ti(0)) ON
312.     G.Last_Click = GO
313.    END IF
314.   CASE G.Yellow_Button
315.    IF StartUp%% THEN TIMER(Ti(0)) OFF: G.Yellow_On = FALSE: StartUp%% = FALSE: Add_Color
316.    G.Last_Click = YELLOW
317.   CASE G.Blue_Button
318.    G.Last_Click = BLUE
319.   CASE G.Green_Button
320.    G.Last_Click = GREEN
321.   CASE G.Red_Button
322.    G.Last_Click = RED
323.  END SELECT
324.  Button_Down_Lock
325. END SUB
326.  
327. SUB Display_Sequence
328.  FOR i%% = 1 TO G.Length
329.   _PUTIMAGE , Layer(7), Layer(0)
330.   Level_LED
331.   Level_Adjust_Arrows
332.   Start_Button G.GamePlay
333.   Start_Tone Sequence(i%%)
334.   SELECT CASE Sequence(i%%)
335.    CASE YELLOW
336.     Yellow_Light
337.    CASE BLUE
338.     Blue_Light
339.    CASE GREEN
340.     Green_Light
341.    CASE RED
342.     Red_Light
343.   END SELECT
344.   _PUTIMAGE , Layer(0), _DISPLAY
345.   _DELAY G.Speed / 12
346.   Stop_Tone Sequence(i%%)
347.  
348.   Build_Display
349.  
350.   _DELAY G.Speed / 20
351.  NEXT i%%
352.  G.Display = FALSE 'done displaying sequence
353.  G.Time_It = TIMER + .25 'start player input timer +.25 for delay
354.  _DELAY .25 'short pause before player can start entering sequence
355.  G.GO_GO_GO = TRUE 'allow player to have mouse actions
356.  G.Last_Click = FALSE
357. END SUB
358.  
359. SUB Press_Color
360.  _PUTIMAGE , Layer(7), Layer(0)
361.  
362.  SELECT CASE G.Last_Click
363.   CASE YELLOW
364.    Yellow_Light
365.   CASE BLUE
366.    Blue_Light
367.   CASE GREEN
368.    Green_Light
369.   CASE RED
370.    Red_Light
371.  END SELECT
372.  
373.  Level_LED
374.  Level_Adjust_Arrows
375.  Start_Button G.GamePlay
376.  _PUTIMAGE , Layer(0), _DISPLAY
377. END SUB
378.  
379. SUB Start_Tone (id%%)
380.  SELECT CASE id%%
381.   CASE LOSER
382.    _SNDLOOP SFX(4)
383.   CASE YELLOW
384.    _SNDLOOP SFX(3)
385.   CASE BLUE
386.    _SNDLOOP SFX(1)
387.   CASE GREEN
388.    _SNDLOOP SFX(2)
389.   CASE RED
390.    _SNDLOOP SFX(0)
391.  END SELECT
392. END SUB
393.  
394. SUB Stop_Tone (id%%)
395.  SELECT CASE id%%
396.   CASE LOSER
397.    _SNDSTOP SFX(4)
398.   CASE YELLOW
399.    _SNDSTOP SFX(3)
400.   CASE BLUE
401.    _SNDSTOP SFX(1)
402.   CASE GREEN
403.    _SNDSTOP SFX(2)
404.   CASE RED
405.    _SNDSTOP SFX(0)
406.  END SELECT
407. END SUB
408.  
409. SUB Build_Display
410.  '---------Build Display--------------------------
411.  _PUTIMAGE , Layer(7), Layer(0)
412.  IF StartUp%% AND G.Yellow_On > 10 THEN Yellow_Light
413.  IF G.Loser THEN Red_Light
414.  Level_LED
415.  Level_Adjust_Arrows
416.  Start_Button G.GamePlay
417.  _PUTIMAGE , Layer(0), _DISPLAY
418.  '------------------------------------------------
419. END SUB
420.  
421. SUB Start_Up_Values
422.  '----------------Start Up Values ----------------
423.  G.Level = 1
424.  G.Speed = SLOWEST
425.  G.Length = 0
426.  G.Loser = FALSE
427.  G.GamePlay = FALSE
428.  G.GO_GO_GO = TRUE
429.  G.Current_Light = 0
430.  G.Display = FALSE
431.  _SOURCE Layer(6)
432.  '------------------------------------------------
433. END SUB
434.  
435. FUNCTION LoadGFX& (Foff&, Size&)
436.  IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
437.  OPEN "temp.dat" FOR BINARY AS #3
438.  dat$ = SPACE$(Size&)
439.  GET #1, Foff&, dat$
440.  PUT #3, , dat$
441.  CLOSE #3
442.  LoadGFX& = _LOADIMAGE("temp.dat", 32)
443. END FUNCTION
444.  
445. FUNCTION LoadSFX& (Foff&, Size&)
446.  IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
447.  OPEN "temp.dat" FOR BINARY AS #3
448.  dat$ = SPACE$(Size&)
449.  GET #1, Foff&, dat$
450.  PUT #3, , dat$
451.  CLOSE #3
452.  LoadSFX& = _SNDOPEN("temp.dat")
453. END FUNCTION
454.  

4 levels of play with patterns of up to 8,16,24, and 32. (think I made it to 14 once)  I'm still tweeking the speed, seems a little too slow in the beginning. I also have not implemented the time restraint so it doesn't matter how long it takes you to enter the sequence as of yet. controls are entirely mouse driven right now.  use the 2 black arrows to raise or lower the level (green, yellow, amber, and red 'LED's) then press START. you will see the Yellow Button flashing, press that once (careful cause if you accidentally double click you lose, still have to address that.) then the sequence begins.
Haven't figured out a nice winner screen or anything yet so right now it just prints "YOU WIN" and quits. If you lose you get a nice loud tone and everything resets(but doesn't quit the game) if you get tired of messing with it, ESC quits though if its in a sequence display you will have to wait it out.(or just close the window)

the max vertical size is 640. I have limitedly tested reduced screen sizes(to 480) and the automatic scaling seems to work. its hard coded to max at 640 vertical at the present and may not scale correctly on the horizontal beyond that.

[Cobalt]

Minor update, added the time limit on sequence entry. Pretty generous at 8 seconds.
 couple other tweaks as well, but nothing major. Wont be giving this the 1.0 go ahead until I figure something out for a winning game.

anybody found any hiccups yet? or anything that just doesn't feel smooth?

Code: QB64: [Select]

1. 'Simon Game
2. 'Cobalt 2019-01-13
3. 'INformation:
4. ' 4 levels:
5. '  1-8 count pattern
6. '  2-16 count pattern
7. '  3-24 count pattern
8. '  4-32 count pattern
9. ' Speed increase at 5,9,13,22,29 counts
10. ' Tones E,C#,A,E-O1 ????
11. 'Program actually adapts based off users screen size(upto 640vl anyway)
12.  
13. '------------------Types-------------------------
14. TYPE Game_Data
15.  Level AS _BYTE '1-4(easy,med,Norm,Hard)
16.  Speed AS _BYTE
17.  Length AS _BYTE
18.  ScrnHeight AS INTEGER 'computer's screen height
19.  Height AS INTEGER 'games screen height
20.  Factor AS SINGLE 'scale factor computer's height \640
21.  GamePlay AS _BYTE 'has player pressed START\GO! button?
22.  GO_GO_GO AS _BYTE 'game started flag\ displaying pattern flag
23.  Yellow_On AS _BYTE
24.  Last_Click AS _BYTE
25.  Display AS _BYTE 'flag to display sequence
26.  Time_It AS SINGLE 'after sequence display give player X# secs to enter each entry
27.  Current_Light AS _BYTE 'where is player in sequence
28.  Loser AS _BYTE
29.  '---these pertain to click area colors-----------
30.  Up_Arrow AS _UNSIGNED LONG
31.  Down_Arrow AS _UNSIGNED LONG
32.  Go_Button AS _UNSIGNED LONG
33.  Yellow_Button AS _UNSIGNED LONG
34.  Blue_Button AS _UNSIGNED LONG
35.  Green_Button AS _UNSIGNED LONG
36.  Red_Button AS _UNSIGNED LONG
37.  '------------------------------------------------
38. END TYPE
39. '------------------------------------------------
40.  
41. '-----------------Arrays and Consts--------------
42. DIM SHARED Sequence(32) AS _BYTE, G AS Game_Data, SFX(5) AS LONG
43. DIM SHARED Play_Back(32), Layer(7) AS LONG, Ti(5) AS LONG
44. DIM SHARED StartUp%%
45. CONST TRUE = -1, FALSE = NOT TRUE
46. CONST EASY = 1, MED = 2, NORM = 3, HARD = 4
47. CONST SLOWEST = 9, SLOWER = 7, SLOW = 6, FAST = 5, FASTER = 3, FASTEST = 1
48. CONST RED = 15, BLUE = 31, GREEN = 63, YELLOW = 127, LOSER = 1, GO = 69
49. '------------------------------------------------
50.  
51. '-------------Setup------------------------------
52. G.ScrnHeight = _DESKTOPHEIGHT
53. G.ScrnHeight = 640
54. IF G.ScrnHeight >= 640 THEN G.Factor = 1 ELSE G.Factor = G.ScrnHeight / 640 - .0125
55. '-------------layer loader-----------------------
56. DIM Size(64) AS LONG, FOffset&(64)
57. OPEN "simon.gfx" FOR BINARY AS #1
58. GET #1, , c~%% 'number of records
59. FOR w% = 1 TO c~%%
60.  GET #1, , FOffset&(w%)
61.  GET #1, , Size(w%)
62.  FOffset&(w%) = FOffset&(w%) + 1
63. NEXT
64. '------------------------------------------------
65. SCREEN _NEWIMAGE(640, 640 * G.Factor, 32)
66. Layer(0) = _NEWIMAGE(640, 640 * G.Factor, 32)
67. Layer(1) = LoadGFX&(FOffset&(4), Size(4))
68. Layer(2) = LoadGFX&(FOffset&(3), Size(3))
69. Layer(3) = LoadGFX&(FOffset&(5), Size(5))
70. Layer(4) = LoadGFX&(FOffset&(2), Size(2))
71. Layer(5) = LoadGFX&(FOffset&(1), Size(1))
72. CLOSE #1 'close GFX file
73. Layer(6) = _NEWIMAGE(640, 640 * G.Factor, 32)
74. Layer(7) = _NEWIMAGE(640, 640 * G.Factor, 32)
75. _CLEARCOLOR _RGB32(0, 0, 0), Layer(1)
76. _CLEARCOLOR _RGB32(0, 0, 0), Layer(2)
77. _CLEARCOLOR _RGB32(0, 0, 0), Layer(3)
78. _CLEARCOLOR _RGB32(0, 0, 0), Layer(4)
79. '--------------Sound Loader----------------------
80. OPEN "simon.SFX" FOR BINARY AS #1
81. GET #1, , c%%
82. FOR w% = 1 TO c%%
83.  GET #1, , FOffset&(w%)
84.  GET #1, , Size(w%)
85.  FOffset&(w%) = FOffset&(w%) + 1
86. NEXT
87. SFX(0) = LoadSFX&(FOffset&(3), Size(3)) '_SNDOPEN("RedTone.wav")
88. SFX(1) = LoadSFX&(FOffset&(1), Size(1)) '_SNDOPEN("BlueTone.wav")
89. SFX(2) = LoadSFX&(FOffset&(2), Size(2)) '_SNDOPEN("GreenTone.wav")
90. SFX(3) = LoadSFX&(FOffset&(4), Size(4)) '_SNDOPEN("YellowTone.wav")
91. SFX(4) = LoadSFX&(FOffset&(5), Size(5)) '_SNDOPEN("LoseTone.wav")
92. CLOSE #1 'Close SFX file
93.  
94. FOR i%% = 0 TO 3
95.  _SNDVOL SFX(i%%), .2
96. NEXT
97. _SNDVOL SFX(4), .2
98. RANDOMIZE TIMER
99. _DELAY .02
100. _SCREENMOVE 64, 16
101. G.Yellow_Button = _RGB32(255, 255, 0)
102. G.Blue_Button = _RGB32(0, 0, 255)
103. G.Green_Button = _RGB32(0, 255, 0)
104. G.Red_Button = _RGB32(255, 0, 0)
105. G.Up_Arrow = _RGB32(128, 0, 128)
106. G.Down_Arrow = _RGB32(160, 0, 160)
107. G.Go_Button = _RGB32(192, 0, 192)
108. Ti(0) = _FREETIMER
109. ON TIMER(Ti(0), .05) Start_Flash_Yellow
110. Simon_Base
111. Simon_Label
112. Setup_Click_Area
113. _SOURCE Layer(6)
114. _TITLE "Simon 64! 2019 V0.9b"
115. '------------------------------------------------
116.  
117. Start_Up_Values
118.  
119. '------------------Main Loop---------------------
120. DO
121.  nul% = _MOUSEINPUT
122.  IF _MOUSEBUTTON(1) AND G.GO_GO_GO THEN
123.   Simon_Mouse
124.  END IF
125.  
126.  IF G.Display THEN _DELAY .75: G.GO_GO_GO = FALSE: Display_Sequence
127.  IF G.GamePlay AND (NOT StartUp%%) AND G.Last_Click THEN
128.   IF G.Last_Click = Sequence(G.Current_Light) THEN
129.    IF G.Current_Light = G.Level * 8 THEN Winner%% = TRUE: exitflag%% = TRUE: G.Current_Light = 0
130.    G.Current_Light = G.Current_Light + 1
131.    IF G.Current_Light > G.Length THEN Add_Color
132.   ELSE
133.    G.Loser = TRUE
134.    Start_Tone LOSER
135.    Build_Display
136.    _DELAY 2.5
137.    Stop_Tone LOSER
138.    Start_Up_Values
139.   END IF
140.  END IF
141.  
142.  IF G.Length = 5 THEN G.Speed = SLOWER
143.  IF G.Length = 9 THEN G.Speed = SLOW
144.  IF G.Length = 14 THEN G.Speed = FAST
145.  IF G.Length = 22 THEN G.Speed = FASTER
146.  IF G.Length = 29 THEN G.Speed = FASTEST
147.  
148.  IF G.Time_It <> 0 AND TIMER > G.Time_It + 8 THEN
149.   G.Loser = TRUE
150.   Start_Tone LOSER
151.   Build_Display
152.   _DELAY 2.5
153.   Stop_Tone LOSER
154.   Start_Up_Values
155.  END IF
156.  
157.  Build_Display
158.  
159.  
160.  _DELAY .05
161.  DO: LOOP WHILE _MOUSEINPUT 'clear mouse buffer
162.  IF INKEY$ = CHR$(27) THEN exitflag%% = TRUE
163.  G.Last_Click = FALSE
164. LOOP UNTIL exitflag%%
165. '------------------------------------------------
166. IF Winner%% THEN PRINT "YOU WIN!"
167.  
168. SUB Lose_Game_Sound
169.  FOR i%% = 0 TO 15
170.   SOUND 142, .8 'lose
171.   SOUND 72, .6 'lose
172.  NEXT
173. END SUB
174.  
175. SUB Red_Sound (t%%)
176.  FOR i%% = o TO t%%
177.   SOUND 440, 1 'Red
178.   _DELAY .015
179.  NEXT i%%
180. END SUB
181.  
182. SUB Blue_Sound (t%%)
183.  FOR i%% = o TO t%%
184.   SOUND 330, 1 'Blue
185.   _DELAY .015
186.  NEXT i%%
187. END SUB
188.  
189. SUB Green_Sound (t%%)
190.  FOR i%% = o TO t%%
191.   SOUND 294, 1 'Green
192.   _DELAY .015
193.  NEXT i%%
194. END SUB
195.  
196. SUB Yellow_Sound (t%%)
197.  FOR i%% = o TO t%%
198.   SOUND 277, 1 'Yellow
199.   _DELAY .015
200.  NEXT i%%
201. END SUB
202.  
203. SUB Yellow_Light
204.  _PUTIMAGE (0, 0)-STEP(320 * G.Factor, 320 * G.Factor), Layer(3), Layer(0), (0, 0)-(146, 146)
205. END SUB
206.  
207. SUB Green_Light
208.  _PUTIMAGE (320 * G.Factor, 320 * G.Factor)-STEP(320 * G.Factor, 320 * G.Factor), Layer(3), Layer(0), (147, 147)-(293, 293)
209. END SUB
210.  
211. SUB Blue_Light
212.  _PUTIMAGE (320 * G.Factor, 0)-STEP(320 * G.Factor, 320 * G.Factor), Layer(3), Layer(0), (147, 0)-(293, 146)
213. END SUB
214.  
215. SUB Red_Light
216.  _PUTIMAGE (0, 320 * G.Factor)-STEP(320 * G.Factor, 320 * G.Factor), Layer(3), Layer(0), (0, 147)-(146, 293)
217. END SUB
218.  
219. SUB Simon_Base
220.  _PUTIMAGE (0, 0)-STEP(640 * G.Factor, 640 * G.Factor), Layer(1), Layer(7)
221. END SUB
222.  
223. SUB Add_Color ()
224.  Result%% = INT(RND * 100)
225.  G.Length = G.Length + 1 'add one level to sequence
226.  G.Display = TRUE 'tell main loop to display new sequence
227.  G.Current_Light = 1 'start player at first entry
228.  SELECT CASE Result%%
229.   CASE 0 TO 24
230.    Sequence(G.Length) = YELLOW
231.   CASE 25 TO 49
232.    Sequence(G.Length) = BLUE
233.   CASE 50 TO 74
234.    Sequence(G.Length) = RED
235.   CASE 75 TO 99
236.    Sequence(G.Length) = GREEN
237.  END SELECT
238. END SUB
239.  
240. SUB Simon_Label
241.  x% = 170 * G.Factor
242.  y% = 158 * G.Factor
243.  _PUTIMAGE (x%, y%)-STEP(294 * G.Factor, 294 * G.Factor), Layer(2), Layer(7)
244. END SUB
245.  
246. SUB Level_LED
247.  x% = 170 * G.Factor
248.  y% = 284 * G.Factor
249.  _PUTIMAGE (x%, y%)-STEP(294 * G.Factor, 37 * G.Factor), Layer(4), Layer(0), (0, 32)-(127, 47)
250.  SELECT CASE G.Level
251.   CASE EASY
252.    _PUTIMAGE (x% + 60, y%)-STEP(45 * G.Factor, 37 * G.Factor), Layer(4), Layer(0), (3, 16)-(22, 31)
253.   CASE MED
254.    _PUTIMAGE (x% + 107, y%)-STEP(44 * G.Factor, 37 * G.Factor), Layer(4), Layer(0), (23, 16)-(42, 31)
255.   CASE NORM
256.    _PUTIMAGE (x% + 152, y%)-STEP(44 * G.Factor, 37 * G.Factor), Layer(4), Layer(0), (43, 16)-(62, 31)
257.   CASE HARD
258.    _PUTIMAGE (x% + 198, y%)-STEP(45 * G.Factor, 37 * G.Factor), Layer(4), Layer(0), (63, 16)-(82, 31)
259.  END SELECT
260. END SUB
261.  
262. SUB Level_Adjust_Arrows
263.  x% = 196 * G.Factor
264.  y% = 284 * G.Factor
265.  _PUTIMAGE (x%, y%)-STEP(22 * G.Factor, 32 * G.Factor), Layer(4), Layer(0), (85, 0)-(96, 15)
266.  _PUTIMAGE (x% + 224, y%)-STEP(22 * G.Factor, 32 * G.Factor), Layer(4), Layer(0), (85, 16)-(96, 31)
267.  _DEST Layer(6)
268.  LINE (x%, y%)-STEP(22 * G.Factor, 32 * G.Factor), G.Down_Arrow, BF
269.  LINE (x% + 224, y%)-STEP(22 * G.Factor, 32 * G.Factor), G.Up_Arrow, BF
270.  _DEST _DISPLAY
271. END SUB
272.  
273. SUB Start_Button (state%%)
274.  x% = 292 * G.Factor
275.  y% = 360 * G.Factor
276.  IF NOT state%% THEN
277.   _PUTIMAGE (x%, y%)-STEP(52 * G.Factor, 32 * G.Factor), Layer(4), Layer(0), (97, 0)-(123, 15)
278.  ELSE
279.   _PUTIMAGE (x%, y%)-STEP(52 * G.Factor, 32 * G.Factor), Layer(4), Layer(0), (97, 16)-(123, 31)
280.  END IF
281.  _DEST Layer(6)
282.  LINE (x%, y%)-STEP(52 * G.Factor, 32 * G.Factor), G.Go_Button, BF
283.  _DEST _DISPLAY
284. END SUB
285.  
286. SUB Button_Down_Lock
287.  ButtonDown%% = TRUE
288.  '--------lock mouse until button release---------
289.  'stops program progess but not timer progress
290.  'player could lose if they hold button down.
291.  'this IS ment to be.
292.  IF G.GO_GO_GO THEN Press_Color: Start_Tone G.Last_Click
293.  DO
294.   IF _MOUSEINPUT THEN
295.    IF NOT _MOUSEBUTTON(1) THEN ButtonDown%% = FALSE
296.   END IF
297.   _DELAY .001
298.  LOOP WHILE ButtonDown%%
299.  Stop_Tone G.Last_Click
300.  '------------------------------------------------
301.  Build_Display
302. END SUB
303.  
304. SUB Start_Flash_Yellow
305.  G.Yellow_On = G.Yellow_On + 1
306.  IF G.Yellow_On > 19 THEN G.Yellow_On = 1
307. END SUB
308.  
309. SUB Setup_Click_Area
310.  _PUTIMAGE (0, 0)-STEP(640 * G.Factor, 640 * G.Factor), Layer(5), Layer(6)
311. END SUB
312.  
313. SUB Simon_Mouse
314.  SELECT CASE POINT(_MOUSEX, _MOUSEY)
315.   CASE G.Up_Arrow
316.    IF G.Level < 4 AND (NOT G.GamePlay) THEN G.Level = G.Level + 1
317.   CASE G.Down_Arrow
318.    IF G.Level > 1 AND (NOT G.GamePlay) THEN G.Level = G.Level - 1
319.   CASE G.Go_Button
320.    IF NOT G.GamePlay THEN
321.     G.GamePlay = TRUE
322.     StartUp%% = TRUE
323.     TIMER(Ti(0)) ON
324.     G.Last_Click = GO
325.    END IF
326.   CASE G.Yellow_Button
327.    IF StartUp%% THEN TIMER(Ti(0)) OFF: G.Yellow_On = FALSE: StartUp%% = FALSE: Add_Color
328.    G.Last_Click = YELLOW
329.   CASE G.Blue_Button
330.    G.Last_Click = BLUE
331.   CASE G.Green_Button
332.    G.Last_Click = GREEN
333.   CASE G.Red_Button
334.    G.Last_Click = RED
335.  END SELECT
336.  Button_Down_Lock
337. END SUB
338.  
339. SUB Display_Sequence
340.  FOR i%% = 1 TO G.Length
341.   _PUTIMAGE , Layer(7), Layer(0)
342.   Level_LED
343.   Level_Adjust_Arrows
344.   Start_Button G.GamePlay
345.   Start_Tone Sequence(i%%)
346.   SELECT CASE Sequence(i%%)
347.    CASE YELLOW
348.     Yellow_Light
349.    CASE BLUE
350.     Blue_Light
351.    CASE GREEN
352.     Green_Light
353.    CASE RED
354.     Red_Light
355.   END SELECT
356.   _PUTIMAGE , Layer(0), _DISPLAY
357.   _DELAY G.Speed / 12
358.   Stop_Tone Sequence(i%%)
359.  
360.   Build_Display
361.  
362.   _DELAY G.Speed / 20
363.  NEXT i%%
364.  G.Display = FALSE 'done displaying sequence
365.  G.Time_It = TIMER + .15 'start player input timer +.25 for delay
366.  _DELAY .15 'short pause before player can start entering sequence
367.  G.GO_GO_GO = TRUE 'allow player to have mouse actions
368.  G.Last_Click = FALSE
369. END SUB
370.  
371. SUB Press_Color
372.  _PUTIMAGE , Layer(7), Layer(0)
373.  
374.  SELECT CASE G.Last_Click
375.   CASE YELLOW
376.    Yellow_Light
377.   CASE BLUE
378.    Blue_Light
379.   CASE GREEN
380.    Green_Light
381.   CASE RED
382.    Red_Light
383.  END SELECT
384.  
385.  Level_LED
386.  Level_Adjust_Arrows
387.  Start_Button G.GamePlay
388.  _PUTIMAGE , Layer(0), _DISPLAY
389. END SUB
390.  
391. SUB Start_Tone (id%%)
392.  SELECT CASE id%%
393.   CASE LOSER
394.    _SNDLOOP SFX(4)
395.   CASE YELLOW
396.    _SNDLOOP SFX(3)
397.   CASE BLUE
398.    _SNDLOOP SFX(1)
399.   CASE GREEN
400.    _SNDLOOP SFX(2)
401.   CASE RED
402.    _SNDLOOP SFX(0)
403.  END SELECT
404. END SUB
405.  
406. SUB Stop_Tone (id%%)
407.  SELECT CASE id%%
408.   CASE LOSER
409.    _SNDSTOP SFX(4)
410.   CASE YELLOW
411.    _SNDSTOP SFX(3)
412.   CASE BLUE
413.    _SNDSTOP SFX(1)
414.   CASE GREEN
415.    _SNDSTOP SFX(2)
416.   CASE RED
417.    _SNDSTOP SFX(0)
418.  END SELECT
419. END SUB
420.  
421. SUB Build_Display
422.  '---------Build Display--------------------------
423.  _PUTIMAGE , Layer(7), Layer(0)
424.  IF StartUp%% AND G.Yellow_On > 10 THEN Yellow_Light
425.  IF G.Loser THEN Red_Light
426.  Level_LED
427.  Level_Adjust_Arrows
428.  Start_Button G.GamePlay
429.  _PUTIMAGE , Layer(0), _DISPLAY
430.  '------------------------------------------------
431. END SUB
432.  
433. SUB Start_Up_Values
434.  '----------------Start Up Values ----------------
435.  G.Level = 1
436.  G.Speed = SLOWEST
437.  G.Length = 0
438.  G.Loser = FALSE
439.  G.GamePlay = FALSE
440.  G.GO_GO_GO = TRUE
441.  G.Current_Light = 0
442.  G.Display = FALSE
443.  G.Time_It = 0
444.  '------------------------------------------------
445. END SUB
446.  
447. FUNCTION LoadGFX& (Foff&, Size&)
448.  IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
449.  OPEN "temp.dat" FOR BINARY AS #3
450.  dat$ = SPACE$(Size&)
451.  GET #1, Foff&, dat$
452.  PUT #3, , dat$
453.  CLOSE #3
454.  LoadGFX& = _LOADIMAGE("temp.dat", 32)
455. END FUNCTION
456.  
457. FUNCTION LoadSFX& (Foff&, Size&)
458.  IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
459.  OPEN "temp.dat" FOR BINARY AS #3
460.  dat$ = SPACE$(Size&)
461.  GET #1, Foff&, dat$
462.  PUT #3, , dat$
463.  CLOSE #3
464.  LoadSFX& = _SNDOPEN("temp.dat")
465. END FUNCTION
466.  

[bplus]

Working fine on my system. There's more?

[Cobalt]

Working fine on my system. There's more?

technically, No. But I just feel it might be more interesting if there was some kind of victory screen if you complete the sequence to the level count(8,16,24,32). maybe a different screen for each level. or just something. Just having a hard time deciding on just what kind of image to use.

[bplus]

Working fine on my system. There's more?

technically, No. But I just feel it might be more interesting if there was some kind of victory screen if you complete the sequence to the level count(8,16,24,32). maybe a different screen for each level. or just something. Just having a hard time deciding on just what kind of image to use.

What does Simon say? ;-))