Almost real desktop Magnifying glass effect (Windows only)

[Dav]

Playing around with Windows Regions API today, made a little fake magnifying glass over desktop effect.  Use mouse to move circle over a captured desktop screenimage, it appears to magnify desktop area (see attached image).  It's not really magnifying the active desktop, but maybe someone could use this effect technique to do something more useful down the road.

Press ESC to end effect and close program.

- Dav

Code: QB64: [Select]

1. '=================
2. 'MagnifyCircle.bas
3. '=================
4. 'Fake magnifying glass effect using Windows API
5. 'Coded by Dav, FEB/2021
6.  
7. 'This mostly just shows how to make a region and use it
8. 'for a special effect.  Grabs desktop, stretches it a little,
9. 'darkens it for an overlay feel.
10.  
11. 'Press ESC to end the effect and close program.
12.  
13. TYPE POINTAPI
14.     x AS LONG
15.     y AS LONG
16. END TYPE
17.  
18. DIM apixy AS POINTAPI
19.  
20. DECLARE DYNAMIC LIBRARY "user32"
21.     FUNCTION SetWindowRgn& (BYVAL hwnd&, BYVAL hrgn~&, BYVAL bredraw%)
22.     FUNCTION GetCursorPos% (lpPoint AS POINTAPI)
23.     FUNCTION SetWindowPos& (BYVAL hWnd&, BYVAL hWndInsertAfter&, BYVAL X&, BYVAL Y&, BYVAL cx&, BYVAL cy&, BYVAL wFlags&)
24. END DECLARE
25.  
26. DECLARE DYNAMIC LIBRARY "gdi32"
27.     FUNCTION CreateRoundRectRgn& (BYVAL x1&, BYVAL y1&, BYVAL x2&, BYVAL y2&, BYVAL x3&, BYVAL y3&)
28. END DECLARE
29.  
30. SCREEN _NEWIMAGE(200, 200, 32)
31. back& = _SCREENIMAGE
32.  
33. hwnd& = _WINDOWHANDLE
34. rgn& = CreateRoundRectRgn(30, 30, 180, 180, 150, 150)
35. IF SetWindowRgn(hwnd&, rgn&, 0) = 0 THEN PRINT "Failed...": END
36.  
37.  
38. DO
39.     mi = GetCursorPos(apixy): mx = apixy.x: my = apixy.y
40.     x& = SetWindowPos(hwnd&, -1, mx - 100, my - 100, 0, 0, &H1)
41.     x1 = -mx + 50: y1 = -my + 50
42.     x2 = _DESKTOPWIDTH + x1: y2 = _DESKTOPHEIGHT + y1
43.     _PUTIMAGE (x1, y1)-(x2 + 75, y2 + 75), back&,
44.     LINE (x1, y1)-(x2 + 75, y2 + 75), _RGBA(0, 0, 0, 50), BF
45.     _DISPLAY
46.     _LIMIT 60
47. LOOP UNTIL INKEY$ = CHR$(27)
48. SYSTEM
49.  

 

[SpriggsySpriggs]

Now THAT IS IMPRESSIVE

[bplus]

Yeah I am getting that desperate. Can you get it to focus where my eyes are pointed ;-)

[Pete]

Useful. I'm trying to figure out a way to incorporate that into a dating app I'm creating. :O

Pete 

[Richard Frost]

It's nice to see short, easily understood demos of unusual library functions.

[Dav]

Thanks everyone.  I have another one that updates & magnifies the active desktop, but have a bug or two to squash before posting.

- Dav

[Petr]

ZOOM without libraries:

modify variables SizeOriginal or SizeZOOM for zooming ratio settings.

Code: QB64: [Select]

1. TYPE xy
2.     X AS SINGLE
3.     Y AS SINGLE
4. END TYPE
5. DIM C(628) AS xy
6.  
7. SizeOriginal = 50
8. SizeZOOM = 70
9.  
10. FOR ci = 0 TO _PI(2) STEP .01
11.     C(i).X = COS(ci)
12.     C(i).Y = SIN(ci)
13.     i = i + 1
14. NEXT
15.  
16. img = _SCREENIMAGE
17.  
18. SCREEN _NEWIMAGE(_DESKTOPWIDTH, _DESKTOPHEIGHT, 32)
19. REM _MOUSEHIDE
20. DO
21.     _PUTIMAGE , img
22.     WHILE _MOUSEINPUT: WEND
23.     MX = _MOUSEX
24.     MY = _MOUSEY
25.  
26.     FOR D = 1 TO i - 1
27.         _MAPTRIANGLE (MX, MY)-(MX + C(D).X * SizeOriginal, MY + C(D).Y * SizeOriginal)-(MX + C(D - 1).X * SizeOriginal, MY + C(D - 1).Y * SizeOriginal), img TO(MX, MY)-(MX + C(D).X * SizeZOOM, MY + C(D).Y * SizeZOOM)-(MX + C(D - 1).X * SizeZOOM, MY + C(D - 1).Y * SizeZOOM), 0
28.     NEXT
29.     _DISPLAY
30. LOOP
31.  

[Dav]

Cool, @Petr !  I gotta start looking into maptriangle.

I'm gonna use that.

- Dav

[Petr]

Thank you Dav. IF you rewrite XY types to INTEGERS, result is square. (Then the same effect can do _PUTIMAGE and it is faster)

[Dav]

Thats good to know, Petr. Thanks.

@Pete, use Petrs zoom version for your dating app. You won't miss seeing anything using that one.

- Dav

[Pete]

Now if we could just get a SCREEN 0 version, so I could see what I'm typing in my WP. I thought I wrote on my dating app: College Graduate, but it turned out my spell checker changed that to: Constantly flatulates. If I had a SCREEN 0 magnifier, maybe I'd have something else to do on Friday nights, besides coding.

Pete

[Petr]

Now if we could just get a SCREEN 0 version, so I could see what I'm typing in my WP

Try use SaveImage to save screen 0 as 32 bit  image and then continue in the same way :)