Estimated Blood Alcohol Calculator (LINUX/Zenity Only)

[George McGinn]

This program was originally written by me in Objective-C for mobile devices. That is until Apple decided to ban all these programs from the iTunes store. (From their 6/7 update: 4.3: Added drinking game apps as a saturated category.).

After learning Zenity, I decided to convert this program to QB64 and give this GUI a test, and I am pleased with the results.

Back when I was a police officer, this formula, in a more advanced form, was used by defense attorneys in the 70's through parts of the 90's when defending their clients on DUI charges. I can tell you that a breathlizer does not accurately measure blood alcohol content, a requirement to convict someone in court. What it does measure is the amount of alcohol that is leaving the body. Which is why the must draw blood to get an accurate BAC figure, which is done today, but wasn't standard back when I was in law enforcement.

I offer this program as a novelty, and if you host parties, you could use it to guide your decision on guests who may drink too much. I do. However, remember that when I created this, I used only the averages for males and females. Many factors are specific to an individual such as metabolism rate, which your doctor can tell you what it is after conducting tests. The comments in the program and the help file lists some of the many factors that are not considered by this program.

The program itself is well documented and lots of comments to help anyone looking to understand how Zenity works with QB64. I use both pipecom and SHELL to serve the GUI, and I am using most of the funtionality of Zenity with some exceptions.

This program will only run on Linux. I have a version for all platforms that uses the QB64 screen for input and output. I will post this program seperately.

To run this program, there is a HELP file that must be loaded in the same directory as the binary executable. The program, due to the constraints of Zenity's Text Information Dialog, the output into the GUI can only come from this file. Also, the program will write out the results of the calculation to a temporary file called "tempfile" that resides in the same directory as the executable. The program removes this file when it ends. If the file somehow exists when the program starts, it will be replaced. So make sure you do not have a file by that name in the directory you plan to run this.

Attached to this post is a compressed file that has both the source code and the help file. I also have the latest pipecom utility by Spriggs in this archive as well. This is for those who do not want to cut/paste a 400+ line program (150 lines consists of the comments at the beginning of the program).

Since this may still be a commercially viable program for me (in that I plan to market it for free), it is provided under the Creative Commons Attribution License. You are free to do what you want with it as long as: 1) I am credited with it, and 2) For your protection, keep the disclaimer intact.

Enjoy. Those who wish to learn about Zenity will find this program very educational.


*** You can find the latest version of Pipecom here: https://www.qb64.org/forum/index.php?topic=3641.msg129938#msg129938

Code: QB64: [Select]

