« previous next »
Pages: [1]   Go Down

Author Topic: QB64 Surabikku-like puzzle.  (Read 4489 times)

0 Members and 1 Guest are viewing this topic.

Offline Dav

  • Forum Resident
  • Posts: 792
    • View Profile
QB64 Surabikku-like puzzle.
« on: October 20, 2021, 11:40:09 am »
I got stuck waiting at the auto mechanics this morning, luckily I had my laptop with me to play with and threw together this sliding block puzzle.  I was playing something like last night online called Surabikku.  I made to use images for the blocks, just in case I want to switch out real pictures tiles in the future.

You simply slide the blocks using the arrows and try to make the puzzle look like the one on the right.  Not too hard, really.  It's harder to pronounce the puzzle name probably.

- Dav

Code: QB64: [Select]
  1. '=============
  2. 'SURABIKKU.BAS
  3. '=============
  4. 'QB64 version of a SURABIKKU like puzzle.
  5. 'Coded by Dav, OCT/2021
  6.  
  7. SCREEN _NEWIMAGE(1024, 675, 32)
  8.  
  9. 'define deminsions for chessboard
  10. DIM SHARED row, col, size: row = 3: col = 3: size = 175
  11. DIM SHARED boxes: boxes = row * col
  12.  
  13. 'define box value, x/y, values...
  14. DIM SHARED bv&(boxes) 'box values (scrambled)
  15. DIM SHARED slv&(boxes) 'box values (solved)
  16. DIM SHARED bx1(boxes), by1(boxes) 'top x/y cords of box
  17. DIM SHARED bx2(boxes), by2(boxes) ' bottom x/y cords of box
  18.  
  19. DIM SHARED red&, blu&, grn&
  20.  
  21. 'draw color boxes
  22. red& = _NEWIMAGE(size, size, 32): _DEST red&: CLS , _RGB(255, 0, 0)
  23. blu& = _NEWIMAGE(size, size, 32): _DEST blu&: CLS , _RGB(0, 0, 255)
  24. grn& = _NEWIMAGE(size, size, 32): _DEST grn&: CLS , _RGB(0, 255, 0)
  26.  
  28.  
  29. 'init box x.y values
  30. bc = 1 'counter
  31. FOR r = 1 TO row
  32.     FOR c = 1 TO col
  33.         x = 75 + (c * size): y = 75 + (r * size)
  34.         bx1(bc) = x - size: bx2(bc) = x ' generate x/y values
  35.         by1(bc) = y - size: by2(bc) = y
  36.         bc = bc + 1
  37.     NEXT
  39.  
  40. 'assign scramble up box values
  41. bv&(1) = red&: bv&(2) = grn&: bv&(3) = red&
  42. bv&(4) = blu&: bv&(5) = grn&: bv&(6) = blu&
  43. bv&(7) = grn&: bv&(8) = blu&: bv&(9) = red&
  44.  
  45. 'assign solved box values
  46. slv&(1) = red&: slv&(2) = red&: slv&(3) = grn&
  47. slv&(4) = red&: slv&(5) = blu&: slv&(6) = grn&
  48. slv&(7) = blu&: slv&(8) = blu&: slv&(9) = grn&
  49.  
  50. CLS , _RGB(64, 64, 64)
  51.  
  52. 'draw puzzle
  53. FOR b = 1 TO boxes
  54.     _PUTIMAGE (bx1(b), by1(b))-(bx2(b), by2(b)), bv&(b)
  55.     LINE (bx1(b), by1(b))-(bx2(b), by2(b)), _RGB(0, 0, 0), B
  57.  
  58. slidespeed = 300
  59.  
  60. PPRINT 668, 28, 25, _RGB(128, 128, 128), 255, "QB64 SURABIKKU"
  61. PPRINT 665, 25, 25, _RGB(255, 255, 0), 255, "QB64 SURABIKKU"
  62. PPRINT 725, 75, 20, _RGB(128, 128, 128), 255, "Click Arrow."
  63. PPRINT 725, 110, 20, _RGB(128, 128, 128), 255, "Move Blocks."
  64.  
  65. PPRINT 725, 250, 20, _RGB(255, 255, 255), 255, "Make it like:"
  66.  
  67. 'draw solved puzzle on right
  68. _PUTIMAGE (725, 300)-(800, 375), slv&(1)
  69. _PUTIMAGE (800, 300)-(875, 375), slv&(2)
  70. _PUTIMAGE (875, 300)-(950, 375), slv&(3)
  71. _PUTIMAGE (725, 375)-(800, 450), slv&(4)
  72. _PUTIMAGE (800, 375)-(875, 450), slv&(5)
  73. _PUTIMAGE (875, 375)-(950, 450), slv&(6)
  74. _PUTIMAGE (725, 450)-(800, 525), slv&(7)
  75. _PUTIMAGE (800, 450)-(875, 525), slv&(8)
  76. _PUTIMAGE (875, 450)-(950, 525), slv&(9)
  77.  
  78. 'draw top arrows
  79. FOR t = 0 TO 450 STEP 175
  80.     LINE (130 + t, 55)-(160 + t, 25), _RGB(128, 128, 128)
  81.     LINE (160 + t, 25)-(190 + t, 55), _RGB(128, 128, 128)
  82.     LINE (130 + t, 55)-(190 + t, 55), _RGB(128, 128, 128)
  84. 'draw bottom arrows
  85. FOR t = 0 TO 450 STEP 175
  86.     LINE (130 + t, 620)-(160 + t, 650), _RGB(128, 128, 128)
  87.     LINE (160 + t, 650)-(190 + t, 620), _RGB(128, 128, 128)
  88.     LINE (130 + t, 620)-(190 + t, 620), _RGB(128, 128, 128)
  90. 'draw left arrows
  91. FOR t = 0 TO 450 STEP 175
  92.     LINE (20, 160 + t)-(50, 130 + t), _RGB(128, 128, 128)
  93.     LINE (20, 160 + t)-(50, 190 + t), _RGB(128, 128, 128)
  94.     LINE (50, 130 + t)-(50, 190 + t), _RGB(128, 128, 128)
  96. 'draw right arrows
  97. FOR t = 0 TO 450 STEP 175
  98.     LINE (620, 130 + t)-(650, 160 + t), _RGB(128, 128, 128)
  99.     LINE (620, 190 + t)-(650, 160 + t), _RGB(128, 128, 128)
  100.     LINE (620, 130 + t)-(620, 190 + t), _RGB(128, 128, 128)
  102.  
  104.  
  106.  
  107.     IF _MOUSEBUTTON(1) = 0 THEN clicked = 0
  108.  
  109.     mi = _MOUSEINPUT: mx = _MOUSEX: my = _MOUSEY
  110.     'LOCATE 1, 1: PRINT mx, my, _MOUSEBUTTON(1)
  111.     '_DISPLAY
  112.  
  113.     IF _MOUSEBUTTON(1) = -1 AND clicked = 0 THEN
  114.  
  115.         clicked = 1
  116.  
  117.         '===== if top-left button clicked...
  118.         IF mx > 75 AND mx < 250 AND my > 0 AND my < 75 THEN
  119.             'slide column up
  120.             FOR y = 0 TO size
  121.                 'just move bottom two images up
  122.                 _PUTIMAGE (bx1(4), by1(4) - y), bv&(4)
  123.                 _PUTIMAGE (bx1(7), by1(7) - y), bv&(7)
  124.                 'expand bottom location with top image
  125.                 _PUTIMAGE (bx1(7), by2(7) - y)-(bx2(7), by2(7)), bv&(1)
  126.                 'redraw boxes around them, for looks
  127.                 LINE (bx1(1), by1(1))-(bx2(1), by2(1)), _RGB(0, 0, 0), B
  128.                 LINE (bx1(4), by1(4))-(bx2(4), by2(4)), _RGB(0, 0, 0), B
  129.                 LINE (bx1(7), by1(7))-(bx2(7), by2(7)), _RGB(0, 0, 0), B
  130.                 _DISPLAY
  131.                 _LIMIT slidespeed
  132.             NEXT
  133.             'update/assign new values
  134.             t1& = bv&(1): t2& = bv&(4): t3& = bv&(7) 'old values
  135.             bv&(1) = t2&: bv&(4) = t3&: bv&(7) = t1& 'new values
  136.         END IF
  137.  
  138.         '===== if bottom-left button clicked...
  139.         IF mx > 75 AND mx < 250 AND my > 600 AND my < 675 THEN
  140.             'slide column down
  141.             FOR y = 0 TO size
  142.                 'expand top location with bottom image
  143.                 _PUTIMAGE (bx1(1), by1(1))-(bx2(1), by2(1) + y), bv&(7)
  144.                 'just move top two images down
  145.                 _PUTIMAGE (bx1(1), by1(1) + y), bv&(1)
  146.                 _PUTIMAGE (bx1(4), by1(4) + y), bv&(4)
  147.                 'redraw boxes around them, for looks
  148.                 LINE (bx1(1), by1(1))-(bx2(1), by2(1)), _RGB(0, 0, 0), B
  149.                 LINE (bx1(4), by1(4))-(bx2(4), by2(4)), _RGB(0, 0, 0), B
  150.                 LINE (bx1(7), by1(7))-(bx2(7), by2(7)), _RGB(0, 0, 0), B
  151.                 _DISPLAY
  152.                 _LIMIT slidespeed
  153.             NEXT
  154.             'update/assign new values
  155.             t1& = bv&(1): t2& = bv&(4): t3& = bv&(7) 'old values
  156.             bv&(1) = t3&: bv&(4) = t1&: bv&(7) = t2& 'new values
  157.         END IF
  158.  
  159.         '===== if top-middle button clicked...
  160.         IF mx > 250 AND mx < 425 AND my > 0 AND my < 75 THEN
  161.             'slide column up
  162.             FOR y = 0 TO size
  163.                 'just move bottom two images up
  164.                 _PUTIMAGE (bx1(5), by1(5) - y), bv&(5)
  165.                 _PUTIMAGE (bx1(8), by1(8) - y), bv&(8)
  166.                 'expand bottom location with top image
  167.                 _PUTIMAGE (bx1(8), by2(8) - y)-(bx2(8), by2(8)), bv&(2)
  168.                 'redraw boxes around them, for looks
  169.                 LINE (bx1(2), by1(2))-(bx2(2), by2(2)), _RGB(0, 0, 0), B
  170.                 LINE (bx1(5), by1(5))-(bx2(5), by2(5)), _RGB(0, 0, 0), B
  171.                 LINE (bx1(8), by1(8))-(bx2(8), by2(8)), _RGB(0, 0, 0), B
  172.                 _DISPLAY
  173.                 _LIMIT slidespeed
  174.             NEXT
  175.             'update/assign new values
  176.             t1& = bv&(2): t2& = bv&(5): t3& = bv&(8) 'old values
  177.             bv&(2) = t2&: bv&(5) = t3&: bv&(8) = t1& 'new values
  178.         END IF
  179.  
  180.         '===== if bottom-middle button clicked...
  181.         IF mx > 250 AND mx < 425 AND my > 600 AND my < 675 THEN
  182.             'slide column down
  183.             FOR y = 0 TO size
  184.                 'expand top location with bottom image
  185.                 _PUTIMAGE (bx1(2), by1(2))-(bx2(2), by2(2) + y), bv&(8)
  186.                 'just move top two images down
  187.                 _PUTIMAGE (bx1(2), by1(2) + y), bv&(2)
  188.                 _PUTIMAGE (bx1(5), by1(5) + y), bv&(5)
  189.                 'redraw boxes around them, for looks
  190.                 LINE (bx1(2), by1(2))-(bx2(2), by2(2)), _RGB(0, 0, 0), B
  191.                 LINE (bx1(5), by1(5))-(bx2(5), by2(5)), _RGB(0, 0, 0), B
  192.                 LINE (bx1(8), by1(8))-(bx2(8), by2(8)), _RGB(0, 0, 0), B
  193.                 _DISPLAY
  194.                 _LIMIT slidespeed
  195.             NEXT
  196.             'update/assign new values
  197.             t1& = bv&(2): t2& = bv&(5): t3& = bv&(8) 'old values
  198.             bv&(2) = t3&: bv&(5) = t1&: bv&(8) = t2& 'new values
  199.         END IF
  200.  
  201.         '===== if top-right button clicked...
  202.         IF mx > 425 AND mx < 600 AND my > 0 AND my < 75 THEN
  203.             'slide column up
  204.             FOR y = 0 TO size
  205.                 'just move bottom two images up
  206.                 _PUTIMAGE (bx1(6), by1(6) - y), bv&(6)
  207.                 _PUTIMAGE (bx1(9), by1(9) - y), bv&(9)
  208.                 'expand bottom location with top image
  209.                 _PUTIMAGE (bx1(9), by2(9) - y)-(bx2(9), by2(9)), bv&(3)
  210.                 'redraw boxes around them, for looks
  211.                 LINE (bx1(3), by1(3))-(bx2(3), by2(3)), _RGB(0, 0, 0), B
  212.                 LINE (bx1(6), by1(6))-(bx2(6), by2(6)), _RGB(0, 0, 0), B
  213.                 LINE (bx1(9), by1(9))-(bx2(9), by2(9)), _RGB(0, 0, 0), B
  214.                 _DISPLAY
  215.                 _LIMIT slidespeed
  216.             NEXT
  217.             'update/assign new values
  218.             t1& = bv&(3): t2& = bv&(6): t3& = bv&(9) 'old values
  219.             bv&(3) = t2&: bv&(6) = t3&: bv&(9) = t1& 'new values
  220.         END IF
  221.  
  222.         '===== if bottom-right button clicked...
  223.         IF mx > 425 AND mx < 600 AND my > 600 AND my < 675 THEN
  224.             'slide column down
  225.             FOR y = 0 TO size
  226.                 'expand top location with bottom image
  227.                 _PUTIMAGE (bx1(3), by1(3))-(bx2(3), by2(3) + y), bv&(9)
  228.                 'just move top two images down
  229.                 _PUTIMAGE (bx1(3), by1(3) + y), bv&(3)
  230.                 _PUTIMAGE (bx1(6), by1(6) + y), bv&(6)
  231.                 'redraw boxes around them, for looks
  232.                 LINE (bx1(3), by1(3))-(bx2(3), by2(3)), _RGB(0, 0, 0), B
  233.                 LINE (bx1(6), by1(6))-(bx2(6), by2(6)), _RGB(0, 0, 0), B
  234.                 LINE (bx1(9), by1(9))-(bx2(9), by2(9)), _RGB(0, 0, 0), B
  235.                 _DISPLAY
  236.                 _LIMIT slidespeed
  237.             NEXT
  238.             'update/assign new values
  239.             t1& = bv&(3): t2& = bv&(6): t3& = bv&(9) 'old values
  240.             bv&(3) = t3&: bv&(6) = t1&: bv&(9) = t2& 'new values
  241.         END IF
  242.  
  243.         '===== if left-top button clicked...
  244.         IF mx > 0 AND mx < 75 AND my > 75 AND my < 250 THEN
  245.             'slide column left
  246.             FOR x = 0 TO size
  247.                 'just move right two images left
  248.                 _PUTIMAGE (bx1(2) - x, by1(2)), bv&(2)
  249.                 _PUTIMAGE (bx1(3) - x, by1(3)), bv&(3)
  250.                 'and expand far right location with far left image
  251.                 _PUTIMAGE (bx2(3) - x, by1(3))-(bx2(3) - x, by2(3)), bv&(1)
  252.                 'redraw boxes around them, for looks
  253.                 LINE (bx1(1), by1(1))-(bx2(1), by2(1)), _RGB(0, 0, 0), B
  254.                 LINE (bx1(2), by1(2))-(bx2(2), by2(2)), _RGB(0, 0, 0), B
  255.                 LINE (bx1(3), by1(3))-(bx2(3), by2(3)), _RGB(0, 0, 0), B
  256.                 _DISPLAY
  257.                 _LIMIT slidespeed
  258.             NEXT
  259.             'update/assign new values
  260.             t1& = bv&(1): t2& = bv&(2): t3& = bv&(3) 'old values
  261.             bv&(1) = t2&: bv&(2) = t3&: bv&(3) = t1& 'new values
  262.         END IF
  263.  
  264.         '===== if right-top button clicked...
  265.         IF mx > 600 AND mx < 675 AND my > 75 AND my < 250 THEN
  266.             'slide column left
  267.             FOR x = 0 TO size
  268.                 'just move left two images right
  269.                 _PUTIMAGE (bx1(1) + x, by1(1)), bv&(1)
  270.                 _PUTIMAGE (bx1(2) + x, by1(2)), bv&(2)
  271.                 'and expand far left location with far right image
  272.                 _PUTIMAGE (bx1(1), by1(1))-(bx1(1) + x, by2(1)), bv&(3)
  273.                 'redraw boxes around them, for looks
  274.                 LINE (bx1(1), by1(1))-(bx2(1), by2(1)), _RGB(0, 0, 0), B
  275.                 LINE (bx1(2), by1(2))-(bx2(2), by2(2)), _RGB(0, 0, 0), B
  276.                 LINE (bx1(3), by1(3))-(bx2(3), by2(3)), _RGB(0, 0, 0), B
  277.                 _DISPLAY
  278.                 _LIMIT slidespeed
  279.             NEXT
  280.             'update/assign new values
  281.             t1& = bv&(1): t2& = bv&(2): t3& = bv&(3) 'old values
  282.             bv&(1) = t3&: bv&(2) = t1&: bv&(3) = t2& 'new values
  283.         END IF
  284.  
  285.         '===== if left-middle button clicked...
  286.         IF mx > 0 AND mx < 75 AND my > 250 AND my < 425 THEN
  287.             'slide column left
  288.             FOR x = 0 TO size
  289.                 'just move right two images left
  290.                 _PUTIMAGE (bx1(5) - x, by1(5)), bv&(5)
  291.                 _PUTIMAGE (bx1(6) - x, by1(6)), bv&(6)
  292.                 'and expand far right location with far left image
  293.                 _PUTIMAGE (bx2(6) - x, by1(6))-(bx2(6) - x, by2(6)), bv&(4)
  294.                 'redraw boxes around them, for looks
  295.                 LINE (bx1(4), by1(4))-(bx2(4), by2(4)), _RGB(0, 0, 0), B
  296.                 LINE (bx1(5), by1(5))-(bx2(5), by2(5)), _RGB(0, 0, 0), B
  297.                 LINE (bx1(6), by1(6))-(bx2(6), by2(6)), _RGB(0, 0, 0), B
  298.                 _DISPLAY
  299.                 _LIMIT slidespeed
  300.             NEXT
  301.             'update/assign new values
  302.             t1& = bv&(4): t2& = bv&(5): t3& = bv&(6) 'old values
  303.             bv&(4) = t2&: bv&(5) = t3&: bv&(6) = t1& 'new values
  304.         END IF
  305.  
  306.         '===== if right-middle button clicked...
  307.         IF mx > 600 AND mx < 675 AND my > 250 AND my < 425 THEN
  308.             'slide column left
  309.             FOR x = 0 TO size
  310.                 'just move left two images right
  311.                 _PUTIMAGE (bx1(4) + x, by1(4)), bv&(4)
  312.                 _PUTIMAGE (bx1(5) + x, by1(5)), bv&(5)
  313.                 'and expand far left location with far right image
  314.                 _PUTIMAGE (bx1(4), by1(4))-(bx1(4) + x, by2(4)), bv&(6)
  315.                 'redraw boxes around them, for looks
  316.                 LINE (bx1(4), by1(4))-(bx2(4), by2(4)), _RGB(0, 0, 0), B
  317.                 LINE (bx1(5), by1(5))-(bx2(5), by2(5)), _RGB(0, 0, 0), B
  318.                 LINE (bx1(6), by1(6))-(bx2(6), by2(6)), _RGB(0, 0, 0), B
  319.                 _DISPLAY
  320.                 _LIMIT slidespeed
  321.             NEXT
  322.             'update/assign new values
  323.             t1& = bv&(4): t2& = bv&(5): t3& = bv&(6) 'old values
  324.             bv&(4) = t3&: bv&(5) = t1&: bv&(6) = t2& 'new values
  325.         END IF
  326.  
  327.         '===== if left-bottom button clicked...
  328.         IF mx > 0 AND mx < 75 AND my > 425 AND my < 600 THEN
  329.             'slide column left
  330.             FOR x = 0 TO size
  331.                 'just move right two images left
  332.                 _PUTIMAGE (bx1(8) - x, by1(8)), bv&(8)
  333.                 _PUTIMAGE (bx1(9) - x, by1(9)), bv&(9)
  334.                 'and expand far right location with far left image
  335.                 _PUTIMAGE (bx2(9) - x, by1(9))-(bx2(9) - x, by2(9)), bv&(7)
  336.                 'redraw boxes around them, for looks
  337.                 LINE (bx1(7), by1(7))-(bx2(7), by2(7)), _RGB(0, 0, 0), B
  338.                 LINE (bx1(8), by1(8))-(bx2(8), by2(8)), _RGB(0, 0, 0), B
  339.                 LINE (bx1(9), by1(9))-(bx2(9), by2(9)), _RGB(0, 0, 0), B
  340.                 _DISPLAY
  341.                 _LIMIT slidespeed
  342.             NEXT
  343.             'update/assign new values
  344.             t1& = bv&(7): t2& = bv&(8): t3& = bv&(9) 'old values
  345.             bv&(7) = t2&: bv&(8) = t3&: bv&(9) = t1& 'new values
  346.         END IF
  347.  
  348.         '===== if right-bottom button clicked...
  349.         IF mx > 600 AND mx < 675 AND my > 425 AND my < 600 THEN
  350.             'slide column left
  351.             FOR x = 0 TO size
  352.                 'just move left two images right
  353.                 _PUTIMAGE (bx1(7) + x, by1(7)), bv&(7)
  354.                 _PUTIMAGE (bx1(8) + x, by1(8)), bv&(8)
  355.                 'and expand far left location with far right image
  356.                 _PUTIMAGE (bx1(7), by1(7))-(bx1(7) + x, by2(7)), bv&(9)
  357.                 'redraw boxes around them, for looks
  358.                 LINE (bx1(7), by1(7))-(bx2(7), by2(7)), _RGB(0, 0, 0), B
  359.                 LINE (bx1(8), by1(8))-(bx2(8), by2(8)), _RGB(0, 0, 0), B
  360.                 LINE (bx1(9), by1(9))-(bx2(9), by2(9)), _RGB(0, 0, 0), B
  361.                 _DISPLAY
  362.                 _LIMIT slidespeed
  363.             NEXT
  364.             'update/assign new values
  365.             t1& = bv&(7): t2& = bv&(8): t3& = bv&(9) 'old values
  366.             bv&(7) = t3&: bv&(8) = t1&: bv&(9) = t2& 'new values
  367.         END IF
  368.  
  369.         '==== check for solved here....
  370.         solved = 1
  371.         FOR s = 1 TO boxes
  372.             IF bv&(s) <> slv&(s) THEN solved = 0
  373.         NEXT
  374.         IF solved = 1 THEN BEEP: BEEP: END
  375.  
  376.     END IF
  378.  
  380.  
  381.  
  382.  
  383. SUB PPRINT (x, y, size, clr&, trans&, text$)
  384.     'This sub outputs to the current _DEST set
  385.     'It makes trans& the transparent color
  386.  
  387.     'x/y is where to print text
  388.     'size is the font size to use
  389.     'clr& is the color of your text
  390.     'trans& is the background transparent color
  391.     'text$ is the string to print
  392.  
  393.     '=== get users current write screen
  394.     orig& = _DEST
  395.  
  396.     '=== if you are using an 8 or 32 bit screen
  397.     bit = 32: IF _PIXELSIZE(0) = 1 THEN bit = 256
  398.  
  399.     '=== step through your text
  400.     FOR t = 0 TO LEN(text$) - 1
  401.         '=== make a temp screen to use
  402.         pprintimg& = _NEWIMAGE(16, 16, bit)
  403.         _DEST pprintimg&
  404.         '=== set colors and print text
  405.         CLS , trans&: COLOR clr&
  406.         PRINT MID$(text$, t + 1, 1);
  407.         '== make background color the transprent one
  408.         _CLEARCOLOR _RGB(0, 0, 0), pprintimg&
  409.         '=== go back to original screen  to output
  410.         _DEST orig&
  411.         '=== set it and forget it
  412.         x1 = x + (t * size): x2 = x1 + size
  413.         y1 = y: y2 = y + size
  414.         _PUTIMAGE (x1 - (size / 2), y1)-(x2, y2 + (size / 3)), pprintimg&
  415.         _FREEIMAGE pprintimg&
  416.     NEXT
  418.  
