StarBlast Game: Shadow Not Translucent

[SirCrow]

I still haven't been able to figure out why my SHIP's shadow is just black and not at all transparent.  All the asteroids have perfect shadows, but not the ship.  Please examine the source and find the image handle Ship_Shade& in lines such as _SETALPHA 120, , Ship_Shade&.  The shadow is drawn onto that 49 x 49 image, which is then placed using _PUTIMAGE.   Alt-S can be used to switch between my orig. version of the ship's shadow and the one in Ship_Shade& -- make sure it's the fully black, unchanging shadow that's currently active (a descending tone should indicate the correct mode).  Oh, and make sure to start the game using F8 on the intro screen.

I'd like to fix the shadow issue and upload the latest version of the game;  but for now, please use the last uploaded version:
https://www.qb64.org/forum/index.php?action=dlattach;topic=347.0;attach=830

If you have the time, please help if you can.  Thank you.

[johnno56]

Might not be easy to fix. Normally I would suggest using a rotate procedure. That would probably be easier than rotating a 'drawn' image. I do not know how to rotate images using QB64. In the meantime, may I suggest, a lighter shadow? Black tends to make it 'stand out'. Perhaps anywhere between _RGB32(64,64,64) and _RGB32(192,192,192)? Just a thought...

J

[bplus]

I don't understand the problem. I run F8 from start and use Alt+S to toggle between a transparent shadow on surface and a solid black one. So it seems you can draw a transparent shadow, so???

Is this the sub code in question?

Code: QB64: [Select]

1. SUB Ship_Shadow
2.  
3.     _DEST Ship_Shade& 'DRAW onto our small Ship Shadow BG image
4.  
5.     DIM C AS _UNSIGNED LONG, C1 AS _UNSIGNED LONG, C2 AS _UNSIGNED LONG, C3 AS _UNSIGNED LONG
6.     ShX = 24: ShY = 24
7.  
8.     PRESET (ShX, ShY) 'Place graphics cursor in centre of Shadow image ---------
9.  
10.     ShadClr& = _RGBA(0, 0, 0, 255) '_RGB(R - SD, G - SD, B - SD) 'Assign colour to Ship's shadow on Planet's surface
11.  
12.     CLS , _RGBA(255, 255, 255, 0)
13.  
14.     '@@@@@@@@@@@@@@@@@@@@@@@@@@@
15.     DRAW "TA=" + VARPTR$(Angle) 'Set the angle based on Ship's Angle
16.     '@@@@@@@@@@@@@@@@@@@@@@@@@@@
17.  
18.     PRESET (ShX, ShY) 'Set to draw Ship's SHADOW -------------------------------
19.  
20.     DRAW "C" + STR$(ShadClr&) 'Shadow Color                             Actual Ship size:
21.  
22.     DRAW "bU2 L3 H3 G14 D6 E3 R3 E3 R21" 'LEFT half (wing) of Shadow Ship  --  "BU3 L5 H4 G20 D9 E5 R5 E4 R29"
23.  
24.     PSET (ShX, ShY), _RGB(255, 255, 255) 'Must be diff. from ShadClr
25.     DRAW "C" + STR$(ShadClr&) 'Back to Shadow color
26.     DRAW "bU2 R3 E3 F14 D6 H3 L3 H3 " 'RIGHT half of Shadow (most of it)        "BU3 R5 E4 F20 D9 H5 L5 H4 "
27.  
28.     PAINT (ShX, ShY), ShadClr&, ShadClr&
29.  
30.     PRESET (ShX, ShY) 'Reset for Ship's Sphere ---------------------------------
31.     DRAW "C" + STR$(ShadClr&) 'Back to Shadow color
32.     'Draw a HINT of the Sphere, then reset for Engine bottom...
33.     DRAW "bU3 bL2 R4  bL3 bU1 R2  bL4 bD14 " 'Merely a 4-pixel line & a 2-pixel line in lieu of CIRCLE
34.     DRAW "R6 bD1 L6" 'Bare bottom of Engine
35.  
36.     _PUTIMAGE (Ship.X - 104, Ship.Y + 56), Ship_Shade&, Scr& '(80+24, 80-24) ...24 being about 1/2 of Ship_Shade image's width or height
37.     'LINE (Ship.X - 104, Ship.Y + 104)-(Ship.X - 55, Ship.Y + 153), _RGB(255, 255, 255), B
38.  
39.     CLS: _DEST Scr&
40.  
41. END SUB
42.  
43.  
44.  

