Labyrinth Tiles

[bplus]

Here is something I found interesting Thursday night, Labyrinth Tiles:

Code: QB64: [Select]

1. _TITLE "Labyrinth Tile, spacebar for random tiling escape for Tile Design" 'b+ 2021-01-15
2.  
3. CONST Xmax = 700, Ymax = 700
4. SCREEN _NEWIMAGE(Xmax, Ymax, 32)
5. _DELAY .25
6. _SCREENMOVE _MIDDLE
7.  
8. DIM SHARED TL AS LONG, TU AS LONG
9.  
10. makeTileImageLeft
11. 'TileLeft 100, 100
12. 'TileRight 0, 100
13.  
14. makeTileImageUp
15. 'TileUp 100, 0
16. 'TileDown 100, 99
17. 'TileDown 100, 199
18.  
19. DO
20.     CLS
21.     FOR y = 0 TO Ymax STEP 100
22.         FOR x = 0 TO Xmax STEP 100
23.             r = RND
24.             IF r < .25 THEN
25.                 TileLeft x, y
26.             ELSEIF r < .5 THEN
27.                 TileDown x, y
28.             ELSEIF r < .75 THEN
29.                 TileRight x, y
30.             ELSE
31.                 TileUp x, y
32.             END IF
33.         NEXT
34.     NEXT
35.     _DISPLAY
36.     SLEEP
37. LOOP UNTIL _KEYDOWN(27)
38.  
39. ' can we make some designs?
40. _TITLE "Labyrinth Tile, a Tile Design, Spacebar to Click your own Design"
41. CLS
42. FOR y = 0 TO 7
43.     FOR x = 0 TO 7
44.         IF y MOD 4 = 0 OR y MOD 4 = 2 THEN
45.             IF x MOD 4 = 0 OR x MOD 4 = 2 THEN
46.                 TileLeft x * 100, y * 100
47.             ELSEIF x MOD 4 = 1 OR x MOD 4 = 3 THEN
48.                 TileRight x * 100, y * 100
49.             END IF
50.         ELSEIF y MOD 4 = 1 THEN
51.             IF x MOD 4 = 0 THEN
52.                 TileDown x * 100, y * 100
53.             ELSEIF x MOD 4 = 2 THEN
54.                 TileUp x * 100, y * 100
55.             ELSEIF x MOD 4 = 1 THEN
56.                 TileDown x * 100, y * 100
57.             ELSEIF x MOD 4 = 3 THEN
58.                 TileUp x * 100, y * 100
59.             END IF
60.         ELSEIF y MOD 4 = 3 THEN
61.             IF x MOD 4 = 0 THEN
62.                 TileUp x * 100, y * 100
63.             ELSEIF x MOD 4 = 2 THEN
64.                 TileDown x * 100, y * 100
65.             ELSEIF x MOD 4 = 1 THEN
66.                 TileUp x * 100, y * 100
67.             ELSEIF x MOD 4 = 3 THEN
68.                 TileDown x * 100, y * 100
69.             END IF
70.         END IF
71.     NEXT
72. NEXT
73. _DISPLAY
74. SLEEP
75.  
76.  
77. _TITLE "Labyrinth Tile, Click tile to turn it, escape to quit..."
78. CLS
79. REDIM t(7, 7) AS LONG
80. FOR y = 0 TO 7
81.     FOR x = 0 TO 7
82.         t(x, y) = INT(RND * 4)
83.     NEXT
84. NEXT
85. DO
86.     CLS
87.     FOR y = 0 TO 7
88.         FOR x = 0 TO 7
89.             SELECT CASE t(x, y)
90.                 CASE 0: TileRight x * 100, y * 100
91.                 CASE 1: TileDown x * 100, y * 100
92.                 CASE 2: TileLeft x * 100, y * 100
93.                 CASE 3: TileUp x * 100, y * 100
94.             END SELECT
95.         NEXT
96.     NEXT
97.     WHILE _MOUSEINPUT: WEND
98.     mb = _MOUSEBUTTON(1): mx = INT(_MOUSEX / 100): my = INT(_MOUSEY / 100)
99.     LINE (mx * 100, my * 100)-STEP(100, 100), , B
100.     IF mb THEN
101.         IF mx >= 0 AND mx <= 7 AND my >= 0 AND my <= 7 THEN
102.             t(mx, my) = (t(mx, my) + 1) MOD 4
103.             PRINT mx, my
104.             _DELAY .25
105.         END IF
106.     END IF
107.     _DISPLAY
108.     _LIMIT 100
109. LOOP UNTIL _KEYDOWN(27)
110.  
111.  
112. SUB TileLeft (x, y)
113.     _PUTIMAGE (x, y), TL, 0
114. END SUB
115. SUB TileRight (x, y)
116.     _PUTIMAGE (x, y), TL, 0, (100, 0)-(0, 100)
117. END SUB
118. SUB TileUp (x, y)
119.     _PUTIMAGE (x, y), TU, 0
120. END SUB
121. SUB TileDown (x, y)
122.     _PUTIMAGE (x, y), TU, 0, (0, 100)-(100, 0)
123. END SUB
124.  
125. SUB makeTileImageLeft ()
126.     s2 = 50 * SQR(2) + .51
127.     TL = _NEWIMAGE(100, 100, 32)
128.     _DEST TL
129.     FOR x = 10 TO 130 STEP 20
130.         x1 = x + s2 * COS(_PI(3 / 4))
131.         y1 = s2 * SIN(_PI(3 / 4))
132.         x2 = x + s2 * COS(_PI(5 / 4))
133.         y2 = 100 + s2 * SIN(_PI(5 / 4))
134.         LINE (x, 0)-(x1, y1)
135.         LINE (x, 100)-(x2, y2)
136.     NEXT
137.     'LINE (0, 0)-STEP(99, 99), , B
138.     _DEST 0
139. END SUB
140.  
141. SUB makeTileImageUp ()
142.     s2 = 50 * SQR(2) + .51
143.     TU = _NEWIMAGE(100, 100, 32)
144.     _DEST TU
145.     FOR y = 10 TO 130 STEP 20
146.         x1 = s2 * COS(_PI(7 / 4))
147.         y1 = y + s2 * SIN(_PI(7 / 4))
148.         x2 = 100 + s2 * COS(_PI(5 / 4))
149.         y2 = y + s2 * SIN(_PI(5 / 4))
150.         LINE (0, y)-(x1, y1)
151.         LINE (100, y)-(x2, y2)
152.     NEXT
153.     'LINE (0, 0)-STEP(99, 99), , B
154.     _DEST 0
155. END SUB
156.  
157.  
158.  

