Turkey Day is around the corner

[bplus]

Code: QB64: [Select]

1. _Title "Turkey Run" ' b+ mod 2021-11-24
2. 'test if can get end of landscape level to start for big looping background
3. '2019-03-27 a more gentle adjustment back to Mountain starting height for
4. 'more seamless connect of back end to front
5. '2019-03-27 start this file with parallax drawing test
6.  
7. Randomize Timer
8. Screen _NewImage(800, 600, 32)
9. _ScreenMove 100, 20
10.  
11. Type parallaxType
12.     handle As Long
13.     rate As Single 'number of pixels per frame added to le (leading edge)
14.     le As Single
15. End Type
16. Dim Shared nLevels As Integer
17. nLevels = 6
18. Dim Shared para(1 To nLevels) As parallaxType
19.  
20. Dim Shared scape&
21. LoadLandscape
22. scapeWidth = _Width(para(1).handle)
23. scapeHeight = _Height(para(1).handle)
24. tr = _LoadImage("turkey run.jpg")
25. _ClearColor Point(10, 10), tr
26. dir = 1.25
27. While _KeyDown(27) = 0 't < 6000
28.     Cls
29.     For i = 1 To nLevels
30.         If para(i).le + 800 > scapeWidth Then
31.             te = scapeWidth - para(i).le
32.             _PutImage (0, 0)-(te, scapeHeight), para(i).handle, 0, (scapeWidth - te, 0)-(scapeWidth, scapeHeight)
33.             _PutImage (te, 0)-(800, scapeHeight), para(i).handle, 0, (0, 0)-(800 - te, scapeHeight)
34.  
35.         Else
36.             _PutImage (0, 0)-(800, scapeHeight), para(i).handle, 0, (para(i).le, 0)-(para(i).le + 800, scapeHeight)
37.         End If
38.  
39.         para(i).le = para(i).le - para(i).rate
40.         If para(i).le < 0 Then para(i).le = scapeWidth
41.     Next
42.     _PutImage (350, 500 + down)-Step(111, 93), tr, 0, (0, 0)-(_Width(tr), _Height(tr) - 30)
43.     t = t + 1
44.     down = down + dir
45.     If down > 37 Then down = 37: dir = -dir
46.     If down < 13 Then down = 13: dir = -dir
47.     _Display
48.     _Limit 120
49. Wend
50.  
51. Sub LoadLandscape
52.     cur& = _Dest
53.     xmax = 800 * 3.25: ymax = 600
54.     hdl& = 1
55.     para(hdl&).handle = _NewImage(xmax, ymax, 32)
56.     _Dest para(hdl&).handle
57.  
58.     For i = 0 To ymax
59.         midInk 0, 0, 128, 128, 128, 200, i / ymax
60.         Line (0, i)-(xmax, i)
61.     Next
62.     'the land
63.     startH = ymax - 250
64.     rr = 70: gg = 70: bb = 90
65.     For mountain = 1 To nLevels
66.         If mountain > 1 Then
67.             para(mountain).handle = _NewImage(xmax, ymax, 32)
68.             _Dest para(mountain).handle
69.         End If
70.         Xright = 0
71.         y = startH
72.         Color _RGB(rr, gg, bb)
73.         While Xright < xmax - 50
74.             ' upDown = local up / down over range, change along Y
75.             ' range = how far up / down, along X
76.             upDown = (Rnd * .8 - .4) * (mountain * .5)
77.             range = Xright + rand%(15, 25) * 2.5 / mountain
78.             If range > xmax - 50 Then range = xmax - 50
79.             lastx = Xright - 1
80.             For x = Xright To range 'need less flat tops
81.                 test = y + upDown
82.                 test2 = y - upDown
83.                 If Abs(test - startH) < .13 * startH Then y = test Else y = test2: upDown = -upDown
84.                 Line (lastx, y)-(x, ymax), , BF 'just lines weren't filling right
85.                 lastx = x
86.             Next
87.             Xright = range
88.         Wend
89.         x = lastx + 1
90.         dy = (startH - y) / 50 'more gentle adjustment back to start of screen
91.         While x <= xmax
92.             y = y + dy
93.             Line (lastx, y)-(x, ymax), , BF 'just lines weren't filling right
94.             lastx = x
95.             x = x + 1
96.         Wend
97.         rr = rand%(rr + 50, rr + 30): gg = rand%(gg + 50, gg + 30): bb = rand%(bb + 50, bb + 30)
98.         If rr < 0 Then rr = 0
99.         If gg < 0 Then gg = 0
100.         If bb < 0 Then bb = 0
101.         startH = startH + mountain * rand%(2, 10)
102.         para(mountain).le = xmax - 800
103.         para(mountain).rate = mountain * .5
104.     Next
105.     _Dest cur&
106. End Sub
107.  
108. Function rand% (lo%, hi%)
109.     rand% = Int(Rnd * (hi% - lo% + 1)) + lo%
110. End Function
111.  
112. Sub midInk (r1%, g1%, b1%, r2%, g2%, b2%, fr##)
113.     Color _RGB(r1% + (r2% - r1%) * fr##, g1% + (g2% - g1%) * fr##, b1% + (b2% - b1%) * fr##)
114. End Sub
115.  
116.  

You will need the image in the zip:

[johnno56]

Not for this little black duck.... Do not like turkey and Thanksgiving is not an Australian holiday...

[bplus]

Not for this little black duck.... Do not like turkey and Thanksgiving is not an Australian holiday...

Too bad!

[TempodiBasic]

Hey is there a challenge to do a game with Turkey day theme?
What is the end of time of challange?
Are there some aspects fixed or is it all free except theme?

[SMcNeill]

Hey is there a challenge to do a game with Turkey day theme?
What is the end of time of challange?
Are there some aspects fixed or is it all free except theme?

No Turkey-day challenge, but it's time for the Xmas theme challenge again!

[bplus]

Hi @TempodiBasic,

Thanksgiving is today in USA, traditionally turkey is served for dinner. If Ben Franklin had his way, turkey would have been the national bird! ;-))

There are jokes that come up around this time about turkeys escaping to Australia or Antarctica. :)

[FellippeHeitor]

No Turkey-day challenge, but it's time for the Xmas theme challenge again!

Hear hear!
🎄

[TempodiBasic]

LOL too late to put on a Turkey! Well the next year it will be possible!

Christmas challange?
Oh oh oh I have something in the box. I can modernize it to this year!