qXed: linked list text editor

[STxAxTIC]

Aright screw it I'll make that change of behavior the next thing I do.
Damn you Pete in the most respectful way possible!

[Pete]

Well, the ESC key just reverses the backspace quirk with an insert quirk. Also, trying that a couple of times made the system lock up.

Anyway, is it my understanding you are also making this as a library for others to use? If so, reinventions are usually expected to follow established norms first, and then add new features. People who are used to the way most WP programs work get a little bent out of shape when they look at what they thought they typed, but the screen results show something different. Especially people like me, who have to look at porn... I mean the keyboard, while I'm typing.

Pete :D

[STxAxTIC]

Lemme take a quick guess - you don't use VI(m) do you? Want to see a learning curve in a text editor that you will curse up and down and then curse again left and right because somehow its the most pervasive in the world? Pop open a linux terminal, type "vi", and try to get *anything* done. It's almost uncrackable, but somehow the most argued-for text editor ever. Just weird.

Anyway, I'll be updating the top post in a number of minutes. The cursor will do the more natural thing.

Thanks again, these posts become very motivational on my end...

[Pete]

Yeah, I'm nothing if not helpful... HEY, where'd I go!

Pete

[STxAxTIC]

Okay, I couldn't resist having a little fun with this one.

I've taken the liberty of pressing the Insert key *for* you in case you want to edit this thing as it goes.

Otherwise, press and hold F7 to watch the Gosper Glider Gun a la Conway's Game of Life.

Code: QB64: [Select]

