Maths accuracy

[jack]

1.2 ^ 3.5 = 1.2 ^ (35/10) does this get us closer?

1.2^3.5=1.2^3*sqr(1.2)

[bplus]

1.2^3.5=1.2^3*sqr(1.2)

Ah yes, that is a hint as to how I do powers (of real numbers not just integers) by converting to binary and then using sqr(2) and half of that and half of that...

Oh it's Sqr of Sqr(2) and on and on... (not half of half of half ...  but sqr(sqr(Sqr(2)))...)

Code: QB64: [Select]

1. _Title "Power Function by bplus"
2. 'QB64 X 64 version 1.2 20180228/86  from git b301f92
3.  
4. ' started 2018-07-23  Naalaa has no power function (or operator), so I wrote a power function for it.
5. ' ''Power pack the short version.txt
6. ' ''written for Naalaa 6 by bplus posted 2018-07-23
7. ' ''extracted from large test of fractions, random number functions, string... in Power test.txt
8.  
9. ' OMG the crazy thing worked! It produced decent estimates of roots given the limitations of precision...
10. ' Now I want to see how well it works with far greater precision available. So here we are, looking to see
11. ' how this function compares to the regualar ^ operator in QB64.
12.  
13. 'from Naalaa comments:
14. ' The main purpose of this code: to demo a power function for real numbers,
15.  
16. ' I had an idea for how real numbers to the power of real numbers might be done ie x ^ y = ?
17. ' This means that not only can you take SQR of a number, you can get cube or cube root, quartic, 5th 6th... roots and any multiple
18.  
19. ' It came from this simple idea
20. ' 2 ^ 3.5 = 2 ^ 3 * 2 ^ .5 = 8 * Sqr(2)
21. ' 3 ^ 3.5 = 3 ^ 3 * 3 ^ .5 = 27 * Sqr(3)
22.  
23. ' so 2 ^ 3.25 = 2 ^ 3 * 2 ^ .25
24. ' what is 2 ^ .25 ?  It is sqr(sqr(2)) !
25.  
26. ' likewise 2 ^ 3.125 = 2 ^ 3 * 2 ^ 1/8
27. ' what is 2 ^ 1/8 ? It is sqr(sqr(sqr(2))) !
28.  
29. ' any decimal can be written as a sum of fraction powers of 2 ie 1/2^n, as any integer can be written in powers of 2.
30. ' in binary expansions
31. ' 1/2 = .1       or .5 base 10
32. ' 1/4 = .01      or .25 base 10
33. ' 1/8 = .001     or .125 base 10
34. ' 1/16 = .0001   or .0625 base 10
35.  
36. ' So with binary expansion of decimal, we can SQR and multiply our way to an estimate
37. ' of any real number to the power of another real number using binary expansion of
38. ' the decimal parts as long as we stay in Naalaa integer limits and are mindful of precision.
39.  
40. Const wW = 800
41. Const wH = 600
42. Screen _NewImage(wW, wH, 32)
43. _ScreenMove 360, 60
44. _Define A-Z As _FLOAT
45.  
46. Do
47.     Print "Testing the power(x, pow) function:"
48.     Input "(nothing) quits, Please enter a real number to raise to some power. x = "; x
49.     If x = 0 Then Exit Do
50.     Input "(nothing) quits, Please enter a real number for the power. pow = ", pw
51.     If pw = 0 Then Exit Do
52.     result = power(x, pw)
53.     Print result; " is what we estimate for"; x; " raised to power of"; pw
54.     Print x ^ pw; " is what the ^ operator gives us."
55.     Print
56. Loop
57. Print
58. Print "Far from precise of course, but this code is clear proof of concept!"
59. Print " OMG, it worked!!!"
60. Sleep
61.  
62.  
63. ' A power function for real numbers (small ones but still!)
64. ' x to the power of pow
65. Function power## (x As _Float, pow As _Float)
66.     'this sub needs 2 other subs
67.     'bExpand20$
68.     'split though for this split is overkill
69.     Dim build As _Float
70.     ReDim s(0) As String
71.     r$ = "0" + Str$(pow) 'in case pow starts with decimal
72.     Split s$(), r$, "."
73.     integer$ = s$(0)
74.     build = 1.0
75.     If integer$ <> "0" Then
76.         p = Val(integer$)
77.         For i = 1 To p
78.             build = build * x
79.         Next
80.     End If
81.     If UBound(s$) = 0 Then power = build: Exit Function
82.     'that takes care of integer part,
83.     'now for the fraction part convert decimal to fraction
84.     n$ = s$(1)
85.     ld = Len(n$)
86.     While Right$(n$, 1) = "0"
87.         n$ = Left$(n$, ld - 1)
88.         ld = Len(n$)
89.     Wend
90.     denom& = 10
91.     For i = 2 To ld
92.         denom& = denom& * 10
93.     Next
94.     numer& = Val(n$)
95.     'OK for bExpand20$ don't have to simplify and that saves us having to extract n and d again from n/d
96.     bs$ = bExpand60$(numer&, denom&)
97.     'at moment we haven't taken any sqr of x
98.     runningXSQR = x
99.     'run through all the 0's and 1's in the bianry expansion of the fraction part of the power float
100.     For i = 1 To Len(bs$)
101.         'this is the matching sqr of the sqr of the sqr... of x
102.         runningXSQR = Sqr(runningXSQR)
103.         'for every 1 in the expansion, multiple our build with the running sqr of ... sqr of x
104.         If Mid$(bs$, i, 1) = "1" Then build = build * runningXSQR
105.     Next
106.     'our build should be a estimate or x to power of pow
107.     power = build
108. End Function
109.  
110. 'write a series of 1s and 0s that represent the decimal fraction n/d in binary 60 places long
111. Function bExpand60$ (nOver&, d&)
112.     Dim b As _Float, r As _Float
113.     ' b for base
114.     b = 0.5
115.     ' r for remainder
116.     r = nOver& / d&
117.     ' s for string$ 0's and 1's that we will build and return for function value
118.     s$ = ""
119.     ' f for flag to stop
120.     f% = 0
121.     ' c for count to track how far we are, don't want to go past 20
122.     c% = 0
123.     While f% = 0
124.         If r < b Then
125.             s$ = s$ + "0"
126.         Else
127.             s$ = s$ + "1"
128.             If r > b Then
129.                 r = r - b
130.             Else
131.                 f% = 1
132.             End If
133.         End If
134.         c% = c% + 1
135.         If c% >= 60 Then f% = 1
136.         b = b * 0.5
137.     Wend
138.     bExpand60$ = s$
139. End Function
140.  
141. Sub Split (arr() As String, mystr As String, delim As String)
142.     Dim c As String * 1, curpos As Long, arrpos As Long, le As Long
143.     curpos = 1: arrpos = 0
144.     le = Len(mystr)
145.     Do Until (curpos > le)
146.         c = Mid$(mystr, curpos, 1) ' Get 1 ctr
147.         If (c <> delim) Then
148.             arr(arrpos) = arr(arrpos) + c
149.         Else
150.             arrpos = arrpos + 1
151.             ReDim _Preserve arr(arrpos + 1) As String 'AS STRING required or it assumes the default type which is SINGLE
152.         End If
153.         curpos = curpos + 1
154.     Loop
155.     ReDim _Preserve arr(arrpos) As String
156. End Sub
157.  
158.  
159.  
160.  

