Optical Illusion Clock

[SierraKen]

I used old code I had from my older analog clocks and added another hand to it which is 1/60 of a second and changed the colors. I also added an optical illusion design that also has a bit of moving color. The clock gongs the hour every hour too. The _Limit command is at 400 so the fast hand will have a smoother animation. Tell me what you think.

Code: QB64: [Select]

1. _Title "Optical Illusion Clock"
2. Screen _NewImage(350, 350, 32)
3. i = _NewImage(350, 350, 32)
4. ' ----------------------------------------
5. ' Draw clock here and use  _DEST i and _DEST 0
6. _Dest i
7. Circle (175, 175), 170, _RGB32(255, 255, 255)
8.  
9. For ls = 1 To 60
10.     ss = (60 - ls) * 6 + 180
11.     x = Int(Sin(ss / 180 * 3.141592) * 75) + 175
12.     y = Int(Cos(ss / 180 * 3.141592) * 75) + 175
13.     Line (x, y)-(x * 1.5, y * 1.5), _RGB32(255, 255, 255)
14. Next ls
15.  
16. _Dest 0
17. '-----------------------------------------
18.  
19.  
20. Do
21.     _Limit 400
22.     hours = Timer \ 3600
23.     minutes = Timer \ 60 - hours * 60
24.     seconds = (Timer - hours * 3600 - minutes * 60)
25.     qseconds = (seconds * 60)
26.     ho$ = Left$(Time$, 2): hou = Val(ho$)
27.     min$ = Mid$(Time$, 4, 2): minu = Val(min$)
28.     seco$ = Right$(Time$, 2): secon = Val(seco$)
29.     '1/60 of a second.
30.     qs = (60 - qseconds) * 6 + 180
31.     x = Int(Sin(qs / 180 * 3.141592) * 125) + 175
32.     y = Int(Cos(qs / 180 * 3.141592) * 125) + 175
33.     For b = -5 To 5 Step .5
34.         Line (175 + b, 175)-(x, y), _RGB32(255, 255, 255)
35.         Line (175, 175 + b)-(x, y), _RGB32(255, 255, 255)
36.     Next b
37.     x2 = Int(Sin(qs / 180 * 3.141592) * 170) + 175
38.     y2 = Int(Cos(qs / 180 * 3.141592) * 170) + 175
39.     For sz = .1 To 5 Step .1
40.         Circle (x2, y2), sz, _RGB32(255, 255, 255)
41.     Next sz
42.     x2 = Int(Sin(qs / 180 * 3.141592) * 75) + 175
43.     y2 = Int(Cos(qs / 180 * 3.141592) * 75) + 175
44.     Line (x2, y2)-(x2 * 1.5, y2 * 1.5), _RGB32(127, 255, 127)
45.     'Seconds
46.     s = (60 - seconds) * 6 + 180
47.     x = Int(Sin(s / 180 * 3.141592) * 125) + 175
48.     y = Int(Cos(s / 180 * 3.141592) * 125) + 175
49.     For b = -5 To 5 Step .5
50.         Line (175 + b, 175)-(x, y), _RGB32(0, 255, 255)
51.         Line (175, 175 + b)-(x, y), _RGB32(0, 255, 255)
52.     Next b
53.     x = Int(Sin(s / 180 * 3.141592) * 170) + 175
54.     y = Int(Cos(s / 180 * 3.141592) * 170) + 175
55.     For sz = .1 To 5 Step .1
56.         Circle (x, y), sz, _RGB32(0, 255, 255)
57.     Next sz
58.     'Minutes
59.     m = 180 - minutes * 6
60.     xx = Int(Sin(m / 180 * 3.141592) * 120) + 175
61.     yy = Int(Cos(m / 180 * 3.141592) * 120) + 175
62.     For b = -5 To 5 Step .5
63.         Line (175 + b, 175)-(xx, yy), _RGB32(127, 255, 127)
64.         Line (175, 175 + b)-(xx, yy), _RGB32(127, 255, 127)
65.     Next b
66.     xx = Int(Sin(m / 180 * 3.141592) * 170) + 175
67.     yy = Int(Cos(m / 180 * 3.141592) * 170) + 175
68.     For sz = .1 To 5 Step .1
69.         Circle (xx, yy), sz, _RGB32(127, 255, 127)
70.     Next sz
71.     'Hours
72.     h = 360 - hours * 30 + 180
73.     xxx = Int(Sin(h / 180 * 3.141592) * 50) + 175
74.     yyy = Int(Cos(h / 180 * 3.141592) * 50) + 175
75.     For b = -5 To 5 Step .5
76.         Line (175 + b, 175)-(xxx, yyy), _RGB32(255, 122, 0)
77.         Line (175, 175 + b)-(xxx, yyy), _RGB32(255, 122, 0)
78.     Next b
79.     xxx = Int(Sin(h / 180 * 3.141592) * 170) + 175
80.     yyy = Int(Cos(h / 180 * 3.141592) * 170) + 175
81.     For sz = .1 To 5 Step .1
82.         Circle (xxx, yyy), sz, _RGB32(255, 122, 0)
83.     Next sz
84.  
85.     For sz = .1 To 5
86.         Circle (175, 175), sz, _RGB32(255, 255, 127)
87.     Next sz
88.  
89.     'Chimes
90.     If minu = 0 And secon = 0 Then
91.         hour2 = hou
92.         If hour2 > 12 Then hour2 = hour2 - 12
93.         If hour2 = 0 Then hour2 = 12
94.         For chimes = 1 To hour2
95.             ttt = 0
96.             Do
97.                 'queue some sound
98.                 Do While _SndRawLen < 0.1 'you may wish to adjust this
99.                     sample = Sin(ttt * 340 * Atn(1) * 8) '340Hz sine wave (ttt * 440 * 2p)
100.                     sample = sample * Exp(-ttt * 3) 'fade out eliminates clicks after sound
101.                     _SndRaw sample
102.                     ttt = ttt + 1 / _SndRate 'sound card sample frequency determines time
103.                 Loop
104.                 'do other stuff, but it may interrupt sound
105.             Loop While ttt < 2 'play for 2 seconds
106.             Do While _SndRawLen > 0 'Finish any left over queued sound!
107.             Loop
108.         Next chimes
109.     End If
110.     two:
111.     _Display
112.     Cls
113.     _PutImage (0, 0)-(350, 350), i
114. Loop
115.  

