Building a Scrolling LED Screen

[bplus]

A quick 100 lines or so to show 3 basic steps:

Code: QB64: [Select]

1. _Title "Building a Scrolling LED Screen" ' b+ 2021-05-08
2. Screen _NewImage(1200, 160, 32)
3. _Delay .25 'give screen time to load
4. _ScreenMove _Middle 'and center screen
5.  
6. 'scroll some text
7. Text$ = "Try scrolling me for awhile until you got it, then press a key...   "
8. lenText = Len(Text$)
9. startTextPos = 1
10. 'put text in sign 15 chars wide in middle of screen print the message moving down 1 character evey frame
11. _Title "Building a Scrolling LED Screen:  Step 1 get some code to scroll your message in middle of screen."
12. Do
13.     k$ = InKey$
14.     Cls
15.     ' two pieces of text?  when get to end of text will have less than 15 chars to fill sign so get remainder from front
16.     len1 = lenText - startTextPos
17.     If len1 < 15 Then len2 = 15 - len1 Else len1 = 15: len2 = 0
18.     ' locate at middle of screen for 15 char long sign
19.     _PrintString ((1200 - 15 * 8) / 2, (160 / 2) - 8), Mid$(Text$, startTextPos, len1) + Mid$(Text$, 1, len2)
20.     startTextPos = startTextPos + 1
21.     If startTextPos > lenText Then startTextPos = 1
22.     _Display ' no blinking when clear screen so often
23.     _Limit 5 ' slow down to see scroll
24. Loop Until Len(k$)
25.  
26. ' OK   now for the enLARGE M E N T   using _PutImage
27. ' our little sign is 16 pixels high and 8 * 15 chars pixels wide = 120
28. Dim sign As Long
29. sign = _NewImage(120, 16, 32) ' we will store the print image here
30.  
31. '  _PUTIMAGE [STEP] [(dx1, dy1)-[STEP][(dx2, dy2)]][, sourceHandle&][, destHandle&][, ][STEP][(sx1, sy1)[-STEP][(sx2, sy2)]][_SMOOTH]
32. '  use same pixel location to _printString as for _PutImage Source rectangle ie (sx1, sy1), -step( sign width and height)
33.  
34. ' test screen capture with _putimage and then blowup with _putimage
35. '_PutImage , 0, sign, ((1200 - 15 * 8) / 2, (160 / 2) - 8)-Step(119, 15)
36. 'Cls
37. '_PutImage , sign, 0 ' stretch to whole screen
38. '_Display
39.  
40. 'now that that works  do it on the move
41.  
42. ' about here I resized the screen to 1200 x 160 to make the text scalable X's 10 ie 120 x 10 wide and 16 x 10 high
43. _Title "Building a Scrolling LED Screen:  Step 2 Blow it up by using _PutImage twice once to capture, then to expand"
44. k$ = ""
45. Do
46.     k$ = InKey$
47.     Cls
48.     ' two pieces of text?  when get to end of text will have less than 15 chars to fill sign so get remainder from front
49.     len1 = lenText - startTextPos
50.     If len1 < 15 Then len2 = 15 - len1 Else len1 = 15: len2 = 0
51.     ' locate at middle of screen for 15 char long sign
52.     _PrintString ((1200 - 15 * 8) / 2, (160 / 2) - 8), Mid$(Text$, startTextPos, len1) + Mid$(Text$, 1, len2)
53.     _PutImage , 0, sign, ((1200 - 15 * 8) / 2, (160 / 2) - 8)-Step(119, 15)
54.  
55.     Cls
56.     _PutImage , sign, 0 ' stretch to whole screen
57.     _Display ' no blinking when clear screen so often
58.     _Limit 5 ' slow down to see scroll
59.     startTextPos = startTextPos + 1
60.     If startTextPos > lenText Then startTextPos = 1
61. Loop Until Len(k$)
62.  
63.  
64.  
65. ' now for a mask just draw a grid  test grid draw here
66. 'For x = 0 To _Width Step 10 ' verticals
67. '    Line (x, 0)-(x + 3, _Height), &HFF000000, BF
68. 'Next
69. 'For y = 0 To _Height Step 10
70. '    Line (0, y)-(_Width, y + 3), &HFF000000, BF
71. 'Next
72.  
73.  
74.  
75. _Title "Building a Scrolling LED Screen:  Step 3 Mask or Cover the thing with a grid or grate."
76. ' here is the whole code not including all setup variables from above
77. k$ = ""
78. Do
79.     k$ = InKey$
80.     Cls
81.     ' two pieces of text?  when get to end of text will have less than 15 chars to fill sign so get remainder from front
82.     len1 = lenText - startTextPos
83.     If len1 < 15 Then len2 = 15 - len1 Else len1 = 15: len2 = 0
84.     ' locate at middle of screen for 15 char long sign
85.     _PrintString ((1200 - 15 * 8) / 2, (160 / 2) - 8), Mid$(Text$, startTextPos, len1) + Mid$(Text$, 1, len2)
86.     _PutImage , 0, sign, ((1200 - 15 * 8) / 2, (160 / 2) - 8)-Step(119, 15)
87.  
88.     Cls
89.     _PutImage , sign, 0 ' stretch to whole screen
90.  
91.     ' now for a mask just draw a grid  best to draw this and copy and layover screen as another layer
92.     ' here QB64 is fast evough to redarw each time
93.     For x = 0 To _Width Step 10 ' verticals
94.         Line (x, 0)-(x + 3, _Height), &HFF000000, BF
95.     Next
96.     For y = 0 To _Height Step 10
97.         Line (0, y)-(_Width, y + 3), &HFF000000, BF
98.     Next
99.  
100.     _Display ' no blinking when clear screen so often
101.     _Limit 5 ' slow down to see scroll
102.     startTextPos = startTextPos + 1
103.     If startTextPos > lenText Then startTextPos = 1
104. Loop Until Len(k$)
105.  
106.  

[johnno56]

Very cool indeed.... Thank you for sharing...

[TempodiBasic]

@bplus
good job! It is a fine approach to the task of LED scrolling screen.

[bplus]

Thanks I hope it helps introduce _PUTIMAGE and using _NEWIMAGE to store an image.

_PUTIMAGE is extremely complex but man! once you master it!!!

I still have to pull a copy of the complete syntax from Help for reference as I showed in code.