Author Topic: 15 days for Halloween code challenge (Read 9691 times)

TempodiBasic · « **Reply #30 on:** October 31, 2018, 08:16:15 pm »

Hi Guys here my code
be patient downloading ZIP.

Your goal is to give sweet to not get the treat (spider)

Code: QB64: [Select]

'Music downloaded from  [No Copyright Music] Halloween - (Royalty Free Halloween Music)
' Images taken from Images downloaded from www.freepik.com
'
OPTION _EXPLICIT
SCREEN _NEWIMAGE(800, 600, 32)
_TITLE "Halloween Challenge"
_SCREENMOVE 200, 20
 
DIM a AS LONG, b AS LONG, c AS LONG, d AS LONG, e(1 TO 9) AS LONG, f AS LONG, f2 AS LONG, g AS INTEGER
DIM RightGo AS _BYTE, LeftGo AS _BYTE, FireActive AS _BYTE, ChangeMusic AS _BYTE, OffMusic AS _BYTE
DIM Xpump(1 TO 9) AS INTEGER, Ypump(1 TO 9) AS INTEGER, xShip AS INTEGER, xFire AS INTEGER, yFire AS INTEGER
DIM Fpump(1 TO 9) AS _BYTE, Lpump(1 TO 9) AS INTEGER, FireActiveP AS _BYTE, xFireP(1 TO 9) AS INTEGER, yFireP(1 TO 9) AS INTEGER
DIM VelP AS INTEGER, GoDown AS _BYTE, path AS STRING, files$, cmd AS INTEGER, GameOver AS INTEGER
DIM j AS INTEGER, k AS INTEGER, h AS INTEGER, i AS INTEGER, l AS INTEGER, m AS LONG
DIM SHARED mus(1 TO 4) AS LONG, snd(1 TO 4) AS LONG, ActualMus AS LONG, IndexMus AS INTEGER
 
CONST RedBack = _RGB(210, 0, 0, 32), Color1 = _RGB(255, 255, 255, 32), Color2 = _RGB(255, 177, 0, 32), Color3 = _RGB(255, 150, 80, 32)
CONST Color4 = _RGB(255, 100, 0, 32), Color5 = _RGB(255, 55, 0, 32), Color6 = _RGB(100, 130, 20, 32)
CONST FireS = 4, FireP = 3, DeathS = 2, DeathP = 1
CONST False = 0, True = -1, Quit = 999, Fire = 100, FireVel = 10, Right = 150, Left = 200, yShip = 500
CONST CMusic = 250, OMusic = 300, widS = 100, higS = 100
 
_PRINTMODE _KEEPBACKGROUND
RANDOMIZE TIMER
' inizialize fonts----------------------------------------------------------
path$ = "C:\Windows\Fonts\"
files$ = "Tahoma.ttf" '  "lucon.ttf"  <-- Alternative fonts of system
loadfont path$ + files$, f, 68
files$ = "seguihis.ttf"
loadfont path$ + files$, f2, 36
 
' initialize music and sounds------------------------------------------------
loadMusic
 
' initialize images----------------------------------------------------------
a = _LOADIMAGE("assets_H\moon.jpg") 'BACKGROUND
IF a >= -1 THEN PRINT "Image not loaded moon"
b = _LOADIMAGE("assets_H\ship_.png") 'USER
IF b >= -1 THEN PRINT "Image not loaded ship"
c = _LOADIMAGE("assets_H\sweet.png") 'FIRE OF USER
IF c >= -1 THEN PRINT "Image not loaded sweet"
d = _LOADIMAGE("assets_H\spider.png") ' FIRE OF PUMPKINS
IF d >= -1 THEN PRINT "Image not loaded spider"
' PUMPKINS
FOR g = 1 TO 9 STEP 1
    e(g) = _LOADIMAGE("assets_H\pum" + LTRIM$(STR$(g)) + ".png") ' FIRE OF PUMPKINS
    IF e(g) >= -1 THEN PRINT "Image not loaded pum" + LTRIM$(STR$(g)) + ".png", e(g)
    Xpump(g) = 80 * g: Ypump(g) = 70
    Lpump(g) = True 'life
    Fpump(g) = False 'firing
NEXT
VelP = 5 ' pumpkins go towards right
 
