TextToImage and DisplayImage (v2.0+ compliant)

[SMcNeill]

Two of my most used routines, updated to work properly with version 2.0 and above:

Code: QB64: [Select]

1. 'SMcNeill  ref https://www.qb64.org/forum/index.php?topic=4374.msg137907#msg137907
2. Screen _NewImage(800, 700, 32)
3. _ScreenMove 250, 0
4. For i = 1 To 4
5.     HW(i) = TextToImage("Hello World", 16, &HFFFFFF00, 0, i)
6. Next
7.  
8.  
9. Cls
10. Print "The first thing to showcase with these two routines is just how simple it is to turn"
11. Print "text into an image with TextToImage."
12. Sleep
13. Print
14. Print "First, let's print it forwards:"
15. _PutImage (250, 48), HW(1)
16. Sleep
17. Print
18. Print "Then, let's print it backwards:"
19. _PutImage (250, 80), HW(2)
20. Sleep
21. Print
22. Print "Then, let's print it up to down:"
23. _PutImage (270, 112), HW(3)
24. Sleep
25. Locate 8, 40: Print "And let's finish with down to up:"
26. _PutImage (580, 112), HW(4)
27. Sleep
28. Locate 20, 1
29. Print
30. Print
31. Print "TextToImage simply transforms text into an image for us, with a few built in options"
32. Print "to it for the direction we want we text to print."
33. Print "It's as simple as a call with:"
34. Print "    Handle = TextToImage(text$, fonthandle, fontcolor, backgroundcolor, mode"
35. Print
36. Print "        text$ is the string which we want to print.  (In this case 'Hello World'"
37. Print "        fonthandle is the handle of the font which we _LOADFONT for use."
38. Print "            (In this case, I choose the default _FONT 16.)"
39. Print "        fontcolor is the color which we want our text in.  (Here, it's YELLOW.)"
40. Print "        backgroundcolor is the background which we want for the text time.  (Clear this time.)"
41. Print "        mode is how we decide to print forwards, backwards, up to down, or down to up."
42. Print
43. Print "Once we have an image handle, we can use that image just the same as we can with any other."
44. Print "For those who don't need to do anything more than display the text as an image,"
45. Print "feel free to use it as I have in the first part of this program with _PUTIMAGE."
46. Print
47. Print "Trust me -- TextToImage works just fine with _PUTIMAGE."
48. Print
49. Print "But....   If you need more..."
50. Sleep
51.  
52. Cls , 0
53.  
54. Print "There's always DisplayImage to help you out!"
55. DisplayImage HW(1), 300, 30, 1, 1, 0, 1
56. Print
57. Print "Display your image at a scale!"
58. Sleep
59. Print
60. Print "Twice as wide! ";
61. DisplayImage HW(1), 300, 60, 2, 1, 0, 1
62. Sleep
63. Print "Twice as tall! "
64. DisplayImage HW(1), 500, 60, 1, 2, 0, 1
65. Sleep
66. Print
67. Print "At an angle!"
68. DisplayImage HW(1), 280, 90, 1, 1, -45, 1
69. Sleep
70. Print: Print: Print: Print: Print
71. Print "Make it rotate!"
72. _Delay .2
73. _KeyClear
74. Do
75.     Line (355, 155)-Step(100, 100), &HFF000000, BF
76.     DisplayImage HW(1), 400, 200, 1, 1, angle, 0
77.  
78.     angle = (angle + 1) Mod 360
79.     _Limit 30
80.     _Display
81. Loop Until _KeyHit
82. _AutoDisplay
83. Print
84. Print
85. Print
86. Print
87. Print "You can basically use DisplayImage just as you'd normally use RotoZoom, EXCEPT..."
88. Sleep
89. Print "You can choose which CORNER of the image you want to display at your coordinates."
90. Print
91. Line (350, 350)-Step(100, 100), -1, B
92. Circle (400, 400), 10, -1
93. Sleep
94. Print "Top Left corner! ";
95. DisplayImage HW(1), 400, 400, 2, 2, 0, 1
96. Sleep
97. Print "Bottom Left corner! ";
98. DisplayImage HW(1), 400, 400, 2, 2, 0, 2
99. Sleep
100. Print "Top Right corner! ";
101. DisplayImage HW(1), 400, 400, 2, 2, 0, 3
102. Sleep
103. Print "Bottom Right corner! "
104. DisplayImage HW(1), 400, 400, 2, 2, 0, 4
105. Sleep
106. _FreeImage HW(1)
107. HW(1) = TextToImage("Hello World", 16, &HFFFF0000, &HFF0000FF, 1)
108. Print "Or Centered!"
109. DisplayImage HW(1), 400, 400, 2, 2, 0, 0
110. Circle (400, 400), 10, -1
111. Sleep
112.  
113. Cls
114.  
115. Print "With TextToImage, you can turn text into an image...  It's that simple!"
116. Print
117. Print "With DisplayImage, you have a ton of options for how to display ANY image"
118. Print "   (NOT just for use with text images!!)"
119. Print
120. Print "Scale them, stretch them, rotate them, position them by various corners..."
121. Print
122. Print "Between these two routines, I generally don't need anything else when working"
123. Print "   with images in my programs.  ;)"
124. Print
125. Print
126. Print "And that's THE END of this demo.  Post any questions you have on the forums for me!"
127.  
128.  
129.  
130.  
131.  
132. ' (Image As Long, x As Integer, y As Integer, xscale As Single, yscale As Single,
133. '  angle As Single, mode As _Byte)
134.  
135.  
136.  
137.  
138. Function TextToImage& (text$, font&, fc&, bfc&, mode As _Byte)
139.     'text$ is the text that we wish to transform into an image.
140.     'font& is the handle of the font we want to use.
141.     'fc& is the color of the font we want to use.
142.     'bfc& is the background color of the font.
143.  
144.     'Mode 1 is print forwards
145.     'Mode 2 is print backwards
146.     'Mode 3 is print from top to bottom
147.     'Mode 4 is print from bottom up
148.     'Mode 0 got lost somewhere, but it's OK.  We check to see if our mode is < 1 or > 4 and compensate automatically if it is to make it one (default).
149.  
150.     If mode < 1 Or mode > 4 Then mode = 1
151.     dc& = _DefaultColor: bgc& = _BackgroundColor
152.     D = _Dest
153.     F = _Font
154.     T2Idown = CsrLin: T2Iright = Pos(0)
155.     If font& <> 0 Then _Font font&
156.     If mode < 3 Then
157.         'print the text lengthwise
158.         w& = _PrintWidth(text$): h& = _FontHeight
159.     Else
160.         'print the text vertically
161.         For i = 1 To Len(text$)
162.             If w& < _PrintWidth(Mid$(text$, i, 1)) Then w& = _PrintWidth(Mid$(text$, i, 1))
163.         Next
164.         h& = _FontHeight * (Len(text$))
165.     End If
166.  
167.     TextToImage_temp& = _NewImage(w&, h&, 32)
168.     TextToImage = TextToImage_temp&
169.     _Dest TextToImage_temp&
170.     If font& <> 0 Then _Font font&
171.     Color fc&, bfc&
172.  
173.     Select Case mode
174.         Case 1
175.             'Print text forward
176.             _PrintString (0, 0), text$
177.         Case 2
178.             'Print text backwards
179.             temp$ = ""
180.             For i = 0 To Len(text$) - 1
181.                 temp$ = temp$ + Mid$(text$, Len(text$) - i, 1)
182.             Next
183.             _PrintString (0, 0), temp$
184.         Case 3
185.             'Print text upwards
186.             'first lets reverse the text, so it's easy to place
187.             temp$ = ""
188.             For i = 0 To Len(text$) - 1
189.                 temp$ = temp$ + Mid$(text$, Len(text$) - i, 1)
190.             Next
191.             'then put it where it belongs
192.             For i = 1 To Len(text$)
193.                 fx = (w& - _PrintWidth(Mid$(temp$, i, 1))) / 2 + .99 'This is to center any non-monospaced letters so they look better
194.                 _PrintString (fx, _FontHeight * (i - 1)), Mid$(temp$, i, 1)
195.             Next
196.         Case 4
197.             'Print text downwards
198.             For i = 1 To Len(text$)
199.                 fx = (w& - _PrintWidth(Mid$(text$, i, 1))) / 2 + .99 'This is to center any non-monospaced letters so they look better
200.                 _PrintString (fx, _FontHeight * (i - 1)), Mid$(text$, i, 1)
201.             Next
202.     End Select
203.     _Dest D
204.     Color dc&, bgc&
205.     _Font F
206.     Locate T2Idown, T2Iright
207. End Function
208.  
209. Sub DisplayImage (Image As Long, x As Integer, y As Integer, xscale As Single, yscale As Single, angle As Single, mode As _Byte)
210.     'Image is the image handle which we use to reference our image.
211.     'x,y is the X/Y coordinates where we want the image to be at on the screen.
212.     'angle is the angle which we wish to rotate the image.
213.     'mode determines HOW we place the image at point X,Y.
214.     'Mode 0 we center the image at point X,Y
215.     'Mode 1 we place the Top Left corner of oour image at point X,Y
216.     'Mode 2 is Bottom Left
217.     'Mode 3 is Top Right
218.     'Mode 4 is Bottom Right
219.  
220.  
221.     Dim px(3) As Integer, py(3) As Integer, w As Integer, h As Integer
222.     Dim sinr As Single, cosr As Single, i As _Byte
223.     w = _Width(Image): h = _Height(Image)
224.     Select Case mode
225.         Case 0 'center
226.             px(0) = -w \ 2: py(0) = -h \ 2: px(3) = w \ 2: py(3) = -h \ 2
227.             px(1) = -w \ 2: py(1) = h \ 2: px(2) = w \ 2: py(2) = h \ 2
228.         Case 1 'top left
229.             px(0) = 0: py(0) = 0: px(3) = w: py(3) = 0
230.             px(1) = 0: py(1) = h: px(2) = w: py(2) = h
231.         Case 2 'bottom left
232.             px(0) = 0: py(0) = -h: px(3) = w: py(3) = -h
233.             px(1) = 0: py(1) = 0: px(2) = w: py(2) = 0
234.         Case 3 'top right
235.             px(0) = -w: py(0) = 0: px(3) = 0: py(3) = 0
236.             px(1) = -w: py(1) = h: px(2) = 0: py(2) = h
237.         Case 4 'bottom right
238.             px(0) = -w: py(0) = -h: px(3) = 0: py(3) = -h
239.             px(1) = -w: py(1) = 0: px(2) = 0: py(2) = 0
240.     End Select
241.     sinr = Sin(angle / 57.2957795131): cosr = Cos(angle / 57.2957795131)
242.     For i = 0 To 3
243.         x2 = xscale * (px(i) * cosr + sinr * py(i)) + x: y2 = yscale * (py(i) * cosr - px(i) * sinr) + y
244.         px(i) = x2: py(i) = y2
245.     Next
246.     _MapTriangle (0, 0)-(0, h - 1)-(w - 1, h - 1), Image To(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
247.     _MapTriangle (0, 0)-(w - 1, 0)-(w - 1, h - 1), Image To(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
248. End Sub
249.  
250.  

The fix to recursion in SUBs and FUNCTIONs keeps sneaking into my code from time to time, and I keep having to make little adjustments to things, but I'm surprised it took so long for me to notice the glitches in these two routines as I use them constantly!

Anywho...  Here they are, all spruced up and fixed for use with the newest versions of QB64.  If you're one of the people who have made use of these routines in the past, you might want to check your code and swap out to the updated versions here, in case you ever need to compile you EXE again in the future.  ;)

[bplus]

@SMcNeill

Your DisplayImage looks like an advancement to RotoZoom3 with the modes.

I wonder if it works better that RotoZoom3 that I tried yesterday with Pie Chart 2 Animation. Looked so raggedy I just hand drew the Pie Chart at the different angles. I will experiment.

Screen works fine at 800 X 700 no delays needed for:
Screen _NewImage(800, 700, 32)
_ScreenMove 200, 0

Nice stuff!

[bplus]

Update just as raggedy.

@SMcNeill  should note that the angle offset is in degrees and that increasing it turns it counter clock wise.

This is counter intuitive because increase the angle (radian or degrees) in Sin and Cos takes you in clockwise direction around the center of a circle.

Here is my test code:

Code: QB64: [Select]

1. _Title "Pie Chart 3 Test DisplayImage" ' b+ 2021-11-06 fix up Russian Circle Diagram
2. 'ref https://www.qb64.org/forum/index.php?topic=4367.msg137864#msg137864
3. '2021-11-07 PieChart 3 Test DisplayImage
4. ' also move one for block out of loop, only need once
5. Screen 12
6. Randomize Timer
7. _PrintMode _KeepBackground
8. N = 13
9. Dim d(1 To N), sumD(1 To N), ra(1 To N)
10. For i = 1 To N
11.     d(i) = Int(Rnd * 90 + 9) ' min 9, max 99.99..
12.     s = s + d(i)
13.     sumD(i) = s
14. Next
15. For i = 1 To N ' better fill method?
16.     ra(i) = sumD(i) * 2 * 3.1416 / s
17. Next
18. radius = _Height / 2.5
19. Circle (_Width / 2 + 50, _Height / 2), radius, &HFFFFFFFF
20. For i = 1 To N
21.     x = _Width / 2 + 50 + radius * Cos(ra(i) + offset)
22.     y = _Height / 2 + radius * Sin(ra(i) + offset)
23.     Line (_Width / 2 + 50, _Height / 2)-(x, y), &HFFFFFFFF
24.     Paint (_Width / 2 + 50 + (radius - 10) * Cos(ra(i) + offset - _Pi(1 / 36)), _Height / 2 + (radius - 10) * Sin(ra(i) + offset - _Pi(1 / 36))), i, &HFFFFFFFF
25. Next
26. For i = 1 To N
27.     If i = 1 Then a = ra(1) / 2 + offset Else a = (ra(i) + ra(i - 1)) / 2 + offset
28.     x = _Width / 2 + 50 + _Height / 3 * Cos(a)
29.     y = _Height / 2 + _Height / 3 * Sin(a) ' <<<<<<<<<< NOT backwards circle function!!!
30.     s$ = _Trim$(Str$(d(i)))
31.     Color 0: _PrintString (x + 2 - 3.5 * Len(s$), y + 2 - 8), s$
32.     Color 15: _PrintString (x - 3.5 * Len(s$), y - 8), _Trim$(Str$(d(i)))
33. Next
34. xc = _Width / 2 + 50
35. yc = _Height / 2
36. wheel& = _NewImage(2 * radius + 2, 2 * radius + 2, 12)
37. _PutImage , 0, wheel&, (xc - radius - 1, yc - radius - 1)-(xc + radius + 1, yc + radius + 1)
38. 'Cls ' check image capture
39. '_PutImage , wheel&, 0
40. 'Sleep
41.  
42. Cls ' do this once
43. For i = 1 To N 'redraw
44.     Color i: Print d(i); ra(i)
45. Next
46. Color 15: Print s; "= SUM "
47. Do
48.     offset = offset + _Pi(1 / 360)
49.  
50.     '           ==== Testing
51.     ' Testing the two subroutines for image rotation, un-comment the one to try and comment out the other
52.     'RotoZoom3 xc, yc, wheel&, 1, 1, offset ' very raggedy with bad edge on circle
53.     DisplayImage wheel&, xc, yc, 1, 1, _R2D(offset), 0
54.     ' ==================================================================================================
55.  
56.     _Display
57.     _Limit 30
58. Loop Until _KeyDown(27)
59.  
60. ' Description:
61. ' Started from a mod of Galleon's in Wiki that both scales and rotates an image.
62. ' This version scales the x-axis and y-axis independently allowing rotations of image just by changing X or Y Scales
63. ' making this tightly coded routine a very powerful and versatile image tool.
64. Sub RotoZoom3 (X As Long, Y As Long, Image As Long, xScale As Single, yScale As Single, radianRotation As Single)
65.     ' This assumes you have set your drawing location with _DEST or default to screen.
66.     ' X, Y - is where you want to put the middle of the image
67.     ' Image - is the handle assigned with _LOADIMAGE
68.     ' xScale, yScale - are shrinkage < 1 or magnification > 1 on the given axis, 1 just uses image size.
69.     ' These are multipliers so .5 will create image .5 size on given axis and 2 for twice image size.
70.     ' radianRotation is the Angle in Radian units to rotate the image
71.     ' note: Radian units for rotation because it matches angle units of other Basic Trig functions
72.     '       and saves a little time converting from degree.
73.     '       Use the _D2R() function if you prefer to work in degree units for angles.
74.  
75.     Dim px(3) As Single: Dim py(3) As Single ' simple arrays for x, y to hold the 4 corners of image
76.     Dim W&, H&, sinr!, cosr!, i&, x2&, y2& '   variables for image manipulation
77.     W& = _Width(Image&): H& = _Height(Image&)
78.     px(0) = -W& / 2: py(0) = -H& / 2 'left top corner
79.     px(1) = -W& / 2: py(1) = H& / 2 ' left bottom corner
80.     px(2) = W& / 2: py(2) = H& / 2 '  right bottom
81.     px(3) = W& / 2: py(3) = -H& / 2 ' right top
82.     sinr! = Sin(-radianRotation): cosr! = Cos(-radianRotation) ' rotation helpers
83.     For i& = 0 To 3 ' calc new point locations with rotation and zoom
84.         x2& = xScale * (px(i&) * cosr! + sinr! * py(i&)) + X: y2& = yScale * (py(i&) * cosr! - px(i&) * sinr!) + Y
85.         px(i&) = x2&: py(i&) = y2&
86.     Next
87.     _MapTriangle _Seamless(0, 0)-(0, H& - 1)-(W& - 1, H& - 1), Image To(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
88.     _MapTriangle _Seamless(0, 0)-(W& - 1, 0)-(W& - 1, H& - 1), Image To(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
89. End Sub
90.  
91. Sub DisplayImage (Image As Long, x As Integer, y As Integer, xscale As Single, yscale As Single, angle As Single, mode As _Byte)
92.     ' SMcNeill ref:  https://www.qb64.org/forum/index.php?topic=4374.msg137907#msg137907
93.     'Image is the image handle which we use to reference our image.
94.     'x,y is the X/Y coordinates where we want the image to be at on the screen.
95.     'angle is the angle which we wish to rotate the image.
96.     'mode determines HOW we place the image at point X,Y.
97.     'Mode 0 we center the image at point X,Y
98.     'Mode 1 we place the Top Left corner of oour image at point X,Y
99.     'Mode 2 is Bottom Left
100.     'Mode 3 is Top Right
101.     'Mode 4 is Bottom Right
102.  
103.  
104.     Dim px(3) As Integer, py(3) As Integer, w As Integer, h As Integer
105.     Dim sinr As Single, cosr As Single, i As _Byte
106.     w = _Width(Image): h = _Height(Image)
107.     Select Case mode
108.         Case 0 'center
109.             px(0) = -w \ 2: py(0) = -h \ 2: px(3) = w \ 2: py(3) = -h \ 2
110.             px(1) = -w \ 2: py(1) = h \ 2: px(2) = w \ 2: py(2) = h \ 2
111.         Case 1 'top left
112.             px(0) = 0: py(0) = 0: px(3) = w: py(3) = 0
113.             px(1) = 0: py(1) = h: px(2) = w: py(2) = h
114.         Case 2 'bottom left
115.             px(0) = 0: py(0) = -h: px(3) = w: py(3) = -h
116.             px(1) = 0: py(1) = 0: px(2) = w: py(2) = 0
117.         Case 3 'top right
118.             px(0) = -w: py(0) = 0: px(3) = 0: py(3) = 0
119.             px(1) = -w: py(1) = h: px(2) = 0: py(2) = h
120.         Case 4 'bottom right
121.             px(0) = -w: py(0) = -h: px(3) = 0: py(3) = -h
122.             px(1) = -w: py(1) = 0: px(2) = 0: py(2) = 0
123.     End Select
124.     sinr = Sin(angle / 57.2957795131): cosr = Cos(angle / 57.2957795131)
125.     For i = 0 To 3
126.         x2 = xscale * (px(i) * cosr + sinr * py(i)) + x: y2 = yscale * (py(i) * cosr - px(i) * sinr) + y
127.         px(i) = x2: py(i) = y2
128.     Next
129.     _MapTriangle (0, 0)-(0, h - 1)-(w - 1, h - 1), Image To(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
130.     _MapTriangle (0, 0)-(w - 1, 0)-(w - 1, h - 1), Image To(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
131. End Sub
132.  
133.  
134.  

[SMcNeill]

They both produce the exact same screens.

Code: QB64: [Select]

1. _Title "Pie Chart 3 Test DisplayImage" ' b+ 2021-11-06 fix up Russian Circle Diagram
2. 'ref https://www.qb64.org/forum/index.php?topic=4367.msg137864#msg137864
3. '2021-11-07 PieChart 3 Test DisplayImage
4. ' also move one for block out of loop, only need once
5. 'Screen 12
6.  
7. Dim Shared FirstScreen, SecondScreen
8.  
9. FirstScreen = _NewImage(640, 480, 256)
10. SecondScreen = _NewImage(640, 480, 256)
11. Screen FirstScreen
12.  
13. Randomize Timer
14. _PrintMode _KeepBackground
15. N = 13
16. Dim d(1 To N), sumD(1 To N), ra(1 To N)
17. For i = 1 To N
18.     d(i) = Int(Rnd * 90 + 9) ' min 9, max 99.99..
19.     S = S + d(i)
20.     sumD(i) = S
21. Next
22. For i = 1 To N ' better fill method?
23.     ra(i) = sumD(i) * 2 * 3.1416 / S
24. Next
25. radius = _Height / 2.5
26. Circle (_Width / 2 + 50, _Height / 2), radius, &HFFFFFFFF
27. For i = 1 To N
28.     x = _Width / 2 + 50 + radius * Cos(ra(i) + offset)
29.     y = _Height / 2 + radius * Sin(ra(i) + offset)
30.     Line (_Width / 2 + 50, _Height / 2)-(x, y), &HFFFFFFFF
31.     Paint (_Width / 2 + 50 + (radius - 10) * Cos(ra(i) + offset - _Pi(1 / 36)), _Height / 2 + (radius - 10) * Sin(ra(i) + offset - _Pi(1 / 36))), i, &HFFFFFFFF
32. Next
33. For i = 1 To N
34.     If i = 1 Then a = ra(1) / 2 + offset Else a = (ra(i) + ra(i - 1)) / 2 + offset
35.     x = _Width / 2 + 50 + _Height / 3 * Cos(a)
36.     y = _Height / 2 + _Height / 3 * Sin(a) ' <<<<<<<<<< NOT backwards circle function!!!
37.     s$ = _Trim$(Str$(d(i)))
38.     Color 0: _PrintString (x + 2 - 3.5 * Len(s$), y + 2 - 8), s$
39.     Color 15: _PrintString (x - 3.5 * Len(s$), y - 8), _Trim$(Str$(d(i)))
40. Next
41. xc = _Width / 2 + 50
42. yc = _Height / 2
43. wheel& = _NewImage(2 * radius + 2, 2 * radius + 2, 12)
44.  
45.  
46. _PutImage , 0, wheel&, (xc - radius - 1, yc - radius - 1)-(xc + radius + 1, yc + radius + 1)
47. 'Cls ' check image capture
48. '_PutImage , wheel&, 0
49. 'Sleep
50.  
51. Cls , 0 ' do this once
52. For i = 1 To N 'redraw
53.     '    Color i: Print d(i); ra(i)
54. Next
55. 'Color 15: Print S; "= SUM "
56. Do
57.     offset = offset + _Pi(1 / 360)
58.  
59.     '           ==== Testing
60.     ' Testing the two subroutines for image rotation, un-comment the one to try and comment out the other
61.     Screen FirstScreen
62.     Cls , 0
63.     Locate 1, 1: Print "First"
64.     RotoZoom3 xc, yc, wheel&, 1, 1, offset ' very raggedy with bad edge on circle
65.  
66.     Sleep
67.  
68.     _Dest SecondScreen
69.     Cls , 0
70.     Screen SecondScreen
71.     Locate 1, 1: Print "Second"
72.     DisplayImage wheel&, xc, yc, 1, 1, offset, 0
73.     Sleep
74.     CompareScreens
75.     ' ==================================================================================================
76.  
77.     '  _Display
78.     _Limit 30
79. Loop Until _KeyDown(27)
80.  
81.  
82. Sub CompareScreens
83.     Dim As Integer p1, p2
84.     For x = 0 To 639
85.         For y = 20 To 479
86.             _Source FirstScreen
87.             p1 = Point(x, y)
88.             _Source SecondScreen
89.             p2 = Point(x, y)
90.             If p1 <> p2 Then _Title "Point mismatch = " + Str$(x) + "," + Str$(y) + Str$(p1) + Str$(p2)
91.         Next
92.     Next
93. End Sub
94.  
95. ' Description:
96. ' Started from a mod of Galleon's in Wiki that both scales and rotates an image.
97. ' This version scales the x-axis and y-axis independently allowing rotations of image just by changing X or Y Scales
98. ' making this tightly coded routine a very powerful and versatile image tool.
99. Sub RotoZoom3 (X As Long, Y As Long, Image As Long, xScale As Single, yScale As Single, radianRotation As Single)
100.     ' This assumes you have set your drawing location with _DEST or default to screen.
101.     ' X, Y - is where you want to put the middle of the image
102.     ' Image - is the handle assigned with _LOADIMAGE
103.     ' xScale, yScale - are shrinkage < 1 or magnification > 1 on the given axis, 1 just uses image size.
104.     ' These are multipliers so .5 will create image .5 size on given axis and 2 for twice image size.
105.     ' radianRotation is the Angle in Radian units to rotate the image
106.     ' note: Radian units for rotation because it matches angle units of other Basic Trig functions
107.     '       and saves a little time converting from degree.
108.     '       Use the _D2R() function if you prefer to work in degree units for angles.
109.  
110.     Dim px(3) As Single: Dim py(3) As Single ' simple arrays for x, y to hold the 4 corners of image
111.     Dim W&, H&, sinr!, cosr!, i&, x2&, y2& '   variables for image manipulation
112.     W& = _Width(Image&): H& = _Height(Image&)
113.     px(0) = -W& / 2: py(0) = -H& / 2 'left top corner
114.     px(1) = -W& / 2: py(1) = H& / 2 ' left bottom corner
115.     px(2) = W& / 2: py(2) = H& / 2 '  right bottom
116.     px(3) = W& / 2: py(3) = -H& / 2 ' right top
117.     sinr! = Sin(-radianRotation): cosr! = Cos(-radianRotation) ' rotation helpers
118.     For i& = 0 To 3 ' calc new point locations with rotation and zoom
119.         x2& = xScale * (px(i&) * cosr! + sinr! * py(i&)) + X: y2& = yScale * (py(i&) * cosr! - px(i&) * sinr!) + Y
120.         px(i&) = x2&: py(i&) = y2&
121.     Next
122.     _MapTriangle _Seamless(0, 0)-(0, H& - 1)-(W& - 1, H& - 1), Image To(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
123.     _MapTriangle _Seamless(0, 0)-(W& - 1, 0)-(W& - 1, H& - 1), Image To(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
124. End Sub
125.  
126. Sub DisplayImage (Image As Long, x As Integer, y As Integer, xscale As Single, yscale As Single, angle As Single, mode As _Byte)
127.     ' SMcNeill ref:  https://www.qb64.org/forum/index.php?topic=4374.msg137907#msg137907
128.     'Image is the image handle which we use to reference our image.
129.     'x,y is the X/Y coordinates where we want the image to be at on the screen.
130.     'angle is the angle which we wish to rotate the image.
131.     'mode determines HOW we place the image at point X,Y.
132.     'Mode 0 we center the image at point X,Y
133.     'Mode 1 we place the Top Left corner of oour image at point X,Y
134.     'Mode 2 is Bottom Left
135.     'Mode 3 is Top Right
136.     'Mode 4 is Bottom Right
137.  
138.  
139.     Dim px(3) As Integer, py(3) As Integer, w As Integer, h As Integer
140.     Dim sinr As Single, cosr As Single, i As _Byte
141.     w = _Width(Image): h = _Height(Image)
142.     Select Case mode
143.         Case 0 'center
144.             px(0) = -w \ 2: py(0) = -h \ 2: px(3) = w \ 2: py(3) = -h \ 2
145.             px(1) = -w \ 2: py(1) = h \ 2: px(2) = w \ 2: py(2) = h \ 2
146.         Case 1 'top left
147.             px(0) = 0: py(0) = 0: px(3) = w: py(3) = 0
148.             px(1) = 0: py(1) = h: px(2) = w: py(2) = h
149.         Case 2 'bottom left
150.             px(0) = 0: py(0) = -h: px(3) = w: py(3) = -h
151.             px(1) = 0: py(1) = 0: px(2) = w: py(2) = 0
152.         Case 3 'top right
153.             px(0) = -w: py(0) = 0: px(3) = 0: py(3) = 0
154.             px(1) = -w: py(1) = h: px(2) = 0: py(2) = h
155.         Case 4 'bottom right
156.             px(0) = -w: py(0) = -h: px(3) = 0: py(3) = -h
157.             px(1) = -w: py(1) = 0: px(2) = 0: py(2) = 0
158.     End Select
159.     'sinr = Sin(angle / 57.2957795131): cosr = Cos(angle / 57.2957795131)
160.     sinr! = Sin(-angle): cosr! = Cos(-angle) ' rotation helpers
161.     For i = 0 To 3
162.         x2 = xscale * (px(i) * cosr + sinr * py(i)) + x: y2 = yscale * (py(i) * cosr - px(i) * sinr) + y
163.         px(i) = x2: py(i) = y2
164.     Next
165.     _MapTriangle (0, 0)-(0, h - 1)-(w - 1, h - 1), Image To(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
166.     _MapTriangle (0, 0)-(w - 1, 0)-(w - 1, h - 1), Image To(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
167. End Sub
168.  

As for the angle, that's just my personal preference at work, and it goes in the direction which one would draw on a piece of graph paper.  45 degrees is sloping from (0,0) up to (1,1) and beyond, not from (0,0) to (1,-1).  Your RotoZoom3 even reverses the angles for you automatically:   sinr! = Sin(-radianRotation): cosr! = Cos(-radianRotation).

Once I swapped from degree to reverse radian with DisplayScreen, everything works the same as yours, though it's slow as crap and requires you to hold down the spacebar or something to watch as it slowly rotates and compares every pixel from one screen against every pixel on the second screen for a discrepancy..

The only difference I made was this one in the SUB:
    FROM -- sinr = Sin(angle / 57.2957795131): cosr = Cos(angle / 57.2957795131)
    TO     -- sinr! = Sin(-angle): cosr! = Cos(-angle) ' rotation helpers

(along with the change to call without having to use _R2D for the angle)

If there's something raggedy at work, it's the same for both RotoZoom3 and DisplayImage.  Afterall, back when I did DisplayImage ages ago, I based it off RotoZoom at the time so that it'd be able to work as I needed it to for a program which was drawing boxes on the screen.  (I think it was a calendar type program...)  Each box needed to be positioned starting AT point (x,y) and not CENTERED at point (x,y), which is why I added the mode option.  And, as usual, I just figured, "If I'm going to sort it out for one corner, why not sort it out for all of them?"

Take the mode adjustment out and you basically have your RotoZoom3 line for line, I think.  (Except for mine is set for degrees by default rather than radians, and the angle isn't reversed as you have yours.)

If you draw a circle on paper, angles go counter-clockwise naturally.  45 degrees is in the first quadrant while 315 degrees is in the 4th quadrant.  You've made yours backwards just to have clockwise rotation.  :P


And something completely unrelated, but odd with the test code above:

If you take out all those SLEEP statements, the program goes 100% buggy weird, like so:

Code: QB64: [Select]

1. _Title "Pie Chart 3 Test DisplayImage" ' b+ 2021-11-06 fix up Russian Circle Diagram
2. 'ref https://www.qb64.org/forum/index.php?topic=4367.msg137864#msg137864
3. '2021-11-07 PieChart 3 Test DisplayImage
4. ' also move one for block out of loop, only need once
5. 'Screen 12
6.  
7. Dim Shared FirstScreen, SecondScreen
8.  
9. FirstScreen = _NewImage(640, 480, 256)
10. SecondScreen = _NewImage(640, 480, 256)
11. Screen FirstScreen
12.  
13. Randomize Timer
14. _PrintMode _KeepBackground
15. N = 13
16. Dim d(1 To N), sumD(1 To N), ra(1 To N)
17. For i = 1 To N
18.     d(i) = Int(Rnd * 90 + 9) ' min 9, max 99.99..
19.     S = S + d(i)
20.     sumD(i) = S
21. Next
22. For i = 1 To N ' better fill method?
23.     ra(i) = sumD(i) * 2 * 3.1416 / S
24. Next
25. radius = _Height / 2.5
26. Circle (_Width / 2 + 50, _Height / 2), radius, &HFFFFFFFF
27. For i = 1 To N
28.     x = _Width / 2 + 50 + radius * Cos(ra(i) + offset)
29.     y = _Height / 2 + radius * Sin(ra(i) + offset)
30.     Line (_Width / 2 + 50, _Height / 2)-(x, y), &HFFFFFFFF
31.     Paint (_Width / 2 + 50 + (radius - 10) * Cos(ra(i) + offset - _Pi(1 / 36)), _Height / 2 + (radius - 10) * Sin(ra(i) + offset - _Pi(1 / 36))), i, &HFFFFFFFF
32. Next
33. For i = 1 To N
34.     If i = 1 Then a = ra(1) / 2 + offset Else a = (ra(i) + ra(i - 1)) / 2 + offset
35.     x = _Width / 2 + 50 + _Height / 3 * Cos(a)
36.     y = _Height / 2 + _Height / 3 * Sin(a) ' <<<<<<<<<< NOT backwards circle function!!!
37.     s$ = _Trim$(Str$(d(i)))
38.     Color 0: _PrintString (x + 2 - 3.5 * Len(s$), y + 2 - 8), s$
39.     Color 15: _PrintString (x - 3.5 * Len(s$), y - 8), _Trim$(Str$(d(i)))
40. Next
41. xc = _Width / 2 + 50
42. yc = _Height / 2
43. wheel& = _NewImage(2 * radius + 2, 2 * radius + 2, 12)
44.  
45.  
46. _PutImage , 0, wheel&, (xc - radius - 1, yc - radius - 1)-(xc + radius + 1, yc + radius + 1)
47. 'Cls ' check image capture
48. '_PutImage , wheel&, 0
49. 'Sleep
50.  
51. Cls , 0 ' do this once
52. For i = 1 To N 'redraw
53.     '    Color i: Print d(i); ra(i)
54. Next
55. 'Color 15: Print S; "= SUM "
56. Do
57.     offset = offset + _Pi(1 / 360)
58.  
59.     '           ==== Testing
60.     ' Testing the two subroutines for image rotation, un-comment the one to try and comment out the other
61.     Screen FirstScreen
62.     Cls , 0
63.     Locate 1, 1: Print "First"
64.     RotoZoom3 xc, yc, wheel&, 1, 1, offset ' very raggedy with bad edge on circle
65.  
66.     'Sleep
67.  
68.     _Dest SecondScreen
69.     Cls , 0
70.     Screen SecondScreen
71.     Locate 1, 1: Print "Second"
72.     DisplayImage wheel&, xc, yc, 1, 1, offset, 0
73.  
74.  
75.     'Sleep
76.  
77.  
78.     'CompareScreens
79.     ' ==================================================================================================
80.  
81.     '  _Display
82.     _Limit 30
83. Loop Until _KeyDown(27)
84.  
85.  
86. Sub CompareScreens
87.     Dim As Integer p1, p2
88.     For x = 0 To 639
89.         For y = 20 To 479
90.             _Source FirstScreen
91.             p1 = Point(x, y)
92.             _Source SecondScreen
93.             p2 = Point(x, y)
94.             If p1 <> p2 Then _Title "Point mismatch = " + Str$(x) + "," + Str$(y) + Str$(p1) + Str$(p2)
95.         Next
96.     Next
97. End Sub
98.  
99. ' Description:
100. ' Started from a mod of Galleon's in Wiki that both scales and rotates an image.
101. ' This version scales the x-axis and y-axis independently allowing rotations of image just by changing X or Y Scales
102. ' making this tightly coded routine a very powerful and versatile image tool.
103. Sub RotoZoom3 (X As Long, Y As Long, Image As Long, xScale As Single, yScale As Single, radianRotation As Single)
104.     ' This assumes you have set your drawing location with _DEST or default to screen.
105.     ' X, Y - is where you want to put the middle of the image
106.     ' Image - is the handle assigned with _LOADIMAGE
107.     ' xScale, yScale - are shrinkage < 1 or magnification > 1 on the given axis, 1 just uses image size.
108.     ' These are multipliers so .5 will create image .5 size on given axis and 2 for twice image size.
109.     ' radianRotation is the Angle in Radian units to rotate the image
110.     ' note: Radian units for rotation because it matches angle units of other Basic Trig functions
111.     '       and saves a little time converting from degree.
112.     '       Use the _D2R() function if you prefer to work in degree units for angles.
113.  
114.     Dim px(3) As Single: Dim py(3) As Single ' simple arrays for x, y to hold the 4 corners of image
115.     Dim W&, H&, sinr!, cosr!, i&, x2&, y2& '   variables for image manipulation
116.     W& = _Width(Image&): H& = _Height(Image&)
117.     px(0) = -W& / 2: py(0) = -H& / 2 'left top corner
118.     px(1) = -W& / 2: py(1) = H& / 2 ' left bottom corner
119.     px(2) = W& / 2: py(2) = H& / 2 '  right bottom
120.     px(3) = W& / 2: py(3) = -H& / 2 ' right top
121.     sinr! = Sin(-radianRotation): cosr! = Cos(-radianRotation) ' rotation helpers
122.     For i& = 0 To 3 ' calc new point locations with rotation and zoom
123.         x2& = xScale * (px(i&) * cosr! + sinr! * py(i&)) + X: y2& = yScale * (py(i&) * cosr! - px(i&) * sinr!) + Y
124.         px(i&) = x2&: py(i&) = y2&
125.     Next
126.     _MapTriangle _Seamless(0, 0)-(0, H& - 1)-(W& - 1, H& - 1), Image To(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
127.     _MapTriangle _Seamless(0, 0)-(W& - 1, 0)-(W& - 1, H& - 1), Image To(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
128. End Sub
129.  
130. Sub DisplayImage (Image As Long, x As Integer, y As Integer, xscale As Single, yscale As Single, angle As Single, mode As _Byte)
131.     ' SMcNeill ref:  https://www.qb64.org/forum/index.php?topic=4374.msg137907#msg137907
132.     'Image is the image handle which we use to reference our image.
133.     'x,y is the X/Y coordinates where we want the image to be at on the screen.
134.     'angle is the angle which we wish to rotate the image.
135.     'mode determines HOW we place the image at point X,Y.
136.     'Mode 0 we center the image at point X,Y
137.     'Mode 1 we place the Top Left corner of oour image at point X,Y
138.     'Mode 2 is Bottom Left
139.     'Mode 3 is Top Right
140.     'Mode 4 is Bottom Right
141.  
142.  
143.     Dim px(3) As Integer, py(3) As Integer, w As Integer, h As Integer
144.     Dim sinr As Single, cosr As Single, i As _Byte
145.     w = _Width(Image): h = _Height(Image)
146.     Select Case mode
147.         Case 0 'center
148.             px(0) = -w \ 2: py(0) = -h \ 2: px(3) = w \ 2: py(3) = -h \ 2
149.             px(1) = -w \ 2: py(1) = h \ 2: px(2) = w \ 2: py(2) = h \ 2
150.         Case 1 'top left
151.             px(0) = 0: py(0) = 0: px(3) = w: py(3) = 0
152.             px(1) = 0: py(1) = h: px(2) = w: py(2) = h
153.         Case 2 'bottom left
154.             px(0) = 0: py(0) = -h: px(3) = w: py(3) = -h
155.             px(1) = 0: py(1) = 0: px(2) = w: py(2) = 0
156.         Case 3 'top right
157.             px(0) = -w: py(0) = 0: px(3) = 0: py(3) = 0
158.             px(1) = -w: py(1) = h: px(2) = 0: py(2) = h
159.         Case 4 'bottom right
160.             px(0) = -w: py(0) = -h: px(3) = 0: py(3) = -h
161.             px(1) = -w: py(1) = 0: px(2) = 0: py(2) = 0
162.     End Select
163.     'sinr = Sin(angle / 57.2957795131): cosr = Cos(angle / 57.2957795131)
164.     sinr! = Sin(-angle): cosr! = Cos(-angle) ' rotation helpers
165.     For i = 0 To 3
166.         x2 = xscale * (px(i) * cosr + sinr * py(i)) + x: y2 = yscale * (py(i) * cosr - px(i) * sinr) + y
167.         px(i) = x2: py(i) = y2
168.     Next
169.     _MapTriangle (0, 0)-(0, h - 1)-(w - 1, h - 1), Image To(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
170.     _MapTriangle (0, 0)-(w - 1, 0)-(w - 1, h - 1), Image To(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
171. End Sub
172.  

Apparently, GL doesn't like the constant switching from SCREEN FirstScreen to SCREEN SecondScreen

WARNING: If you decide to test the second code, for the love of your PC, know how to open your Task Manager and end a process.  I've tested it several times and lets just say the results end up getting completely unreliable with us.  The red X in the top right *might* end and close the program.  It might not...   Alt-F4 may work...  ESC might stop it...  Then again, it may not...

The constant swap from one SCREEN to another 30 times per second ends up doing something to the video memory with GL.  Honestly, I'd suggest being prepared to do a system reboot once you're finished playing around with it and watching it die horribly.


Even more oddly, if you REPLACE those two SLEEP statements with _DISPLAY and make the screen manually update, the program works just fine.  It's just wuth _AUTODISPLAY at work that GL doesn't like the swapping of screen modes constantly.

Who knew?!!

[bplus]

Once I swapped from degree to reverse radian with DisplayScreen, everything works the same as yours, though it's slow as crap and requires you to hold down the spacebar or something to watch as it slowly rotates and compares every pixel from one screen against every pixel on the second screen for a discrepancy..

Slow as crap because I am using angle in Radian Units and you are using angle in Degrees Units, notice in my code test I converted offset to Degrees before trying your DisplayImage.

    '           ==== Testing
    ' Testing the two subroutines for image rotation, un-comment the one to try and comment out the other
    'RotoZoom3 xc, yc, wheel&, 1, 1, offset ' very raggedy with bad edge on circle
    DisplayImage wheel&, xc, yc, 1, 1, _R2D(offset), 0
    ' ==================================================================================================

[SMcNeill]

Slow as crap because I am using angle in Radian Units and you are using angle in Degrees Units, notice in my code test I converted offset to Degrees before trying your DisplayImage.

I was talking about my second code where I made the changes to compare results as being slow as crap, and both routines there are using radian angles.  As far as Rotozoom and DisplayImage in the original, both run and rotate the screen at around 900+ FPS on my laptop -- more than fast enough for a program with a _LIMIT 30.  (And that's with us clearing and printing the text to both screens as well on each pass so they'll look identical.)  :P

If there's a difference in speed or performance in the two routines, I'm not seeing it. 

Code: QB64: [Select]

1. _Title "Pie Chart 3 Test DisplayImage" ' b+ 2021-11-06 fix up Russian Circle Diagram
2. 'ref https://www.qb64.org/forum/index.php?topic=4367.msg137864#msg137864
3. '2021-11-07 PieChart 3 Test DisplayImage
4. ' also move one for block out of loop, only need once
5. Screen 12
6. Randomize Timer
7. _PrintMode _KeepBackground
8. N = 13
9. Dim d(1 To N), sumD(1 To N), ra(1 To N)
10. For i = 1 To N
11.     d(i) = Int(Rnd * 90 + 9) ' min 9, max 99.99..
12.     s = s + d(i)
13.     sumD(i) = s
14. Next
15. For i = 1 To N ' better fill method?
16.     ra(i) = sumD(i) * 2 * 3.1416 / s
17. Next
18. radius = _Height / 2.5
19. Circle (_Width / 2 + 50, _Height / 2), radius, &HFFFFFFFF
20. For i = 1 To N
21.     x = _Width / 2 + 50 + radius * Cos(ra(i) + offset)
22.     y = _Height / 2 + radius * Sin(ra(i) + offset)
23.     Line (_Width / 2 + 50, _Height / 2)-(x, y), &HFFFFFFFF
24.     Paint (_Width / 2 + 50 + (radius - 10) * Cos(ra(i) + offset - _Pi(1 / 36)), _Height / 2 + (radius - 10) * Sin(ra(i) + offset - _Pi(1 / 36))), i, &HFFFFFFFF
25. Next
26. For i = 1 To N
27.     If i = 1 Then a = ra(1) / 2 + offset Else a = (ra(i) + ra(i - 1)) / 2 + offset
28.     x = _Width / 2 + 50 + _Height / 3 * Cos(a)
29.     y = _Height / 2 + _Height / 3 * Sin(a) ' <<<<<<<<<< NOT backwards circle function!!!
30.     s$ = _Trim$(Str$(d(i)))
31.     Color 0: _PrintString (x + 2 - 3.5 * Len(s$), y + 2 - 8), s$
32.     Color 15: _PrintString (x - 3.5 * Len(s$), y - 8), _Trim$(Str$(d(i)))
33. Next
34. xc = _Width / 2 + 50
35. yc = _Height / 2
36. wheel& = _NewImage(2 * radius + 2, 2 * radius + 2, 12)
37. _PutImage , 0, wheel&, (xc - radius - 1, yc - radius - 1)-(xc + radius + 1, yc + radius + 1)
38. 'Cls ' check image capture
39. '_PutImage , wheel&, 0
40. 'Sleep
41.  
42.  
43.  
44. Do
45.     k = _KeyHit
46.  
47.     Cls ' do this once
48.     For i = 1 To N 'redraw
49.         Color i: Print d(i); ra(i)
50.     Next
51.     Color 15: Print s; "= SUM "
52.     If Roto Then
53.         Print "RotoZoom"
54.     Else
55.         Print "Display Image"
56.     End If
57.     Print "FPS = "; maxFPS
58.  
59.     offset = offset + _Pi(1 / 360)
60.     If k > 0 Then Roto = Not Roto
61.     If Roto Then
62.         RotoZoom3 xc, yc, wheel&, 1, 1, offset ' very raggedy with bad edge on circle
63.     Else
64.         DisplayImage wheel&, xc, yc, 1, 1, _R2D(-offset), 0
65.     End If
66.     If Timer > t# + 1 Then t# = Timer: maxFPS = FPS: FPS = 0
67.     FPS = FPS + 1
68.     _Display
69.     ' _Limit 30
70. Loop Until k = 27
71.  
72.  
73. ' Description:
74. ' Started from a mod of Galleon's in Wiki that both scales and rotates an image.
75. ' This version scales the x-axis and y-axis independently allowing rotations of image just by changing X or Y Scales
76. ' making this tightly coded routine a very powerful and versatile image tool.
77. Sub RotoZoom3 (X As Long, Y As Long, Image As Long, xScale As Single, yScale As Single, radianRotation As Single)
78.     ' This assumes you have set your drawing location with _DEST or default to screen.
79.     ' X, Y - is where you want to put the middle of the image
80.     ' Image - is the handle assigned with _LOADIMAGE
81.     ' xScale, yScale - are shrinkage < 1 or magnification > 1 on the given axis, 1 just uses image size.
82.     ' These are multipliers so .5 will create image .5 size on given axis and 2 for twice image size.
83.     ' radianRotation is the Angle in Radian units to rotate the image
84.     ' note: Radian units for rotation because it matches angle units of other Basic Trig functions
85.     '       and saves a little time converting from degree.
86.     '       Use the _D2R() function if you prefer to work in degree units for angles.
87.  
88.     Dim px(3) As Single: Dim py(3) As Single ' simple arrays for x, y to hold the 4 corners of image
89.     Dim W&, H&, sinr!, cosr!, i&, x2&, y2& '   variables for image manipulation
90.     W& = _Width(Image&): H& = _Height(Image&)
91.     px(0) = -W& / 2: py(0) = -H& / 2 'left top corner
92.     px(1) = -W& / 2: py(1) = H& / 2 ' left bottom corner
93.     px(2) = W& / 2: py(2) = H& / 2 '  right bottom
94.     px(3) = W& / 2: py(3) = -H& / 2 ' right top
95.     sinr! = Sin(-radianRotation): cosr! = Cos(-radianRotation) ' rotation helpers
96.     For i& = 0 To 3 ' calc new point locations with rotation and zoom
97.         x2& = xScale * (px(i&) * cosr! + sinr! * py(i&)) + X: y2& = yScale * (py(i&) * cosr! - px(i&) * sinr!) + Y
98.         px(i&) = x2&: py(i&) = y2&
99.     Next
100.     _MapTriangle _Seamless(0, 0)-(0, H& - 1)-(W& - 1, H& - 1), Image To(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
101.     _MapTriangle _Seamless(0, 0)-(W& - 1, 0)-(W& - 1, H& - 1), Image To(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
102. End Sub
103.  
104. Sub DisplayImage (Image As Long, x As Integer, y As Integer, xscale As Single, yscale As Single, angle As Single, mode As _Byte)
105.     ' SMcNeill ref:  https://www.qb64.org/forum/index.php?topic=4374.msg137907#msg137907
106.     'Image is the image handle which we use to reference our image.
107.     'x,y is the X/Y coordinates where we want the image to be at on the screen.
108.     'angle is the angle which we wish to rotate the image.
109.     'mode determines HOW we place the image at point X,Y.
110.     'Mode 0 we center the image at point X,Y
111.     'Mode 1 we place the Top Left corner of oour image at point X,Y
112.     'Mode 2 is Bottom Left
113.     'Mode 3 is Top Right
114.     'Mode 4 is Bottom Right
115.  
116.  
117.     Dim px(3) As Integer, py(3) As Integer, w As Integer, h As Integer
118.     Dim sinr As Single, cosr As Single, i As _Byte
119.     w = _Width(Image): h = _Height(Image)
120.     Select Case mode
121.         Case 0 'center
122.             px(0) = -w \ 2: py(0) = -h \ 2: px(3) = w \ 2: py(3) = -h \ 2
123.             px(1) = -w \ 2: py(1) = h \ 2: px(2) = w \ 2: py(2) = h \ 2
124.         Case 1 'top left
125.             px(0) = 0: py(0) = 0: px(3) = w: py(3) = 0
126.             px(1) = 0: py(1) = h: px(2) = w: py(2) = h
127.         Case 2 'bottom left
128.             px(0) = 0: py(0) = -h: px(3) = w: py(3) = -h
129.             px(1) = 0: py(1) = 0: px(2) = w: py(2) = 0
130.         Case 3 'top right
131.             px(0) = -w: py(0) = 0: px(3) = 0: py(3) = 0
132.             px(1) = -w: py(1) = h: px(2) = 0: py(2) = h
133.         Case 4 'bottom right
134.             px(0) = -w: py(0) = -h: px(3) = 0: py(3) = -h
135.             px(1) = -w: py(1) = 0: px(2) = 0: py(2) = 0
136.     End Select
137.     sinr = Sin(angle / 57.2957795131): cosr = Cos(angle / 57.2957795131)
138.     For i = 0 To 3
139.         x2 = xscale * (px(i) * cosr + sinr * py(i)) + x: y2 = yscale * (py(i) * cosr - px(i) * sinr) + y
140.         px(i) = x2: py(i) = y2
141.     Next
142.     _MapTriangle (0, 0)-(0, h - 1)-(w - 1, h - 1), Image To(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
143.     _MapTriangle (0, 0)-(w - 1, 0)-(w - 1, h - 1), Image To(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
144. End Sub
145.  

Hit any key to toggle display methods, ESC to end.

[bplus]

@SMcNeill

Yeah DisplayImage has similar results as Rotozoom3, I was hoping it would do better with the lines in the Pie Chart. They are fuzzy looking either way.

And yes, Rotozoom3 was a hack off the original just adding a separate scale for x and y axis which could be handy. So the handling of the goofy y axis increasing going down was not changed.

I am now testing TextToImage with a font, does not look good. What am I doing wrong?
I just changed top of program to this:

Code: QB64: [Select]

1. 'SMcNeill  ref https://www.qb64.org/forum/index.php?topic=4374.msg137907#msg137907
2. Screen _NewImage(800, 700, 32)
3. _ScreenMove 250, 0
4. Dim HW(1 To 4)
5. f& = _LoadFont("ariblk.ttf", 24) ' Test with Windows 10 font
6. Print f& ' check font loaded
7. If f& < 1 Then Print "Font did not load, goodbye.  ...zzz": Sleep: System
8. For i = 1 To 4
9.     HW(i) = TextToImage("Hello World", f&, &HFFFFFF00, 0, i)
10. Next
11.  

Is there more needed to be changed?

[SMcNeill]

Good catch.  When I reworked it, I lost a font change in there.   This version should work with your custom font; I'll update the first post so it works as intended as well:

Code: QB64: [Select]

1. 'SMcNeill  ref https://www.qb64.org/forum/index.php?topic=4374.msg137907#msg137907
2. Screen _NewImage(800, 700, 32)
3. _ScreenMove 250, 0
4. Dim HW(1 To 4)
5. f& = _LoadFont("ariblk.ttf", 24) ' Test with Windows 10 font
6. Print f& ' check font loaded
7. If f& < 1 Then Print "Font did not load, goodbye.  ...zzz": Sleep: System
8. For i = 1 To 4
9.     HW(i) = TextToImage("Hello World", f&, &HFFFFFF00, 0, i)
10. Next
11.  
12.  
13. Cls
14. Print "The first thing to showcase with these two routines is just how simple it is to turn"
15. Print "text into an image with TextToImage."
16. Sleep
17. Print
18. Print "First, let's print it forwards:"
19. _PutImage (250, 48), HW(1)
20. Sleep
21. Print
22. Print "Then, let's print it backwards:"
23. _PutImage (250, 80), HW(2)
24. Sleep
25. Print
26. Print "Then, let's print it up to down:"
27. _PutImage (270, 112), HW(3)
28. Sleep
29. Locate 8, 40: Print "And let's finish with down to up:"
30. _PutImage (580, 112), HW(4)
31. Sleep
32. Locate 20, 1
33. Print
34. Print
35. Print "TextToImage simply transforms text into an image for us, with a few built in options"
36. Print "to it for the direction we want we text to print."
37. Print "It's as simple as a call with:"
38. Print "    Handle = TextToImage(text$, fonthandle, fontcolor, backgroundcolor, mode"
39. Print
40. Print "        text$ is the string which we want to print.  (In this case 'Hello World'"
41. Print "        fonthandle is the handle of the font which we _LOADFONT for use."
42. Print "            (In this case, I choose the default _FONT 16.)"
43. Print "        fontcolor is the color which we want our text in.  (Here, it's YELLOW.)"
44. Print "        backgroundcolor is the background which we want for the text time.  (Clear this time.)"
45. Print "        mode is how we decide to print forwards, backwards, up to down, or down to up."
46. Print
47. Print "Once we have an image handle, we can use that image just the same as we can with any other."
48. Print "For those who don't need to do anything more than display the text as an image,"
49. Print "feel free to use it as I have in the first part of this program with _PUTIMAGE."
50. Print
51. Print "Trust me -- TextToImage works just fine with _PUTIMAGE."
52. Print
53. Print "But....   If you need more..."
54. Sleep
55.  
56. Cls , 0
57.  
58. Print "There's always DisplayImage to help you out!"
59. DisplayImage HW(1), 300, 30, 1, 1, 0, 1
60. Print
61. Print "Display your image at a scale!"
62. Sleep
63. Print
64. Print "Twice as wide! ";
65. DisplayImage HW(1), 300, 60, 2, 1, 0, 1
66. Sleep
67. Print "Twice as tall! "
68. DisplayImage HW(1), 500, 60, 1, 2, 0, 1
69. Sleep
70. Print
71. Print "At an angle!"
72. DisplayImage HW(1), 280, 90, 1, 1, -45, 1
73. Sleep
74. Print: Print: Print: Print: Print
75. Print "Make it rotate!"
76. _Delay .2
77. _KeyClear
78. Do
79.     Line (355, 155)-Step(100, 100), &HFF000000, BF
80.     DisplayImage HW(1), 400, 200, 1, 1, angle, 0
81.  
82.     angle = (angle + 1) Mod 360
83.     _Limit 30
84.     _Display
85. Loop Until _KeyHit
86. _AutoDisplay
87. Print
88. Print
89. Print
90. Print
91. Print "You can basically use DisplayImage just as you'd normally use RotoZoom, EXCEPT..."
92. Sleep
93. Print "You can choose which CORNER of the image you want to display at your coordinates."
94. Print
95. Line (350, 350)-Step(100, 100), -1, B
96. Circle (400, 400), 10, -1
97. Sleep
98. Print "Top Left corner! ";
99. DisplayImage HW(1), 400, 400, 2, 2, 0, 1
100. Sleep
101. Print "Bottom Left corner! ";
102. DisplayImage HW(1), 400, 400, 2, 2, 0, 2
103. Sleep
104. Print "Top Right corner! ";
105. DisplayImage HW(1), 400, 400, 2, 2, 0, 3
106. Sleep
107. Print "Bottom Right corner! "
108. DisplayImage HW(1), 400, 400, 2, 2, 0, 4
109. Sleep
110. _FreeImage HW(1)
111. HW(1) = TextToImage("Hello World", 16, &HFFFF0000, &HFF0000FF, 1)
112. Print "Or Centered!"
113. DisplayImage HW(1), 400, 400, 2, 2, 0, 0
114. Circle (400, 400), 10, -1
115. Sleep
116.  
117. Cls
118.  
119. Print "With TextToImage, you can turn text into an image...  It's that simple!"
120. Print
121. Print "With DisplayImage, you have a ton of options for how to display ANY image"
122. Print "   (NOT just for use with text images!!)"
123. Print
124. Print "Scale them, stretch them, rotate them, position them by various corners..."
125. Print
126. Print "Between these two routines, I generally don't need anything else when working"
127. Print "   with images in my programs.  ;)"
128. Print
129. Print
130. Print "And that's THE END of this demo.  Post any questions you have on the forums for me!"
131.  
132.  
133.  
134.  
135.  
136. ' (Image As Long, x As Integer, y As Integer, xscale As Single, yscale As Single,
137. '  angle As Single, mode As _Byte)
138.  
139.  
140.  
141.  
142. Function TextToImage& (text$, font&, fc&, bfc&, mode As _Byte)
143.     'text$ is the text that we wish to transform into an image.
144.     'font& is the handle of the font we want to use.
145.     'fc& is the color of the font we want to use.
146.     'bfc& is the background color of the font.
147.  
148.     'Mode 1 is print forwards
149.     'Mode 2 is print backwards
150.     'Mode 3 is print from top to bottom
151.     'Mode 4 is print from bottom up
152.     'Mode 0 got lost somewhere, but it's OK.  We check to see if our mode is < 1 or > 4 and compensate automatically if it is to make it one (default).
153.  
154.     If mode < 1 Or mode > 4 Then mode = 1
155.     dc& = _DefaultColor: bgc& = _BackgroundColor
156.     D = _Dest
157.     F = _Font
158.     T2Idown = CsrLin: T2Iright = Pos(0)
159.     If font& <> 0 Then _Font font&
160.     If mode < 3 Then
161.         'print the text lengthwise
162.         w& = _PrintWidth(text$): h& = _FontHeight
163.     Else
164.         'print the text vertically
165.         For i = 1 To Len(text$)
166.             If w& < _PrintWidth(Mid$(text$, i, 1)) Then w& = _PrintWidth(Mid$(text$, i, 1))
167.         Next
168.         h& = _FontHeight * (Len(text$))
169.     End If
170.  
171.     TextToImage_temp& = _NewImage(w&, h&, 32)
172.     TextToImage = TextToImage_temp&
173.     _Dest TextToImage_temp&
174.     If font& <> 0 Then _Font font&
175.     Color fc&, bfc&
176.  
177.     Select Case mode
178.         Case 1
179.             'Print text forward
180.             _PrintString (0, 0), text$
181.         Case 2
182.             'Print text backwards
183.             temp$ = ""
184.             For i = 0 To Len(text$) - 1
185.                 temp$ = temp$ + Mid$(text$, Len(text$) - i, 1)
186.             Next
187.             _PrintString (0, 0), temp$
188.         Case 3
189.             'Print text upwards
190.             'first lets reverse the text, so it's easy to place
191.             temp$ = ""
192.             For i = 0 To Len(text$) - 1
193.                 temp$ = temp$ + Mid$(text$, Len(text$) - i, 1)
194.             Next
195.             'then put it where it belongs
196.             For i = 1 To Len(text$)
197.                 fx = (w& - _PrintWidth(Mid$(temp$, i, 1))) / 2 + .99 'This is to center any non-monospaced letters so they look better
198.                 _PrintString (fx, _FontHeight * (i - 1)), Mid$(temp$, i, 1)
199.             Next
200.         Case 4
201.             'Print text downwards
202.             For i = 1 To Len(text$)
203.                 fx = (w& - _PrintWidth(Mid$(text$, i, 1))) / 2 + .99 'This is to center any non-monospaced letters so they look better
204.                 _PrintString (fx, _FontHeight * (i - 1)), Mid$(text$, i, 1)
205.             Next
206.     End Select
207.     _Dest D
208.     Color dc&, bgc&
209.     _Font F
210.     Locate T2Idown, T2Iright
211. End Function
212.  
213. Sub DisplayImage (Image As Long, x As Integer, y As Integer, xscale As Single, yscale As Single, angle As Single, mode As _Byte)
214.     'Image is the image handle which we use to reference our image.
215.     'x,y is the X/Y coordinates where we want the image to be at on the screen.
216.     'angle is the angle which we wish to rotate the image.
217.     'mode determines HOW we place the image at point X,Y.
218.     'Mode 0 we center the image at point X,Y
219.     'Mode 1 we place the Top Left corner of oour image at point X,Y
220.     'Mode 2 is Bottom Left
221.     'Mode 3 is Top Right
222.     'Mode 4 is Bottom Right
223.  
224.  
225.     Dim px(3) As Integer, py(3) As Integer, w As Integer, h As Integer
226.     Dim sinr As Single, cosr As Single, i As _Byte
227.     w = _Width(Image): h = _Height(Image)
228.     Select Case mode
229.         Case 0 'center
230.             px(0) = -w \ 2: py(0) = -h \ 2: px(3) = w \ 2: py(3) = -h \ 2
231.             px(1) = -w \ 2: py(1) = h \ 2: px(2) = w \ 2: py(2) = h \ 2
232.         Case 1 'top left
233.             px(0) = 0: py(0) = 0: px(3) = w: py(3) = 0
234.             px(1) = 0: py(1) = h: px(2) = w: py(2) = h
235.         Case 2 'bottom left
236.             px(0) = 0: py(0) = -h: px(3) = w: py(3) = -h
237.             px(1) = 0: py(1) = 0: px(2) = w: py(2) = 0
238.         Case 3 'top right
239.             px(0) = -w: py(0) = 0: px(3) = 0: py(3) = 0
240.             px(1) = -w: py(1) = h: px(2) = 0: py(2) = h
241.         Case 4 'bottom right
242.             px(0) = -w: py(0) = -h: px(3) = 0: py(3) = -h
243.             px(1) = -w: py(1) = 0: px(2) = 0: py(2) = 0
244.     End Select
245.     sinr = Sin(angle / 57.2957795131): cosr = Cos(angle / 57.2957795131)
246.     For i = 0 To 3
247.         x2 = xscale * (px(i) * cosr + sinr * py(i)) + x: y2 = yscale * (py(i) * cosr - px(i) * sinr) + y
248.         px(i) = x2: py(i) = y2
249.     Next
250.     _MapTriangle (0, 0)-(0, h - 1)-(w - 1, h - 1), Image To(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
251.     _MapTriangle (0, 0)-(w - 1, 0)-(w - 1, h - 1), Image To(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
252. End Sub
253.  
254.  

[bplus]

Thanks @SMcNeill

[SMcNeill]

And WHY do I tend to use _DISPLAYIMAGE instead of RotoZoom, since they basically run the same speed and produce the same results?

Because DisplayImage can do *more*!  For example, try to work up this little routine using putimage or displayimage -- you might can do it, but you won't do it with anywhere near the number of lines.

Code: QB64: [Select]

1. Screen _NewImage(640, 480, 32)
2. Do Until _Width <> 0 And _Height <> 0: Loop 'This seems to work better than _SCREENEXISTS for an initial delay
3. _ScreenMove _Middle
4. $Color:32
5.  
6. hLine = TextToImage("                    ", 8, Red, Red, 1)
7. vLine = TextToImage("                    ", 8, Red, Red, 3)
8.  
9. Do
10.     Cls
11.     k = _KeyHit
12.     Select Case k
13.         Case 18432, 19200
14.             angle = (angle + 1) Mod 360
15.         Case 20480, 19712
16.             angle = (angle - 1) Mod 360
17.     End Select
18.     DisplayImage vLine, 155, 0, 2, 3, 0, 1
19.     DisplayImage vLine, 475, 0, 2, 3, 0, 1
20.     DisplayImage hLine, 160, 236, 1, 1, angle, 1
21.     DisplayImage hLine, 480, 236, 1, 1, -angle, 3
22.     _Display
23.     _Limit 30
24. Loop Until _KeyDown(27)
25.  
26. Function TextToImage& (text$, font&, fc&, bfc&, mode As _Byte)
27.     'text$ is the text that we wish to transform into an image.
28.     'font& is the handle of the font we want to use.
29.     'fc& is the color of the font we want to use.
30.     'bfc& is the background color of the font.
31.  
32.     'Mode 1 is print forwards
33.     'Mode 2 is print backwards
34.     'Mode 3 is print from top to bottom
35.     'Mode 4 is print from bottom up
36.     'Mode 0 got lost somewhere, but it's OK.  We check to see if our mode is < 1 or > 4 and compensate automatically if it is to make it one (default).
37.  
38.     If mode < 1 Or mode > 4 Then mode = 1
39.     dc& = _DefaultColor: bgc& = _BackgroundColor
40.     D = _Dest
41.     F = _Font
42.     T2Idown = CsrLin: T2Iright = Pos(0)
43.     If font& <> 0 Then _Font font&
44.     If mode < 3 Then
45.         'print the text lengthwise
46.         w& = _PrintWidth(text$): h& = _FontHeight
47.     Else
48.         'print the text vertically
49.         For i = 1 To Len(text$)
50.             If w& < _PrintWidth(Mid$(text$, i, 1)) Then w& = _PrintWidth(Mid$(text$, i, 1))
51.         Next
52.         h& = _FontHeight * (Len(text$))
53.     End If
54.  
55.     TextToImage_temp& = _NewImage(w&, h&, 32)
56.     TextToImage = TextToImage_temp&
57.     _Dest TextToImage_temp&
58.     If font& <> 0 Then _Font font&
59.     Color fc&, bfc&
60.  
61.     Select Case mode
62.         Case 1
63.             'Print text forward
64.             _PrintString (0, 0), text$
65.         Case 2
66.             'Print text backwards
67.             temp$ = ""
68.             For i = 0 To Len(text$) - 1
69.                 temp$ = temp$ + Mid$(text$, Len(text$) - i, 1)
70.             Next
71.             _PrintString (0, 0), temp$
72.         Case 3
73.             'Print text upwards
74.             'first lets reverse the text, so it's easy to place
75.             temp$ = ""
76.             For i = 0 To Len(text$) - 1
77.                 temp$ = temp$ + Mid$(text$, Len(text$) - i, 1)
78.             Next
79.             'then put it where it belongs
80.             For i = 1 To Len(text$)
81.                 fx = (w& - _PrintWidth(Mid$(temp$, i, 1))) / 2 + .99 'This is to center any non-monospaced letters so they look better
82.                 _PrintString (fx, _FontHeight * (i - 1)), Mid$(temp$, i, 1)
83.             Next
84.         Case 4
85.             'Print text downwards
86.             For i = 1 To Len(text$)
87.                 fx = (w& - _PrintWidth(Mid$(text$, i, 1))) / 2 + .99 'This is to center any non-monospaced letters so they look better
88.                 _PrintString (fx, _FontHeight * (i - 1)), Mid$(text$, i, 1)
89.             Next
90.     End Select
91.     _Dest D
92.     Color dc&, bgc&
93.     _Font F
94.     Locate T2Idown, T2Iright
95. End Function
96.  
97. Sub DisplayImage (Image As Long, x As Integer, y As Integer, xscale As Single, _
98.                   yscale As Single, angle As Single, mode As _Byte)
99.     'Image is the image handle which we use to reference our image.
100.     'x,y is the X/Y coordinates where we want the image to be at on the screen.
101.     'angle is the angle which we wish to rotate the image.
102.     'mode determines HOW we place the image at point X,Y.
103.     'Mode 0 we center the image at point X,Y
104.     'Mode 1 we place the Top Left corner of oour image at point X,Y
105.     'Mode 2 is Bottom Left
106.     'Mode 3 is Top Right
107.     'Mode 4 is Bottom Right
108.  
109.  
110.     Dim px(3) As Integer, py(3) As Integer, w As Integer, h As Integer
111.     Dim sinr As Single, cosr As Single, i As _Byte
112.     w = _Width(Image): h = _Height(Image)
113.     Select Case mode
114.         Case 0 'center
115.             px(0) = -w \ 2: py(0) = -h \ 2: px(3) = w \ 2: py(3) = -h \ 2
116.             px(1) = -w \ 2: py(1) = h \ 2: px(2) = w \ 2: py(2) = h \ 2
117.         Case 1 'top left
118.             px(0) = 0: py(0) = 0: px(3) = w: py(3) = 0
119.             px(1) = 0: py(1) = h: px(2) = w: py(2) = h
120.         Case 2 'bottom left
121.             px(0) = 0: py(0) = -h: px(3) = w: py(3) = -h
122.             px(1) = 0: py(1) = 0: px(2) = w: py(2) = 0
123.         Case 3 'top right
124.             px(0) = -w: py(0) = 0: px(3) = 0: py(3) = 0
125.             px(1) = -w: py(1) = h: px(2) = 0: py(2) = h
126.         Case 4 'bottom right
127.             px(0) = -w: py(0) = -h: px(3) = 0: py(3) = -h
128.             px(1) = -w: py(1) = 0: px(2) = 0: py(2) = 0
129.     End Select
130.     sinr = Sin(angle / 57.2957795131): cosr = Cos(angle / 57.2957795131)
131.     For i = 0 To 3
132.         x2 = xscale * (px(i) * cosr + sinr * py(i)) + x: y2 = yscale * (py(i) * cosr - px(i) * sinr) + y
133.         px(i) = x2: py(i) = y2
134.     Next
135.     _MapTriangle (0, 0)-(0, h - 1)-(w - 1, h - 1), Image To(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
136.     _MapTriangle (0, 0)-(w - 1, 0)-(w - 1, h - 1), Image To(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
137. End Sub
138.  

Putimage just puts an image into a square of the screen.  It doesn't handle rotations...
Rotozoom handles angles and rotations, but it only works from the center point of where you position it.

DisplayImage works with whichever *corner* you want for the point where you place your image.  In this case, this allows us to create a pretty looking set of double doors which we can push or pull open with the arrow keys.  These doors crack in the middle, move smoothly, and basically look and act like we'd expect them to look -- and each with just a single line of code.

Now, I could've did this little demo with even fewer lines, if I'd just went with a single image for the wall/door and then rotated it 90 degrees between horizontal and vertical, but I was also wanting to keep things simple and not make the math look a little confusing for our angles being used.

24 lines for the main program and then an additional line for a graphic $INCLUDE library reference.  It'd be hard to get much shorter and simpler than that!  ;)