Impossible to beat Tic-Tac-Toe Bot

[Zeppelin]

Hey,
I got a bit bored and decided to type up a Tic-Tac-Toe bot that could not be beaten.
Give it a shot, try your luck.

Thanks,
Zeppelin


P.s If you beat it let me know, either you've modified my code or there is a bug :)

[Zeppelin]

Ok. I just realised that I forgot to make the bot actually try to win instead of just defend everything.
So Im gonna go fix that now.
You still can't win by the way.

Zeppelin

[TempodiBasic]

Hi Zeppelin

I'm sorry but at the first time I got this (see picture attached) playing with your TicTacToeBot

So IMHO AI must be enpowered!

[TempodiBasic]

As feedback for debug I can post the sequence of choices

        first game                          second game
I     2  5  6  4      wins        I       2  5  7  6   4   wins
Bot  3  8  7                       Bot    9  8  3  1

Good Debug

[bplus]

Hi TempodiBasic,

Let me know if you can beat this mouse version (don't have to use X's or O's, AI calls itself AI):

Code: QB64: [Select]

1. _TITLE "Tic Tac Toe with AI"
2. 'QB64 version 2017 1106/82 (the day before they switched to version 1.2)
3. 'bplus 2018-01-23
4. CONST xmax = 800
5. CONST ymax = 600
6. CONST redh& = &HFFFF0000
7. CONST greenh& = &HFF00FF00
8. CONST blueh& = &HFF0000FF
9.  
10. SCREEN _NEWIMAGE(xmax, ymax, 32)
11. _SCREENMOVE 360, 60
12.  
13. DEFINT A-Z
14. COMMON SHARED player$, AI$
15. DIM SHARED board$(2, 2) 'store X and O here 3x3
16.  
17. WHILE 1
18.     COLOR greenh&: CLS
19.     winner$ = "": count = 0: done = 0: ERASE board$
20.  
21.     'get player's choice
22.     INPUT "Player, enter symbol to use for your squares: (nothing quits) "; player$
23.     IF player$ = "" THEN END
24.     IF player$ = "AI" THEN AI$ = "#1 AI" ELSE AI$ = "AI"
25.     IF LEN(player$) > 15 THEN player$ = LEFT$(player$, 15)
26.  
27.     'who plays first
28.     INPUT "And now please enter y for yes, if you want to go first: "; first$
29.     IF first$ = "y" THEN turn$ = player$ ELSE turn$ = AI$
30.  
31.     'prep, make grid according to size of longest participant string
32.     IF LEN(player$) > LEN(AI$) THEN s = LEN(player$) ELSE s = LEN(AI$)
33.     sq = 16 * (s + 2)
34.     xoff = (xmax - 3 * sq) / 2
35.     yoff = (ymax - 3 * sq) / 2
36.  
37.     'make # grid once
38.     CLS
39.     FOR i = 1 TO 2
40.         LINE (sq * i + xoff, yoff)-STEP(0, 3 * sq)
41.         LINE (xoff, sq * i + yoff)-STEP(3 * sq, 0)
42.     NEXT
43.  
44.     'take turns filling out the board until a winner$ is found or board is out of spaces
45.     DO
46.         IF turn$ = AI$ THEN
47.             rc = AIchoice
48.             bx = rc MOD 3: by = INT(rc / 3)
49.             board$(bx, by) = AI$
50.             _DELAY 1 'let player think AI is thinking
51.             COLOR blueh&
52.             _PRINTSTRING (bx * sq + xoff + sq / 2 - _PRINTWIDTH(AI$) / 2, by * sq + yoff + sq / 2 - 8), AI$
53.             count = count + 1
54.             IF checkwin THEN winner$ = AI$
55.             turn$ = player$
56.         ELSE
57.             'player's turn from mouse click
58.  
59.             'this might NOT be too intuitive but proper mouse catching demands we wait for mouse button release
60.             m = _MOUSEINPUT: mb = _MOUSEBUTTON(1): mx = _MOUSEX: my = _MOUSEY
61.             IF mb THEN 'get last place mouse button was down
62.                 mb = _MOUSEBUTTON(1): mx = _MOUSEX: my = _MOUSEY
63.                 WHILE mb 'left button down, wait for mouse button release before doing anything as a "click"
64.                     'this updates mx, my while waiting for button release
65.                     m = _MOUSEINPUT: mb = _MOUSEBUTTON(1): mx = _MOUSEX: my = _MOUSEY
66.                 WEND
67.  
68.                 'board x and board y?
69.                 ' board is offset by (xoff, yoff) = top left corner, so subtract these from mouse mx, my
70.                 ' then divide by the size of the square (sq) to get the position in the board array
71.                 ' check that position is inbounds of board array
72.                 bx = INT((mx - xoff) / sq): by = INT((my - yoff) / sq)
73.  
74.                 'now we have mouse pixels converted to board position of array
75.                 IF bx >= 0 AND bx <= 2 AND by >= 0 AND by <= 2 THEN 'caught mouse in a box!
76.                     IF board$(bx, by) <> "" THEN
77.                         BEEP 'NO good! already clicked!
78.                     ELSE
79.                         'OK it all checks out, update the board array and the screen display
80.                         COLOR redh&
81.                         _PRINTSTRING (bx * sq + xoff + sq / 2 - _PRINTWIDTH(player$) / 2, by * sq + yoff + sq / 2 - 8), player$
82.                         board$(bx, by) = player$
83.                         count = count + 1
84.                         IF checkwin THEN winner$ = player$
85.                         turn$ = AI$
86.                     END IF
87.                 ELSE
88.                     BEEP 'you are clicking out of bounds of board!
89.                 END IF
90.             END IF
91.         END IF 'turn
92.         IF winner$ <> "" THEN done = 1
93.         IF done = 0 AND count >= 9 THEN done = -1
94.     LOOP UNTIL done
95.     COLOR greenh&
96.     IF done = -1 THEN s$ = "Out of spaces." ELSE s$ = winner$ + " is the winner!"
97.     _PRINTSTRING ((xmax - _PRINTWIDTH(s$)) / 2, 2 * _FONTHEIGHT), s$
98.     s$ = "Wait 5 secs for next game..."
99.     _PRINTSTRING ((xmax - _PRINTWIDTH(s$)) / 2, 4 * _FONTHEIGHT), s$
100.     _DELAY 5
101. WEND
102.  
103. FUNCTION checkwin
104.     FOR i = 0 TO 2
105.         IF (board$(0, i) = board$(1, i) AND board$(1, i) = board$(2, i)) AND (board$(2, i) <> "") THEN checkwin = 1: EXIT SUB
106.     NEXT
107.     FOR i = 0 TO 2
108.         IF (board$(i, 0) = board$(i, 1) AND board$(i, 1) = board$(i, 2)) AND board$(i, 2) <> "" THEN checkwin = 1: EXIT SUB
109.     NEXT
110.     IF (board$(0, 0) = board$(1, 1) AND board$(1, 1) = board$(2, 2)) AND board$(2, 2) <> "" THEN checkwin = 1: EXIT SUB
111.     IF (board$(0, 2) = board$(1, 1) AND board$(1, 1) = board$(2, 0)) AND board$(2, 0) <> "" THEN checkwin = 1
112. END FUNCTION
113.  
114. FUNCTION AIchoice
115.     'test all moves to win
116.     FOR r = 0 TO 2
117.         FOR c = 0 TO 2
118.             IF board$(c, r) = "" THEN
119.                 board$(c, r) = AI$
120.                 IF checkwin THEN
121.                     board$(c, r) = ""
122.                     AIchoice = 3 * r + c
123.                     EXIT FUNCTION
124.                 ELSE
125.                     board$(c, r) = ""
126.                 END IF
127.             END IF
128.         NEXT
129.     NEXT
130.  
131.     'still here? then no winning moves for AI, how about for player$
132.     FOR r = 0 TO 2
133.         FOR c = 0 TO 2
134.             IF board$(c, r) = "" THEN
135.                 board$(c, r) = player$
136.                 IF checkwin THEN
137.                     board$(c, r) = ""
138.                     AIchoice = 3 * r + c 'spoiler move!
139.                     EXIT FUNCTION
140.                 ELSE
141.                     board$(c, r) = ""
142.                 END IF
143.             END IF
144.         NEXT
145.     NEXT
146.  
147.     'still here? no winning moves, no spoilers then is middle sq available
148.     IF board$(1, 1) = "" THEN AIchoice = 4: EXIT FUNCTION
149.  
150.     'still here still? how about a corner office?
151.     IF board$(0, 0) = "" THEN AIchoice = 0: EXIT FUNCTION
152.     IF board$(2, 0) = "" THEN AIchoice = 2: EXIT FUNCTION
153.     IF board$(0, 2) = "" THEN AIchoice = 6: EXIT FUNCTION
154.     IF board$(2, 2) = "" THEN AIchoice = 8: EXIT FUNCTION
155.  
156.     'still here??? one of these has to go!
157.     IF board$(1, 0) = "" THEN AIchoice = 1: EXIT FUNCTION
158.     IF board$(0, 1) = "" THEN AIchoice = 3: EXIT FUNCTION
159.     IF board$(2, 1) = "" THEN AIchoice = 5: EXIT FUNCTION
160.     IF board$(1, 2) = "" THEN AIchoice = 7: EXIT FUNCTION
161.  
162. END FUNCTION
163.  

[TempodiBasic]

Hi Bplus
Thanks to promote me to betatester....
I find your AI as stronge as to draw both starting for first both starting for second.
Moreover if user looses attention

[bplus]

Hi Bplus
Thanks to promote me to betatester....
I find your AI as stronge as to draw both starting for first both starting for second.
Moreover if user looses attention

Thanks how much do I owe you?

[TempodiBasic]

@Bplus

:-)
as many ideas or suggestions you can pass to a QB64_friend that likes joke and programming