This line does not make sense if you want transparent, yet when I try less than 255, I get light colored squares drawn.
ShadClr& = _RGBA(0, 0, 0, 255)

Does the Draw "C" command allow for ALPHA colors? The wiki says only _rgb().

[bplus]

OK this has nice effect!

Code: QB64: [Select]

1.  
2. SUB Ship_Shadow
3.  
4.     _DEST Ship_Shade& 'DRAW onto our small Ship Shadow BG image
5.  
6.     DIM C AS _UNSIGNED LONG, C1 AS _UNSIGNED LONG, C2 AS _UNSIGNED LONG, C3 AS _UNSIGNED LONG
7.     ShX = 24: ShY = 24
8.  
9.     PRESET (ShX, ShY) 'Place graphics cursor in centre of Shadow image ---------
10.  
11.     ShadClr& = _RGBA(0, 0, 0, 255) '_RGB(R - SD, G - SD, B - SD) 'Assign colour to Ship's shadow on Planet's surface
12.  
13.     CLS , _RGBA(255, 255, 255, 0)
14.  
15.     '@@@@@@@@@@@@@@@@@@@@@@@@@@@
16.     DRAW "TA=" + VARPTR$(Angle) 'Set the angle based on Ship's Angle
17.     '@@@@@@@@@@@@@@@@@@@@@@@@@@@
18.  
19.     PRESET (ShX, ShY) 'Set to draw Ship's SHADOW -------------------------------
20.  
21.     DRAW "C" + STR$(ShadClr&) 'Shadow Color                             Actual Ship size:
22.  
23.     DRAW "bU2 L3 H3 G14 D6 E3 R3 E3 R21" 'LEFT half (wing) of Shadow Ship  --  "BU3 L5 H4 G20 D9 E5 R5 E4 R29"
24.  
25.     PSET (ShX, ShY), _RGB(255, 255, 255) 'Must be diff. from ShadClr
26.     DRAW "C" + STR$(ShadClr&) 'Back to Shadow color
27.     DRAW "bU2 R3 E3 F14 D6 H3 L3 H3 " 'RIGHT half of Shadow (most of it)        "BU3 R5 E4 F20 D9 H5 L5 H4 "
28.  
29.     PAINT (ShX, ShY), ShadClr&, ShadClr&
30.  
31.     PRESET (ShX, ShY) 'Reset for Ship's Sphere ---------------------------------
32.     DRAW "C" + STR$(ShadClr&) 'Back to Shadow color
33.     'Draw a HINT of the Sphere, then reset for Engine bottom...
34.     DRAW "bU3 bL2 R4  bL3 bU1 R2  bL4 bD14 " 'Merely a 4-pixel line & a 2-pixel line in lieu of CIRCLE
35.     DRAW "R6 bD1 L6" 'Bare bottom of Engine
36.  
37.     _SETALPHA 50, _RGB32(0, 0, 0) '<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< this has nice effect!!!!!!!!
38.  
39.     _PUTIMAGE (Ship.X - 104, Ship.Y + 56), Ship_Shade&, Scr& '(80+24, 80-24) ...24 being about 1/2 of Ship_Shade image's width or height
40.     'LINE (Ship.X - 104, Ship.Y + 104)-(Ship.X - 55, Ship.Y + 153), _RGB(255, 255, 255), B
41.  
42.     CLS: _DEST Scr&
43.  
44. END SUB
45.  
46.  
47.  

[bplus]

BTW those are really nice graphics, I hadn't seen the program for awhile, it's coming along nicely!

[SirCrow]

BTW those are really nice graphics, I hadn't seen the program for awhile, it's coming along nicely!

I'm very glad you like it.  Hey, thanks!  You've solved it!  It simply hadn't occurred to me to put that there.
The only change I've made to your line is this, to match it with all the asteroids' shadows:

 _SETALPHA 120, _RGB32(0, 0, 0)

By the way, the transparent shadow you saw while using Alt-S is not quite as it appears.  It's really a solid shade that changes with the ground under or around it by sampling pixels with POINT(), and averaging values and stuff like that.  You can see that it's different from the shadows of the floating rocks.  It took some work to get it that way, and I like it, but I most wanted the ship to have the same shadow as the asteroids.  And now it does.  Thanks again!

[SirCrow]