1. _TITLE "ebacCalculator.bas"
2. '------------------------------------------------------------------------------------------------
3. ' EBAC Calculator v1.0 by George McGinn, APRIL, 2021
4. ' Copyright (C)2021 by George McGinn
5. '                      All Rights Reserved.
6. '
7. ' 6/19/2021 - Updated To use Zenity and SHELL commands to run on Linux with a simple GUI. (GJM)
8. '
9. ' Original code designed to run as an App in iTunes to run specifically
10. ' on an iPhone so those who would like to know their esitmate BAC and
11. ' how long it will take to get to a level to drive safely and legally.
12. '
13. ' Modified to run on the Desktop for use at home. You can judge the amount of drinks your guests
14. ' have had and use this program to help in deciding who can drive and approximately how long
15. ' someone needs to wait before they could possibly drive.
16. '
17. ' *** There is no warranty (See Disclaimer) as to the fitness or accuracy of the results.
18. ' *** While every effort has been made to provide accurate results, other factors not considered
19. ' *** also play a role in determining one's Blood Alcohol Content.
20. '
21. ' Blood alcohol content (BAC) can be estimated by a method developed by Swedish professor
22. ' Erik Widmark in the 1920s.
23. '
24. ' Gives the estimated BAC (EBAC), algorhithm reduced as:
25. '    EBAC=A/(r*Wt)*1.055-B*T (verified by Wiki source listed below)
26. ' Where:
27. '    EBAC: Estimated Blood Alcohol Content (%)
28. '        A: Alcohol consumed (in ounces to grams) or FLoz
29. '        r: Ratio of body water to total weight (men: .68, women: .55)
30. '      Wt: Body weight (in pounds to kilograms)
31. '        B: Rate alcohol metabolized (men: .019/hr, women: .017/hr)
32. '        T: Time alcohol in blood or time since consumption began
33. '    1.055: Constant value of density of blood
34. '
35. ' The formula can also be reduced as follows (called the 8/10 formula):
36. '    For Men:   EBAC = 7.97*A/Wt-B*T
37. '    For Women: EBAC = 9.86*A/Wt-B*T
38. '
39. ' Factors 7.97 and 9.86 are derived from "r" and 1.055 among other factors.
40. ' Also, this formula is geared to fluid ounces and pounds, not
41. ' grams and kilograms. While the suggested values were 8 and 10,
42. ' testing showed the results were not accurate. So I reworked it
43. ' and found that 7.97 and 9.86 gives better results.
44. '
45. ' It will be this reduced formula the program will use.
46. '
47. ' Each shot, wine glass and bottle/can of beer contains .6oz of
48. ' alcohol. User records the number of drinks, which will then be
49. ' converted to ounces (drinks * .6)
50. '
51. ' *** Formulas created/translated by George McGinn using the following sources:
52. '    * Blood alcohol content can be estimated by a method developed
53. '      by Swedish professor Erik Widmark [sv] in the 1920s.
54. '      (https://web.archive.org/web/20031202155933/http://www.dui-law.com/810art.htm)
55. '    * https://www.ou.edu/police/faid/blood-alcohol-calculator
56. '    * https://www.gambonelaw.com/faqs/the-widmark-formula-and-calculating-your-bac-level/
57. '    * https://en.wikipedia.org/wiki/Blood_alcohol_content
58. '    * https://en.wikipedia.org/wiki/Binge_drinking
59. '    * https://en.wikipedia.org/wiki/Alcohol_intoxication
60. '    * https://en.wikipedia.org/wiki/Breathalyzer
61. '    * https://ndaa.org/wp-content/uploads/toxicology_final.pdf
62. '    * http://njlaw.rutgers.edu/collections/courts/supreme/a-96-06.doc.html
63. '    * https://www.researchgate.net/profile/Alan-Jones-14/publication/318055507_Profiles_in_Forensic_Toxicology_Professor_Erik_Widmark_1889-1945/links/595794330f7e9ba95e0fd91d/Profiles-in-Forensic-Toxicology-Professor-Erik-Widmark-1889-1945.pdf?origin=publication_detail
64. '    * https://www.cdc.gov/alcohol
65. '------------------------------------------------------------------------------------------------
66. '
67. ' PROGRAM NOTES:
68. ' --------------
69. ' This blood alcohol content or BAC, for short, calculator can estimate
70. ' your blood alcohol levels. Metabolism, body fat percentage and
71. ' medication are some of the other factors that can affect the rate of absorption
72. ' by the body, and these are not considered in this calculation.
73. '
74. ' Blood alcohol content (BAC) or blood alcohol level is the
75. ' concentration of alcohol in the bloodstream. It is usually measured
76. ' as mass per volume. For example, a Blood alcohol content BAC of
77. ' 0.04% means 0.4% (permille) or 0.04 grams of alcohol per 100 grams
78. ' of individuals blood. Use this BAC Calculator for informational
79. ' purposes only, and not to drink and drive or drink and work.
80. '
81. ' Important Note: There is no BAC calculator that is 100% accurate.
82. ' This is due to the number of factors that come into play regarding
83. ' the consumption and alcohol processing rates of different people.
84. ' Other factors not considered here include:
85. '    * Overall health and wellness
86. '    * Body type
87. '    * Metabolism (Program uses an Average for Males & Females)
88. '    * Alcohol tolerance
89. '    * What kind of alcohol is consumed (Program uses average drink of 40% ETOH)
90. '    * Medications
91. '    * Amount of food eaten
92. '    * Emotional, mental state
93. '
94. ' The best that can be done is a rough estimation of the
95. ' bloodstreams alcohol content or the BAC level based on known inputs.
96. '
97. ' Every state in the U.S. has a legal Blood Alcohol (BAC) limit of 0.05% or 0.08%,
98. ' (depending on the state you are driving in). Most states also have lower legal
99. ' BAC limits for young and inexperienced drivers, professional drivers and commercial
100. ' drivers. Sentences for drunk driving include imprisonment, large fines, lengthy drivers
101. ' license suspension and/or revocation, house arrest, community service, DUI schools,
102. ' alcohol treatment programs, vehicle forfeiture and ignition interlock restrictions.
103. '
104. '------------------------------------------------------------------------------------------------
105. ' Program Copyright (C)2021 by George McGinn
106. ' All Rights Reserved.
107. '
108. ' EBAC Calculator by George McGinn is licensed under a Creative Commons
109. ' Attribution-NonCommercial 4.0 International License.
110. '
111. ' Full License Link: https://creativecommons.org/licenses/by-nc/4.0/
112. '
113. '
114. ' You are free to (For non-commerical purposes only):
115. '     Share          - copy and redistribute the material in any medium or format.
116. '     Adapt          - remix, transform, and build upon the material.
117. '     Attribution    - You must give appropriate credit, provide a link to
118. '                      the license, and indicate if changes were made. You may do so in any
119. '                      reasonable manner, but not in any way that suggests the licensor
120. '                      endorses you or your use.
121. '     Non Commercial - You may not use the material for commercial purposes.
122. '
123. ' *** None of this code is considered in the Public Domain. Rights granted under CC 4.0
124. '     are outlined as above and the disclaimer below:
125. '
126. ' *** DISCLAIMER ***
127. ' Unless otherwise separately undertaken by the Licensor, to the extent possible,
128. ' the Licensor offers the Licensed Material as-is and as-available, and makes no
129. ' representations or warranties of any kind concerning the Licensed Material, whether
130. ' express, implied, statutory, or other. This includes, without limitation, warranties
131. ' of title, merchantability, fitness for a particular purpose, non-infringement, absence
132. ' of latent or other defects, accuracy, or the presence or absence of errors, whether or
133. ' not known or discoverable. Where disclaimers of warranties are not allowed in full or
134. ' in part, this disclaimer may not apply to You.
135. '
136. ' To the extent possible, in no event will the Licensor be liable to You on any legal theory
137. ' (including, without limitation, negligence) or otherwise for any direct, special, indirect,
138. ' incidental, consequential, punitive, exemplary, or other losses, costs, expenses, or damages
139. ' arising out of this Public License or use of the Licensed Material, even if the Licensor has
140. ' been advised of the possibility of such losses, costs, expenses, or damages. Where a limitation
141. ' of liability is not allowed in full or in part, this limitation may not apply to You.
142. '
143. ' The disclaimer of warranties and limitation of liability provided above shall be interpreted
144. ' in a manner that, to the extent possible, most closely approximates an absolute disclaimer and
145. ' waiver of all liability.
146. '------------------------------------------------------------------------------------------------
147.  
148.  
149. '--------------------------------
150. '*** Initialize
151.  
152. '*** If You comment the line below out, you will see the [DEBUG] PRINT statements in the QB64 Window. You can add your own PRINT statements if needed
153. $SCREENHIDE
154. SCREEN _NEWIMAGE(500, 700, 32)
155.  
156. DIM SHARED AS INTEGER l
157. DIM SHARED AS DOUBLE A, T
158. DIM SHARED AS SINGLE B, OZ, Wt
159. DIM SHARED AS SINGLE EBAC
160. DIM SHARED numeric(255)
161. DIM SHARED AS INTEGER TRUE, FALSE, SOBER
162. DIM SHARED Sex AS STRING
163. DIM SHARED AS STRING Weight, Drinks, TimeElapsed
164. DIM SHARED AS STRING cmd, stdout, stderr, stdbutton
165. DIM SHARED AS LONG result
166. DIM SHARED AS STRING prt_text
167.  
168. '--------------------------------
169. '*** Setup NUMERIC Check Table
170. FOR I = 48 TO 57
171.     numeric(I) = -1
172. NEXT
173.  
174. EBACMain:
175. '--------------------------------
176. '*** Setup constant variables
177.     A = 0
178.     Wt = 0
179.     B = .0
180.     T = 0: St = 0
181.     I = 0
182.     Bdl = 1.055
183.     OZ = .5
184.     TRUE = -1: FALSE = 0
185.     SOBER = FALSE
186.  
187.  
188. EBACForm:
189. '--------------------------------
190. '*** Produce the Input Form
191.     stdout = ""
192.     cmd = "zenity --forms --title=" + CHR$(34) + "EBAC Blood Alcohol Calculator" + CHR$(34) + _
193.           " --text=" + CHR$(34) + "Enter information about your friend." + CHR$(34) + _
194.           " --add-entry=" + CHR$(34) + "Sex (M or F)" + CHR$(34) + _
195.           " --add-entry=" + CHR$(34) + "Weight (lbs)" + CHR$(34) + _
196.           " --add-entry=" + CHR$(34) + "Number of drinks" + CHR$(34) + _
197.           " --add-entry=" + CHR$(34) + "Time (hrs) from first drink" + CHR$(34) + _
198.           " --extra-button=HELP --extra-button=QUIT"
199.  
200.     result = pipecom(cmd, stdout, stderr)
201.  
202.     stdbutton = LEFT$(stdout, 4)
203.  
204.     IF result = 1 AND stdbutton = "QUIT" THEN GOTO endPROG
205.  
206.     IF result = 1 AND stdbutton = "HELP" THEN
207.         cmd = "zenity --text-info " + _
208.               " --title=" + CHR$(34) + "HELP/ABOUT: EBAC Calculator" + CHR$(34) + _
209.               " --filename=" + "EBACHelp.txt" + _
210.               " --width=525 --height=600"
211.         SHELL (cmd)
212.         GOTO EBACForm
213.     END IF
214.  
215.     IF result <> 0 THEN
216.         SHELL ("zenity --error --text=" + CHR$(34) + "Main Form did not load. Program Terminated." + CHR$(34) + " --width=175 --height=100")
217.         GOTO endPROG
218.     END IF
219.  
220. '----------------------------------------------------------
221. '*** Populate QB64 variables from the form's stdout results
222.  
223. '--------------------------------------------------
224. '*** Get and Validate Sex Input
225.     Sex = MID$(stdout, 1, INSTR(stdout, "|") - 1)
226.     Sex = UCASE$(Sex)
227.     IF Sex <> "M" AND Sex <> "F" THEN
228.         SHELL ("zenity --warning --text=" + CHR$(34) + "SEX must be either M or F." + CHR$(34) + " --width=175 --height=100")
229.         GOTO EBACForm
230.     END IF
231.  
232. '---------------------------------------------------
233. '*** Get and Validate Weight Input
234.     stdout = MID$(stdout, INSTR(stdout, "|") + 1)
235.     Weight = MID$(stdout, 1, INSTR(stdout, "|") - 1)
236.     IF ISNUMERIC(Weight) THEN
237.         Wt = VAL(Weight)
238.     ELSE
239.         SHELL ("zenity --warning --text=" + CHR$(34) + "Weight must be numeric." + CHR$(34) + " --width=175 --height=100")
240.         GOTO EBACForm
241.     END IF
242.  
243.  
244. '-----------------------------------------------------
245. '*** Get and Validate Number of Drinks Input
246.     stdout = MID$(stdout, INSTR(stdout, "|") + 1)
247.     Drinks = MID$(stdout, 1, INSTR(stdout, "|") - 1)
248.     IF ISNUMERIC(Drinks) THEN
249.         A = VAL(Drinks)
250.     ELSE
251.         SHELL ("zenity --warning --text=" + CHR$(34) + "Number of drinks must be numeric." + CHR$(34) + " --width=175 --height=100")
252.         GOTO EBACForm
253.     END IF
254.  
255. '-------------------------------------------------------------------
256. '*** Get and Validate Time Since First Drink (Time Elapsed) Input
257.     TimeElapsed = MID$(stdout, INSTR(stdout, "|") + 1)
258.     l = LEN(TimeElapsed)
259.     TimeElapsed$ = LEFT$(TimeElapsed, l - 1)
260.     IF ISNUMERIC(TimeElapsed) THEN
261.         T = VAL(TimeElapsed)
262.     ELSE
263.         SHELL ("zenity --warning --text=" + CHR$(34) + "Time since first drink must be numeric." + CHR$(34) + " --width=175 --height=100")
264.         GOTO EBACForm
265.     END IF
266.  
267. '--------------------------------------------------------------------------------------------------------
268. '*** Calculate the value of the Estimated Blood Alcohol Content (EBAC) and check for sucessful completion
269.     result = calcEBAC
270.     IF result <> 0 THEN
271.         SHELL ("zenity --error --text=" + CHR$(34) + "Calulating the EBAC results failed. Program Terminated" + CHR$(34) + " --width=175 --height=100")
272.         GOTO endPROG
273.     END IF
274.  
275. '---------------------------------------------------------------------------------------------------------------------------------------------
276. '*** Create a temp file for the Zenity Information Box and write out prt_text (This box cannot have text passed to it unless it is in a file)
277.     OPEN "tempfile" FOR OUTPUT AS #1
278.     PRINT #1, USING "ESTIMATED BLOOD ALCOHOL CONTENT (EBAC) in g/dL = #.###"; EBAC
279.     PRINT #1, prt_text
280.     CLOSE #1
281.  
282. displayEBAC:
283. '------------------------------------------------------------------
284. '*** Prepare the Zenity command and execute, check for good return
285.  
286.     cmd = "zenity --text-info " + _
287.           " --title=" + CHR$(34) + "EBAC Blood Alcohol Calculator" + CHR$(34) + _
288.           " --width=525 --height=400" + _
289.           " --filename=tempfile" + _
290.           " --checkbox=" + CHR$(34) + "I agree that this program and its results are not legally binding." + CHR$(34)
291.  
292.     result = SHELL(cmd)
293.  
294.     IF result = 1 THEN
295.         result = SHELL("zenity --warning --text=" + CHR$(34) + "You must agree to the terms of use. Please check the confirmation box." + CHR$(34) + " --width=175 --height=100")
296.         GOTO displayEBAC
297.     END IF
298.  
299.     result = SHELL("zenity --question --text=" + CHR$(34) + "Do you want to run another calculation?" + CHR$(34) + " --width=175 --height=100")
300.     IF result = 0 THEN
301.         SHELL ("rm tempfile")
302.         GOTO EBACForm
303.     END IF
304.  
305. endPROG:
306.     SHELL ("rm tempfile")
307.     result = SHELL("zenity --info --text=" + CHR$(34) + "Thank You for using EBAC Calculator. Please Don't Drink and Drive." + CHR$(34) + " --width=175 --height=100")
308.     END
309.  
310.  
311. FUNCTION calcEBAC
312. '-------------------------------------------------------------
313. '*** Convert Drinks into Fluid Ounces of EtOH (Pure Alcohol).
314. '*** A is number of drinks. 1 drink is about .6 FLoz of alcohol
315.     FLoz = A * OZ
316.  
317. '-----------------------------------------------------
318. '*** Set/calculate EBAC values based on Sex
319.     SELECT CASE Sex
320.         CASE "M"
321.             B = .017
322.             EBAC = 7.97 * FLoz / Wt - B * T
323.         CASE "F"
324.             B = .019
325.             EBAC = 9.86 * FLoz / Wt - B * T
326.     END SELECT
327.  
328.     IF EBAC < 0 THEN EBAC = 0
329.  
330. '----------------------------------------------------------------------------------------------
331. '*** Populate the EBAC string with the EBAC value formatted to 3 decimal places for FORM output
332. '    prt_text = "ESTIMATED BLOOD ALCOHOL CONTENT (EBAC) in g/dL = " + EBAC_ST$ + CHR$(10) + CHR$(10)
333.     prt_text = "" + CHR$(10)
334.  
335. '-----------------------------------------------------------------------------------------
336. '*** Based on EBAC range values, populate the FORM output string with the approriate text
337.     SELECT CASE EBAC
338.         CASE .500 TO 1.9999
339.             prt_text = prt_text + "*** ALERT: CALL AN AMBULANCE, DEATH LIKELY" + CHR$(10)
340.             prt_text = prt_text + "Unconsious/coma, unresponsive, high likelihood of death. It is illegal to operate a motor vehicle at this level of intoxication in all states."
341.         CASE .400 TO .4999
342.             prt_text = prt_text + "*** ALERT: CALL AN AMBULANCE, DEATH POSSIBLE" + CHR$(10)
343.             prt_text = prt_text + "Onset of coma, and possible death due to respiratory arrest. It is illegal to operate a motor vehicle at this level of intoxication in all states."
344.         CASE .350 TO .3999
345.             prt_text = prt_text + "*** ALERT: CALL AN AMBULANCE, SEVERE ALCOHOL POISONING" + CHR$(10)
346.             prt_text = prt_text + " Coma is possible. This is the level of surgical anesthesia. It is illegal to operate a motor vehicle at this level of intoxication in all states."
347.         CASE .300 TO .3499
348.             prt_text = prt_text + "*** ALERT: YOU ARE IN A DRUNKEN STUP0R, AT RISK TO PASSING OUT" + CHR$(10)
349.             prt_text = prt_text + "STUPOR. You have little comprehension of where you are. You may pass out suddenly and be difficult to awaken. It is illegal to operate a motor vehicle at this level of intoxication in all states."
350.         CASE .250 TO .2999
351.             prt_text = prt_text + "*** ALERT: SEVERLY IMPAIRED - DRUNK ENOUGH TO CAUSE SEVERE INJURY/DEATH TO SELF" + CHR$(10)
352.             prt_text = prt_text + "All mental, physical and sensory functions are severely impaired. Increased risk of asphyxiation from choking on vomit and of seriously injuring yourself by falls or other accidents. It is illegal to operate a motor vehicle at this level of intoxication in all states."
353.         CASE .200 TO .2499
354.             prt_text = prt_text + "YOU ARE EXTREMELY DRUNK" + CHR$(10)
355.             prt_text = prt_text + "Feeling dazed/confused or otherwise disoriented. May need help to stand/walk. If you injure yourself you may not feel the pain. Some people have nausea and vomiting at this level. The gag reflex is impaired and you can choke if you do vomit. Blackouts are likely at this level so you may not remember what has happened. It is illegal to operate a motor vehicle at this level of intoxication in all states."
356.         CASE .160 TO .1999
357.             prt_text = prt_text + "YOUR ARE SEVERLY DRUNK - ENOUGH TO BECOME VERY SICK" + CHR$(10)
358.             prt_text = prt_text + "Dysphoria predominates, nausea may appear. The drinker has the appearance of a 'sloppy drunk.' It is illegal to operate a motor vehicle at this level of intoxication in all states." + CHR$(10) + CHR$(10)
359.             prt_text = prt_text + "* Dysphoria: An emotional state of anxiety, depression, or unease."
360.         CASE .130 TO .1599
361.             prt_text = prt_text + "YOU ARE VERY DRUNK - ENOUGH TO LOSE PHYSICAL & MENTAL CONTROL" + CHR$(10)
362.             prt_text = prt_text + "Gross motor impairment and lack of physical control. Blurred vision and major loss of balance. Euphoria is reduced and dysphoria* is beginning to appear. Judgment and perception are severely impaired. It is illegal to operate a motor vehicle at this level of intoxication in all states." + CHR$(10) + CHR$(10)
363.             prt_text = prt_text + "* Dysphoria: An emotional state of anxiety, depression, or unease."
364.         CASE .100 TO .1299
365.             prt_text = prt_text + "YOU ARE LEGALLY DRUNK" + CHR$(10)
366.             prt_text = prt_text + "Significant impairment of motor coordination and loss of good judgment. Speech may be slurred; balance, vision, reaction time and hearing will be impaired. Euphoria. It is illegal to operate a motor vehicle at this level of intoxication in all states."
367.         CASE .070 TO .0999
368.             prt_text = prt_text + "YOU MAY BE LEGALLY DRUNK" + CHR$(10)
369.             prt_text = prt_text + "Slight impairment of balance, speech, vision, reaction time, and hearing. Euphoria. Judgment and self-control are reduced, and caution, reason and memory are impaired (in some* states .08 is legally impaired and it is illegal to drive at this level). You will probably believe that you are functioning better than you really are." + CHR$(10) + CHR$(10)
370.             prt_text = prt_text + "(*** As of July, 2004 ALL states had passed .08 BAC Per Se Laws. The final one took effect in August of 2005.)"
371.         CASE .040 TO .0699
372.             prt_text = prt_text + "YOU MAY BE LEGALLY BUZZED" + CHR$(10)
373.             prt_text = prt_text + "Feeling of well-being, relaxation, lower inhibitions, sensation of warmth. Euphoria. Some minor impairment of reasoning and memory, lowering of caution. Your behavior may become exaggerated and emotions intensified (Good emotions are better, bad emotions are worse)"
374.         CASE .020 TO .0399
375.             prt_text = prt_text + "YOU MAY BE OK TO DRIVE, BUT IMPAIRMENT BEGINS" + CHR$(10)
376.             prt_text = prt_text + "No loss of coordination, slight euphoria and loss of shyness. Depressant effects are not apparent. Mildly relaxed and maybe a little lightheaded."
377.         CASE .000 TO .0199
378.             prt_text = prt_text + "YOU ARE OK TO DRIVE" + CHR$(10)
379.     END SELECT
380.  
381. '-----------------------------------------------------------
382. '*** Determine if Drunk (>.08 EBAC) and calculate:
383. '***    - When user will be less than .08
384. '***    - How long it will take to become completely sober
385.     IF EBAC > .08 THEN
386.         SOBER = FALSE
387.         CEBAC = EBAC
388.         st = T
389.         DO UNTIL SOBER = TRUE
390.             T = T + 1
391.             IF CEBAC > .0799 THEN I = I + 1
392.  
393.             SELECT CASE Sex
394.                 CASE "M"
395.                     B = .017
396.                     CEBAC = 7.97 * FLoz / Wt - B * T
397.                 CASE "F"
398.                     B = .019
399.                     CEBAC = 9.86 * FLoz / Wt - B * T
400.             END SELECT
401.  
402.             IF legalToDrive = FALSE THEN
403.                 IF CEBAC < .08 THEN
404.                     prt_text = prt_text + CHR$(10) + CHR$(10) + "It will take about " + STR$(I) + " hours from your last drink to be able to drive." + CHR$(10)
405.                     legalToDrive = TRUE
406.                 END IF
407.             END IF
408.  
409.             IF CEBAC <= 0 THEN
410.                 prt_text = prt_text + "It will take about " + STR$(T - st) + " hours from your last drink to be completely sober."
411.                 SOBER = TRUE
412.             END IF
413.         LOOP
414.     END IF
415.  
416. END FUNCTION
417.  
418.  
419. FUNCTION ISNUMERIC (A$)
420. '-----------------------------------------------------
421. '*** Numeric Check of a STRING
422.     l = LEN(A$)
423.     FOR I = 1 TO l
424.         ACODE = ASC(A$, I)
425.         IF numeric(ACODE) THEN
426.             ISNUMERIC = TRUE
427.         ELSE
428.             ISNUMERIC = FALSE
429.             EXIT FUNCTION
430.         END IF
431.     NEXT I
432. END FUNCTION
433.  
434.  
435. '$INCLUDE:'pipecomqb64.bas'
436.  

 