[bplus]

Hey Ken, well you know I had to give this a try ;-))

Code: QB64: [Select]

1. _Title "Optical Illusion Clock" ' b+ make over 2022-01-22
2. Screen _NewImage(350, 350, 32)
3. _PrintMode _KeepBackground
4. Dim ticksX(59), ticksY(59)
5. For i = 0 To 59
6.     ticksX(i) = 175 + 170 * Cos(i * _Pi(2 / 60))
7.     ticksY(i) = 175 + 170 * Sin(i * _Pi(2 / 60))
8. Next
9. Do
10.     Cls
11.     hours = Timer \ 3600
12.     minutes = Timer \ 60 - hours * 60
13.     seconds = (Timer - hours * 3600 - minutes * 60)
14.  
15.     ho$ = Left$(Time$, 2): hou = Val(ho$)
16.     min$ = Mid$(Time$, 4, 2): minu = Val(min$)
17.     seco$ = Right$(Time$, 2): secon = Val(seco$)
18.  
19.     'Hours
20.     h = 360 - hours * 30 + 180
21.     radius = 15
22.     colr~& = _RGB32(200, 0, 0)
23.     x = Int(Sin(h / 180 * 3.141592) * 80) + 175
24.     y = Int(Cos(h / 180 * 3.141592) * 80) + 175
25.     GoSub drawStuff
26.     _Font 16
27.     Color &HFFFFFFFF
28.     _PrintString (x - 8, y - 7), Mid$(Time$, 1, 2)
29.  
30.  
31.     'Minutes
32.     m = 180 - minutes * 6
33.     colr~& = _RGB32(0, 128, 0)
34.     radius = 14
35.     x = Int(Sin(m / 180 * 3.141592) * 125) + 175
36.     y = Int(Cos(m / 180 * 3.141592) * 125) + 175
37.     GoSub drawStuff
38.     _Font 16
39.     Color &HFFFFFFFF
40.     _PrintString (x - 8, y - 7), Mid$(Time$, 4, 2)
41.  
42.  
43.     'Seconds
44.     s = (60 - seconds) * 6 + 180
45.     colr~& = _RGB32(0, 0, 128)
46.     radius = 12
47.     x = Int(Sin(s / 180 * 3.141592) * 160) + 175
48.     y = Int(Cos(s / 180 * 3.141592) * 160) + 175
49.     GoSub drawStuff
50.     _Font 8
51.     Color &HFFFFFFFF
52.     _PrintString (x - 6, y - 4), Mid$(Time$, 7, 2)
53.  
54.     'Chimes
55.     If minu = 0 And secon = 0 Then
56.         hour2 = hou
57.         If hour2 > 12 Then hour2 = hour2 - 12
58.         If hour2 = 0 Then hour2 = 12
59.         For chimes = 1 To hour2
60.             ttt = 0
61.             Do
62.                 'queue some sound
63.                 Do While _SndRawLen < 0.1 'you may wish to adjust this
64.                     sample = Sin(ttt * 340 * Atn(1) * 8) '340Hz sine wave (ttt * 440 * 2p)
65.                     sample = sample * Exp(-ttt * 3) 'fade out eliminates clicks after sound
66.                     _SndRaw sample
67.                     ttt = ttt + 1 / _SndRate 'sound card sample frequency determines time
68.                 Loop
69.                 'do other stuff, but it may interrupt sound
70.             Loop While ttt < 2 'play for 2 seconds
71.             Do While _SndRawLen > 0 'Finish any left over queued sound!
72.             Loop
73.         Next chimes
74.     End If
75.     _Display
76.     _Limit 60
77. Loop
78. drawStuff:
79. For i = 0 To 59
80.     Line (ticksX(i), ticksY(i))-(x, y), colr~&
81. Next
82. For sz = .1 To radius Step .2
83.     Circle (x, y), sz, colr~&
84. Next sz
85.  
86. Return
87.  
88.  
89.  