« Last Edit: October 20, 2021, 02:13:32 pm by Dav »
Logged

Offline bplus

  • Global Moderator
  • Forum Resident
  • Posts: 8053
  • b = b + ...
    • View Profile
Re: QB64 Surabikku-like puzzle.
« Reply #1 on: October 20, 2021, 12:22:54 pm »
Nice, I got it but don't know how? :)
Logged

Offline bplus

  • Global Moderator
  • Forum Resident
  • Posts: 8053
  • b = b + ...
    • View Profile
Re: QB64 Surabikku-like puzzle.
« Reply #2 on: October 20, 2021, 12:52:45 pm »
@Dav This is begging to do images with difficulty levels of pieces.
Logged

Offline Dav

  • Forum Resident
  • Posts: 792
    • View Profile
Re: QB64 Surabikku-like puzzle.
« Reply #3 on: October 20, 2021, 02:17:25 pm »
Yeah I was thinking along that line.  I need to come up with a way to PUTIMAGE just a portion of an image on screen, for when sliding the edge tiles.  Maybe make a temporary images offscreen using _NEWIMAGE/_DEST for that.

- Dav
Logged

Offline bplus

  • Global Moderator
  • Forum Resident
  • Posts: 8053
  • b = b + ...
    • View Profile
Re: QB64 Surabikku-like puzzle.
« Reply #4 on: October 20, 2021, 04:31:23 pm »
To avoid _NewImage for each rectangle chunk of image, you could use a formula that takes an image number and converts to a row and col from the image and vice versa. From row, col convert to x, y top left corner of image chunk then Step(width, height) of each chunk.