1. _TITLE "qXed"
2. _DELAY .15
3. SCREEN _NEWIMAGE(90, 30, 0)
4.  
5. ' Define fundamental structures.
6. TYPE Vector
7.     X AS INTEGER
8.     Y AS INTEGER
9. END TYPE
10.  
11. TYPE Cell
12.     Identity AS LONG
13.     Pointer AS LONG
14.     Lagger AS LONG
15.     Content AS STRING * 1
16. END TYPE
17.  
18. DIM SHARED MemLimit AS LONG
19. DIM SHARED BOC AS LONG ' Beginning of chain.
20. DIM SHARED EOC AS LONG ' End of chain.
21. MemLimit = 64000
22. BOC = -1
23. EOC = MemLimit
24.  
25. ' Define text window properties.
26. DIM SHARED TextWrapping
27. DIM SHARED TextFormatting
28. DIM SHARED VisibleLines
29. DIM SHARED TopIndent
30. DIM SHARED LeftIndent
31. DIM SHARED TextHeight
32. DIM SHARED TextWidth
33. DIM SHARED HScroll
34. DIM SHARED InsertKey
35. TextWrapping = 1
36. TextFormatting = -1
37. TopIndent = 1
38. LeftIndent = 1
39. TextHeight = _HEIGHT - 2 * TopIndent
40. TextWidth = _WIDTH - 2 * LeftIndent
41. HScroll = 1
42. InsertKey = 1
43.  
44. ' Initiate text inside window.
45. DIM SHARED StartIndex ' First visible character address.
46. DIM SHARED LineAsMapped(TextHeight) AS STRING
47. DIM SHARED Cursor1 AS Vector
48. DIM SHARED Cursor2 AS Vector
49. DIM SHARED ID1
50. DIM SHARED ID2
51.  
52. DIM SHARED FunGrid(TextWidth, TextHeight, 2) AS STRING
53.  
54. ' Load text file into memory if applicable, use example string if not.
55. DIM SHARED FileName$
56. c$ = COMMAND$
57. IF (c$ <> "") THEN
58.     q$ = ""
59.     OPEN c$ FOR INPUT AS #1
60.     DO WHILE NOT EOF(1)
61.         LINE INPUT #1, r$
62.         q$ = q$ + r$ + CHR$(13)
63.     LOOP
64.     CLOSE #1
65.     i = INSTR(c$, ".")
66.     IF (i <> 0) THEN j = i - 1 ELSE j = LEN(c$)
67.     FileName$ = LEFT$(c$, j) + "-" + LTRIM$(RTRIM$(STR$(INT(TIMER)))) + ".txt"
68. ELSE
69.     FileName$ = "Newfile" + "-" + DATE$ + "-" + LTRIM$(RTRIM$(STR$(INT(TIMER)))) + ".txt"
70.     'q$ = "I sank to the floor. I [experienced] this hallucination of tumbling forward into these fractal geometric spaces made of light and then I found myself in the equivalent of the Pope's private chapel and there were insect elf machines proffering strange little tablets with strange writing on them, and I was aghast, completely appalled, because [in] a matter of seconds . . . my entire expectation of the nature of the world was just being shredded in front of me. I've never actually gotten over it. These self-transforming machine elf creatures were speaking in a colored language which condensed into rotating machines that were like Faberge eggs but crafted out of luminescent superconducting ceramics and liquid crystal gels. All this stuff was just so weird and so alien and so un-English-able that it was a complete shock - I mean, the literal turning inside out of [my] intellectual universe!" + CHR$(13) + CHR$(13) + "This went on for two or three minutes, this situation of [discontinuous] orthogonal dimensions to reality just engulfing me. As I came out of it and the room reassembled itself, I said, " + CHR$(34) + "I can't believe it, it's impossible." + CHR$(34) + " To call that a drug is ridiculous; that just means that you just don't have a word for it and so you putter around and you come upon this sloppy concept [that] something goes into your body and there's a change. It's not like that; it's like being struck by noetic lightning. [Note: " + CHR$(34) + "Noetic" + CHR$(34) + " derives from the theologian Pierre Teilhard de Chardin's " + CHR$(34) + "noosphere" + CHR$(34) + " - the collective consciousness of humankind conceived of as a sort of philosophical virtuality.]" + CHR$(13) + CHR$(13) + "[What] astonished me was [that] . . . in the carpets of Central Asia, in the myths of the Maya, in the visions of an Arcimboldi or a Fra Angelico or a Bosch, there is not a hint, not a clue, not an atom of the presence of this thing, This was more [multiplex] than the universe that we share with each other. It was the victory of Neo-Platonic metaphysics; everything [was] made out of a fourth-dimensional mosaic of energy. I was knocked off my feet, and set myself the goal of understanding this. There was really no choice, you see."
71.     q$ = "                                          " + CHR$(13) + "                                          " + CHR$(13) + "                                          " + CHR$(13) + "                                          " + CHR$(13) + "                         **         **    " + CHR$(13) + "                        * *         **    " + CHR$(13) + "  **       **           **                " + CHR$(13) + "  **      * *                             " + CHR$(13) + "          **      **                      " + CHR$(13) + "                  * *                     " + CHR$(13) + "                  *                       " + CHR$(13) + "                                     **   " + CHR$(13) + "                                     * *  " + CHR$(13) + "                                     *    " + CHR$(13) + "                                          " + CHR$(13) + "                                          " + CHR$(13) + "                          ***             " + CHR$(13) + "                          *               " + CHR$(13) + "                           *              " + CHR$(13) + "                                          " + CHR$(13) + "                                          " + CHR$(13) + "                                          " + CHR$(13)
72. END IF
73.  
74. ' Create memory space for string.
75. DIM SHARED TheChain(MemLimit) AS Cell
76.  
77. ' Create character list.
78. CALL Assimilate(q$)
79.  
80. ' Prime main loop.
81. CALL MapText
82. CALL CalibrateCursor(ID1)
83. CALL CalibrateCursor(ID2)
84. CALL PrintEverything
85.  
86. DIM SHARED DEBUG$
87.  
88. DO ' Main loop.
89.     IF StateChange THEN PrintEverything
90.     _DISPLAY
91.     _LIMIT 120
92. LOOP
93. SYSTEM
94.  
95. SUB PrintEverything
96.     CLS
97.     COLOR 7, 1
98.     FOR i = 1 TO VisibleLines
99.         c$ = LineAsMapped(i)
100.         IF ((TextFormatting = 1) AND (TextWrapping <> 2)) THEN
101.             FOR j = 1 TO TextWidth - LEN(c$)
102.                 c$ = c$ + "_"
103.             NEXT
104.         END IF
105.         _PRINTSTRING (LeftIndent + 1, TopIndent + i), MID$(c$, HScroll, TextWidth)
106.     NEXT
107.  
108.     COLOR 11, 0
109.     c$ = "qXed" + DEBUG$
110.     _PRINTSTRING (1, 1), c$
111.  
112.     IF ((Cursor2.X > 0 AND Cursor2.X < _WIDTH) AND ((Cursor2.Y > 0) AND (Cursor2.Y < _HEIGHT))) THEN
113.         p1 = LinearCount(StartIndex, ID1)
114.         p2 = LinearCount(StartIndex, ID2)
115.         pe = LinearCount(StartIndex, EOC)
116.         IF ((p2 > p1) AND (p2 < pe)) THEN
117.             COLOR 0, 6
118.             c$ = TheChain(ID2).Content
119.             IF (c$ = " ") THEN c$ = "_"
120.             IF (c$ = CHR$(13)) THEN c$ = "~"
121.             _PRINTSTRING (Cursor2.X, Cursor2.Y), c$
122.         END IF
123.     END IF
124.  
125.     IF ((Cursor1.X > 0 AND Cursor1.X < _WIDTH) AND ((Cursor1.Y > 0) AND (Cursor1.Y < _HEIGHT))) THEN
126.         IF ((Cursor1.X = Cursor2.X) AND (Cursor1.Y = Cursor2.Y)) THEN COLOR 16, 5 ELSE COLOR 16, 3
127.         c$ = TheChain(ID1).Content
128.         IF (c$ = " ") THEN c$ = "_"
129.         IF (c$ = CHR$(13)) THEN c$ = "~"
130.         _PRINTSTRING (Cursor1.X, Cursor1.Y), c$
131.     END IF
132.  
133.     d$ = TheChain(ID1).Content
134.     e$ = TheChain(ID2).Content
135.     IF ((ASC(d$) = 10) OR (ASC(d$) = 13)) THEN d$ = "~"
136.     IF ((ASC(e$) = 10) OR (ASC(e$) = 13)) THEN e$ = "~"
137.     IF (ASC(d$) = 32) THEN d$ = "_"
138.     IF (ASC(e$) = 32) THEN e$ = "_"
139.  
140.     IF ((Cursor1.X = Cursor2.X) AND (Cursor1.Y = Cursor2.Y)) THEN COLOR 0, 5 ELSE COLOR 0, 3
141.     c$ = "(" + LTRIM$(RTRIM$(STR$(Cursor1.X - LeftIndent))) + "," + LTRIM$(RTRIM$(STR$(Cursor1.Y - TopIndent))) + ":" + " " + LTRIM$(RTRIM$(d$)) + " " + LTRIM$(RTRIM$(STR$(ID1))) + ")"
142.     _PRINTSTRING (2, _HEIGHT), c$
143.     IF (LinearCount(StartIndex, ID2) > LinearCount(StartIndex, ID1)) THEN
144.         COLOR 0, 6
145.         _PRINTSTRING (3 + LEN(c$), _HEIGHT), "(" + LTRIM$(RTRIM$(STR$(Cursor2.X - LeftIndent))) + "," + LTRIM$(RTRIM$(STR$(Cursor2.Y - TopIndent))) + ":" + " " + LTRIM$(RTRIM$(e$)) + " " + LTRIM$(RTRIM$(STR$(ID2))) + ")"
146.     END IF
147.  
148.     COLOR 8, 7
149.     p = LinearCount(ID1, NthP(ID1, MemLimit + 1))
150.     q = LinearCount(NthL(ID1, MemLimit + 1), NthP(ID1, MemLimit + 1))
151.     IF (q = 0) THEN r = 1 ELSE r = 1 - p / q
152.     _PRINTSTRING (_WIDTH, 1 + INT(r * (_HEIGHT - 1))), "*"
153.  
154.     COLOR 15, 0
155.     SELECT CASE TextWrapping
156.         CASE 0: d$ = "Square"
157.         CASE 1: d$ = "Fluid"
158.         CASE 2: d$ = "None"
159.     END SELECT
160.     c$ = "[F6=Save] [F11=Formatting] [F12=Wrapping: " + d$ + "]"
161.     IF (TextWrapping = 2) THEN c$ = "[F1/2=HScroll] " + c$
162.     c$ = c$ + STR$(INT(100 * r)) + "%"
163.     _PRINTSTRING (_WIDTH - LEN(c$), 1), c$
164.  
165.     c$ = "[Esc=Sync] [Mouse2=Copy] [Mouse3=Paste]"
166.     IF (InsertKey = 1) THEN c$ = "[Ins] " + c$
167.     _PRINTSTRING (_WIDTH - LEN(c$), _HEIGHT), c$
168. END SUB
169.  
170. SUB Assimilate (a AS STRING)
171.     ' Load a string to initialize chain.
172.     FOR k = 1 TO MemLimit
173.         TheChain(k).Identity = 0
174.     NEXT
175.     StartIndex = 1
176.     PreviousIdentity = BOC
177.     NextIdentity = NextOpenIdentity(StartIndex)
178.     FOR k = 1 TO LEN(a)
179.         j = NextIdentity
180.         TheChain(j).Identity = j
181.         TheChain(j).Content = ReFormat$(MID$(a, k, 1))
182.         TheChain(j).Lagger = PreviousIdentity
183.         PreviousIdentity = j
184.         IF (k < LEN(a)) THEN
185.             NextIdentity = NextOpenIdentity(j)
186.             TheChain(j).Pointer = NextIdentity
187.         ELSE
188.             TheChain(j).Pointer = EOC
189.         END IF
190.         PRINT TheChain(j).Content
191.     NEXT
192.     ID1 = StartIndex
193.     ID2 = ID1
194. END SUB
195.  
196. FUNCTION ReFormat$ (a AS STRING)
197.     c$ = a
198.     IF c$ = CHR$(10) THEN c$ = CHR$(13)
199.     IF c$ = CHR$(9) THEN c$ = "    "
200.     ReFormat = c$
201. END FUNCTION
202.  
203. FUNCTION NthP (a AS LONG, b AS LONG)
204.     ' Returns the address that is b jumps ahead of address a.
205.     i = a
206.     IF (i <> EOC) THEN
207.         k = 0
208.         j = 0
209.         DO WHILE (k < b)
210.             k = k + 1
211.             j = TheChain(i).Identity
212.             i = TheChain(j).Pointer
213.             IF (i = EOC) THEN EXIT DO
214.         LOOP
215.     END IF
216.     NthP = j
217. END FUNCTION
218.  
219. FUNCTION NthPC (a AS LONG, b AS STRING)
220.     ' Returns the address holding b first enLinearCountered from a.
221.     i = a
222.     DO
223.         j = TheChain(i).Identity
224.         i = TheChain(j).Pointer
225.         IF (TheChain(j).Content = b) THEN EXIT DO
226.         IF (i = EOC) THEN
227.             j = BOC
228.             EXIT DO
229.         END IF
230.     LOOP
231.     NthPC = j
232. END FUNCTION
233.  
234. FUNCTION NthL (a AS LONG, b AS LONG)
235.     ' Returns the address that is b jumps behind address a.
236.     i = a
237.     k = 0
238.     DO WHILE k < b
239.         k = k + 1
240.         j = TheChain(i).Identity
241.         i = TheChain(j).Lagger
242.         IF (i = BOC) THEN EXIT DO
243.     LOOP
244.     NthL = j
245. END FUNCTION
246.  
247. FUNCTION NextOpenIdentity (a AS LONG)
248.     ' Returns first nonzero identity.
249.     FOR j = a TO MemLimit
250.         IF (TheChain(j).Identity = 0) THEN EXIT FOR
251.     NEXT
252.     IF (j > MemLimit) THEN
253.         PRINT "Out of memory: "; MemLimit
254.         SLEEP
255.         SYSTEM
256.     END IF
257.     NextOpenIdentity = j
258. END FUNCTION
259.  
260. FUNCTION BackBreak (a AS LONG)
261.     ' Function for scrolling up.
262.     j = a
263.     lastbreak = 0
264.     c$ = ""
265.     DO
266.         IF (j = BOC) THEN EXIT DO
267.         k = TheChain(j).Lagger
268.         IF (k = BOC) THEN
269.             lastbreak = j
270.             EXIT DO
271.         END IF
272.         j = k
273.         d$ = TheChain(j).Content
274.         IF ((TextWrapping = 1) AND (d$ = " ")) THEN lastbreak = j
275.         c$ = d$ + c$
276.         IF (TextWrapping <> 2) AND (LEN(c$) = TextWidth) THEN EXIT DO
277.         IF (d$ = CHR$(13)) THEN EXIT DO
278.     LOOP
279.     IF (lastbreak <> 0) THEN j = TheChain(lastbreak).Identity
280.     BackBreak = j
281. END FUNCTION
282.  
283. SUB InsertBefore (a AS LONG, b AS STRING)
284.     ' Inserts a single cell before address a in the chain.
285.     j = NextOpenIdentity(a)
286.     al = TheChain(a).Lagger
287.     TheChain(j).Identity = j
288.     TheChain(j).Pointer = a
289.     TheChain(j).Lagger = al
290.     TheChain(j).Content = ReFormat$(b)
291.     TheChain(a).Lagger = j
292.     IF (al = BOC) THEN StartIndex = j ELSE TheChain(al).Pointer = j
293. END SUB
294.  
295. SUB InsertAfter (a AS LONG, b AS STRING)
296.     ' Inserts a single cell after address a in the chain.
297.     j = NextOpenIdentity(a)
298.     ap = TheChain(a).Pointer
299.     TheChain(j).Identity = j
300.     TheChain(j).Pointer = ap
301.     TheChain(j).Lagger = a
302.     TheChain(j).Content = ReFormat$(b)
303.     TheChain(a).Pointer = j
304.     IF (ap <> EOC) THEN TheChain(ap).Lagger = j
305. END SUB
306.  
307. SUB InsertRange (a AS LONG, b AS STRING)
308.     ' Inserts a sub-chain anywhere.
309.     FOR k = 1 TO LEN(b)
310.         c$ = MID$(b, k, 1)
311.         CALL InsertBefore(a, c$)
312.     NEXT
313. END SUB
314.  
315. SUB UnlinkCell (a AS LONG)
316.     ' Remove single cell from chain and clear identity.
317.     ap = TheChain(a).Pointer
318.     al = TheChain(a).Lagger
319.     IF ((ap = EOC) AND (al = BOC)) THEN
320.         TheChain(a).Content = " "
321.         'ID1 = a
322.         'ID2 = ID1
323.     ELSE
324.         TheChain(a).Identity = 0
325.         IF ((ap <> EOC) AND (al <> BOC)) THEN
326.             TheChain(al).Pointer = ap
327.             TheChain(ap).Lagger = al
328.         END IF
329.         IF (ap = EOC) THEN TheChain(al).Pointer = EOC
330.         IF (al = BOC) THEN
331.             StartIndex = ap
332.             TheChain(ap).Lagger = BOC
333.         END IF
334.     END IF
335. END SUB
336.  
337. SUB UnlinkRange (a AS LONG, b AS LONG)
338.     ' Remove sub-chain and clear identity of each cell.
339.     bp = TheChain(b).Pointer
340.     al = TheChain(a).Lagger
341.     IF ((al = BOC) AND (bp = EOC)) THEN
342.         CALL UnlinkRange(NthP(a, 2), b)
343.         TheChain(a).Content = " "
344.         TheChain(a).Pointer = bp
345.     ELSE
346.         k = a
347.         DO WHILE ((k <> b) AND (k <> EOC))
348.             TheChain(k).Identity = 0
349.             k = TheChain(k).Pointer
350.         LOOP
351.         TheChain(b).Identity = 0
352.         TheChain(bp).Lagger = al
353.         IF (al = BOC) THEN StartIndex = bp ELSE TheChain(al).Pointer = bp
354.     END IF
355. END SUB
356.  
357. FUNCTION LinearCount (a AS LONG, b AS LONG)
358.     ' Returns number of links between two addresses.
359.     i = a
360.     k = 0
361.     DO WHILE (i <> b)
362.         k = k + 1
363.         j = TheChain(i).Identity
364.         i = TheChain(j).Pointer
365.         IF (i = EOC) THEN EXIT DO
366.     LOOP
367.     LinearCount = k
368. END FUNCTION
369.  
370. FUNCTION Projection$ (a AS LONG, b AS LONG)
371.     ' Returns the linear content for all address between a and b, inclusive.
372.     DIM TheReturn AS STRING
373.     TheReturn = ""
374.     IF (a = b) THEN
375.         TheReturn = TheChain(a).Content
376.     ELSE
377.         j = a
378.         DO
379.             c$ = TheChain(j).Content
380.             TheReturn = TheReturn + c$
381.             k = TheChain(j).Pointer
382.             IF (j = b) THEN EXIT DO
383.             IF (k = EOC) THEN EXIT DO
384.             j = k
385.         LOOP
386.     END IF
387.     Projection$ = TheReturn
388. END SUB
389.  
390. SUB MapText
391.     IF (TextFormatting = 1) THEN br$ = "~" ELSE br$ = " "
392.     j = StartIndex
393.     i = 1
394.     q$ = ""
395.     d$ = ""
396.     DO ' Begin with any left-over text from previous iteration.
397.         q$ = d$
398.         d$ = ""
399.         r = TextWidth - LEN(q$)
400.         IF (TextWrapping = 2) THEN r = MemLimit + 1
401.         k1 = NthP(j, r)
402.         k2 = NthPC(j, CHR$(13))
403.         c1 = LinearCount(j, k1)
404.         c2 = LinearCount(j, k2)
405.         IF (c2 = 0) THEN ' Line is blank-returned.
406.             k = k2
407.             q$ = q$ + br$
408.             j = NthP(k, 2)
409.         ELSE
410.             IF (c1 = c2) THEN ' Possible end of chain.
411.                 k = TheChain(k1).Lagger
412.                 q$ = q$ + Projection$(j, k)
413.                 j = NthP(k, 2)
414.             END IF
415.             IF (c1 < c2) THEN ' Width limit case (not always maximum).
416.                 k = k1
417.                 q$ = q$ + Projection$(j, k)
418.                 j = NthP(k, 2)
419.             END IF
420.             IF (c1 > c2) THEN ' Break return somewhere in line (not first).
421.                 k = k2
422.                 q$ = q$ + Projection$(j, TheChain(k).Lagger) + br$
423.                 n = TheChain(k).Pointer
424.                 IF (n <> EOC) THEN j = n
425.             END IF
426.         END IF
427.         IF (TextWrapping = 1) THEN ' Wrap text at first space from right, send remainder to next line.
428.             IF (LEN(q$) >= TextWidth) THEN
429.                 FOR m = LEN(q$) TO 1 STEP -1
430.                     c$ = MID$(q$, m, 1)
431.                     IF (c$ = " ") OR (c$ = "-") THEN
432.                         q$ = LEFT$(q$, m)
433.                         EXIT FOR
434.                     END IF
435.                     d$ = c$ + d$
436.                     IF (m = 1) THEN ' Line is too long for allowed space and contains no wrapping characters.
437.                         q$ = LEFT$(q$, TextWidth)
438.                         d$ = ""
439.                         EXIT FOR
440.                     END IF
441.                 NEXT
442.             END IF
443.         END IF
444.         LineAsMapped(i) = q$
445.         i = i + 1
446.         IF (i >= TextHeight) THEN EXIT DO
447.         IF (j = k) THEN EXIT DO
448.     LOOP
449.     VisibleLines = i - 1
450. END SUB
451.  
452. FUNCTION StateChange
453.     DIM TheReturn AS INTEGER
454.     TheReturn = 0
455.     MH = 0
456.     DO WHILE _MOUSEINPUT
457.         MH1 = _MOUSEBUTTON(1)
458.         MH2 = _MOUSEBUTTON(2)
459.         MH3 = _MOUSEBUTTON(3)
460.     LOOP
461.     IF (MH1 = -1) THEN ' Move Cursor1.
462.         MH = 1
463.         IF (_MOUSEX > LeftIndent) AND (_MOUSEX < TextWidth + LeftIndent + 1) AND (_MOUSEY > TopIndent) AND (_MOUSEY < TopIndent + TextHeight + 1) THEN
464.             Cursor1.X = _MOUSEX
465.             q = LeftIndent + LEN(LineAsMapped(_MOUSEY - TopIndent))
466.             IF (Cursor1.X > q) THEN Cursor1.X = q
467.             Cursor1.Y = _MOUSEY
468.             CALL ReassignID1
469.         END IF
470.     END IF
471.     IF (MH2 = -1) THEN ' Move Cursor2 and copy anything between Cursor1 and Cursor2 to clipboard.
472.         MH = 1
473.         IF (_MOUSEX > LeftIndent) AND (_MOUSEX < TextWidth + LeftIndent + 1) AND (_MOUSEY > TopIndent) AND (_MOUSEY < TopIndent + TextHeight + 1) THEN
474.             Cursor2.X = _MOUSEX
475.             q = LeftIndent + LEN(LineAsMapped(_MOUSEY - TopIndent))
476.             IF (Cursor2.X > q) THEN Cursor2.X = q
477.             Cursor2.Y = _MOUSEY
478.             CALL ReassignID2
479.             IF (LinearCount(StartIndex, ID2) > LinearCount(StartIndex, ID1)) THEN _CLIPBOARD$ = Projection$(ID1, ID2)
480.         END IF
481.     END IF
482.     IF (MH3 = -1) THEN ' Paste at Cursor1 position.
483.         MH = 1
484.         IF (LinearCount(StartIndex, ID2) > LinearCount(StartIndex, ID1)) THEN CALL InsertRange(ID1, _CLIPBOARD$)
485.     END IF
486.  
487.     KH = 0
488.     KH = _KEYHIT
489.     ' Bksp
490.     IF (KH = 8) THEN
491.         r = TheChain(ID1).Pointer
492.         q = TheChain(ID1).Lagger
493.         CALL UnlinkCell(ID1)
494.         IF ((r = EOC) AND (q = BOC)) THEN
495.         ELSE
496.             IF (q <> BOC) THEN ID1 = q ELSE ID1 = r
497.             IF (r = EOC) THEN ID2 = ID1
498.         END IF
499.     END IF
500.     ' Tab
501.     IF (KH = 9) THEN CALL InsertRange(ID1, "    ")
502.     ' Esc
503.     IF (KH = 27) THEN
504.         IF (ID2 <> ID1) THEN ID2 = ID1 ELSE ID2 = NthL(ID2, MemLimit + 1)
505.     END IF
506.     ' Enter, Alphanumerics
507.     IF (KH = 13) OR ((KH >= 32) AND (KH <= 126)) THEN
508.         IF (InsertKey = -1) THEN
509.             IF (ID1 = ID2) THEN
510.                 CALL InsertBefore(ID1, LTRIM$(RTRIM$(CHR$(KH))))
511.             ELSE
512.                 CALL InsertAfter(ID1, LTRIM$(RTRIM$(CHR$(KH))))
513.                 ID1 = NthP(ID1, 2)
514.             END IF
515.         ELSE
516.             TheChain(ID1).Content = LTRIM$(RTRIM$(CHR$(KH)))
517.             IF (ID1 = ID2) THEN
518.                 ID1 = NthP(ID1, 2)
519.                 ID2 = ID1
520.             ELSE
521.                 ID1 = NthP(ID1, 2)
522.             END IF
523.         END IF
524.     END IF
525.     ' F1
526.     IF (KH = 15104) THEN
527.         IF (TextWrapping = 2) THEN
528.             HScroll = HScroll - 1
529.             IF (HScroll < 1) THEN HScroll = 1
530.             CALL ReassignID1
531.             CALL ReassignID2
532.         END IF
533.     END IF
534.     ' F2
535.     IF (KH = 15360) THEN
536.         IF (TextWrapping = 2) THEN
537.             HScroll = HScroll + 1
538.             CALL ReassignID1
539.             CALL ReassignID2
540.         END IF
541.     END IF
542.     ' F5
543.     IF (KH = 16128) THEN
544.         q$ = Projection$(NthL(ID1, MemLimit + 1), NthP(ID1, MemLimit + 1))
545.         Assimilate q$
546.     END IF
547.     ' F4
548.     IF (KH = 15872) THEN
549.         'CALL InsertRange(NthP(ID2, 2), "=" + SxriptEval$(Projection(ID1, ID2)))
550.     END IF
551.     ' F6
552.     IF (KH = 16384) THEN
553.         OPEN FileName$ FOR OUTPUT AS #1
554.         q$ = Projection$(NthL(ID1, MemLimit + 1), NthP(ID1, MemLimit + 1))
555.         PRINT #1, q$
556.         CLOSE #1
557.     END IF
558.     ' F7
559.     IF (KH = 16640) THEN
560.         CALL ConvertToGrid
561.         CALL GOL
562.         CALL ConvertFromGrid
563.     END IF
564.     ' F8
565.     IF (KH = 16896) THEN
566.  
567.     END IF
568.     ' Home
569.     IF (KH = 18176) THEN
570.         IF (TextWrapping = 2) THEN HScroll = 1
571.         Cursor1.X = LeftIndent + 1
572.         CALL ReassignID1
573.     END IF
574.     ' UpArrow
575.     IF (KH = 18432) THEN
576.         IF (Cursor1.Y > TopIndent + 1) THEN
577.             Cursor1.Y = Cursor1.Y - 1
578.         ELSE
579.             StartIndex = BackBreak(StartIndex)
580.         END IF
581.         q = LEN(LineAsMapped(Cursor1.Y - TopIndent)) + 1
582.         IF (Cursor1.X > q) THEN Cursor1.X = q
583.         CALL ReassignID1
584.     END IF
585.     ' LeftArrow
586.     IF (KH = 19200) THEN
587.         ID1 = NthL(ID1, 2)
588.         IF (TextWrapping = 2) THEN
589.             IF (Cursor1.X = LeftIndent + 1) THEN
590.                 IF (HScroll > 1) THEN
591.                     HScroll = HScroll - 1
592.                 ELSE
593.                     j = Cursor1.Y - TopIndent - 1
594.                     IF (j >= 1) THEN
595.                         k = LEN(LineAsMapped(j)) - TextWidth + 1
596.                         IF (k >= 1) THEN
597.                             HScroll = k
598.                         END IF
599.                     END IF
600.                 END IF
601.             END IF
602.         END IF
603.     END IF
604.     ' RightArrow
605.     IF (KH = 19712) THEN
606.         ID1 = NthP(ID1, 2)
607.         IF (TextWrapping = 2) THEN
608.             m = Cursor1.X - LeftIndent
609.             n = LEN(LineAsMapped(Cursor1.Y - TopIndent)) - HScroll + 1
610.             IF (m >= TextWidth) THEN
611.                 HScroll = HScroll + 1
612.                 CALL ReassignID1
613.             END IF
614.             IF (m >= n) THEN
615.                 j = Cursor1.Y - TopIndent + 1
616.                 IF (j <= TextHeight) THEN
617.                     HScroll = 1
618.                 END IF
619.             END IF
620.         END IF
621.     END IF
622.     ' End
623.     IF (KH = 20224) THEN
624.         Cursor1.X = LeftIndent + LEN(LineAsMapped(Cursor1.Y - TopIndent))
625.         CALL ReassignID1
626.         IF (TextWrapping = 2) THEN
627.             q = LEN(LineAsMapped(Cursor1.Y - TopIndent)) - TextWidth + 1
628.             IF (q >= 1) THEN HScroll = q
629.         END IF
630.     END IF
631.     ' DownArrow
632.     IF (KH = 20480) THEN
633.         IF (Cursor1.Y = TopIndent + VisibleLines) THEN
634.             IF (VisibleLines > 1) THEN
635.                 StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
636.                 CALL MapText
637.             END IF
638.         ELSE
639.             Cursor1.Y = Cursor1.Y + 1
640.         END IF
641.         q = LEN(LineAsMapped(Cursor1.Y - TopIndent)) + 1
642.         IF (Cursor1.X > q) THEN
643.             Cursor1.X = q
644.         END IF
645.         CALL ReassignID1
646.     END IF
647.     ' Insert
648.     IF (KH = 20992) THEN
649.         InsertKey = -InsertKey
650.     END IF
651.     ' Del
652.     IF (KH = 21248) THEN
653.         IF (LinearCount(StartIndex, ID2) > LinearCount(StartIndex, ID1)) THEN
654.             r = TheChain(ID2).Pointer
655.             q = TheChain(ID1).Lagger
656.             p = ID1
657.             CALL UnlinkRange(ID1, ID2)
658.             IF ((r = EOC) AND (q = BOC)) THEN
659.                 ID1 = p
660.                 ID2 = ID1
661.                 StartIndex = p
662.             ELSE
663.                 IF (q <> BOC) THEN ID1 = q ELSE ID1 = r
664.                 ID2 = NthP(ID1, 2)
665.             END IF
666.         END IF
667.     END IF
668.     ' F11
669.     IF (KH = 34048) THEN TextFormatting = -TextFormatting
670.     ' F12
671.     IF (KH = 34304) THEN
672.         TextWrapping = TextWrapping + 1
673.         IF (TextWrapping > 2) THEN TextWrapping = 0
674.         ID1 = StartIndex
675.         ID2 = ID1
676.         HScroll = 1
677.     END IF
678.     ' Cursor sync and autoscrolling.
679.     IF ((MH <> 0) OR (KH > 0)) THEN
680.         TheReturn = 1
681.         CALL MapText
682.         CALL CalibrateCursor(ID1)
683.         CALL CalibrateCursor(ID2)
684.         IF (Cursor1.Y > TopIndent + TextHeight - 1) THEN StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
685.     END IF
686.     StateChange = TheReturn
687. END FUNCTION
688.  
689. SUB CalibrateCursor (a AS LONG)
690.     ' Place Cursor under ID on rendered line.
691.     s = StartIndex
692.     IF ((TextWrapping = 2) AND (HScroll > 1)) THEN s = NthP(s, HScroll)
693.     c = LinearCount(s, a)
694.     k = 0
695.     FOR j = 1 TO VisibleLines
696.         n = LEN(LineAsMapped(j))
697.         IF (k + n < c) THEN
698.             k = k + n
699.         ELSE
700.             i = c - k + 1
701.             EXIT FOR
702.         END IF
703.     NEXT
704.     IF (i >= LeftIndent + LEN(LineAsMapped(j))) THEN
705.         IF (j < VisibleLines) THEN
706.             i = LeftIndent
707.             j = j + 1
708.         ELSE
709.             i = LeftIndent + LEN(LineAsMapped(j))
710.         END IF
711.     END IF
712.     IF (a = ID1) THEN
713.         Cursor1.X = LeftIndent + i
714.         Cursor1.Y = TopIndent + j
715.     END IF
716.     IF (a = ID2) THEN
717.         Cursor2.X = LeftIndent + i
718.         Cursor2.Y = TopIndent + j
719.     END IF
720. END SUB
721.  
722. FUNCTION FindID (a AS INTEGER, b AS LONG)
723.     ' Find identity under a map location.
724.     RelX = a - LeftIndent
725.     RelY = b - TopIndent
726.     FOR k = 1 TO RelY - 1
727.         t = t + LEN(LineAsMapped(k))
728.     NEXT
729.     t = t + RelX
730.     FindID = t
731. END FUNCTION
732.  
733. SUB ReassignID1
734.     ' Reassign identity under Cursor1.
735.     ID1 = NthP(StartIndex, FindID(Cursor1.X, Cursor1.Y) + (HScroll - 1))
736. END SUB
737.  
738. SUB ReassignID2
739.     ' Reassign identity under Cursor2.
740.     ID2 = NthP(StartIndex, FindID(Cursor2.X, Cursor2.Y) + (HScroll - 1))
741. END SUB
742.  
743. SUB ConvertToGrid
744.     FOR j = 1 TO VisibleLines
745.         c$ = LineAsMapped(j)
746.         FOR i = 1 TO LEN(c$) - 1 ' BR offset to exclude break return at line end.
747.             FunGrid(i, j, 1) = MID$(c$, i, 1)
748.         NEXT
749.     NEXT
750. END SUB
751.  
752. SUB ConvertFromGrid
753.     q$ = ""
754.     FOR j = 1 TO VisibleLines
755.         FOR i = 1 TO LEN(LineAsMapped(j)) - 1
756.             q$ = q$ + FunGrid(i, j, 1)
757.         NEXT
758.         q$ = q$ + CHR$(13) ' Undoes BR offset.
759.     NEXT
760.     Assimilate q$
761. END SUB
762.  
763. SUB GOL
764.     FOR j = 1 TO VisibleLines
765.         FOR i = 1 TO LEN(LineAsMapped(j)) - 1
766.             c$ = FunGrid(i, j, 1)
767.             IF (c$ = " ") THEN c$ = "0" ELSE c$ = "1"
768.             FunGrid(i, j, 1) = c$
769.             FunGrid(i, j, 2) = c$
770.         NEXT
771.     NEXT
772.     FOR j = 2 TO VisibleLines - 2 ' BR offset.
773.         FOR i = 2 TO LEN(LineAsMapped(j)) - 2 ' BR offset.
774.             c$ = FunGrid(i, j, 1)
775.             a1 = VAL(FunGrid(i - 1, j + 1, 1))
776.             a2 = VAL(FunGrid(i, j + 1, 1))
777.             a3 = VAL(FunGrid(i + 1, j + 1, 1))
778.             a4 = VAL(FunGrid(i - 1, j, 1))
779.             a6 = VAL(FunGrid(i + 1, j, 1))
780.             a7 = VAL(FunGrid(i - 1, j - 1, 1))
781.             a8 = VAL(FunGrid(i, j - 1, 1))
782.             a9 = VAL(FunGrid(i + 1, j - 1, 1))
783.             t = a1 + a2 + a3 + a4 + a6 + a7 + a8 + a9
784.             IF (c$ = "1") THEN
785.                 SELECT CASE t
786.                     CASE IS < 2
787.                         FunGrid(i, j, 2) = "0"
788.                     CASE 2
789.                         FunGrid(i, j, 2) = "1"
790.                     CASE 3
791.                         FunGrid(i, j, 2) = "1"
792.                     CASE IS > 3
793.                         FunGrid(i, j, 2) = "0"
794.                 END SELECT
795.             ELSE
796.                 IF (t = 3) THEN FunGrid(i, j, 2) = "1"
797.             END IF
798.         NEXT
799.     NEXT
800.     FOR j = 1 TO VisibleLines
801.         FOR i = 1 TO LEN(LineAsMapped(j)) - 1
802.             c$ = FunGrid(i, j, 2)
803.             IF (c$ = "0") THEN c$ = " " ELSE c$ = CHR$(219)
804.             FunGrid(i, j, 1) = c$
805.             FunGrid(i, j, 2) = c$
806.         NEXT
807.     NEXT
808. END SUB
809.  