' setting for starting------------------------------------------------------------
_PUTIMAGE (1, 1)-(800, 600), a
Credits
IntroStart f, f2
xShip = 200
GoDown = False
GameOver = 0
m = _NEWIMAGE(800, 600, 32)
'main loop
DO
 
    cmd = 0 ' clear buffer commands
    '---------------------------INPUT MANAGEMENT--------------------------------
    ' take commands
    IF _KEYDOWN(32) AND FireActive = 0 THEN cmd = Fire
    IF _KEYDOWN(27) THEN cmd = quits
    IF _KEYDOWN(19200) THEN cmd = Right
    IF _KEYDOWN(19712) THEN cmd = Left
    IF _KEYDOWN(77) OR _KEYDOWN(109) THEN cmd = CMusic
    IF _KEYDOWN(13) AND (_KEYDOWN(77) OR _KEYDOWN(109)) THEN cmd = OMusic
 
    '---------------------------COMMAND TRANSLATOR------------------------------
    ' command Fire
    IF cmd = Fire THEN
        FireActive = True
        yFire = yShip
    END IF
    ' command go right
    IF cmd = Right THEN RightGo = True ELSE RightGo = False
    ' command go left
    IF cmd = Left THEN LeftGo = True ELSE LeftGo = False
    ' command change music
    IF OffMusic = False AND cmd = CMusic THEN ChangeMusic = True
    ' command off music
    IF cmd = OMusic THEN OffMusic = NOT OffMusic
 
 
    '-------------------------EVENT MANAGEMENT-----------------------------------
 
    ' event Fire  @----------------------------------------------
    IF FireActive THEN
        IF yFire = yShip THEN _SNDPLAY snd(FireS): xFire = xShip + INT(widS / 2) - 20
        IF yFire - FireVel > 0 THEN
            yFire = yFire - FireVel
        ELSE
            yFire = 0
            FireActive = False
        END IF
    END IF
 
    ' event go to right  @----------------------------------------------
    IF RightGo THEN
        IF xShip - 10 < 1 THEN xShip = 1 ELSE xShip = xShip - 10
        RightGo = False
    END IF
 
    ' event go to left  @----------------------------------------------
    IF LeftGo THEN
        IF xShip + 10 + widS > 800 THEN xShip = 800 - widS ELSE xShip = xShip + 10
        LeftGo = False
    END IF
 
 
    ' event  change music   @----------------------------------------------
    IF ChangeMusic = True THEN
        IF IndexMus = 4 THEN IndexMus = 1 ELSE IndexMus = IndexMus + 1
        _SNDSTOP ActualMus
        ActualMus = mus(IndexMus)
        _SNDPLAY ActualMus
        ChangeMusic = False
    END IF
 
    ' event Off music  @----------------------------------------------
    IF OffMusic = True THEN _SNDSTOP ActualMus
 
    ' event end music on playing  @----------------------------------------------
    IF _SNDPLAYING(ActualMus) = False THEN _SNDPLAY ActualMus
 
    ' event Move Pumpkins  @----------------------------------------------
    IF VelP > 0 THEN ' moving to right
        FOR j = 9 TO 1 STEP -1
            IF Lpump(j) = True THEN EXIT FOR
        NEXT
        IF Xpump(j) + VelP + 60 > 800 THEN
            VelP = VelP * -1 ' it changes direction
            GoDown = True ' pumpkins go towards ship
        ELSE
            GoDown = False
        END IF
    ELSE 'moving to left
        FOR j = 1 TO 9 STEP 1
            IF Lpump(j) = True THEN EXIT FOR
        NEXT
        IF Xpump(j) + VelP < 0 THEN
            VelP = VelP * -1 ' it changes direction
            GoDown = True ' pumpkins go towards ship
        ELSE
            GoDown = False
        END IF
    END IF
    ' it calculates the new position for pumpkins
    FOR k = 1 TO 9 STEP 1
        IF Lpump(k) = True THEN
            Xpump(k) = Xpump(k) + VelP
            IF GoDown = True THEN Ypump(k) = Ypump(k) + 10
        END IF
    NEXT
 
    ' event Fire Pumpkins  @----------------------------------------------
    FOR h = 1 TO 9 STEP 1
        IF Lpump(h) = True THEN ' if pumpkin exists
            IF (INT(RND * 3) + 1) > 2 THEN
                IF Fpump(h) = False THEN 'if pumpkin is not firing
                    Fpump(h) = True ' it starts to fire
                    yFireP(h) = Ypump(h)
                END IF
            END IF
        END IF
 
        ' event firing pumpkins       @----------------------------------------------
        IF Fpump(h) = True THEN
            IF yFireP(h) = Ypump(h) THEN _SNDPLAY snd(FireP): xFireP(h) = Xpump(h) + INT(widS / 2) - 20
            IF yFireP(h) + FireVel < 600 THEN
                yFireP(h) = yFireP(h) + FireVel
            ELSE
                yFireP(h) = 540
                Fpump(h) = False
            END IF
        END IF
        ' event destroy ship       @----------------------------------------------
        IF (xFireP(h) > xShip AND xFireP(h) < xShip + widS) OR (xFireP(h) + 40 > xShip AND xFireP(h) + 40 < xShip + widS) THEN
            IF (yFireP(h) > yShip AND yFireP(h) < yShip + higS) OR (yFireP(h) + 20 > yShip AND yFireP(h) + 20 < yShip + higS) THEN
                _SNDPLAY snd(2)
                cmd = Quit
            END IF
        END IF
        ' event destroy fireship   @----------------------------------------------
        IF (xFireP(h) >= xFire AND xFireP(h) <= xFire + 40) OR (xFireP(h) + 40 >= xFire AND xFireP(h) + 40 <= xFire + 40) THEN
            IF (yFireP(h) >= yFire AND yFireP(h) <= yFire + 20) OR (yFireP(h) + 20 >= yFire AND yFireP(h) + 20 <= yFire + 20) THEN
                _SNDPLAY snd(1)
                Fpump(h) = False
                FireActive = False
            END IF
        END IF
 
    NEXT
 
    ' event destroy pumpkin @----------------------------------------------
    IF FireActive THEN
        FOR l = 1 TO 9 STEP 1
            IF Lpump(l) = True THEN ' pumpkins is alive
                IF (xFire > Xpump(l)) AND (Xpump(l) + 60 > xFire) OR (xFire + 40 > Xpump(l)) AND (Xpump(l) + 60 > xFire + 40) THEN
                    IF (yFire < Ypump(l) + 60) AND (yFire > Ypump(l)) OR (yFire + 20 < Ypump(l) + 60) AND (yFire + 20 > Ypump(l)) THEN
                        Lpump(l) = False
                        FireActive = False
                        GameOver = GameOver + 1
                        _SNDPLAY snd(1)
                    END IF
                END IF
            END IF
        NEXT
    END IF
 
 
    '-----------------------------------------OUTPUT --------------------
    ' all graphic operations go onto hidden panel m
    _PUTIMAGE (1, 1)-(800, 600), a, m 'background layer
    _PUTIMAGE (xShip, yShip)-(xShip + widS, yShip + higS), b, m ' astroship layer
    IF FireActive THEN _PUTIMAGE (xFire, yFire)-(xFire + 40, yFire + 20), c, m ' FireShip
    FOR i = 1 TO 9 STEP 1
        IF Lpump(i) THEN _PUTIMAGE (Xpump(i), Ypump(i))-(Xpump(i) + 60, Ypump(i) + 60), e(i), m
        IF Fpump(i) THEN _PUTIMAGE (xFireP(i), yFireP(i))-(xFireP(i) + 40, yFireP(i) + 20), d, m
    NEXT
    _PUTIMAGE , m, 0 'copy panel m to screen
    _LIMIT 10
 
    'debug
 
 