Image number = row * (nCellsWide -1) + col
EDIT >>>>>>> row * nCellsWide + col    both rows and columns start at 0

row = INT( image number / nCellsWide)   ' rows 0 to nCellsHigh - 1
col = ( image number) mod nCellsWide     ' cols 0 to nCellsWide - 1

x = row * cellWidth   EDIT: x = col * cellWidth
y = col * cellHeight   EDIT: y = row * cellHeight

_putimage (destinationX, destinationY)-step(cellWidth, cellHeight), image, screen, (x, y) -step(cellWidth, cellHeight)
(destinationX, destinationY) or more likely (destRow, destCol) EDIT >>> (destCol, destRow) has to be tracked by the progress of the puzzle.

_Putimage uses 2 line boxes one from source (the image) and one for destination (the screen) just have to track the image number with the game setup and play.

eg image number 0 is top left corner of image, 1 is next cell to right, new row (2nd) starts at image number = nCellsWide

Sorry for EDITs but I hope to get this correct.

EDIT: Row is vertical associated with Y's of graphic,  Col (Column) is horizontal associated with X's of graphic.
I've learned to say Row, Col when it comes to Locate for Text and x, y when it comes to graphics but they are reversed text and graphic.
« Last Edit: October 20, 2021, 08:35:45 pm by bplus »
Logged