Now all I need to do is covert it to string math functions ;-))

[George McGinn]

Passing power to root can be used to get your result or if you don’t have a whole solution, to express the result as a root.

For example, using my n'th root function, you could solve 1,2^3.5 as:

X = 10th root of 1.2^35, which = 1.2^3.5. (Answer is 1.892929159)

1.2 becomes the radicando (root content), 10 becomes the root index and 35 remains as exponent of 1.2

Passing power to root can be used to get your result.

Just spitballing, but if you Check for the y in x^y not = to its modulus will tell the function it needs to calculate the power using the root.

I will try and code that for your Math Regulator program.

George

Hmm...

Like I said a ^ b where b is integer, I get that though god help us if that integer is huge ;-))

But if b were float?

What if I mult b by 10 until it is all integer? mult a (b  * 10 ^ Integer times) then what? divide by some log of 10 Integer times? Yeah, nah... ;-))

1.2 ^ 3.5 = 1.2 ^ (35/10) does this get us closer?

[Dav]

hi @JohnUKresults.  I'm very late to the party with this, but here's another workaround if you're interested (you asked if there is another).  Since PRINT USING returns correct results you want, here's a way to convert/return a PRINT USING output as a variable, by reading a second screen output.  It's no better, but just shows another way, mostly that it’s possible to get PRINT USING output as a variable.

- Dav

Code: QB64: [Select]

1. finishseconds! = 39818.38
2. startseconds! = 34200.77
3.  
4. PRINT finishseconds! - startseconds!
5. PRINT USING "#####.##"; finishseconds! - startseconds!
6. r = PU2(finishseconds! - startseconds!)
7. PRINT r
8.  
9. FUNCTION PU2 (math)
10.     'returns a print using readout as a variable
11.     org& = _DEST 'save current screen
12.     pun& = _NEWIMAGE(600, 100, 256) 'make new one
13.     _DEST pun& 'switch to it
14.     _SOURCE pun&
15.     PRINT USING "#############.##"; math 'do the deed
16.     FOR x = 1 TO 30 'read chracters off screen
17.         n$ = n$ + CHR$(SCREEN(1, x, 0))
18.     NEXT
19.     n$ = LTRIM$(RTRIM$(n$)) 'remove any spaces
20.     _DEST org& 'switch back to original screen
21.     _SOURCE org&
22.     PU2 = VAL(n$) 'return variable
23. END FUNCTION
24.  

 

[JohnUKresults]

Hi Dav

Thanks for that suggestion.

However, it's the calculation which is important, not the display of the result, so I will have to stick with multiplying the time to make an integer, doing the subtraction, and then putting the decimal point back into the right place for the results.

Like your idea though - might be useful for something else!