LOOP UNTIL GameOver = 9 OR cmd = Quit ' events GameOver and Quit
IF GameOver = 9 THEN
    _SNDPLAY snd(1)
    CLS
    PRINT "YOU WIN"
    PRINT "GAME OVER"
    SLEEP 5
END IF
IF cmd = Quit THEN
    _SNDPLAY snd(2)
    CLS
    PRINT "YOU LOOSE"
    PRINT "GAME OVER"
    SLEEP 5
END IF
 
SYSTEM
 
SUB IntroStart (fn1&, fn2&)
    DIM cont%
    FOR cont% = 1 TO 2 STEP 1
        IF cont% = 1 THEN
            CLS
            IF fn2& > 0 THEN _FONT fn2& ELSE PRINT "No file font loaded" + " seguihis.ttf"
            COLOR Color6
            _PRINTSTRING (260, 200), "Press a key to start"
        ELSE
            CLS , RedBack
            _FONT fn1&
            COLOR Color1
            _PRINTSTRING (30, 120), "INSTRUCTIONS:"
            _PRINTSTRING (30, 200), "space = fire"
            _PRINTSTRING (30, 250), "arrows left/right = move"
            _PRINTSTRING (30, 300), "M = change music"
            _PRINTSTRING (30, 350), "Enter+M =Off/On music"
            _PRINTSTRING (30, 410), "ESC to quit"
        END IF
        IF fn1& > 0 THEN _FONT fn1& ELSE PRINT "No file font loaded" + " Tahoma.ttf"
        COLOR Color1
        _PRINTSTRING (2, 20), "HALLOWEEN CHALLENGE", 0
        COLOR Color2
        _PRINTSTRING (6, 28), "HALLOWEEN CHALLENGE", 0
        COLOR Color3
        _PRINTSTRING (10, 36), "HALLOWEEN CHALLENGE", 0
        COLOR Color4
        _PRINTSTRING (14, 40), "HALLOWEEN CHALLENGE", 0
        COLOR Color5
        _PRINTSTRING (18, 44), "HALLOWEEN CHALLENGE", 0
        IF cont% = 1 THEN SLEEP ELSE SLEEP 4
    NEXT cont%