Offline Dav

  • Forum Resident
  • Posts: 792
    • View Profile
Re: QB64 Surabikku-like puzzle.
« Reply #5 on: October 20, 2021, 06:53:14 pm »
Oh wow - I haven't used _PUTIMAGE in that way before.  I'll play around with it.  Not sure I fully grasp the formula yet, but will chew on it for awhile.

Thanks!

- Dav
Logged

Offline Pete

  • Forum Resident
  • Posts: 2361
  • Cuz I sez so, varmint!
    • View Profile
Re: QB64 Surabikku-like puzzle.
« Reply #6 on: October 20, 2021, 07:43:25 pm »
Quote from: bplus on October 20, 2021, 04:31:23 pm
To avoid _NewImage for each rectangle chunk of image, you could use a formula that takes an image number and converts to a row and col from the image and vice versa. From row, col convert to x, y top left corner of image chunk then Step(width, height) of each chunk.

Image number = row * (nCellsWide -1) + col

row = INT( image number / nCellsWide)   ' rows 0 to nCellsHigh - 1
col = ( image number) mod nCellsWide     ' cols 0 to nCellsWide - 1

x = row * cellWidth
y = col * cellHeight

_putimage (destinationX, destinationY)-step(cellWidth, cellHeight), image, screen, (x, y) -step(cellWidth, cellHeight)
(destinationX, destinationY) or more likely (destRow, destCol) has to be tracked by the progress of the puzzle.