[bplus]

Here is more interesting optical illusion:

Code: QB64: [Select]

1. _Title "Optical Illusion Clock" ' b+ make over 2022-01-22
2. Screen _NewImage(350, 350, 32)
3. _ScreenMove 400, 200
4. _PrintMode _KeepBackground
5.  
6. grid& = _NewImage(_Width - 1, _Height - 1, 32)
7. _Dest grid&
8. Color &HFFFFFF00
9. side = 170 * Sqr(2)
10. sided2 = side / 2
11. drawGrid _Width / 2 - sided2, _Height / 2 - sided2, side / 60, side / 60, 60, 60
12. _Dest 0
13. Cls
14. Dim ticksX(59), ticksY(59)
15. For i = 0 To 59
16.     ticksX(i) = 175 + 170 * Cos(i * _Pi(2 / 60))
17.     ticksY(i) = 175 + 170 * Sin(i * _Pi(2 / 60))
18. Next
19. Do
20.     Cls
21.     a = a + _Pi(2 / 3600)
22.     b = b + _Pi(2 / 3599)
23.     RotoZoom3 _Width / 2, _Height / 2, grid&, 1, 1, -a
24.     RotoZoom3 _Width / 2, _Height / 2, grid&, 1, 1, b
25.     hours = Timer \ 3600
26.     minutes = Timer \ 60 - hours * 60
27.     seconds = (Timer - hours * 3600 - minutes * 60)
28.  
29.     ' for chimes
30.     ho$ = Left$(Time$, 2): hou = Val(ho$)
31.     min$ = Mid$(Time$, 4, 2): minu = Val(min$)
32.     seco$ = Right$(Time$, 2): secon = Val(seco$)
33.  
34.     'Hours
35.     h = 360 - hours * 30 + 180
36.     radius = 15
37.     colr~& = _RGB32(160, 0, 0)
38.     x = Int(Sin(h / 180 * 3.141592) * 80) + 175
39.     y = Int(Cos(h / 180 * 3.141592) * 80) + 175
40.     GoSub drawStuff
41.     _Font 16
42.     Color &HFFFFFFFF
43.     _PrintString (x - 8, y - 7), Mid$(Time$, 1, 2)
44.  
45.  
46.     'Minutes
47.     m = 180 - minutes * 6
48.     colr~& = _RGB32(0, 128, 0)
49.     radius = 14
50.     x = Int(Sin(m / 180 * 3.141592) * 125) + 175
51.     y = Int(Cos(m / 180 * 3.141592) * 125) + 175
52.     GoSub drawStuff
53.     _Font 16
54.     Color &HFFFFFFFF
55.     _PrintString (x - 8, y - 7), Mid$(Time$, 4, 2)
56.  
57.  
58.     'Seconds
59.     s = (60 - seconds) * 6 + 180
60.     colr~& = _RGB32(0, 0, 128)
61.     radius = 12
62.     x = Int(Sin(s / 180 * 3.141592) * 160) + 175
63.     y = Int(Cos(s / 180 * 3.141592) * 160) + 175
64.     GoSub drawStuff
65.     _Font 8
66.     Color &HFFFFFFFF
67.     _PrintString (x - 6, y - 4), Mid$(Time$, 7, 2)
68.  
69.     'Chimes
70.     If minu = 0 And secon = 0 Then
71.         hour2 = hou
72.         If hour2 > 12 Then hour2 = hour2 - 12
73.         If hour2 = 0 Then hour2 = 12
74.         For chimes = 1 To hour2
75.             ttt = 0
76.             Do
77.                 'queue some sound
78.                 Do While _SndRawLen < 0.1 'you may wish to adjust this
79.                     sample = Sin(ttt * 340 * Atn(1) * 8) '340Hz sine wave (ttt * 440 * 2p)
80.                     sample = sample * Exp(-ttt * 3) 'fade out eliminates clicks after sound
81.                     _SndRaw sample
82.                     ttt = ttt + 1 / _SndRate 'sound card sample frequency determines time
83.                 Loop
84.                 'do other stuff, but it may interrupt sound
85.             Loop While ttt < 2 'play for 2 seconds
86.             Do While _SndRawLen > 0 'Finish any left over queued sound!
87.             Loop
88.         Next chimes
89.     End If
90.     _Display
91.     _Limit 60
92. Loop
93. drawStuff:
94. For sz = .1 To radius Step .2
95.     Circle (x, y), sz, colr~&
96. Next sz
97. Return
98.  
99. Sub drawGrid (x, y, xs, ys, xn, yn) ' top left x, y, x side, y side, number of x, nmber of y
100.     Dim As Long i, dx, dy
101.     dx = xs * xn: dy = ys * yn
102.     For i = 0 To xn
103.         Line (x + xs * i, y)-(x + xs * i, y + dy)
104.     Next
105.     For i = 0 To yn
106.         Line (x, y + ys * i)-(x + dx, y + ys * i)
107.     Next
108. End Sub
109.  
110. Sub RotoZoom3 (X As Long, Y As Long, Image As Long, xScale As Single, yScale As Single, radianRotation As Single) ' 0 at end means no scaling of x or y
111.     Dim px(3) As Single: Dim py(3) As Single
112.     Dim W&, H&, sinr!, cosr!, i&, x2&, y2&
113.     W& = _Width(Image&): H& = _Height(Image&)
114.     px(0) = -W& / 2: py(0) = -H& / 2: px(1) = -W& / 2: py(1) = H& / 2
115.     px(2) = W& / 2: py(2) = H& / 2: px(3) = W& / 2: py(3) = -H& / 2
116.     sinr! = Sin(-radianRotation): cosr! = Cos(-radianRotation)
117.     For i& = 0 To 3
118.         x2& = xScale * (px(i&) * cosr! + sinr! * py(i&)) + X: y2& = yScale * (py(i&) * cosr! - px(i&) * sinr!) + Y
119.         px(i&) = x2&: py(i&) = y2&
120.     Next
121.     _MapTriangle _Seamless(0, 0)-(0, H& - 1)-(W& - 1, H& - 1), Image To(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
122.     _MapTriangle _Seamless(0, 0)-(W& - 1, 0)-(W& - 1, H& - 1), Image To(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
123. End Sub
124.  
125.  

[SierraKen]

LOL Great ones B+! I found that cone illusion on accident actually messing with loops and math. lol