END SUB
 
SUB loadfont (pat$, h&, size)
    IF _FILEEXISTS(pat$) THEN
        h& = _LOADFONT(pat$, size, "BOLD")
    ELSE
        PRINT "File font not found"
    END IF
END SUB
 
SUB Credits
    DIM cp AS STRING
    COLOR Color4
    _FONT 16
    PRINT "CREDITS:"
    cp = " MUSIC: downloaded from  [No Copyright Music] Halloween - (Royalty Free Halloween Music)" + CHR$(13) + "  on www.youtube.com"
    LOCATE 2, 2
    PRINT cp
    cp = " IMAGES: downloaded from freepik.com created: Pumpkin and Starship by Freepik, Moon by Kjpargeter,  Sweet and spider by Titusurya"
    PRINT cp
    LOCATE 12, 2
    PRINT "PRESS A KEY TO CONTINE..."
    SLEEP
    CLS
END SUB
 
SUB loadMusic
    SHARED OffMusic AS _BYTE
    DIM a AS INTEGER
    CLS
    LOCATE 2, 2
    PRINT "LOADING MUSIC....."
    mus(1) = _SNDOPEN("assets_H\UnknownFear.mp3")
    mus(2) = _SNDOPEN("assets_H\Halloween.mp3")
    mus(3) = _SNDOPEN("assets_H\WonderAndMagic.mp3")
    mus(4) = _SNDOPEN("assets_H\Spook.mp3")
    FOR a = 1 TO 4 STEP 1
        IF mus(a) = 0 THEN PRINT "No music " + STR$(a) + " found!"
    NEXT
    _SNDPLAY mus(a - 1) ' it plays the last music loaded
    ActualMus = mus(a - 1)
    OffMusic = False
    PRINT
    PRINT "LOADING SOUND....."
    snd(1) = _SNDOPEN("assets_H\DeathPump.mp3")
    snd(2) = _SNDOPEN("assets_H\DeathShip.mp3")
    snd(3) = _SNDOPEN("assets_H\FirePump.mp3")
    snd(4) = _SNDOPEN("assets_H\FireShip.mp3")
    FOR a = 1 TO 4 STEP 1
        IF snd(a) = 0 THEN PRINT "No music " + STR$(a) + " found!"
    NEXT
    SLEEP 2
    CLS
END SUB
 
FUNCTION quits
    DIM a$
    COLOR , 0
    _PRINTSTRING (200, 200), "Do you Quit?"
    _PRINTSTRING (300, 260), "Y/N"
    DO
        a$ = LCASE$(INPUT$(1))
    LOOP UNTIL a$ = "y" OR a$ = "n"
    IF a$ = "y" THEN quits = Quit ELSE quits = False
END FUNCTION

Thanks to try

TempodiBasic · « **Reply #31 on:** October 31, 2018, 08:21:35 pm »

If you find too huge .ZIP here 2 screenshots

About midnight... someoneelse can post somethingelse before his/her midnight... it can be...

TempodiBasic · « **Reply #32 on:** October 31, 2018, 08:56:34 pm »

@Bplus

Fine your rotating sphere :-)

Pete · « **Reply #33 on:** October 31, 2018, 09:04:03 pm »

ROFL. It went from a basketball to a sphere... anything but a pumpkin!

Pete

News:

Author Topic: 15 days for Halloween code challenge (Read 9691 times)

TempodiBasic

Re: 15 days for Halloween code challenge

TempodiBasic

Re: 15 days for Halloween code challenge

TempodiBasic

Re: 15 days for Halloween code challenge

Pete

Re: 15 days for Halloween code challenge