ArcRings

[bplus]

I saw on Discord today someone wanted Thick Circles, I call them Rings soon you will want thick Arcs too. We'll do ArcRings you will have both and they will work with transparent colors too.

Well here's all that, for raStart and raEnd, ra stands for Radian Angle (not degrees) Radian Angles are expressed in fractions of Pi eg Pi = 180 degrees and whole circle is 2*Pi so 1/10 of circle is 2*pi / 10 equivalent to 36 degrees.

Now I use Basic trig Sin(RadianAngle) and Cos(RadianAngle) that go around circle Clockwise as Radian Angle increases unlike Basic's Circle which goes opposite. So between the trig mention and Radian Angle mention I have probably lost most my audience ;-))

Anyway, it will be handy if you want a transparent color arc or ring and you understand what I am calling raStart and raEnd, I hope the rest is self explanatory:

Code: QB64: [Select]

1. _Title "ArcRings  test" 'B+ 2019-02-21  for Raceman Sequence graphing
2. ' 2021-12-23 reviewed remove confusing comments and test code then rewrote again for Option _Explicit
3.  
4. Screen _NewImage(1000, 700, 32)
5. _ScreenMove 180, 20
6.  
7. While _KeyDown(27) = 0
8.     i = i + 1
9.     If i Mod 50 = 0 Then Cls: i = 0
10.     ro = Rnd * 100 + 50: ri = ro - ro * Rnd - 10
11.     ArcRing Rnd * 800 + 100, Rnd * 500 + 100, ro, ri, Rnd * _Pi(2), Rnd * _Pi(2), _RGBA32(255 * Rnd, 255 * Rnd, 255 * Rnd, 255 * Rnd)
12.     _Display
13.     _Limit 10
14. Wend
15.  
16. Sub ArcRing (x0, y0, outerR, innerR, raStart, raEnd, colr As _Unsigned Long)
17.     Dim Pi2, Pi32, PiH, P, raS, raE, ck1, y, x, d, ra
18.     Pi2 = _Pi(2)
19.     Pi32 = _Pi(1.5)
20.     PiH = _Pi(.5)
21.     P = _Pi
22.     raS = raStart ' checking raStart and raEnd to behave as expected
23.     While raS >= Pi2
24.         raS = raS - Pi2
25.     Wend
26.     While raS < 0
27.         raS = raS + Pi2
28.     Wend
29.     raE = raEnd
30.     While raE < 0
31.         raE = raE + Pi2
32.     Wend
33.     While raE >= Pi2
34.         raE = raE - Pi2
35.     Wend
36.     If raE > raS Then ck1 = -1
37.     For y = y0 - outerR To y0 + outerR
38.         For x = x0 - outerR To x0 + outerR
39.             d = Sqr((x - x0) * (x - x0) + (y - y0) * (y - y0))
40.             If d >= innerR And d <= outerR Then 'within 2 radii
41.                 'angle of x, y to x0, y0
42.                 If x - x0 <> 0 And y - y0 <> 0 Then
43.                     ra = _Atan2(y - y0, x - x0)
44.                     If ra < 0 Then ra = ra + Pi2
45.                 ElseIf x - x0 = 0 Then
46.                     If y >= y0 Then ra = _Pi / 2 Else ra = Pi32
47.                 ElseIf y - y0 = 0 Then
48.                     If x >= x0 Then ra = 0 Else ra = PI
49.                 End If
50.                 If ck1 Then 'raEnd > raStart
51.                     If ra >= raS And ra <= raE Then
52.                         PSet (x, y), colr
53.                     End If
54.                 Else 'raEnd < raStart, raEnd is falls before raStart clockwise so fill through 2 * PI
55.                     If ra >= raS And ra < Pi2 Then
56.                         PSet (x, y), colr
57.                     Else
58.                         If ra >= 0 And ra <= raE Then
59.                             PSet (x, y), colr
60.                         End If
61.                     End If
62.                 End If
63.             End If
64.         Next
65.     Next
66. End Sub
67.  

 

[Richard Frost]

Nice party simulation, but why would Pac Men, Commodore enthusiasts, and Communists hang out together?

[SMcNeill]

Nice party simulation, but why would Pac Men, Commodore enthusiasts, and Communists hang out together?

Russian Retro C64 Pacman Championships, of course!

[bplus]

but why would Pac Men, Commodore enthusiasts, and Communists hang out together?

To see the Olympics:
 

If you don't need transparent colors, here is much simpler code for Rings and Thick Arcs:

Code: QB64: [Select]

