Windows buttons for 32 and 64 bit IDE - Take 2

[mpgcan]

With the release of QB64 v2.0  a seperate manifest nolonger required for Windows controls:
"Automatically embeds a manifest file when compiling an exe with $VersionInfo, so that Common Controls v6.0 gets linked at runtime."

Regarding windows controls,  I  found this page  https://www.qb64.org/forum/index.php?topic=3217.msg124966#msg124966  informative and useful. Seems it was never completed which is a shame!  However it is easy to comment and be critical of others, hence  I wrote an upgrade to give something back.

Talking about comments, you will notice  there are several lines that have comments, these are alternatives for doing the same thing. Comment an active line to disable it,  un-comment an alternative line if available to see what it does.

Save the following files and place them in your QB64 folder:

window_controls_7.bas

Code: QB64: [Select]

1. Option _Explicit
2. DefStr A-Z
3. $VersionInfo:Comments=This uses Controls! 'Creates flat controls remove for 3D
4. Do: Loop Until _ScreenExists '             before using _WindowHandle or _title
5. ' A Simple Window for QB64 32 & 64 bit
6. ' window_controls_7.bas
7. ' MPG 30-9-2021
8. '
9. '---------------------------------------------------------------
10. 'NOTE:
11. 'Create a new file WIN.h with the following content (Remove the comments '):
12. '---Start of file contents:---
13. 'ptrszint FUNC_WINDOWPROC(ptrszint*_FUNC_WINDOWPROC_OFFSET_HWND,uint32*_FUNC_WINDOWPROC_ULONG_UMSG,uptrszint*_FUNC_WINDOWPROC_UOFFSET_WPARAM,ptrszint*_FUNC_WINDOWPROC_OFFSET_LPARAM);
14.  
15. 'LRESULT CALLBACK WindowProc(HWND hwnd, UINT uMsg, WPARAM wParam, LPARAM lParam) {
16. ' return FUNC_WINDOWPROC((ptrszint *) (& hwnd), & uMsg, & wParam, (ptrszint *) (& lParam));
17. '}
18.  
19. 'void * GetWindowProc() {
20. ' return (void *) WindowProc;
21. '}
22. '---End of file contents---
23. 'Your program uses the WIN.h file to get the WindowProc. Note: Place above file in your working folder (The QB64 folder).
24. '----------------------------------------------------------------
25.  
26. '--Constants
27.      
28. Const IDC_ARROW = &H7F00
29. Const COLOR_WINDOW = 5
30.  
31. Const WS_OVERLAPPED = 0
32. Const WS_EX_CLIENTEDGE = &H00000200
33. Const WS_CAPTION = &H00C00000
34. Const WS_SYSMENU = &H00080000
35. Const WS_THICKFRAME = &H00040000
36. Const WS_MINIMIZEBOX = &H00020000
37. Const WS_MAXIMIZEBOX = &H00010000
38. Const WS_VSCROLL = &H00200000
39. Const WS_HSCROLL = &H00100000
40. 'Const WS_OVERLAPPEDWINDOW = WS_OVERLAPPED Or WS_CAPTION Or WS_SYSMENU Or WS_THICKFRAME Or WS_MINIMIZEBOX Or WS_MAXIMIZEBOX
41. Const WS_OVERLAPPEDWINDOW = WS_OVERLAPPED Or WS_CAPTION Or WS_SYSMENU
42. Const WS_TABSTOP = &H00010000
43. Const WS_VISIBLE = &H10000000
44. Const WS_CHILD = &H40000000
45. Const WS_GROUP = &H00020000
46.  
47. Const CW_USEDEFAULT = &H80000000
48.  
49. Const WM_CLOSE = &H0010
50. Const WM_CREATE = 1
51. Const WM_DESTROY = 2
52. Const WM_COMMAND = &H0111
53. Const WM_SETTEXT = &H000C
54. Const WM_GETTEXT = &H000D
55.  
56. Const SW_SHOWDEFAULT = &HA
57.  
58. Const BS_PUSHBUTTON = 0 '     Standard button
59. Const BS_AUTOCHECKBOX = 3 '   Multi-Checkbox button
60. Const BN_CLICKED = 0
61. Const BS_RADIOBUTTON = 4 '     Single Radio button
62. Const BS_AUTORADIOBUTTON = 9 ' Multi-radio buttons
63. Const BS_GROUPBOX = 7 '        Group box "eye candy"
64.  
65. Const BM_GETCHECK = &HF0
66. Const BST_CHECKED = &H1
67. Const BM_CLICK = &H00F5
68. Const BM_SETCHECK = &HF1
69.  
70. Const ES_LEFT = 0
71. Const EM_SETPASSWORDCHAR = &HCC
72.  
73. Const ES_NUMBER = &H2000
74. Const ES_PASSWORD = &H0020
75.  
76. Const ES_MULTILINE = 4
77. Const ES_AUTOVSCROLL = &H0040
78. Const ES_AUTOHSCROLL = &H0080
79. Const ES_WANTRETURN = &H1000
80.  
81.  
82. '--Types
83. Type POINT
84.     As Long x
85.     As Long y
86. End Type
87.  
88. Type MSG
89.     As _Offset hwnd
90.     As _Unsigned Long message
91.     As _Unsigned _Offset wParam 'unsigned pointer sized integer
92.     As _Offset lParam 'pointer sized integer
93.     As _Unsigned Long time
94.     As POINT pt
95. End Type
96.  
97. Type WNDCLASSA
98.     As _Unsigned Long style
99.     $If 64BIT Then
100.         As String * 4 padding
101.     $End If
102.  
103.     As _Offset lpfnWndProc
104.     As Long cbClsExtra, cbWndExtra
105.     As _Offset hInstance, hIcon, hCursor, hbrBackground, lpszMenuName, lpszClassName
106. End Type
107.  
108. '--Libaries
109. Declare Library "win"
110.     Function GetWindowProc%& ()
111. End Declare
112.  
113. Declare Dynamic Library "user32"
114.     Function SendMessageA%& (ByVal hWnd As _Offset, Byval Msg As _Unsigned Long, Byval wParam As _Unsigned _Offset, Byval lParam As _Offset)
115.     Function DefWindowProcA%& (ByVal hWnd As _Offset, Byval Msg As _Unsigned Long, Byval wParam As _Unsigned _Offset, Byval lParam As _Offset)
116.     Sub PostQuitMessage (ByVal nExitCode As Long)
117.     Function LoadCursorW%& (ByVal hInstance As _Offset, Byval lpCursorName As _Offset)
118.     Function RegisterClassA~% (ByVal lpWndClass As _Offset)
119.     Function CreateWindowExA%& (ByVal dwExStyle As Long, Byval lpClassName As _Offset, Byval lpWindowName As _Offset, Byval dwStyle As Long, Byval X As Long, Byval Y As Long, Byval nWidth As Long, Byval nHeight As Long, Byval hWndParent As _Offset, Byval hMenu As _Offset, Byval hInstance As _Offset, Byval lpParam As _Offset)
120.     Function ShowWindow& (ByVal hWnd As _Offset, Byval nCmdShow As Long)
121.     Function UpdateWindow& (ByVal hWnd As _Offset)
122.     Function GetMessageA% (ByVal lpMsg As _Offset, Byval hWnd As _Offset, Byval wMsgFilterMin As _Unsigned Long, Byval wMsgFilterMax As _Unsigned Long)
123.     Function TranslateMessage& (ByVal lpMsg As _Offset)
124.     Function DispatchMessageA%& (ByVal lpmsg As _Offset)
125.     Sub DestroyWindow (ByVal hWnd As _Offset)
126.     Function PostMessageA%& (ByVal hWnd As _Offset, Byval Msg As _Unsigned Long, Byval wParam As _Unsigned _Offset, Byval lParam As _Offset)
127.     Function SetWindowTextA& (ByVal hWnd As _Offset, Byval lpString As _Offset)
128.     Function GetWindowLongA& (ByVal hwnd As _Offset, Byval nIndex As Long)
129.     Function SetWindowLongA& (ByVal hwnd As _Offset, Byval nIndex As Long, Byval dwNewLong As Long)
130. End Declare
131.  
132. Declare Dynamic Library "kernel32"
133.     Function GetModuleHandleW%& (ByVal lpModuleName%&)
134.     Function GetLastError~& ()
135. End Declare
136.  
137.  
138. '--Variables
139.  
140. Dim Shared hi As _Offset '   Handle to application instance
141. Dim Shared wc As WNDCLASSA ' define wc as WNDCLASSEX structure
142. Dim msg As MSG
143. Dim Shared hw As _Offset '    Handle to window created
144.  
145. Dim Shared hwb0 As _Offset '  Handle to window button created
146. Dim Shared hwb1 As _Offset '  Handle to window button created
147. Dim Shared hwb2 As _Offset '  Handle to window button created
148.  
149. Dim Shared hwcb0 As _Offset ' Handle to window checkbox button created
150. Dim Shared hwcb1 As _Offset ' Handle to window checkbox button created
151. Dim Shared hwcb2 As _Offset ' Handle to window checkbox button created
152.  
153. Dim Shared hwgb1 As _Offset ' Handle to group box 1
154. Dim Shared hwr11 As _Offset ' Handle to window radio botton
155. Dim Shared hwr12 As _Offset
156. Dim Shared hwr13 As _Offset
157.  
158. Dim Shared hwgb2 As _Offset ' Handle to group box 2
159. Dim Shared hwr21 As _Offset ' Handle to window radio botton
160. Dim Shared hwr22 As _Offset
161. Dim Shared hwr23 As _Offset
162.  
163. Dim Shared hwLabel1 As _Offset
164. Dim Shared hwLabel2 As _Offset
165.  
166. Dim Shared hwe1 As _Offset 'Single line edit control
167. Dim Shared hwe2 As _Offset 'Multiline edit control
168. Dim Shared hwLB As _Offset 'Handle to list box
169. Dim Shared hwCB As _Offset 'Handle to combo drop-down list box
170.  
171. Dim Shared discardb As Long 'Dummy variable
172. Dim Shared discardp As _Offset 'Dummy variable
173. Dim Shared t0 As String 'Type of component
174. Dim Shared t1 As String 'Title or componets text
175. Dim Shared buf1 As String * 64 'Single line edit buffer
176. Dim Shared buf2 As String * 4096 'Multi line edit buffer
177.      
178. Dim Shared MainClassName As String * 5
179. MainClassName = "main" + Chr$(0)
180.  
181. Dim CrLf As String * 2 '    define as 2 byte STRING
182. CrLf = Chr$(13) + Chr$(10) 'carriage return&line feed
183.  
184.  
185. Dim Shared As String className '       Variable className stores name of our window class
186. className = "myWindowClass" + Chr$(0) 'Used in wc. which in turn is used to register window class with the system.
187.  
188. hi = GetModuleHandleW(0) 'Handle to application instance
189.  
190. '---Step 1: Registering the Window Class
191. 'Fill out the members of WNDCLASSEX structure (wc) and call RegisterClassA
192.  
193. wc.style = 0 '                            Class Styles (CS_*), not Window Styles (WS_*) This is usually be set to 0.
194. wc.lpfnWndProc = GetWindowProc '          Pointer to the window procedure for this window class. (see WIN.h)
195. wc.cbClsExtra = 0 '                       Amount of extra data allocated for this class in memory. Usually 0.
196. wc.cbWndExtra = 0 '                       Amount of extra data allocated in memory per window of this type. Usually 0.
197. wc.hInstance = hi '                       Handle to application instance .
198. wc.hIcon = 0 '                            Large (usually 32x32) icon shown when the user presses Alt+Tab. Set to 0
199. wc.hCursor = LoadCursorW(0, IDC_ARROW) '  Cursor that will be displayed over our window.
200. wc.hbrBackground = COLOR_WINDOW 'was +1   Background Brush to set the color of our window. '
201. wc.lpszMenuName = 0 '                     Name of a menu resource to use for the windows with this class.
202. wc.lpszClassName = _Offset(className) '   Name to identify the class with.
203.  
204. If RegisterClassA(_Offset(wc)) = 0 Then
205.     Print "RegisterClassA failed:"; GetLastError
206.     End
207.     'Else Print "OK"
208. End If
209.  
210. '--Step 2: Creating the Windows
211.  
212. '--Main window
213. 'After registering the class, create a window with it using CreateWindowExA.
214.  
215. 'HWND CreateWindowExA(
216. '  DWORD     dwExStyle,     0                     Extended windows style. Not used set to 0
217. '  LPCSTR    lpClassName,  _Offset(className)     Tells the system what kind of window to create.
218. '  LPCSTR    lpWindowName, _Offset(t1)            Text displayed in the Caption or Title Bar.
219. '  DWORD     dwStyle,      WS_OVERLAPPEDWINDOW... Window Style parameters see constants
220. '  int       X,            CW_USEDEFAULT          Top left corner of your window. Let windows choose
221. '  int       Y,            CW_USEDEFAULT          Top left corner of your window. Let windows choose
222. '  int       nWidth,       432                    Width and
223. '  int       nHeight,      400                    height of the window
224. '  HWND      hWndParent,     0                    No parent window set handle to 0
225. '  HMENU     hMenu,          0                    Not menu set to 0
226. '  HINSTANCE hInstance,     hi                    Module instance handle associated with the window.
227. ' LPVOID    lpParam         0                    Used with MDI child window not used set to 0
228. ')
229.  
230. t1 = "Window Ref 1" + Chr$(0)
231. 'hw = CreateWindowExA(0, _Offset(className), _Offset(t1), WS_HSCROLL Or WS_OVERLAPPEDWINDOW Or WS_VSCROLL, CW_USEDEFAULT, CW_USEDEFAULT, 432, 400, 0, 0, hi, 0): If 0 = hw Then System
232. hw = CreateWindowExA(0, _Offset(className), _Offset(t1), WS_OVERLAPPEDWINDOW, CW_USEDEFAULT, CW_USEDEFAULT, 432, 520, 0, 0, hi, 0): If 0 = hw Then System
233.  
234. '--Standard Controls: Button, Edit, List Box etc
235. 'Controls are just child windows. They have a procedure, a class etc... that is registered by the system.
236. 'Anything you can do with a normal window you can do with a control.
237.  
238. '-Standard Buttons require style BS_PUSHBUTTON
239.  
240. t0 = "BUTTON" + Chr$(0) '  Set: Window control is BUTTON predefined class
241. t1 = "Button 0" + Chr$(0) 'Set: Button display text
242. hwb0 = CreateWindowExA(0, _Offset(t0), _Offset(t1), WS_TABSTOP Or WS_VISIBLE Or WS_CHILD Or BS_PUSHBUTTON, 10, 10, 75, 23, hw, 0, hi, 0): If 0 = hwb0 Then System
243.  
244. t0 = "BUTTON" + Chr$(0) '  Set: Window control is BUTTON predefined class
245. t1 = "Button 1" + Chr$(0) 'Set: Button display text
246. hwb1 = CreateWindowExA(0, _Offset(t0), _Offset(t1), WS_TABSTOP Or WS_VISIBLE Or WS_CHILD Or BS_PUSHBUTTON, 10, 37, 75, 23, hw, 0, hi, 0): If 0 = hwb1 Then System
247.  
248. t0 = "BUTTON" + Chr$(0) '  Set: Window control is BUTTON
249. t1 = "Button 2" + Chr$(0) 'Set: Button display text
250. hwb2 = CreateWindowExA(0, _Offset(t0), _Offset(t1), WS_TABSTOP Or WS_VISIBLE Or WS_CHILD Or BS_PUSHBUTTON, 10, 64, 75, 23, hw, 0, hi, 0): If 0 = hwb2 Then System
251.  
252. '-Checkbox Buttons require style BS_AUTOCHECKBOX
253. t0 = "BUTTON" + Chr$(0) '  Set: Window control is BUTTON
254. t1 = "ChkBox0" + Chr$(0) 'Check box label display text
255. hwcb0 = CreateWindowExA(0, _Offset(t0), _Offset(t1), WS_TABSTOP Or WS_VISIBLE Or WS_CHILD Or BS_AUTOCHECKBOX, 10, 91, 90, 23, hw, 0, hi, 0): If 0 = hwcb0 Then System
256.  
257. t0 = "BUTTON" + Chr$(0) '  Set: Window control is BUTTON
258. t1 = "ChkBox1" + Chr$(0) 'Check box label display text
259. hwcb1 = CreateWindowExA(0, _Offset(t0), _Offset(t1), WS_TABSTOP Or WS_VISIBLE Or WS_CHILD Or BS_AUTOCHECKBOX, 10, 118, 90, 23, hw, 0, hi, 0): If 0 = hwcb1 Then System
260.  
261. t0 = "BUTTON" + Chr$(0) '  Set: Window control is BUTTON
262. t1 = "ChkBox2" + Chr$(0) 'Check box label display text
263. hwcb2 = CreateWindowExA(0, _Offset(t0), _Offset(t1), WS_TABSTOP Or WS_VISIBLE Or WS_CHILD Or BS_AUTOCHECKBOX, 10, 145, 90, 23, hw, 0, hi, 0): If 0 = hwcb2 Then System
264.  
265.  
266. 'Standard Radio Buttons require style BS_RADIOBUTTON (single) or BS_AUTORADIOBUTTON (group)
267. 'First button of a group must have following styles WS_TABSTOP WS_GROUP
268. 'The first control after last group must have style WS_GROUP to terminate last group
269. 'Note: A BS_GROUPBOX is "eye candy" and does not contribute to a radio box group.
270. ' The crucial parameter to control radio or check box grouping is the style WS_GROUP
271.  
272. '--Bank 1: Group box1
273. t0 = "BUTTON" + Chr$(0) 'predefined class
274. t1 = "Group box1" + Chr$(0)
275. hwgb1 = CreateWindowExA(0, _Offset(t0), _Offset(t1), WS_VISIBLE Or WS_CHILD Or BS_GROUPBOX, 100, 10, 300, 50, hw, 0, hi, 0): If 0 = hwgb1 Then System
276. t1 = "Radio 11" + Chr$(0)
277. hwr11 = CreateWindowExA(0, _Offset(t0), _Offset(t1), WS_VISIBLE Or WS_CHILD Or BS_AUTORADIOBUTTON Or WS_TABSTOP Or WS_GROUP, 105, 30, 90, 23, hw, 0, hi, 0): If 0 = hwr11 Then System
278. t1 = "Radio 12" + Chr$(0)
279. hwr12 = CreateWindowExA(0, _Offset(t0), _Offset(t1), WS_VISIBLE Or WS_CHILD Or BS_AUTORADIOBUTTON, 200, 30, 90, 23, hw, 0, hi, 0): If 0 = hwr12 Then System
280. t1 = "Radio 12" + Chr$(0)
281. hwr13 = CreateWindowExA(0, _Offset(t0), _Offset(t1), WS_VISIBLE Or WS_CHILD Or BS_AUTORADIOBUTTON, 300, 30, 90, 23, hw, 0, hi, 0): If 0 = hwr13 Then System
282.  
283. '--Bank 2: Group box2
284. t0 = "BUTTON" + Chr$(0) 'predefined class
285. t1 = "Group box2" + Chr$(0)
286. hwgb2 = CreateWindowExA(0, _Offset(t0), _Offset(t1), WS_VISIBLE Or WS_CHILD Or BS_GROUPBOX, 100, 70, 300, 50, hw, 0, hi, 0): If 0 = hwgb2 Then System
287. t1 = "Radio 21" + Chr$(0)
288. hwr21 = CreateWindowExA(0, _Offset(t0), _Offset(t1), WS_VISIBLE Or WS_CHILD Or BS_AUTORADIOBUTTON Or WS_TABSTOP Or WS_GROUP, 105, 90, 90, 23, hw, 0, hi, 0): If 0 = hwr21 Then System
289. t1 = "Radio 22" + Chr$(0)
290. hwr22 = CreateWindowExA(0, _Offset(t0), _Offset(t1), WS_VISIBLE Or WS_CHILD Or BS_AUTORADIOBUTTON, 200, 90, 90, 23, hw, 0, hi, 0): If 0 = hwr22 Then System
291. t1 = "Radio 23" + Chr$(0)
292. hwr23 = CreateWindowExA(0, _Offset(t0), _Offset(t1), WS_VISIBLE Or WS_CHILD Or BS_AUTORADIOBUTTON, 300, 90, 90, 23, hw, 0, hi, 0): If 0 = hwr23 Then System
293.  
294. '--Label1
295. t0 = "STATIC" + Chr$(0) 'predefined class
296. t1 = "Label1 Enter your score:" + Chr$(0)
297. hwLabel1 = CreateWindowExA(0, _Offset(t0), _Offset(t1), WS_VISIBLE Or WS_CHILD, 100, 125, 372, 16, hw, 0, hi, 0): If 0 = hwLabel1 Then System
298.  
299. '--Label2
300. t0 = "STATIC" + Chr$(0) 'predefined class
301. t1 = "Label2 Enter your name:" + Chr$(0)
302. hwLabel2 = CreateWindowExA(0, _Offset(t0), _Offset(t1), WS_VISIBLE Or WS_CHILD, 100, 142, 372, 16, hw, 0, hi, 0): If 0 = hwLabel2 Then System
303.  
304. '--Edit single line
305.  
306. t0 = "EDIT" + Chr$(0) 'predefined class
307. t1 = "This is a edit control." + Chr$(0)
308. hwe1 = CreateWindowExA(WS_EX_CLIENTEDGE, _Offset(t0), _Offset(t1), WS_TABSTOP Or WS_VISIBLE Or WS_CHILD Or ES_LEFT, 12, 175, 372, 26, hw, 0, hi, 0): If 0 = hwe1 Then System
309.  
310. '---Edit  multiline control
311.  
312. t0 = "EDIT" + Chr$(0) 'predefined class
313. t1 = "This is a" + CrLf + "multiline edit control." + CrLf + "Click in me and type." + CrLf + "It should scroll automatically in both directions, but there aren't any scroll bars." + CrLf + "Close the window to see the text printed to the console." + Chr$(0)
314. hwe2 = CreateWindowExA(WS_EX_CLIENTEDGE, _Offset(t0), _Offset(t1), WS_VSCROLL Or WS_HSCROLL Or WS_TABSTOP Or WS_VISIBLE Or WS_CHILD Or ES_AUTOHSCROLL Or ES_AUTOVSCROLL Or ES_LEFT Or ES_MULTILINE Or ES_WANTRETURN, 10, 210, 400, 120, hw, 0, hi, 0): If 0 = hwe2 Then System
315.  
316. '---List box control
317. Const LBS_NOTIFY = 1
318. t0 = "LISTBOX" + Chr$(0) 'predefined class
319. hwLB = CreateWindowExA(WS_EX_CLIENTEDGE, _Offset(t0), 0, WS_CHILD Or WS_VISIBLE Or LBS_NOTIFY Or WS_VSCROLL Or ES_AUTOVSCROLL, 10, 340, 150, 120, hw, 0, hi, 0): If 0 = hwLB Then System
320.  
321. '---Combo drop-down List control
322. Const CBS_READONLY = &H1000 'Remove to edit selection
323. Const CBS_NOTIFY = &H0008
324. Const CBS_DROPDOWN = 2
325. Const CBS_DROPDOWNLIST = 3
326. t0 = "COMBOBOX" + Chr$(0) 'predefined class
327. hwCB = CreateWindowExA(WS_EX_CLIENTEDGE, _Offset(t0), 0, WS_CHILD Or WS_VISIBLE Or CBS_DROPDOWNLIST Or CBS_READONLY, 170, 340, 150, 110, hw, 0, hi, 0): If 0 = hwCB Then System
328.  
329. '--hwCB Add items to combo box
330. Const CB_ADDSTRING = 323
331. Dim j As Long
332. For j = 1 To 10
333.     t0 = "Combo box Item" + Str$(j) + Chr$(0)
334.     discardp = SendMessageA(hwCB, CB_ADDSTRING, 0, _Offset(t0)) ' Add text
335. Next
336. '--End hwCB Add items to combo box
337.  
338. '--hwCB Initialize combo control default selection. Note -1 no selection
339. Dim Shared CB_selected_item As Long 'Ref selection
340. CB_selected_item = 7 'set initial selection value
341.  
342. 'Zero index. Note index 2 selects the third element
343. Const CB_SETCURSEL = 334 'Set selection
344. discardp = SendMessageA(hwCB, CB_SETCURSEL, CB_selected_item, 0)
345. 'discardp = SendMessageA(hwCB, CB_SETCURSEL, -1, 0) 'No selection
346. '---End combo control
347.  
348.  
349. '--hwLB Add items to list box
350. Const LB_ADDSTRING = &H180
351. Dim i As Long
352. For i = 1 To 10
353.     t0 = "List Box Item" + Str$(i) + Chr$(0)
354.     discardp = SendMessageA(hwLB, LB_ADDSTRING, 0, _Offset(t0)) ' Add text
355. Next
356. '--End hwLB Add items to list box
357.  
358. '--hwLB Initialize list control default selection. Note -1 no selection
359. 'Zero index. Note index 2 selects the third element
360. Const LB_SETCURSEL = &H186 'Set selection
361. Dim Shared LB_selected_item As Long 'Ref selection
362. LB_selected_item = 8 'set initial selection value
363. discardp = SendMessageA(hwLB, LB_SETCURSEL, LB_selected_item, 0)
364. 'discardp = SendMessageA(hwLB, LB_SETCURSEL, -1, 0) 'No selection
365. '---End list control
366.  
367. '--Initialize set initial conditions
368. discardp = SendMessageA(hwcb1, BM_SETCHECK, BST_CHECKED, 0) 'Set check box
369. discardp = SendMessageA(hwr13, BM_SETCHECK, BST_CHECKED, 0) 'Set radio button
370. discardp = SendMessageA(hwr23, BM_SETCHECK, BST_CHECKED, 0) 'Set radio button
371.  
372. t0 = "CLOSE" + Chr$(0) '  Text to send to buttton Button2
373. 'discardp = SetWindowTextA&(hwb2, _Offset(t0)) '             Method 1 Change button text from Button2 to Close
374. discardp = SendMessageA(hwb2, WM_SETTEXT, 0, _Offset(t0)) '  Method 2 Alternative
375.  
376. t0 = "Label2 text changed ?" + Chr$(0) '    Text to send to Label2
377. 'discardp = SetWindowTextA&(hwLabel2, _Offset(t0)) '             Method 1
378. discardp = SendMessageA(hwLabel2, WM_SETTEXT, 0, _Offset(t0)) ' Method 2 Alternative
379.  
380. t0 = "Edit control:" + Chr$(0) '             Text to send to Edit control
381. 'discardp = SetWindowTextA&(hwe1, _Offset(t0)) '            Method 1
382. discardp = SendMessageA(hwe1, WM_SETTEXT, 0, _Offset(t0)) ' Method 2 Alternative
383.  
384. 'discardp = SendMessageA(hwe1, EM_SETPASSWORDCHAR, 0, 0) '        Edit control Remove password character
385. 'discardp = SendMessageA(hwe1, EM_SETPASSWORDCHAR, Asc("*"), 0) ' Edit control Set password character
386.  
387. 'Dim Shared winstyle As Long 'current window style variable
388. Const GWL_STYLE = -16 'Window style command
389.  
390. 'winstyle = GetWindowLongA(hwe1, GWL_STYLE)
391. 'discardp = SetWindowLongA(hwe1, GWL_STYLE, winstyle Or ES_NUMBER) '     Add number style
392.  
393. 'winstyle = GetWindowLongA(hwe1, GWL_STYLE)
394. 'discardp = SetWindowLongA(hwe1, GWL_STYLE, winstyle And Not ES_NUMBER) 'Remove number style
395.  
396. '--End Initialize set initial conditions
397.  
398. '----How to set top/bottom margins of a Win32 Edit control "hwe2"
399. Declare CustomType Library
400.     Function GetWindowRect& (ByVal hWnd As _Offset, Byval lpRect As _Offset)
401.     Function GetClientRect& (ByVal hWnd As _Offset, Byval lpRect As _Offset)
402.     Function InflateRect& (ByVal lpRect As _Offset, Byval x As Long, Byval y As Long)
403. End Declare
404. Type RECT
405.     As Long left, top, right, bottom
406. End Type
407. Dim As RECT rect
408. Const EM_SETRECT = &H00B3
409. If GetClientRect(hwe2, _Offset(rect)) Then
410.     Print rect.left, rect.top, rect.right, rect.bottom
411.  
412.     If InflateRect(_Offset(rect), -5, -5) Then
413.         Print rect.left, rect.top, rect.right, rect.bottom
414.         ' Edit control set margin
415.         If SendMessageA(hwe2, EM_SETRECT, 0, _Offset(rect)) Then ' Edit control set margin
416.             Print "margin set hwe2"
417.         End If
418.     End If
419. End If
420.  
421.  
422. 'Display and Update window to ensure it has properly redrawn itself on the screen.
423. discardb = ShowWindow(hw, SW_SHOWDEFAULT)
424. discardb = UpdateWindow(hw)
425.  
426. '-- Step 3: The Message Loop
427. While GetMessageA(_Offset(msg), 0, 0, 0) > 0 '   gets a message from your application's message queue.
428.     discardb = TranslateMessage(_Offset(msg)) '  performs some additional processing on keyboard events
429.     discardp = DispatchMessageA(_Offset(msg)) '  sends the message out to the window that the message was sent to
430. Wend
431.  
432.  
433. Print "End"
434. End
435. System
436. '####== End program ==###
437.  
438. '-- Step 4: the Window Procedure
439. Function WindowProc%& (hWnd As _Offset, uMsg As _Unsigned Long, wParam As _Unsigned _Offset, lParam As _Offset)
440.     Dim As String a, srch, replace
441.  
442.     Select Case uMsg
443.  
444.         ' Case WM_CREATE
445.         '     WindowProc = 0
446.  
447.         Case WM_CLOSE
448.             discardp = SendMessageA(hwe2, WM_GETTEXT, Len(buf2), _Offset(buf2)) 'Get text
449.             Print: Print "First part of the edit control text:": Print
450.  
451.             a$ = _Trim$(buf2) '                      Remove spaces
452.             a$ = Left$(a$, InStr(a$, Chr$(0)) - 1) ' Buffer contains a null terminated string. Find position of null.
453.             buf2 = "" '                              Extract characters upto this null character. Clear buffer
454.  
455.             '----Remove unwanted CRLF---
456.             srch$ = Chr$(13) + Chr$(10)
457.             replace$ = Chr$(10)
458.             Do While InStr(a$, srch$)
459.                 a$ = Mid$(a$, 1, InStr(a$, srch$) - 1) + replace$ + Mid$(a$, InStr(a$, srch$) + Len(srch$))
460.             Loop
461.             '-----END remove-------------
462.  
463.  
464.             Print a$
465.  
466.             Print "Radio 11: 0x"; Hex$(SendMessageA(hwr11, BM_GETCHECK, 0, 0))
467.             Print "Radio 12: 0x"; Hex$(SendMessageA(hwr12, BM_GETCHECK, 0, 0))
468.             If SendMessageA(hwcb1, BM_GETCHECK, 0, 0) = BST_CHECKED Then
469.                 Print: Print "Check box is checked:": Print
470.             End If
471.  
472.  
473.             DestroyWindow (hWnd) 'Destroy window and child windows
474.             WindowProc = 0
475.  
476.         Case WM_DESTROY
477.             PostQuitMessage 0 'Want to exit the program
478.             WindowProc = 0
479.  
480.         Case WM_COMMAND
481.             '===============
482.  
483.             '---Respond to Listbox selection
484.             Const LBN_SELCHANGE = 1
485.             Const LB_GETCURSEL = &H188 ' get index of currently selected item in listbox
486.             Const LB_GETTEXT = &H189 '   get selected item text
487.  
488.             Dim LBwParm As Long
489.             Dim selectedIndexLB As _Offset 'item selected returned as offset
490.             Dim tempLB As Long '            temp variable
491.             Dim textBuffLB As String * 32 ' Buffer to store selected string
492.  
493.             LBwParm = ConvertOffset&&(wParam) ' Convert to long
494.  
495.             'listbox hwLB selection changed
496.             If (HIWORD(LBwParm) = LBN_SELCHANGE) And (lParam = hwLB) Then
497.                 selectedIndexLB = SendMessageA(hwLB, LB_GETCURSEL, 0, 0) 'Get current selection
498.                 tempLB = ConvertOffset&&(selectedIndexLB) '               convert to long
499.                 '--Get item text store in buffer
500.                 discardp = SendMessageA(hwLB, LB_GETTEXT, tempLB, _Offset(textBuffLB))
501.  
502.                 Print "LBzzzzzzz", LBwParm, HIWORD(LBwParm)
503.                 Print "List box selection = "; tempLB
504.                 Print textBuffLB
505.                 WindowProc = 0
506.             End If
507.             '---End Respond to Listbox selection
508.  
509.  
510.             '---Respond to Combo Listbox selection
511.             Const CBN_SELCHANGE = 1
512.             Const CB_GETCURSEL = 327 ' get index of currently selected item in combo listbox
513.             Const CB_GETLBTEXT = 328 ' get selected item text
514.  
515.             Dim CBwParm As Long
516.             Dim selectedIndexCB As _Offset 'item selected returned as offset
517.             Dim tempCB As Long '            temp variable
518.             Dim textBuffCB As String * 32 ' Buffer to store selected string
519.  
520.             CBwParm = ConvertOffset&&(wParam) 'Convert to long
521.  
522.             'Combo listbox hwCB selection changed
523.             If (HIWORD(CBwParm) = CBN_SELCHANGE) And (lParam = hwCB) Then
524.                 selectedIndexCB = SendMessageA(hwCB, CB_GETCURSEL, 0, 0) 'Get current selection
525.                 tempCB = ConvertOffset&&(selectedIndexCB) '               convert to long
526.                 '--Get item text store in buffer
527.                 discardp = SendMessageA(hwCB, CB_GETLBTEXT, tempCB, _Offset(textBuffCB))
528.  
529.                 Print "CBxxxxxx", LBwParm, HIWORD(LBwParm)
530.                 Print "Combo box selection = "; tempCB
531.                 Print textBuffCB
532.                 WindowProc = 0
533.             End If
534.             '---End Respond to Combo Listbox selection
535.  
536.  
537.             '=====================
538.             If wParam = BN_CLICKED Then
539.                 Select Case lParam
540.                     'A button was clicked test each one
541.  
542.                     '---Three standard buttons---
543.                     Case hwb0
544.                         Print "Button 0 pressed"
545.                         WindowProc = 0
546.                     Case hwb1
547.                         'Get input text and copy to buffer (1)
548.  
549.                         discardp = SendMessageA(hwe1, WM_GETTEXT, Len(buf1), _Offset(buf1)) 'Read text from Edit control into buf1
550.                         Print "Button 1 pressed"
551.                         a$ = Left$(buf1, InStr(buf1, Chr$(0)) - 1) 'Buffer contains a null terminated string. Find position of null.
552.                         Print "Button 1 pressed. Text read from edit control: ### " + a$ + " ###" '                  Extract characters upto this null character.
553.                         buf1 = "" '                                 Clear buffer
554.  
555.                         WindowProc = 0
556.                     Case hwb2
557.                         Print "Button 2 pressed Also used as close button"
558.                         discardp = PostMessageA(hWnd, WM_CLOSE, 0, 0) 'Use a button close Close
559.                         WindowProc = 0
560.                         '---End standard buttons---
561.  
562.                         '---Three checkbox standard buttons---
563.                     Case hwcb0
564.                         Print "Check box 0 click"
565.                         If SendMessageA(hwcb0, BM_GETCHECK, 0, 0) = BST_CHECKED Then
566.                             Print "Check box 0 is checked:"
567.                         Else
568.                             Print "Check box 0 is un-checked:"
569.                         End If
570.                         WindowProc = 0
571.                     Case hwcb1
572.                         Print "Check box 1 click"
573.                         WindowProc = 0
574.                     Case hwcb2
575.                         Print "Check box 2 click"
576.                         WindowProc = 0
577.                         '---End checkbox standard buttons---
578.  
579.                         '---Bank 1 - Radio buttons---
580.                     Case hwr11
581.                         Print "Radio 11 clicked"
582.                         WindowProc = 0
583.                     Case hwr12
584.                         Print "Radio 12 clicked"
585.                         WindowProc = 0
586.                     Case hwr13
587.                         Print "Radio 13 clicked"
588.                         WindowProc = 0
589.                         '---End Bank 1 - Radio buttons---
590.  
591.                         '---Bank 2 - Radio buttons---
592.                     Case hwr21
593.                         Print "Radio 21 clicked"
594.                         If SendMessageA(hwr21, BM_GETCHECK, 0, 0) = BST_CHECKED Then
595.                             Print: Print "Button Radio 21 is checked:": Print
596.                         End If
597.                         WindowProc = 0
598.                     Case hwr22
599.                         Print "Radio 22 clicked"
600.                         WindowProc = 0
601.                     Case hwr23
602.                         Print "Radio 23 clicked"
603.  
604.                         '---End Bank 2 - Radio buttons---
605.  
606.                 End Select
607.             Else
608.                 'Not our message send back to system for processing
609.                 WindowProc = DefWindowProcA(hWnd, uMsg, wParam, lParam)
610.             End If
611.  
612.             WindowProc = DefWindowProcA(hWnd, uMsg, wParam, lParam)
613.         Case Else
614.             'Not our message send back to system for processing
615.             WindowProc = DefWindowProcA(hWnd, uMsg, wParam, lParam)
616.     End Select
617. End Function
618.  
619. Function ConvertOffset&& (value As _Offset)
620.     Dim m As _MEM 'Define a memblock
621.     m = _Mem(value) 'Point it to use value
622.     $If 64BIT Then
623.         Dim temp As _Integer64
624.         'On 64 bit OSes, an OFFSET is 8 bytes in size.  We can put it directly into an Integer64
625.         _MemGet m, m.OFFSET, temp
626.         ConvertOffset = temp
627.     $Else
628.         Dim temp As Long
629.         'However, on 32 bit OSes, an OFFSET is only 4 bytes.  We need to put it into a LONG variable first
630.         _MemGet m, m.OFFSET, temp 'Like this
631.         ConvertOffset = temp 'And then assign that long value to ConvertOffset&&
632.     $End If
633.     _MemFree m 'Free the memblock
634. End Function
635.  
636. Function HIWORD% (dw As Long)
637.     If dw And &H80000000 Then
638.         HIWORD = (dw \ 65535) - 1
639.     Else
640.         HIWORD = dw \ 65535
641.     End If
642. End Function
643.  
644. Function LOWORD% (dw As Long)
645.     If dw And &H8000& Then
646.         LOWORD = &H8000 Or (dw And &H7FFF&)
647.     Else
648.         LOWORD = dw And &HFFFF&
649.     End If
650. End Function
651.  