ebacCalculator-qb64.zip

[Craz1000]

In reading your post i have come up with this question. I have never thought about a breathalyzer actually measuring the alcohol actually leaving the body and not what is actually in the blood at the time. So then does this mean that being young vs old puts you at a disadvantage because your body works more efficiently and therefore can remove more alcohol than someone who is older. And if this is the case then i would also imagine an older smoker has a serious advantage in this test while having a much higher BAC level than a fit and healthy 21 year old who is just below the limit but blows higher because their body functions better?

[George McGinn]

Yes. Your metabolism rate changes with age, so in a way, age is another factor. Smoking would fall in the categories of health and even drugs, as nicotine is a drug. So smoking is another factor.

There are too many factors that go into both absorption rate and even the rate that the body removes alcohol, and both rates can be different!

The thing about alcohol level is that no matter how long it takes to metabolize it in to your system, if you drink 4 drinks, you will eventually have 4 drinks in your blood, It all depends on the amount of time it takes to get to that level, and the amount of time it takes for the body to remove it.

Theoretically, if you are in perfect health with average metabolism rates, if you have one drink an hour, you will never get drunk. But that does not happen in real life due to all the other factors involved, including alcohol tolerance.

In reading your post i have come up with this question. I have never thought about a breathalyzer actually measuring the alcohol actually leaving the body and not what is actually in the blood at the time. So then does this mean that being young vs old puts you at a disadvantage because your body works more efficiently and therefore can remove more alcohol than someone who is older. And if this is the case then i would also imagine an older smoker has a serious advantage in this test while having a much higher BAC level than a fit and healthy 21 year old who is just below the limit but blows higher because their body functions better?