1. Option _Explicit
2.  
3. _Title "Ring and Arc by Circle Demo" 'b+ 2021-12-23
4. Const ORadius = 100, IRadius = 80, Margin = 10
5. Const Red = &HFFFF1946
6. Const Green = &HFF00A748
7. Const Yellow = &HFFFFBE1C
8. Const Blue = &HFF645AFF
9. Dim sw, sh
10.  
11.  
12. sw = ORadius * 3 * 2 + 4 * Margin: sh = ORadius * 3 + 2 * Margin
13.  
14. Screen _NewImage(sw, sh, 32)
15. _ScreenMove 300, 200
16. Color , &HFFFFFFFF
17. Cls
18. Ring Margin + ORadius, Margin + ORadius, IRadius, ORadius, Blue
19. Ring 1.5 * Margin + 2 * ORadius, Margin + 2 * ORadius, IRadius, ORadius, Yellow
20.  
21. Ring 2 * Margin + 3 * ORadius, Margin + ORadius, IRadius, ORadius, &HFF000000
22. Ring 2.5 * Margin + 4 * ORadius, Margin + 2 * ORadius, IRadius, ORadius, Green
23.  
24. Ring 3 * Margin + 5 * ORadius, Margin + ORadius, IRadius, ORadius, Red
25.  
26. ' overlap arcs
27. ' blue over yellow
28. ArcRing Margin + ORadius, Margin + ORadius, IRadius, ORadius, _Pi(1.75), 0, Blue
29. ' yellow over black
30. ArcRing 1.5 * Margin + 2 * ORadius, Margin + 2 * ORadius, IRadius, ORadius, _Pi(.25), _Pi(.5), Yellow
31. ' black over green
32. ArcRing 2 * Margin + 3 * ORadius, Margin + ORadius, IRadius, ORadius, _Pi(1.75), _Pi(0), &HFF000000
33. ' green over red
34. ArcRing 2.5 * Margin + 4 * ORadius, Margin + 2 * ORadius, IRadius, ORadius, _Pi(.25), _Pi(.5), Green
35. Sleep
36.  
37. Sub Ring (cx, cy, innerRadius, outerRadius, colr~&) ' wont work well with alpha's < 255
38.     Dim r
39.     For r = innerRadius To outerRadius Step .25
40.         Circle (cx, cy), r, colr~&
41.     Next
42. End Sub
43.  
44. 'ra's here go Counter Clockwise from East
45. Sub ArcRing (cx, cy, innerRadius, outerRadius, raStart, raEnd, colr~&) ' ra's 0 to <2*pi (almost)
46.     Dim r
47.     For r = innerRadius To outerRadius Step .25
48.         Circle (cx, cy), r, colr~&, raStart, raEnd
49.     Next
50. End Sub
51.  

[Richard Frost]

I threw in a _DELAY .01 after the last circle to be able to follow the action.  What I
learned  from this, mainly, is the _PI multiplier.   Super demo of that function.

[DANILIN]

Next step: Anaglyph red-cyan

240 KB =1000x1000

 

+ en.wikipedia.org/wiki/Anaglyph_3D

https://en.wikipedia.org/wiki/Anaglyph_3D

[bplus]

OK ArcRing of Ellipse:

Code: QB64: [Select]

1. Option _Explicit
2.  
3. _Title "Arc of Ellisps" 'b+ 2021-12-25
4.  
5. Dim sw, sh
6. sw = 600: sh = 600
7.  
8. Screen _NewImage(sw, sh, 32)
9. _ScreenMove 300, 200
10.  
11. ArcRingOfEllipse sw / 2, sh / 2, 120, 200, _Pi(0), _Pi(1), .25, &HFFAAAAFF
12. Ring sw / 2, sh / 2, 0, 85, &HFF880088
13. ArcRingOfEllipse sw / 2, sh / 2, 120, 200, _Pi(1), _Pi(1.999), .25, &HFFAAAAFF
14.  
15. Sub Ring (cx, cy, innerRadius, outerRadius, colr~&) ' wont work well with alpha's < 255
16.     Dim r
17.     For r = innerRadius To outerRadius Step .25
18.         Circle (cx, cy), r, colr~&
19.     Next
20. End Sub
21.  
22. 'ra's here go Counter Clockwise from East
23. Sub ArcRing (cx, cy, innerRadius, outerRadius, raStart, raEnd, colr~&) ' ra's 0 to <2*pi (almost)
24.     Dim r
25.     For r = innerRadius To outerRadius Step .25
26.         Circle (cx, cy), r, colr~&, raStart, raEnd
27.     Next
28. End Sub
29.  
30. 'ra's here go Counter Clockwise from East
31. Sub ArcRingOfEllipse (cx, cy, innerRadius, outerRadius, raStart, raEnd, aspect, colr~&) ' ra's 0 to <2*pi (almost)
32.     Dim r
33.     For r = innerRadius To outerRadius Step .25
34.         Circle (cx, cy), r, colr~&, raStart, raEnd, aspect
35.     Next
36. End Sub
37.  
38.  
39.