Multithreaded webserver

[mdijkens]

For workshops I give, I sometimes need an easy mechanism to share (big) files with the audience or vice-versa on a local network.
I decided it would be a nice challenge to build something myself in QB64.
I've also added multithtreading (single CPU core) so people don't have to wait for eachother when downloading/uploading big files

Comments and advice always welcome ...

Code: QB64: [Select]

1. Const VERSION = "v22.03.30.4"
2. ' Start with root path of webserver as parameter and optional port e.g. mdserver2 d:\mysite 8088
3. ' Place 'favicon.ico' file (+R+H) in root directory
4. ' Place '.auth' file (+R+H) with authorized hashes in all protected directories
5.  
6. DefInt A-Z
7. Const FALSE = 0, TRUE = Not FALSE
8.  
9. Const TIMEOUT = 10
10. Const MAXURLLEN = 32000
11. Const BLOCKSIZE = 2 ^ 21
12. Const MAXFILESIZE = 2 ^ 39
13. $If WIN Then
14.   Const SEP0 = "/", SEP = "\"
15. $Else
16.   Const SEP0 = "\", SEP = "/"
17. $End If
18.  
19. Type reqType
20.   thread As Integer '                 thread#
21.   client As Integer '                 http-client#
22.   Typ As String '                     GET / POST / PUT
23.   Path As String '                    Path in Url '/../../'
24.   File As String '                    File in Url 'file.ext'
25.   Param As String '                   param=123
26.   Auth As String '                    Authorization hash
27.   cLen As _Unsigned _Integer64 '      Centent-Length
28.   cStart As _Unsigned _Integer64 '    Content start
29.   cEnd As _Unsigned _Integer64 '      Content end
30.   cBytes As _Unsigned _Integer64 '    Content bytes
31.   cMime As String '                   Content mime type
32.   cBoundary As String '               Content multi-part boundary string
33.   cFileNameIn As String '             Post filename 'file.ext'
34.   cFileNameOut As String '            '<SEP>...<SEP>file.ext'
35.   cFileSize As _Unsigned _Integer64 ' Filesize in bytes
36. End Type
37. Dim Shared CRLF As String * 2: CRLF = Chr$(13) + Chr$(10)
38. Dim Shared As String APPLNAME, SITEPATH, PORT
39. Dim Shared As Integer HOST
40.  
41. $Console:Only
42. _Dest _Console
43.  
44. If init Then
45.   main
46. End If
47. System
48.  
49. Function init%
50.   APPLNAME = appName$: SITEPATH = ".": PORT = "8088"
51.   For c% = 1 To _CommandCount
52.     cv~% = Val(Command$(c%))
53.     If cv~% > 0 Then
54.       PORT = _Trim$(Str$(cv~%))
55.     Else
56.       SITEPATH = replace$(_Trim$(Command$(c%)), SEP0, SEP)
57.     End If
58.   Next c%
59.   If SITEPATH = SEP Or Right$(SITEPATH, 2) = ":\" Then SITEPATH = SITEPATH + "."
60.   If Right$(SITEPATH, 1) = SEP Then SITEPATH = Left$(SITEPATH, Len(SITEPATH) - 1)
61.   If SITEPATH = "" Or Not _DirExists(SITEPATH) Then SITEPATH = Left$(APPLNAME, _InStrRev(APPLNAME, SEP$) - 1)
62.  
63.   printLog "SERVER: '" + APPLNAME + "'"
64.   printLog "VERSION: " + VERSION
65.   printLog "PORT: " + PORT
66.   If Right$(SITEPATH, 2) = "\." Then
67.     printLog "SITEPATH: '" + Left$(SITEPATH, Len(SITEPATH) - 2) + SEP + "'"
68.   Else
69.     printLog "SITEPATH: '" + SITEPATH + SEP + "'"
70.   End If
71.   Dim thread(0 To 9) As Integer
72.   For t% = 0 To 9: thread(t%) = _FreeTimer: Next t%
73.   On Timer(thread(0), .01) Thread0
74.   On Timer(thread(1), .01) Thread1
75.   On Timer(thread(2), .01) Thread2
76.   On Timer(thread(3), .01) Thread3
77.   On Timer(thread(4), .01) Thread4
78.   On Timer(thread(5), .01) Thread5
79.   On Timer(thread(6), .01) Thread6
80.   On Timer(thread(7), .01) Thread7
81.   On Timer(thread(8), .01) Thread8
82.   On Timer(thread(9), .01) Thread9
83.   For t% = 0 To 9: Timer(thread(t%)) On: Next t%
84.  
85.   HOST = _OpenHost("TCP/IP:" + PORT)
86.   init% = (HOST < 0)
87. End Function
88.  
89. Sub main
90.   Timer On
91.   Do Until _KeyHit = 27
92.     _Limit 10
93.   Loop
94.   Timer Off
95. End Sub
96.  
97. Sub processRequest (thread%)
98.   client% = _OpenConnection(HOST)
99.   If client% < 0 Then
100.     Dim req As reqType: req.thread = thread%: req.client = client%
101.     Get req.client, , reqBytes$
102.     If parseRequest(req, reqBytes$) Then
103.       log$ = LTrim$(Str$(-req.client)) + ":" + req.Typ + " " + req.Path
104.       If Not authorized(req) Then
105.         log$ = log$ + "  Authenticate: "
106.         If req.Auth <> "" Then log$ = log$ + req.Auth
107.         res$ = httpHeader$(req, 401, ""): Put req.client, , res$
108.       ElseIf req.Typ = "POST" Then
109.         received~&& = handlePost(req, reqBytes$)
110.         log$ = log$ + req.cFileNameIn + " (" + _Trim$(Str$(req.cFileSize)) + ")"
111.         If received~&& <> req.cLen Then log$ = log$ + "  ERROR !!!"
112.         'redirect
113.         res$ = httpHeader$(req, 301, ""): Put req.client, , res$
114.       ElseIf req.Typ = "GET" Then
115.         If req.File <> "" Then 'download file
116.           sent~&& = handleGetFile(req)
117.           log$ = log$ + req.File
118.           If req.Param <> "" Then log$ = log$ + "?" + req.Param
119.           log$ = log$ + " (" + _Trim$(Str$(sent~&&)) + ")"
120.           If sent~&& = 0 Then ' redirect
121.             log$ = log$ + "  ERROR: File not found"
122.             req.Path = "/": res$ = httpHeader$(req, 404, ""): Put req.client, , res$
123.           End If
124.         Else ' render page
125.           html$ = renderDirectory$(req)
126.           If html$ <> "" Then
127.             res$ = httpHeader$(req, 200, html$)
128.           Else
129.             log$ = log$ + "  ERROR: Path not found"
130.             res$ = httpHeader$(req, 404, "")
131.           End If
132.           Put req.client, , res$
133.         End If
134.       Else
135.         log$ = "ERROR: NOT ALLOWED !!!"
136.         'redirect
137.         res$ = httpHeader$(req, 404, ""): Put req.client, , res$
138.       End If
139.       printLog log$
140.     End If
141.     Close req.client
142.   End If
143. End Sub
144.  
145. Function renderDirectory$ (req As reqType)
146.   If Left$(req.Path, 1) <> "/" Or Right$(req.Path, 1) <> "/" Then Exit Function
147.   fspec$ = replace$(SITEPATH + req.Path, SEP0, SEP)
148.   If Not _DirExists(fspec$) Then Exit Function
149.   px12$ = "style='font-family:" + quoted$("Courier New") + "; font-size:12px;'"
150.   px14$ = "style='font-family:" + quoted$("Arial") + "; font-size:14px;'"
151.   px20$ = "style='font-family:" + quoted$("Courier New") + "; font-size:20px;'"
152.   html$ = "<html><body><form enctype='multipart/form-data' action='.' method='POST'>" + _
153.           "<input type='file' name='filename' " + px14$ + ">" + _
154.           "<input type='submit' " + px14$ + "></form><hr>" + _
155.           "<p " + px20$ + ">"
156.   If req.Path = "/" Then
157.     html$ = html$ + "/"
158.   Else
159.     Dim p$(1000): parts% = split(req.Path, "/", p$())
160.     href$ = ""
161.     For i% = 0 To parts% - 2
162.       href$ = href$ + p$(i%) + "/"
163.       html$ = html$ + "<a href='" + href$ + "'>" + p$(i%) + "/</a> "
164.     Next i%
165.     html$ = html$ + p$(i%)
166.   End If
167.   html$ = html$ + "</p><table " + px12$ + ">"
168.   tmp$ = APPLNAME + LTrim$(Str$(req.thread)) + ".tmp"
169.   $If WIN Then
170.     Shell _Hide "DIR /O:GN " + fspec$ + " >" + tmp$
171.   $Else
172.     Shell _Hide "ls -l --group-directories-first " + fspec$ + " >" + tmp$
173.   $End If
174.   If _FileExists(tmp$) Then
175.     ff% = FreeFile
176.     Open tmp$ For Input As ff%
177.     tdp$ = "<td style='padding-right: 20px;"
178.     tda$ = tdp$ + " text-align:right;'>"
179.     apName$ = Mid$(APPLNAME, _InStrRev(APPLNAME, SEP) + 1)
180.     Do While Not EOF(ff%)
181.       Line Input #ff%, l$
182.       $If WIN Then
183.         If Val(Left$(l$, 2)) > 0 And Right$(l$, 1) <> "." Then
184.           dat$ = Left$(l$, 16): sz~&& = Val(replace$(Mid$(l$, 18), ",", "")): f$ = Mid$(l$, 36)
185.           If InStr(l$, "<DIR>") > 0 And sz~&& = 0 Then
186.     html$ = html$ + "<tr>" + tdp$ + "'><a href='" + req.Path + f$ + "/'>" + f$ + "</a></td>" + _
187.     "<td/><td>" + dat$ + "</td></tr>"
188.           ElseIf Left$(f$, 1) <> "." And Left$(f$, Len(apName$)) <> apName$ Then
189.     html$ = html$ + "<tr>" + tdp$ + "'><a href='" + req.Path + f$ + "'>" + f$ + "</a></td>" + _
190.     tda$ + Str$(sz~&&) + "</td><td>" + dat$ + "</td></tr>"
191.           End If
192.         End If
193.       $Else
194.         If InStr("-d", Left$(l$, 1)) > 0 Then
195.         sp% = 0: For i% = 1 To 4: sp% = InStr(sp% + 1, l$, " "): Next i%: sp% = sp% + 1
196.         Do While InStr("0123456789", Mid$(l$, sp%, 1)) = 0: sp% = sp% + 1: Loop
197.         dp% = InStr(sp% + 1, l$, " ")
198.         sz~&& = Val(Mid$(l$, sp%, dp% - sp%))
199.         dat$ = _Trim$(Mid$(l$, dp%, 14))
200.         f$ = _Trim$(Mid$(l$, dp% + 13))
201.         If Left$(l$, 1) = "d" And sz~&& = 0 Then
202.         html$ = html$ + "<tr>" + tdp$ + "'><a href='" + req.Path + f$ + "/'>" + f$ + "</a></td>" + _
203.         "<td/><td>" + dat$ + "</td></tr>"
204.         ElseIf Left$(f$, 1) <> "." And Left$(f$, Len(apName$)) <> apName$ Then
205.         html$ = html$ + "<tr>" + tdp$ + "'><a href='" + req.Path + f$ + "'>" + f$ + "</a></td>" + _
206.         tda$ + Str$(sz~&&) + "</td><td>" + dat$ + "</td></tr>"
207.         End If
208.         End If
209.       $End If
210.     Loop
211.     Close ff%
212.     Kill tmp$
213.   End If
214.   html$ = html$ + "</table></body></html>"
215.   renderDirectory$ = html$
216. End Function
217.  
218. Function handleGetFile~&& (req As reqType)
219.   If Left$(req.Path, 1) <> "/" Or Right$(req.Path, 1) <> "/" Or req.File = "" Then Exit Function
220.   fspec$ = replace$(SITEPATH + req.Path + req.File, SEP0, SEP)
221.   If Not _FileExists(fspec$) Then Exit Function
222.   ff% = FreeFile: Open fspec$ For Binary Access Read As ff%
223.   req.cFileSize = LOF(ff%)
224.   res$ = httpHeader$(req, 200, "")
225.   If req.cFileSize <= BLOCKSIZE Then
226.     Put req.client, , res$
227.     dat$ = String$(req.cFileSize, 0)
228.     Get ff%, , dat$
229.     req.cBytes = Len(dat$)
230.     Put req.client, , dat$
231.     _Delay .001 'for other threads
232.   Else
233.     blocks& = _Ceil((req.cFileSize / BLOCKSIZE))
234.     dat$ = String$(BLOCKSIZE, 0)
235.     Put req.client, , res$
236.     req.cBytes = 0
237.     For b& = 1 To blocks& - 1
238.       Get ff%, , dat$
239.       req.cBytes = req.cBytes + Len(dat$)
240.       Put req.client, , dat$
241.       _Delay .001 'for other threads
242.     Next b&
243.     dat$ = String$(req.cFileSize Mod BLOCKSIZE, 0)
244.     Get ff%, , dat$
245.     req.cBytes = req.cBytes + Len(dat$)
246.     Put req.client, , dat$
247.   End If
248.   Close ff%
249.   handleGetFile~&& = req.cBytes
250. End Function
251.  
252. Function handlePost~&& (req As reqType, reqBytes$)
253.   If _FileExists(req.cFileNameOut) Then Exit Function
254.   If req.cEnd = 0 Then
255.     content$ = Mid$(reqBytes$, req.cStart)
256.     req.cBytes = req.cBytes + Len(content$)
257.   Else
258.     content$ = Mid$(reqBytes$, req.cStart, req.cEnd - req.cStart - 4)
259.     req.cBytes = req.cBytes + Len(content$) + Len(req.cBoundary) + 8
260.   End If
261.   ff% = FreeFile: Open req.cFileNameOut For Binary Access Write As ff%
262.   Put ff%, , content$
263.   req.cFileSize = Len(content$)
264.   _Delay .001 'for other threads
265.   If req.cEnd = 0 Then
266.     Get req.client, , reqBytes$
267.     tim! = Timer
268.     Do While req.cBytes < req.cLen And ((86400 + Timer - tim!) Mod 86400) < TIMEOUT
269.       If Len(reqBytes$) > 0 Then
270.         req.cEnd = InStr(reqBytes$, req.cBoundary)
271.         If req.cEnd = 0 Then
272.           content$ = reqBytes$
273.           req.cBytes = req.cBytes + Len(content$)
274.         Else
275.           content$ = Left$(reqBytes$, req.cEnd - 5)
276.           req.cBytes = req.cBytes + Len(content$) + Len(req.cBoundary) + 8
277.         End If
278.         Put ff%, , content$
279.         req.cFileSize = req.cFileSize + Len(content$)
280.         _Delay .001 'for other threads
281.         tim! = Timer
282.       End If
283.       Get req.client, , reqBytes$
284.     Loop
285.   End If
286.   Close ff%
287.   handlePost~&& = req.cBytes
288. End Function
289.  
290. Function parseRequest% (req As reqType, reqBytes$)
291.   'printLog reqBytes$ '@@
292.   parseRequest = FALSE
293.   req.Typ = "": req.Path = "": req.Param = "": req.File = "": req.Auth = ""
294.   req.cLen = 0: req.cStart = 0: req.cEnd = 0: req.cMime = "": req.cBoundary = ""
295.   req.cFileNameIn = "": req.cFileNameOut = ""
296.   req.cBytes = 0: req.cFileSize = 0
297.   If Len(reqBytes$) < 36 Then Exit Function
298.   If Left$(reqBytes$, 5) = "GET /" Then
299.     req.Typ = "GET": s% = 5
300.   ElseIf Left$(reqBytes$, 6) = "POST /" Then
301.     req.Typ = "POST": s% = 6
302.   Else
303.     Exit Function
304.   End If
305.   h% = InStr(s%, reqBytes$, " HTTP/1.1" + CRLF): If h% = 0 Or h% > MAXURLLEN Then Exit Function
306.   url$ = Mid$(reqBytes$, s%, h% - s%)
307.   For i% = 1 To Len(url$)
308.     uc$ = Mid$(url$, i%, 1)
309.     If uc$ = "?" Then param% = TRUE
310.     If Not param% Then
311.       If InStr("./_-~ 0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz", uc$) > 0 Then req.Path = req.Path + uc$
312.     Else
313.       If InStr("=_-~ 0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz", uc$) > 0 Then req.Param = req.Param + uc$
314.     End If
315.   Next i%
316.   If InStr(req.Path, "..") > 0 Or InStr(req.Path, "/.") > 0 Or InStr(req.Path, "./") > 0 Then Exit Function
317.   If InStr(req.Path, "//") > 0 Or Left$(req.Path, 1) <> "/" Then Exit Function
318.   bs% = _InStrRev(req.Path, "/")
319.   req.File = Mid$(req.Path, bs% + 1)
320.   req.Path = Left$(req.Path, bs%)
321.   auth% = InStr(reqBytes$, "Authorization: ")
322.   If auth% > 0 Then req.Auth = Mid$(reqBytes$, auth% + 15, InStr(auth%, reqBytes$, CRLF) - auth% - 15)
323.   If req.Typ = "POST" Then
324.     s% = InStr(h%, reqBytes$, "Content-Length: "): If s% = 0 Or s% > h% + 1000 Then Exit Function
325.     req.cLen = Val(Mid$(reqBytes$, s% + 16)): If req.cLen < 1 Or req.cLen > MAXFILESIZE Then Exit Function
326.     h% = InStr(s%, reqBytes$, "Content-Type: "): If h% = 0 Or h% > s% + 1000 Then Exit Function
327.     s% = InStr(h%, reqBytes$, "; boundary="): If s% = 0 Or s% > h% + 100 Then Exit Function
328.     h% = InStr(s%, reqBytes$, CRLF): If h% = 0 Or h% > s% + 100 Then Exit Function
329.     req.cBoundary = Mid$(reqBytes$, s% + 11, h% - s% - 11)
330.     req.cBytes = InStr(h%, reqBytes$, CRLF + CRLF) + 4: If req.cBytes = 0 Or req.cBytes > h% + 1000 Then Exit Function
331.     s% = InStr(req.cBytes, reqBytes$, req.cBoundary): If s% = 0 Or s% > h% + 1000 Then Exit Function
332.     h% = InStr(s%, reqBytes$, "; filename="): If h% = 0 Or h% > s% + 100 Then Exit Function
333.     s% = InStr(h%, reqBytes$, CRLF): If s% = 0 Or s% > h% + 100 Then Exit Function
334.     req.cFileNameIn = unquoted$(Mid$(reqBytes$, h% + 11, s% - h% - 11))
335.     req.cFileNameOut = replace$(SITEPATH + req.Path + req.cFileNameIn, SEP0, SEP)
336.     h% = InStr(s%, reqBytes$, "Content-Type: "): If h% = 0 Or h% > s% + 10 Then Exit Function
337.     s% = InStr(h%, reqBytes$, CRLF): If s% = 0 Or s% > h% + 100 Then Exit Function
338.     req.cMime = Mid$(reqBytes$, h% + 14, s% - h% - 14)
339.     req.cStart = s% + 4
340.     req.cBytes = req.cStart - req.cBytes
341.     req.cEnd = InStr(req.cStart, reqBytes$, req.cBoundary)
342.   End If
343.   parseRequest = TRUE
344. End Function
345.  
346. Function authorized% (req As reqType)
347.   fspec$ = replace$(SITEPATH + req.Path, SEP0, SEP) + ".auth"
348.   If _FileExists(fspec$) Then
349.     ff% = FreeFile
350.     Open fspec$ For Input As ff%
351.     Do While Not EOF(ff%)
352.       Line Input #ff%, lin$
353.       If req.Auth = lin$ Then authorized% = TRUE: Exit Do
354.     Loop
355.     Close ff%
356.   Else
357.     authorized% = TRUE
358.   End If
359. End Function
360.  
361. Function httpHeader$ (req As reqType, code%, html$)
362.   Select Case code%
363.     Case 200 ' render page & favicon.ico & get file
364.   res$ ="HTTP/1.1 200 OK" + CRLF + _
365.   "Server: md" + CRLF + "Connection: close" + CRLF
366.       If html$ <> "" Then ' render page
367.         res$ = res$ + "Content-Type: text/html" + CRLF + "Content-Length:" + Str$(Len(html$)) + CRLF + CRLF + html$
368.       ElseIf req.File = "favicon.ico" Then 'get favicon.ico
369.   res$ = res$ + "Content-Type: image/png" + CRLF + _
370.   "Content-Length:" + CRLF + Ltrim$(Str$(req.cFileSize)) + CRLF + CRLF
371.       ElseIf req.cFileSize > 0 Then 'get file
372.   res$ = res$ + "Content-Type: application/force-download" + CRLF + _
373.   "Content-Length:" + CRLF + Ltrim$(Str$(req.cFileSize)) + CRLF + _
374.   "Content-Transfer-Encoding: binary" + _
375.   "Content-Disposition: attachment; filename=" + quoted$(req.File) + CRLF + CRLF
376.       End If
377.     Case 301 'after post & not allowed
378.   res$ ="HTTP/1.1 301 Moved Permanently" + CRLF + _
379.   "Location: " + req.Path + CRLF + _
380.   "Server: md" + CRLF + "Connection: close" + CRLF + "Content-Type: text/html" + CRLF + CRLF
381.     Case 401 'authenticate
382.   res$ ="HTTP/1.1 401 Unauthorized" + CRLF + _
383.   "WWW-Authenticate: Basic" + CRLF + _
384.   "Server: md" + CRLF + "Connection: close" + CRLF + CRLF
385.     Case Else '404
386.   res$ ="HTTP/1.1 404 Not Found" + CRLF + _
387.   "Server: md" + CRLF + "Connection: close" + CRLF + CRLF
388.   End Select
389.   httpHeader$ = res$
390. End Function
391.  
392. Sub printLog (l$)
393.   ll$ = Date$ + " " + Time$ + " : " + l$
394.   ff% = FreeFile: Open APPLNAME + ".log" For Append Access Write As ff%
395.   Print #ff%, ll$
396.   Close ff%
397.   Print ll$
398. End Sub
399.  
400. Function quoted$ (q$)
401.   quoted$ = Chr$(34) + q$ + Chr$(34)
402. End Function
403.  
404. Function unquoted$ (qq$)
405.   uq$ = _Trim$(qq$): l& = Len(uq$)
406.   If l& > 0 Then
407.     If Asc(Left$(uq$, 1)) = 34 And Asc(Mid$(uq$, l&, 1)) = 34 Then
408.       unquoted$ = _Trim$(Mid$(uq$, 2, l& - 2))
409.     Else
410.       unquoted$ = uq$
411.     End If
412.   End If
413. End Function
414.  
415. Function replace$ (ir$, i0$, i1$)
416.   or$ = ir$
417.   i0len& = Len(i0$)
418.   i& = InStr(or$, i0$)
419.   If i0len& = Len(i1$) Then
420.     Do While i& > 0
421.       Mid$(or$, i&, i0len&) = i1$
422.       i& = InStr(or$, i0$)
423.     Loop
424.   Else
425.     Do While i& > 0
426.       or$ = Left$(or$, i& - 1) + i1$ + Mid$(or$, i& + Len(i0$))
427.       i& = InStr(or$, i0$)
428.     Loop
429.   End If
430.   replace$ = or$
431. End Function
432.  
433. Function split& (inString As String, delim As String, outArray() As String)
434.   Dim curpos As Long, arrpos As Long, LD As Long, dpos As Long
435.   curpos = 1: arrpos = LBound(outArray): LD = Len(delim)
436.   dpos = InStr(curpos, inString, delim)
437.   Do Until dpos = 0
438.     outArray(arrpos) = Mid$(inString, curpos, dpos - curpos)
439.     arrpos = arrpos + 1
440.     If arrpos > UBound(outArray) Then ReDim _Preserve outArray(LBound(outArray) To UBound(outArray) + 1000) As String
441.     curpos = dpos + LD
442.     dpos = InStr(curpos, inString, delim)
443.   Loop
444.   outArray(arrpos) = Mid$(inString, curpos)
445.   ReDim _Preserve outArray(LBound(outArray) To arrpos) As String
446.   split& = arrpos
447. End Function
448.  
449. Function appName$ ()
450.   $If WIN Then
451.     Declare Library 'Directory Information using KERNEL32
452.       Function GetModuleFileNameA (ByVal hModule As Long, lpFileName As String, Byval nSize As Long)
453.     End Declare
454.     Static appNam$
455.     If appNam$ = "" Then
456.       FileName$ = Space$(512): res = GetModuleFileNameA(0, FileName$, Len(FileName$))
457.       appNam$ = Left$(FileName$, Len(RTrim$(FileName$)) - 5)
458.     End If
459.     appName$ = appNam$
460.   $Else
461.     appName$ = Command$(0)
462.   $End If
463. End Function
464.  
465. Sub Thread0 (): processRequest 0: End Sub
466. Sub Thread1 (): processRequest 1: End Sub
467. Sub Thread2 (): processRequest 2: End Sub
468. Sub Thread3 (): processRequest 3: End Sub
469. Sub Thread4 (): processRequest 4: End Sub
470. Sub Thread5 (): processRequest 5: End Sub
471. Sub Thread6 (): processRequest 6: End Sub
472. Sub Thread7 (): processRequest 7: End Sub
473. Sub Thread8 (): processRequest 8: End Sub
474. Sub Thread9 (): processRequest 9: End Sub
475.  

edit: cleaned it up a bit

[bplus]

Interesting!