_Putimage uses 2 line boxes one from source (the image) and one for destination (the screen) just have to track the image number with the game setup and play.

eg image number 0 is top left corner of image, 1 is next cell to right, new row (2nd) starts at image number = nCellsWide

🤯🤯🤯
Logged
Want to learn how to write code on cave walls? https://www.tapatalk.com/groups/qbasic/qbasic-f1/

Offline bplus

  • Global Moderator
  • Forum Resident
  • Posts: 8053
  • b = b + ...
    • View Profile
Re: QB64 Surabikku-like puzzle.
« Reply #7 on: October 20, 2021, 07:56:55 pm »
@Pete kinda' of thought this would be the reaction so as I said before a picture is worth a thousand words.

Here is a demo of using _PutImage. I make an image, divide it into cells, number those cells, and then choose cell numbers randomly to rebuild the original image a cell at a time as far as 100 random choices takes us.

Code: QB64: [Select]
  1. _Title "PutImage test Image Number Sheet" ' b+ 2021-10-20
  2.  
  3. Screen _NewImage(800, 600, 32) '
  4. _Delay .25
  6.  
  7. ' make sample image
  8. snap& = _NewImage(_Width, _Height, 32)
  10. For r = 20 To _Width / 1.5 Step 20
  11.     Circle (_Width / 2, _Height / 2), r
  13. For i = 1 To _Width * _Height * .00035
  14.     Line (Rnd * _Width, Rnd * _Height)-Step(Rnd * 50, Rnd * 50), _RGB32(Rnd * 255, Rnd * 255, Rnd * 255, Rnd * 255), BF
  16. _PutImage , 0, snap&
  17. Print "Here is Image sheet,    zzz."
  20. _PutImage , snap&, 0
  21. cellWidth = _Width / 10
  22. cellHeight = _Height / 10
  23. For i = 0 To _Width Step cellWidth
  24.     Line (i, 0)-(i, _Height - 1)
  26. For i = 0 To _Height Step cellHeight
  27.     Line (0, i)-(_Width - 1, i)
  29. i = 0
  30. For r = 0 To 9
  31.     For c = 0 To 9
  32.         _PrintString (c * cellWidth + 20, r * cellHeight + 20), _Trim$(Str$(i))
  33.         i = i + 1
  34.     Next
  36. Print "Here is sheet divided into image cells with Image Numbers,  zzz"
  38. snapCopy& = _CopyImage(snap&)
  39. _SetAlpha 20, , snapCopy&
  41. _PutImage , snapCopy&, 0
  42. For i = 1 To 100
  43.     rcell = Int(Rnd * 100)
  44.     row = Int(rcell / 10)
  45.     col = rcell Mod 10
  46.     _PutImage (col * cellWidth, row * cellHeight)-Step(cellWidth, cellHeight), snap&, 0, (col * cellWidth, row * cellHeight)-Step(cellWidth, cellHeight)
  47.     Locate 1, 1: Print "Here is 100 randomly chosen image numbers from image. Newest random cell #"; _Trim$(Str$(rcell))
  48.     _Delay 1.5
  49.     _PrintString (col * cellWidth + 20, row * cellHeight + 20), _Trim$(Str$(rcell))
  50.     _Delay 1.5
  52.  