Might not be easy to fix. Normally I would suggest using a rotate procedure. That would probably be easier than rotating a 'drawn' image. I do not know how to rotate images using QB64. In the meantime, may I suggest, a lighter shadow? Black tends to make it 'stand out'. Perhaps anywhere between _RGB32(64,64,64) and _RGB32(192,192,192)? Just a thought...

Thanks, Johnno.  But it seems that the all-elusive solution has been found by bplus.  As I'd expected, something simple that I just didn't see.Anyway, I've added more cool features to the game and I hope to upload it soon.  And I think I'll have to employ those reduced images you've prepared for me.  Thanks.
J

[FellippeHeitor]

If you still need to rotate an image here's a routine (and helper routines) alongside a sample code showing usage to rotate any image by the provided amount of degrees: https://github.com/FellippeHeitor/Snippets/blob/master/rotateImage.bas

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. TYPE vertex
4.     x AS SINGLE
5.     y AS SINGLE
6. END TYPE
7.  
8. SCREEN _NEWIMAGE(800, 600, 32)
9. DIM bee AS LONG
10. bee = _LOADIMAGE("bee-12.jpg")
11.  
12. DIM i AS SINGLE
13. DO
14.     WHILE _MOUSEINPUT: WEND
15.     CLS
16.     i = map(_MOUSEX, 0, _WIDTH - 1, -90, 90)
17.     IF _KEYDOWN(100306) THEN i = INT(i)
18.     PRINT "rotation angle:"; i
19.     putImage _WIDTH / 2 - _WIDTH(bee) / 2, _HEIGHT / 2 - _HEIGHT(bee) / 2, bee, i
20.     _DISPLAY
21.     _LIMIT 30
22. LOOP
23.  
24. SUB putImage (__x AS SINGLE, __y AS SINGLE, image AS LONG, angleDegrees AS SINGLE)
25.     DIM i AS LONG
26.  
27.     DIM center AS vertex
28.     DIM corner(1 TO 4) AS vertex
29.  
30.     center.x = __x + _WIDTH(image) / 2
31.     center.y = __y + _HEIGHT(image) / 2
32.  
33.     FOR i = 1 TO 4
34.         SELECT CASE i
35.             CASE 1
36.                 corner(i).x = __x
37.                 corner(i).y = __y
38.             CASE 2
39.                 corner(i).x = __x
40.                 corner(i).y = (__y + _HEIGHT(image) - 1)
41.             CASE 3
42.                 corner(i).x = (__x + _WIDTH(image) - 1)
43.                 corner(i).y = __y
44.             CASE 4
45.                 corner(i).x = (__x + _WIDTH(image) - 1)
46.                 corner(i).y = (__y + _HEIGHT(image) - 1)
47.         END SELECT
48.  
49.         rotate corner(i), center, angleDegrees
50.     NEXT
51.  
52.     _MAPTRIANGLE (0, 0)-(0, _HEIGHT(image) - 1)-(_WIDTH(image) - 1, 0), image TO(corner(1).x, corner(1).y)-(corner(2).x, corner(2).y)-(corner(3).x, corner(3).y)
53.     _MAPTRIANGLE (0, _HEIGHT(image) - 1)-(_WIDTH(image) - 1, 0)-(_WIDTH(image) - 1, _HEIGHT(image) - 1), image TO(corner(2).x, corner(2).y)-(corner(3).x, corner(3).y)-(corner(4).x, corner(4).y)
54. END SUB
55.  
56. SUB rotate (p AS vertex, center AS vertex, angleDegrees AS SINGLE)
57.     'as seen on https://stackoverflow.com/questions/2259476/rotating-a-point-about-another-point-2d
58.     DIM s AS SINGLE, c AS SINGLE
59.     DIM newP AS vertex
60.     DIM angle AS SINGLE
61.  
62.     angle = _D2R(angleDegrees)
63.  
64.     s = SIN(angle)
65.     c = COS(angle)
66.  
67.     p.x = p.x - center.x
68.     p.y = p.y - center.y
69.  
70.     newP.x = p.x * c - p.y * s
71.     newP.y = p.x * s + p.y * c
72.  
73.     p.x = newP.x + center.x
74.     p.y = newP.y + center.y
75. END SUB
76.  
77. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
78.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
79. END FUNCTION
80.  

[SirCrow]

Thanks, Fellippe.  I may have use for that in the near future.