WIN.h

Code: QB64: [Select]

1. ptrszint FUNC_WINDOWPROC(ptrszint*_FUNC_WINDOWPROC_OFFSET_HWND,uint32*_FUNC_WINDOWPROC_ULONG_UMSG,uptrszint*_FUNC_WINDOWPROC_UOFFSET_WPARAM,ptrszint*_FUNC_WINDOWPROC_OFFSET_LPARAM);
2.  
3. LRESULT CALLBACK WindowProc(HWND hwnd, UINT uMsg, WPARAM wParam, LPARAM lParam) {
4.  return FUNC_WINDOWPROC((ptrszint *) (& hwnd), & uMsg, & wParam, (ptrszint *) (& lParam));
5. }
6.  
7. void * GetWindowProc() {
8.  return (void *) WindowProc;
9. }
10.  

Result shown below:
 

Note: For an example of subclassing a control see the edit control on the following page: https://www.qb64.org/forum/index.php?topic=4111.msg136749#msg136749

[SpriggsySpriggs]

You're doing excellent work, @mpgcan !

[bplus]

Wow multi-line edit control, my holy grail! So is this like GUI in about 1K LOC?

[bplus]

I am trying out code way over my head, what's this about?

In file included from ..\\temp\\regsf.txt:1,
                 from qbx.cpp:1131:
..\\temp\\..\\..\\win.h: In function 'LRESULT WindowProc(HWND, UINT, WPARAM, LPARAM)':
..\\temp\\..\\..\\win.h:4:2: error: 'RETURN' was not declared in this scope
  RETURN FUNC_WINDOWPROC((ptrszint *) (& hwnd), & uMsg, & wParam, (ptrszint *) (& lParam));
  ^~~~~~
compilation terminated due to -Wfatal-errors.

[FellippeHeitor]

mpg can added the c++ code above in a QB64 code box, which turned "return" into "RETURN". That's the problem.

[Petr]

@mpgcan

This is absolutely famous. Perfect. Useful. As soon as I finish my work, I will study your code. The first compilation did not work correctly because the C ++ code for the win.h file is inserted as QB64 source code and has been formatted, which is not possible because C ++ is known to be case sensitive. I had to take a source block in C ++ in the source code with QB64 and uncomment it in the editor and then save it as win.h

Then the compilation went smoothly in the latest IDE QB64 2.0

Good job. Thanks for sharing.

[bplus]

Holy controls! I can copy/paste from Multi-Edit Control to here!!!

Hi Petr and Fellippe, thanks to your clues
I got this baby going!
I am very pleased to see this control works.
Now how do I get these contents into my QB64 program?
And what is the Console Screen telling me?

 