Logged

Offline Dav

  • Forum Resident
  • Posts: 792
    • View Profile
Re: QB64 Surabikku-like puzzle.
« Reply #8 on: October 20, 2021, 08:13:09 pm »
Ahh I see.  That will be very useful.  Cool snippet. Thank you!

- Dav
Logged

Offline Pete

  • Forum Resident
  • Posts: 2361
  • Cuz I sez so, varmint!
    • View Profile
Re: QB64 Surabikku-like puzzle.
« Reply #9 on: October 20, 2021, 08:23:29 pm »
I get what it does, it's just a lot of parameters to "see" at once. All this stuff gets a lot more intuitive once a person has put several coding projects together. Hell, I'm even getting used to putting up with _PUTSTRING.

Nice demo, but _delay 1.5, RU flocking kidding me. .1. I'm old, but I'm not dead... wait, let me check... yep, there's a pulse, sort of.

Pet^V^V______e
Logged
Want to learn how to write code on cave walls? https://www.tapatalk.com/groups/qbasic/qbasic-f1/

Offline johannhowitzer

  • Forum Regular
  • Posts: 118
    • View Profile
Re: QB64 Surabikku-like puzzle.
« Reply #10 on: October 23, 2021, 09:57:08 pm »
Quote
It's harder to pronounce the puzzle name probably.

Soo-rah-beak-oo.  Japanese has similar vowels to Spanish, and when you see a double-consonant, you jump to that consonant quicker.  It's the romaji (english characters) representation of the Japanese small "tsu."

The method bplus describes is pretty much how my sprite sheet slicer routine works.  One big image, and the routine goes through and hunts for detector pixels and stores where each sprite is, then you just store the reference for the sprite in each object, and when you go to draw, you can call up the location of the sprite from the object's data.
Logged
Pages: [1]   Go Up
« previous next »