[bplus]

Well that is one very interesting way to go with an editor!

[STxAxTIC]

Heya all,

Made a pretty fat update that is best kept at the top. I direct you here for the latest: https://www.qb64.org/forum/index.php?topic=597

[STxAxTIC]

Heya folks,

I want to take some people back to a painful memory of 2014, following the IRC bot wars. In that struggle, I attempted to create an end-all SCREEN 0 program that would perform so many essential functions that a person would never want to close it. In certain ways I succeeded back then, as my go-to IRC client for over a year was an instance of the handmade program to which I'm alluding, the notorious MathBlab. You could do anything but make toast - go online, play poker, evaluate LISP expressions a la qbguy, yada yada - all that stuff. The thing still works, but I'm never pasting the code again under my own name. The guys at #qb64 on irc.freenode.net are still traumatized by the whole thing (mainly the ability to public test Eliza the therapist). See below for a screenshot.

Years later I find my projects at a similar collision point, but the pieces are not as crappy this time. The Sxript thing has gone through a total rewrite since then and is well-trusted, all essential web stuff (for my purposes) has been abstracted into Sprezzo. With a universal SCREEN 0 slate like qXed, I can see these coming together to form a QB64 approximation of emacs. See the second screenshot (my awesome paint skills). (There is one connection missing, and that is between Fellippe's InForm and a general way to handle text. That is being cooked behind the scenes - give it a few weeks or months.)

As for the connections that are marked, you can see why we try to make programs that interact nicely with other ones. Certain combinations give calculators, messaging apps, you see the idea. When three lines collide however, it's time for a new node. The square in the middle sounds suspiciously like the old MathBlab program. So... I have no choice. Expect a web-enabled does-lots-of-screen-zero-stuff program to emerge on this thread next.