[bplus]

PS how do you like my new IDE colors for V2.0?

[Petr]

@bplus wrote:

PS how do you like my new IDE colors for V2.0?

You have it nice :) i use dark blue scheme.

[Aurel]

Very nice...
It looks to me like when i started to work on my windows include "awinh.inc" read same as .h files
ok..i am going to testing...

[bplus]

I see too much blue already hanging out with johnn56 ;-))

@Petr thanks to your help, I tried the input_box again from what I learned here and got that going too!

I have learned along with .h files, .BI and .BM files can be stored in QB64.exe folder and source bas like the dem,bas file in separate folder bare naked, no support un-pathed .BI and .BM, and no need to path those either.

[Aurel]

The first compilation did not work correctly because the C ++ code for the win.h file is inserted as QB64 source code and has been formatted, which is not possible because C ++ is known to be case sensitive. I had to take a source block in C ++ in the source code with QB64 and uncomment it in the editor and then save it as win.h

I saved C++ code as win.h...but compilation still not work ...
i will try with lower case win.h..to see is that problem ..hmmm

[Aurel]

oh gee i don't get it C++
ahh i see i need to add return in lower case
( i am not sure that C have return but ok )

now is compiled..!!

[Aurel]

oh..this is a type of programming i am familiar with
cool it work well...if i catch time i will try to add richEdit
(i am not sure but it looks that is used old WindowClassA older version but work)

[bplus]

@Aurel you have an AurelEdit version for QB64? well from screen shot I guess so. :)