Here is design I clicked up today:
 

Couldn't figure out how to get rid of that one pesky pixel hole set. Maybe one last try with Rotozoom...

[Pete]

Is it available in oak or walnut? Reminds me of Parkay floor tiles.

Pete

[FellippeHeitor]

Neat! Kind of like:

10 PRINT CHR$(205.5+RND(1)); : GOTO 10

For the old Commodore.

 

[Pete]

Is that available in 64 and 128? Oh well, lucky for me, I was an Atari guy. We just had plain old black screens. You know... like SCREEN Zero. The way God intended it.

Pete

[bplus]

Is it available in oak or walnut? Reminds me of Parkay floor tiles.

Pete

Actually it was Old Moses Chess board that had me thinking about tiles. :)

I started thinking about mazes that might turn after a player passes so there is no going back.

Yeah @FellippeHeitor  I remember that! Alas, these tiles don't make very good mazes.

Too bad Rotozoom can not translate a straight line! it has the gaps between tiles more than filled:

Code: QB64: [Select]

1. _TITLE "Labyrinth Tile, spacebar for random tiling escape for Tile Design" 'b+ 2021-01-15
2.  
3. CONST Xmax = 700, Ymax = 700
4. SCREEN _NEWIMAGE(Xmax, Ymax, 32)
5. _DELAY .25
6. _SCREENMOVE _MIDDLE
7.  
8. DIM SHARED TU AS LONG
9.  
10. makeTileImageUp
11.  
12. DO
13.     CLS
14.     FOR y = 0 TO Ymax STEP 100
15.         FOR x = 0 TO Xmax STEP 100
16.             r = RND
17.             IF r < .25 THEN
18.                 TileLeft x, y
19.             ELSEIF r < .5 THEN
20.                 TileDown x, y
21.             ELSEIF r < .75 THEN
22.                 TileRight x, y
23.             ELSE
24.                 TileUp x, y
25.             END IF
26.         NEXT
27.     NEXT
28.     _DISPLAY
29.     SLEEP
30. LOOP UNTIL _KEYDOWN(27)
31.  
32. ' can we make some designs?
33. _TITLE "Labyrinth Tile, a Tile Design, Spacebar to Click your own Design"
34. CLS
35. FOR y = 0 TO 7
36.     FOR x = 0 TO 7
37.         IF y MOD 4 = 0 OR y MOD 4 = 2 THEN
38.             IF x MOD 4 = 0 OR x MOD 4 = 2 THEN
39.                 TileLeft x * 100, y * 100
40.             ELSEIF x MOD 4 = 1 OR x MOD 4 = 3 THEN
41.                 TileRight x * 100, y * 100
42.             END IF
43.         ELSEIF y MOD 4 = 1 THEN
44.             IF x MOD 4 = 0 THEN
45.                 TileDown x * 100, y * 100
46.             ELSEIF x MOD 4 = 2 THEN
47.                 TileUp x * 100, y * 100
48.             ELSEIF x MOD 4 = 1 THEN
49.                 TileDown x * 100, y * 100
50.             ELSEIF x MOD 4 = 3 THEN
51.                 TileUp x * 100, y * 100
52.             END IF
53.         ELSEIF y MOD 4 = 3 THEN
54.             IF x MOD 4 = 0 THEN
55.                 TileUp x * 100, y * 100
56.             ELSEIF x MOD 4 = 2 THEN
57.                 TileDown x * 100, y * 100
58.             ELSEIF x MOD 4 = 1 THEN
59.                 TileUp x * 100, y * 100
60.             ELSEIF x MOD 4 = 3 THEN
61.                 TileDown x * 100, y * 100
62.             END IF
63.         END IF
64.     NEXT
65. NEXT
66. _DISPLAY
67. SLEEP
68.  
69.  
70. _TITLE "Labyrinth Tile, Click tile to turn it, escape to quit..."
71. CLS
72. REDIM t(7, 7) AS LONG
73. FOR y = 0 TO 7
74.     FOR x = 0 TO 7
75.         t(x, y) = INT(RND * 4)
76.     NEXT
77. NEXT
78. DO
79.     CLS
80.     FOR y = 0 TO 7
81.         FOR x = 0 TO 7
82.             SELECT CASE t(x, y)
83.                 CASE 0: TileRight x * 100, y * 100
84.                 CASE 1: TileDown x * 100, y * 100
85.                 CASE 2: TileLeft x * 100, y * 100
86.                 CASE 3: TileUp x * 100, y * 100
87.             END SELECT
88.         NEXT
89.     NEXT
90.     WHILE _MOUSEINPUT: WEND
91.     mb = _MOUSEBUTTON(1): mx = INT(_MOUSEX / 100): my = INT(_MOUSEY / 100)
92.     LINE (mx * 100, my * 100)-STEP(100, 100), , B
93.     IF mb THEN
94.         IF mx >= 0 AND mx <= 7 AND my >= 0 AND my <= 7 THEN
95.             t(mx, my) = (t(mx, my) + 1) MOD 4
96.             PRINT mx, my
97.             _DELAY .25
98.         END IF
99.     END IF
100.     _DISPLAY
101.     _LIMIT 100
102. LOOP UNTIL _KEYDOWN(27)
103.  
104.  
105. SUB TileLeft (x, y)
106.     RotoZoom x + 50, y + 50, TU, 1, 270
107. END SUB
108. SUB TileRight (x, y)
109.     RotoZoom x + 50, y + 50, TU, 1, 90
110. END SUB
111. SUB TileUp (x, y)
112.     RotoZoom x + 50, y + 50, TU, 1, 0
113. END SUB
114. SUB TileDown (x, y)
115.     RotoZoom x + 50, y + 50, TU, 1, 180
116. END SUB
117.  
118. SUB makeTileImageUp ()
119.     s2 = 50 * SQR(2)
120.     TU = _NEWIMAGE(100, 100, 32)
121.     _DEST TU
122.     FOR y = 10 TO 130 STEP 20
123.         x1 = s2 * COS(_PI(7 / 4))
124.         y1 = y + s2 * SIN(_PI(7 / 4))
125.         x2 = 100 + s2 * COS(_PI(5 / 4))
126.         y2 = y + s2 * SIN(_PI(5 / 4))
127.         LINE (0, y)-(x1, y1)
128.         LINE (99, y)-(x2, y2)
129.     NEXT
130.     'LINE (0, 0)-STEP(99, 99), , B
131.     _DEST 0
132. END SUB
133.  
134. SUB RotoZoom (X AS LONG, Y AS LONG, Image AS LONG, Scale AS SINGLE, degreesRotation AS SINGLE)
135.     DIM px(3) AS SINGLE, py(3) AS SINGLE, W&, H&, sinr!, cosr!, i&, x2&, y2&
136.     W& = _WIDTH(Image&): H& = _HEIGHT(Image&)
137.     px(0) = -W& / 2: py(0) = -H& / 2: px(1) = -W& / 2: py(1) = H& / 2
138.     px(2) = W& / 2: py(2) = H& / 2: px(3) = W& / 2: py(3) = -H& / 2
139.     sinr! = SIN(-degreesRotation / 57.2957795131): cosr! = COS(-degreesRotation / 57.2957795131)
140.     FOR i& = 0 TO 3
141.         x2& = (px(i&) * cosr! + sinr! * py(i&)) * Scale + X: y2& = (py(i&) * cosr! - px(i&) * sinr!) * Scale + Y
142.         px(i&) = x2&: py(i&) = y2&
143.     NEXT
144.     _MAPTRIANGLE (0, 0)-(0, H& - 1)-(W& - 1, H& - 1), Image& TO(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
145.     _MAPTRIANGLE (0, 0)-(W& - 1, 0)-(W& - 1, H& - 1), Image& TO(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
146. END SUB
147.  
148.  

[Richard Frost]

TILE: Totally Insane Line Excursions

Code: QB64: [Select]

1. _TITLE "Truchet Tiling, SciAm Jul89 pg 111"
2. DEFINT A-Z
3. DIM a(1000)
4. s = 18: xm = 800 / s: ym = 600 / s: z = (800 - ((xm - 2) * s)) / 2
5. SCREEN _NEWIMAGE(800, 600, 12)
6. _DELAY .3: _SCREENMOVE _MIDDLE
7. FOR i = 0 TO 1 '             create tiles (just 2)
8.     FOR j = 0 TO 1
9.         FOR a = 0 TO 90
10.             r! = _D2R(a + j * 180)
11.             FOR q = -1 TO 1
12.                 x = j * s + ((s \ 2) + q) * COS(r!)
13.                 y = j * s + ((s \ 2) + q) * SIN(r!)
14.                 IF i THEN y = s - y
15.                 PSET (x, y), 1
16.             NEXT q
17.         NEXT a
18.     NEXT j
19.     GET (0, 0)-(s, s), a(i * 500)
20.     CLS
21. NEXT i
22.  
23. DO: _LIMIT 2 '               display tiles
24.     FOR i = 0 TO xm - 3
25.         FOR j = 0 TO ym - 3
26.             xs = i * s + z
27.             ys = j * s + z
28.             PUT (xs, ys), a(INT(RND * 2) * 500), PSET
29.         NEXT j
30.     NEXT i
31.     LINE (z, z)-((xm - 2) * s + z, (ym - 2) * s + z), 1, B
32.     _DISPLAY
33. LOOP UNTIL LEN(INKEY$)
34. SYSTEM

[bplus]

Yeah for 2 Tiler System!

Code: QB64: [Select]

1. _TITLE "2 Tiler press any for next, esc to quit" 'b+ 2021-01-16
2.  
3. CONST Xmax = 700, Ymax = 700, s = 10, sd2 = 5
4. SCREEN _NEWIMAGE(Xmax, Ymax, 32)
5. _DELAY .25
6. _SCREENMOVE _MIDDLE
7. DO
8.     CLS
9.     FOR y = 0 TO Ymax STEP s
10.         FOR x = 0 TO Xmax STEP s
11.             IF RND < .5 THEN t1 x, y ELSE t2 x, y
12.         NEXT
13.     NEXT
14.     FOR x = 1 TO 100
15.         PAINT (RND * Xmax, RND * Ymax), _RGB32(RND * 255, RND * 255, RND * 254), &HFFFFFFFF
16.         _LIMIT 30
17.     NEXT
18.     ' _DISPLAY
19.     SLEEP
20. LOOP UNTIL _KEYDOWN(27)
21.  
22. SUB t1 (x, y)
23.     LINE (x + sd2, y)-(x, y + sd2)
24.     LINE (x + s, y + sd2)-(x + sd2, y + s)
25. END SUB
26.  
27. SUB t2 (x, y)
28.     LINE (x + sd2, y)-(x + s, y + sd2)
29.     LINE (x, y + sd2)-(x + sd2, y + s)
30. END SUB
31.  
32.  

 

[Richard Frost]

What a gem - endless beauty from 26 lines of code, 25 since
the _DELAY should not be required.  I likes de foist one too.

[johannhowitzer]

Got inspired, so I pared this down to 16 lines, 15 if you don't care about the constants and just put their values in-line.  STEP is used to turn the two SUBs into three lines of code... r is set to 1 or -1, and then that's used to flip the result of the STEPs horizontally.  Thanks bplus!  That was really fun.

Code: QB64: [Select]

1. const w = 700, s = 5
2. screen _newimage(w, w, 32)
3. do
4.    cls
5.    for y = 0 to w step s * 2
6.       for x = 0 to w step s * 2
7.          r = ((int(rnd * 2)) * 2) - 1
8.          line(x + s, y)-step(s * r, s)
9.          line(x + s, y + (s * 2))-step(-s * r, -s)
10.       next
11.    next
12.    for x = 1 to 100
13.       paint(rnd * w, rnd * w), _rgb32(rnd * 255, rnd * 255, rnd * 254), &HFFFFFFFF
14.    next
15.    sleep
16. loop

[bplus]

Thanks Richard Frost, I am delighted we enjoy simple things.

Nice @johannhowitzer, 2 tile Subs down to 2 lines!

[bplus]

Take a walk amongst the tiles with keypad, diagonals burn bridges, up, down left right jumps corners and spacebar reverses all your neighbors! Just follow the yellow brick road!

Code: QB64: [Select]

1. _TITLE "Walk amongst the 2 Tilers: USE KEYPAD  Diagonal keys 7,9,3,1 burns bridges, 8,6,2,4 jumps corners, spacebar reverses neighbors" 'b+ 2021-01-17
2. RANDOMIZE TIMER
3. CONST Xmax = 1000, Ymax = 700, S = 20, Sd2 = S \ 2, Xcells = Xmax \ S, Ycells = Ymax \ S
4. SCREEN _NEWIMAGE(Xmax, Ymax, 32): _DELAY .25: _SCREENMOVE _MIDDLE
5. REDIM TS(Xcells, Ycells) AS LONG
6. FOR y = 0 TO Ycells
7.     FOR x = 0 TO Xcells
8.         TS(x, y) = INT(RND * 2)
9.     NEXT
10. NEXT
11. bx = Xcells \ 2: by = Ycells \ 2
12. DO
13.     CLS
14.     FOR y = 0 TO Ycells
15.         FOR x = 0 TO Xcells
16.             IF TS(x, y) THEN t1 x * S, y * S ELSE t2 x * S, y * S
17.         NEXT
18.     NEXT
19.     drawBplusPath bx, by
20.     numLock = _KEYDOWN(100300)
21.     KH& = _KEYHIT
22.  
23.     ' go diagonally if the target block is same as current                    and burn bridges as you go!
24.     IF KH& = 18176 OR (numLock AND (KH& = 55)) THEN 'up, left number 7
25.         IF bx - 1 >= 0 AND by - 1 >= 0 THEN
26.             IF TS(bx, by) = TS(bx - 1, by - 1) THEN
27.                 TS(bx, by) = (TS(bx, by) + 1) MOD 2
28.                 bx = bx - 1: by = by - 1
29.             END IF
30.         END IF
31.     ELSEIF KH& = 18688 OR (numLock AND (KH& = 57)) THEN ' up, right   number 9
32.         IF bx + 1 < Xcells AND by - 1 >= 0 THEN
33.             IF TS(bx, by) = TS(bx + 1, by - 1) THEN
34.                 TS(bx, by) = (TS(bx, by) + 1) MOD 2
35.                 bx = bx + 1: by = by - 1
36.             END IF
37.         END IF
38.     ELSEIF KH& = 20736 OR (numLock AND (KH& = 51)) THEN ' down right number 3
39.         IF bx + 1 < Xcells AND by + 1 < Ycells THEN
40.             IF TS(bx, by) = TS(bx + 1, by + 1) THEN
41.                 TS(bx, by) = (TS(bx, by) + 1) MOD 2
42.                 bx = bx + 1: by = by + 1
43.             END IF
44.         END IF
45.     ELSEIF KH& = 20224 OR (numLock AND (KH& = 49)) THEN ' down left number 1
46.         IF bx - 1 >= 0 AND by + 1 < Ycells THEN
47.             IF TS(bx, by) = TS(bx - 1, by + 1) THEN
48.                 TS(bx, by) = (TS(bx, by) + 1) MOD 2
49.                 bx = bx - 1: by = by + 1
50.             END IF
51.         END IF
52.  
53.         '                          ' go up down left right for cornering
54.     ELSEIF KH& = 18432 OR (numLock AND (KH& = 56)) THEN 'up
55.         IF by - 1 >= 0 THEN
56.             IF TS(bx, by) <> TS(bx, by - 1) THEN
57.                 by = by - 1
58.             END IF
59.         END IF
60.     ELSEIF KH& = 19712 OR (numLock AND (KH& = 54)) THEN 'right
61.         IF bx + 1 < Xcells THEN
62.             IF TS(bx, by) <> TS(bx + 1, by) THEN
63.                 bx = bx + 1
64.             END IF
65.         END IF
66.     ELSEIF KH& = 20480 OR (numLock AND (KH& = 50)) THEN 'down
67.         IF by + 1 < Ycells THEN
68.             IF TS(bx, by) <> TS(bx, by + 1) THEN
69.                 by = by + 1
70.             END IF
71.         END IF
72.  
73.     ELSEIF KH& = 19200 OR (numLock AND (KH& = 52)) THEN 'left
74.         IF bx - 1 >= 0 THEN
75.             IF TS(bx, by) <> TS(bx - 1, by) THEN
76.                 bx = bx - 1
77.             END IF
78.         END IF
79.     ELSEIF KH& = 32 THEN 'space bar, reverse your neighbors!
80.         FOR y = -1 TO 1
81.             FOR x = -1 TO 1
82.                 IF bx + x >= 0 AND bx + x < Xcells THEN
83.                     IF by + y >= 0 AND by + y < Ycells THEN
84.                         IF NOT (x = 0 AND y = 0) THEN
85.                             TS(bx + x, by + y) = (TS(bx + x, by + y) + 1) MOD 2
86.                         END IF
87.                     END IF
88.                 END IF
89.             NEXT
90.         NEXT
91.     END IF
92.     _DISPLAY
93.     _LIMIT 30
94.  
95. LOOP UNTIL _KEYDOWN(27)
96.  
97. SUB t1 (x, y)
98.     LINE (x + Sd2, y)-(x, y + Sd2), &HFF006600
99.     LINE (x + S, y + Sd2)-(x + Sd2, y + S), &HFF006600
100.     'LINE (x, y)-STEP(S, S), &HFFFFFFFF, B
101. END SUB
102.  
103. SUB t2 (x, y)
104.     LINE (x + Sd2, y)-(x + S, y + Sd2), &HFF006600
105.     LINE (x, y + Sd2)-(x + Sd2, y + S), &HFF006600
106.     'LINE (x, y)-STEP(S, S), &HFFFFFFFF, B
107. END SUB
108.  
109. SUB drawBplusPath (x, y)
110.     'CIRCLE (x * S + Sd2, y * S + Sd2), 2, &HFF006600
111.     PAINT (x * S + Sd2, y * S + Sd2), &HFFFFFF00, &HFF006600
112.     FOR r = 0 TO 6 STEP .25
113.         CIRCLE (x * S + Sd2, y * S + Sd2), r, &HFF0000FF
114.     NEXT
115.     COLOR , &H00000000
116.     _PRINTSTRING (x * S + Sd2 - 4, y * S + Sd2 - 7), "B"
117.     COLOR , &HFF000000
118. END SUB
119.  
120.  
121.  

 

[johannhowitzer]

Thanks Richard Frost, I am delighted we enjoy simple things.

Nice @johannhowitzer, 2 tile Subs down to 2 lines!

[NOVARSEG]

A variation with 2 lines of code.

How it works I don't know

working on a horizontal code so objects can move around the grid with arrow keys

Code: QB64: [Select]

1. DIM y AS INTEGER
2. DIM x AS INTEGER
3. DIM r AS INTEGER
4. DIM s AS INTEGER
5. DIM w AS INTEGER
6. s = 5
7. w = 700
8.  
9. SCREEN _NEWIMAGE(w, w, 32)
10. _FULLSCREEN
11.  
12. DO
13.  
14.     CLS
15.     IF INKEY$ = CHR$(27) THEN END
16.     FOR y = 0 TO w STEP s * 2
17.  
18.         FOR x = 0 TO w STEP s * 2
19.  
20.             r = ((INT(RND * 2)) * 2) - 1 'returns  -1, 1
21.  
22.             LINE (x - s * r, y)-(x, y + s)
23.             LINE (x + s * r, y)-(x, y - s)
24.  
25.         NEXT x
26.  
27.     NEXT y
28.     SLEEP
29. LOOP
30.  

[NOVARSEG]

It is hard to explain how the code generates the labyrinth.

This code will show how the diagonal labyrinth is generated.

press space bar to see how it works.

It should be possible to generate a vertical/horizontal labyrinth in the same way. 

Code: QB64: [Select]

1. DIM y AS INTEGER
2. DIM x AS INTEGER
3. DIM r AS INTEGER
4. DIM s AS INTEGER
5. DIM w AS INTEGER
6. DIM h AS INTEGER
7. s = 5
8. w = 1024
9. h = 768
10.  
11. SCREEN _NEWIMAGE(w, h, 32)
12. _FULLSCREEN
13.  
14. DO
15.  
16.     CLS
17.     'IF INKEY$ = CHR$(27) THEN END
18.     FOR y = 10 TO h STEP s * 2
19.  
20.         FOR x = 0 TO w STEP s * 2
21.  
22.             r = ((INT(RND * 2)) * 2) - 1 'returns  -1, 1
23.  
24.             LINE (x - s * r, y)-(x, y + s)
25.             LINE (x + s * r, y)-(x, y - s)
26.             DO
27.                 I$ = INKEY$
28.                 IF I$ = CHR$(27) THEN END
29.                 IF I$ = CHR$(32) THEN EXIT DO
30.             LOOP
31.  
32.         NEXT x
33.  
34.     NEXT y
35.     SLEEP
36.  
37. LOOP
38.  

Shows nice diagonal boxes if alternate 1, -1 are fed into the code

This gives an idea of how to generate a grid of horizontal / vertical boxes.

Code: QB64: [Select]

1. DIM y AS INTEGER
2. DIM x AS INTEGER
3. DIM r AS INTEGER
4. DIM s AS INTEGER
5. DIM w AS INTEGER
6. DIM h AS INTEGER
7. s = 5
8. w = 1024
9. h = 768
10. r = 1
11. SCREEN _NEWIMAGE(w, h, 32)
12. _FULLSCREEN
13.  
14. DO
15.  
16.     CLS
17.     'IF INKEY$ = CHR$(27) THEN END
18.     FOR y = 10 TO h STEP s * 2
19.  
20.         FOR x = 0 TO w STEP s * 2
21.  
22.             'r = ((INT(RND * 2)) * 2) - 1 'returns  -1, 1
23.  
24.             IF r = 1 THEN r = -1: GOTO LL
25.             IF r = -1 THEN r = 1: GOTO LL
26.             ' r = 1
27.  
28.             LL:
29.  
30.             LINE (x - s * r, y)-(x, y + s)
31.             LINE (x + s * r, y)-(x, y - s)
32.  
33.  
34.             DO
35.                 I$ = INKEY$
36.                 IF I$ = CHR$(27) THEN END
37.                 IF I$ = CHR$(32) THEN EXIT DO
38.             LOOP
39.  
40.         NEXT x
41.  
42.     NEXT y
43.     SLEEP
44.  
45. LOOP
46.  

[bplus]

This gives an idea of how to generate a grid of horizontal / vertical boxes.

Here is another way to see how 2 simple lines on 2 different tiles can make the "maze" by drawing the tile outlines.

Code: QB64: [Select]

1. CONST w = 700, s = 20
2. SCREEN _NEWIMAGE(w, w, 32)
3.  
4. CLS
5. FOR y = 0 TO w STEP s * 2
6.     FOR x = 0 TO w STEP s * 2
7.         r = ((INT(RND * 2)) * 2) - 1
8.         LINE (x + s, y)-STEP(s * r, s)
9.         LINE (x + s, y + (s * 2))-STEP(-s * r, -s)
10.         LINE (x, y)-STEP(2 * s, 2 * s), , B
11.     NEXT
12. NEXT
13.  

I did this to figure out how to move inside the "maze" with "arrow keys" on number pad
https://www.qb64.org/forum/index.php?topic=3498.msg128347#msg128347