Author Topic: reduce numbers of: for. next (Read 4136 times)

carloscordeiro · « **on:** January 01, 2021, 08:33:28 pm »

Code: QB64: [Select]

_TITLE "Qbasic 64"
SCREEN _NEWIMAGE(920, 740, 256)
_DELAY .25
_SCREENMOVE 20, 15
 
'Moldura...
LINE (0, 0)-(929, 719), 11, B 'Moldura inteira
LINE (1, 1)-(928, 718), 11, B
LINE (2, 2)-(927, 717), 11, B
LINE (3, 3)-(926, 716), 11, B
LINE (4, 4)-(925, 715), 11, B
 
LINE (927, 40)-(2, 40), 11, B 'Linha Horizontal
LINE (927, 41)-(2, 41), 11, B
'LINE (817, 45)-(2, 45), 11, B
 
'Mostra Data
d$ = MID$(DATE$, 1, 3)
c$ = MID$(DATE$, 4, 3)
e$ = MID$(DATE$, 7, 4)
f$ = c$ + d$ + e$
COLOR 11: LOCATE 2, 40: PRINT "* * * Repeated dozens  * * *"
LOCATE 2, 105: PRINT TIME$
LOCATE 2, 4: PRINT f$: COLOR 7
'----------------------------------------------------------------------------
 
 
DIM n(1 TO 3000) AS STRING * 41 ' Is this variable declared correctly?
DIM nt(1 TO 3000) AS STRING * 41 ' Is this variable declared correctly?
DIM total AS _INTEGER64 ' Is this variable declared correctly?
DIM ei AS _INTEGER64 ' Is this variable declared correctly?
DIM v AS _INTEGER64 ' Is this variable declared correctly?
DIM b AS _INTEGER64 ' Is this variable declared correctly?
DIM r AS _INTEGER64 ' Is this variable declared correctly?
DIM t AS _INTEGER64 ' Is this variable declared correctly?
 
'Is there a need to declare all variables used in Qbasic 64?
 
 
OPEN "complete.txt" FOR INPUT AS #1
total = LOF(1) \ 41
COLOR 15: LOCATE 4, 3: PRINT "Number of records =>"; total: COLOR 7
FOR t = 1 TO total
    LINE INPUT #1, n$(t)
NEXT t
CLOSE #1
 
 
FOR r = 1 TO total '   Put the number 11 in order
    FOR ei = 1 TO total - 1
        IF VAL(MID$(n$(ei), 14, 3)) > VAL(MID$(n$(ei + 1), 14, 3)) THEN
            SWAP n$(ei), n$(ei + 1)
        END IF
    NEXT ei
NEXT
 
v = 5
FOR b = total TO total - 38 STEP -1 ' Sort by highest number of times
    v = v + 1
    COLOR 15: LOCATE v, 3: PRINT LEFT$(n$(b), 4); " => ";: COLOR 11: PRINT ; MID$(n$(b), 9, 8);: COLOR 29: PRINT " - Times"
NEXT b
 
FOR r = 1 TO total 'Put the number 12 in order
    FOR ei = 1 TO total - 1
        IF VAL(MID$(n$(ei), 23, 2)) > VAL(MID$(n$(ei + 1), 23, 2)) THEN
            SWAP n$(ei), n$(ei + 1)
        END IF
    NEXT ei
NEXT
 
v = 5
FOR b = total TO total - 38 STEP -1 'Sort by highest number of times
    v = v + 1
    COLOR 15: LOCATE v, 31: PRINT LEFT$(n$(b), 4); " => ";: COLOR 12: PRINT MID$(n$(b), 18, 7);: COLOR 29: PRINT " - Times"
NEXT b
 
FOR r = 1 TO total 'Put the number 13 in order
    FOR ei = 1 TO total - 1
        IF VAL(MID$(n$(ei), 31, 2)) > VAL(MID$(n$(ei + 1), 31, 2)) THEN
            SWAP n$(ei), n$(ei + 1)
        END IF
    NEXT ei
NEXT
 
v = 5
FOR b = total TO total - 38 STEP -1 'Sort by highest number of times
    v = v + 1
    COLOR 15: LOCATE v, 58: PRINT LEFT$(n$(b), 4); " => ";: COLOR 13: PRINT MID$(n$(b), 26, 7);: COLOR 29: PRINT " - Times"
NEXT b
 
FOR r = 1 TO total 'Put the number 14 in order
    FOR ei = 1 TO total
        IF VAL(MID$(n$(ei), 39, 2)) > VAL(MID$(n$(ei + 1), 39, 2)) THEN
            SWAP n$(ei), n$(ei + 1)
        END IF
    NEXT ei
NEXT
 
v = 5
FOR b = total TO total - 38 STEP -1 'Sort by highest number of times
    v = v + 1
    COLOR 15: LOCATE v, 85: PRINT LEFT$(n$(b), 4); " => ";: COLOR 14: PRINT MID$(n$(b), 34, 6);: COLOR 29: PRINT " - Times"
NEXT b

Hi Bplus,
Happy New Year to you and everyone on the forum.

I come again to ask you an idea without sub. To to decrease the number of for ... next of the code that I made.
They are making the code slow. for excess of repeating the same thing.

I want to remind you that this code is similar to another one that you solved .: https://www.qb64.org/forum/index.php?topic=3209.msg124899#msg124899

I don't want association but to leave it faster.

In the file complete.txt, there are 2120 lines. Each line has 4 numbers from 11 to 14.

Each number has a result. This result is the repetition of times of himself.

Here is an example of the complete.txt file.

0001 => 11 = 208 12 = 38 13 = 04 14 = 0
0002 => 11 = 181 12 = 35 13 = 06 14 = 0
0003 => 11 = 178 12 = 41 13 = 02 14 = 0
0004 => 11 = 188 12 = 41 13 = 03 14 = 0

I believe, that this time, it is more explained for a better understanding.

Carlos.

bplus · « **Reply #1 on:** January 01, 2021, 10:15:05 pm »

Hi Carlos, happy New Year!

I am still working on a version of TTT that ARB got me wondering about. I'll be back to this tomorrow, maybe really late tonight.

Maybe someone else can work it out before me :)

bplus · « **Reply #2 on:** January 02, 2021, 02:09:08 am »

Quote

I come again to ask you an idea without sub.

Sorry, if you want kick-butt time you need a proper sort routine! Here is that!

Code: QB64: [Select]

_TITLE "carlos Qbasic 64 mod bplus 2021-01-02  Any key to page down the whole table!"
SCREEN _NEWIMAGE(930, 600, 32)
_DELAY .25
_SCREENMOVE _MIDDLE
 
'Is there a need to declare all variables used in Qbasic 64?   >>>> don't have to  unless use OPTION _EXPLICT,  but good form!
 
DEFLNG A-Z '   make everything long unless $ for string
TYPE record
    index AS LONG
    value AS LONG
END TYPE
REDIM n11(1 TO 2120) AS record, n12(1 TO 2120) AS record, n13(1 TO 2120) AS record, n14(1 TO 2120) AS record
OPEN "complete.txt" FOR INPUT AS #1
total = LOF(1) \ 41
FOR t = 1 TO 2120
    LINE INPUT #1, fline$
    n11(t).index = t: n11(t).value = VAL(MID$(fline$, 14, 3))
    n12(t).index = t: n12(t).value = VAL(MID$(fline$, 23, 2))
    n13(t).index = t: n13(t).value = VAL(MID$(fline$, 31, 2))
    n14(t).index = t: n14(t).value = VAL(MID$(fline$, 39, 2))
NEXT t
CLOSE #1
QuickSort 1, 2120, n11()
QuickSort 1, 2120, n12()
QuickSort 1, 2120, n13()
QuickSort 1, 2120, n14()
GOSUB drawFrame
FOR i = 1 TO 2120
    COLOR &HFFCCCCCC
    LOCATE , 3: PRINT RIGHT$(SPC(4) + STR$(i), 4);
    COLOR &HFFAAAAFF
    LOCATE , 15: PRINT "N11: "; RIGHT$(SPC(4) + STR$(n11(i).index), 4); " = "; RIGHT$(SPC(3) + STR$(n11(i).value), 3);
    COLOR &HFFFF0000
    LOCATE , 40
    PRINT "N12: "; RIGHT$(SPC(4) + STR$(n12(i).index), 4); " = "; RIGHT$(SPC(3) + STR$(n12(i).value), 3);
    COLOR &HFFFFFF00
    LOCATE , 65
    PRINT "N13: "; RIGHT$(SPC(4) + STR$(n13(i).index), 4); " = "; RIGHT$(SPC(3) + STR$(n13(i).value), 3);
    COLOR &HFF8800FF
    LOCATE , 90
    PRINT "N14: "; RIGHT$(SPC(4) + STR$(n14(i).index), 4); " = "; RIGHT$(SPC(3) + STR$(n14(i).value), 3)
    IF i MOD 25 = 24 THEN SLEEP: CLS: GOSUB drawFrame
NEXT
SLEEP
END
 
drawFrame:
'Moldura...
LINE (0, 0)-(929, 599), &HFFCCCCCC, B 'Moldura inteira
LINE (1, 1)-(928, 598), &HFFCCCCCC, B
LINE (2, 2)-(927, 597), &HFFCCCCCC, B
LINE (3, 3)-(926, 596), &HFFCCCCCC, B
LINE (4, 4)-(925, 595), &HFFCCCCCC, B
 
LINE (927, 40)-(2, 40), &HFFCCCCCC, B 'Linha Horizontal
LINE (927, 41)-(2, 41), &HFFCCCCCC, B
 
'Mostra Data
d$ = MID$(DATE$, 1, 3)
c$ = MID$(DATE$, 4, 3)
e$ = MID$(DATE$, 7, 4)
f$ = c$ + d$ + e$
COLOR &HFFCCCCCC: LOCATE 2, 40: PRINT "* * * Repeated dozens  * * *"
LOCATE 2, 105: PRINT TIME$
LOCATE 2, 4: PRINT f$
LOCATE 4, 3: PRINT "Number of records =>"; total
LOCATE 5, 3: PRINT
RETURN
 
SUB QuickSort (start AS LONG, finish AS LONG, array() AS record)
    DIM Hi AS LONG, Lo AS LONG, Middle AS SINGLE
    Hi = finish: Lo = start
    Middle = array((Lo + Hi) / 2).value 'find middle of array
    DO
        DO WHILE array(Lo).value > Middle: Lo = Lo + 1: LOOP
        DO WHILE array(Hi).value < Middle: Hi = Hi - 1: LOOP
        IF Lo <= Hi THEN
            SWAP array(Lo), array(Hi)
            Lo = Lo + 1: Hi = Hi - 1
        END IF
    LOOP UNTIL Lo > Hi
    IF Hi > start THEN CALL QuickSort(start, Hi, array())
    IF Lo < finish THEN CALL QuickSort(Lo, finish, array())
END SUB
 
 
 

EDIT: fixed alignment of numbers

carloscordeiro · « **Reply #3 on:** January 02, 2021, 06:20:57 pm »

Hi Bplus
I am very old to work with routines.
I always liked simple code ...
Your code is excellent, very fast compared to mine, full of FOR ... NEXT.
I saw many lines in your classification routine that I can take advantage of in another way, without many FOR.NEXT.
Since I registered in this forum, I have learned and enjoyed many lines of your codes and also Mr. SMcNeill codes, in the first posts.
Again, thanks for replying

Carlos

carloscordeiro · « **Reply #4 on:** January 06, 2021, 08:44:07 pm »

Hi Bplus
good evening

I was able to create a code without SUB, copying several lines of its routine classification code.

I want to point out that you are very skilled at creating code.
I really like the lines you create.

I put a timer to compare the execution time. I was wondering if my code's time was approaching with yours.

Of course, that was just out of curiosity.

Nowhere has mine come close to yours in terms of execution time.
However, it is much better than the first one I did, full of FOR ... NEXT.

I want to end with a question:
Why did the COLOR statement change the value to hexadecimal?

Carlos

Code: QB64: [Select]

_TITLE "Qbasic 64  Version Version without SUB, copied several lines of the Bplus friend code."
SCREEN _NEWIMAGE(930, 600, 32)
_DELAY .25
_SCREENMOVE _MIDDLE
REDIM n11(0 TO 1, 1 TO 2120)
REDIM n12(0 TO 1, 1 TO 2120)
REDIM n13(0 TO 1, 1 TO 2120)
REDIM n14(0 TO 1, 1 TO 2120)
 
PRINT
td# = TIMER(.001)
PRINT td#
 
OPEN "complete.txt" FOR INPUT AS #1
total = LOF(1) \ 41
FOR t = 1 TO 2120
    LINE INPUT #1, fline$
    n11(0, t) = t: n11(1, t) = VAL(MID$(fline$, 14, 3))
    n12(0, t) = t: n12(1, t) = VAL(MID$(fline$, 23, 2))
    n13(0, t) = t: n13(1, t) = VAL(MID$(fline$, 31, 2))
    n14(0, t) = t: n14(1, t) = VAL(MID$(fline$, 39, 2))
NEXT t
CLOSE #1
 
GOSUB drawFrame
 
FOR i = 1 TO 2119
    FOR j = i + 1 TO 2120
        IF n11(1, i) < n11(1, j) THEN
            SWAP n11(0, j), n11(0, i)
            SWAP n11(1, j), n11(1, i)
        END IF
        IF n12(1, i) < n12(1, j) THEN
            SWAP n12(0, j), n12(0, i)
            SWAP n12(1, j), n12(1, i)
        END IF
        IF n13(1, i) < n13(1, j) THEN
            SWAP n13(0, j), n13(0, i)
            SWAP n13(1, j), n13(1, i)
        END IF
        IF n14(1, i) < n14(1, j) THEN
            SWAP n14(0, j), n14(0, i)
            SWAP n14(1, j), n14(1, i)
        END IF
    NEXT
NEXT
 
FOR i = 1 TO 2120
    COLOR &HFFCCCCCC
    LOCATE , 3: PRINT RIGHT$(SPC(3) + STR$(i), 4);
    COLOR &HFFAAAAFF
    LOCATE , 15: PRINT "N11: "; RIGHT$("0000" + LTRIM$(STR$(n11(0, i))), 4); " ="; n11(1, i);
    COLOR &HFFFF0000
    LOCATE , 40
    PRINT "N12: "; RIGHT$("0000" + LTRIM$(STR$(n12(0, i))), 4); " ="; n12(1, i);
    COLOR &HFFFFFF00
    LOCATE , 65
    PRINT "N13: "; RIGHT$("0000" + LTRIM$(STR$(n11(0, i))), 4); " ="; n13(1, i);
    COLOR &HFF8800FF
    LOCATE , 90
    PRINT "N14: "; RIGHT$("0000" + LTRIM$(STR$(n11(0, i))), 4); " ="; n14(1, i)
    'IF i MOD 25 = 24 THEN td# = TIMER(.001): PRINT td#: SLEEP: GOSUB drawFrame
NEXT
 
END
drawFrame:
'Moldura...
LINE (0, 0)-(929, 599), &HFFCCCCCC, B 'Moldura inteira
LINE (1, 1)-(928, 598), &HFFCCCCCC, B
LINE (2, 2)-(927, 597), &HFFCCCCCC, B
LINE (3, 3)-(926, 596), &HFFCCCCCC, B
LINE (4, 4)-(925, 595), &HFFCCCCCC, B
 
LINE (927, 40)-(2, 40), &HFFCCCCCC, B 'Linha Horizontal
LINE (927, 41)-(2, 41), &HFFCCCCCC, B
 
'Mostra Data
'd$ = MID$(DATE$, 1, 3)
'c$ = MID$(DATE$, 4, 3)
'e$ = MID$(DATE$, 7, 4)
'f$ = c$ + d$ + e$
COLOR &HFFCCCCCC: LOCATE 2, 40: PRINT "* * * Repeated dozens  * * *"
LOCATE 2, 105: PRINT TIME$
LOCATE 2, 4: PRINT f$
LOCATE 4, 3: PRINT "Number of records =>"; total
LOCATE 5, 3: PRINT
RETURN
 
]

bplus · « **Reply #5 on:** January 06, 2021, 09:26:42 pm »

Quote

Why did the COLOR statement change the value to hexadecimal?

Hi @carloscordeiro,

I changed the colors.

SCREEN _NEWIMAGE(930, 600, 32) '<<<< the 32 here allows me to use the full blown range of color QB64 is capable of giving us 255 * 255 * 255 colors at 255 transparency levels.

&H FF FF FF FF 'white at full opaque or solid color, no see through

the first set of FF is transparency or lack of 0 is transparent 255 or hex FF is solid
2nd set of FF's are red 0 to 255, or 00 to FF in hex
3rd set of FF's are green 0 to 255 or 00 to FF in hex
4th set of FF's are blue 0 to 255 or 00 toFF in hex

&HFFFFFFFF (white) = _RGB32(255, 255, 255, 255)

&HFFFFFF00 (yellow = full red + full green) = _RGB32(255, 255, 0) ' without 4th transparent = 255 default

&HFF0000FF (blue) = _RGB32(0, 0, 255)

half transparent blue &H880000FF or _RGB32(0, 0, 255, 128)

notice alpha = transparent level is on left in the hex number but last on right 4th place in _RGB32(red, green, blue, alpha ) number.

carloscordeiro · « **Reply #6 on:** January 07, 2021, 07:31:48 am »

Bplus, would it be like this image? Or have more colors in HEX?

You may have already noticed that I love colors. :)

bplus · « **Reply #7 on:** January 07, 2021, 10:15:36 am »

Quote from: carloscordeiro on January 07, 2021, 07:31:48 am

Bplus, would it be like this image? Or have more colors in HEX?

You may have already noticed that I love colors. :)

Yeah, colors are saver for me for Winters in N. Ohio, USA, we have clouds and occasional snow move in November and do not really leave until April.

Both Hex color method or _RGB32 have 255 * 255 * 255 color mixes = 16,581,375 plus 255 levels of transparencies.

Hex is just a quicker way to input color for me and might be slightly faster compiling as they are constant literals, maybe you'd like _RGB32() better because the numbers are base 10 instead of base 16.

Just waves of color, press spacebar for different patterns.

Code: QB64: [Select]

_TITLE "Wavy with Plama:  Press Spacebar for New Plasma Injection."
' for QB64 fork (B+=MGA) 2017-05-05
' Wavy with Plasma Treatment.bas SmallBASIC 0.12.9 (B+=MGA) 2017-05-03
' from: animated circles started by Admin at SdlBasic 2017-05-03
' I added Plasma treatment and spacebar  changer
 
' 2018-08-04 updated with better circle fill
 
'===================================================================
 
' Instructions: press spacebar for new injection of plasma
 
'==================================================================
 
RANDOMIZE TIMER
 
CONST xmax = 1100
CONST ymax = 700
CONST DPI = 3.141516 * 2
CONST PHIDELTA = DPI / 15
CONST PHISTEP = DPI / 50
CONST RADIUS = 20
CONST SMALL_R = 20
CONST DISTANCE = 23
CONST W = xmax
CONST H = ymax
 
SCREEN _NEWIMAGE(xmax, ymax, 32)
_SCREENMOVE (1280 - xmax) / 2 + 30, (760 - ymax) / 2
DIM SHARED cN AS DOUBLE
DIM SHARED pR, pG, pB AS INTEGER
DIM x, y, xball, yball AS INTEGER
DIM current_phi, phiIndex, phi AS DOUBLE
current_phi = 0
cN = 1
resetPlasma
WHILE NOT _KEYDOWN(27)
    CLS
    _LIMIT 10
    IF _KEYHIT = 32 THEN cN = 1: resetPlasma
    current_phi = current_phi + PHISTEP
    FOR x = 0 TO (W + RADIUS) STEP DISTANCE
        FOR y = 0 TO (H + RADIUS) STEP DISTANCE
            phiIndex = ((x + y) MOD (2 * W)) / RADIUS
            phi = phiIndex * PHIDELTA + current_phi
            xball = COS(phi) * RADIUS + x
            yball = SIN(phi) * RADIUS + y
            changePlasma
            fcirc xball, yball, SMALL_R
        NEXT
    NEXT
    _DISPLAY
WEND
 
SUB changePlasma ()
    cN = cN + 1
    COLOR _RGB(127 + 127 * SIN(pR * cN), 127 + 127 * SIN(pG * cN), 127 + 127 * SIN(pB * cN))
END SUB
 
SUB resetPlasma ()
    pR = RND: pG = RND: pB = RND
END SUB
 
'Steve McNeil's  copied from his forum   note: Radius is too common a name
SUB fcirc (CX AS LONG, CY AS LONG, R AS LONG)
    DIM subRadius AS LONG, RadiusError AS LONG
    DIM X AS LONG, Y AS LONG
 
    subRadius = ABS(R)
    RadiusError = -subRadius
    X = subRadius
    Y = 0
 
    IF subRadius = 0 THEN PSET (CX, CY): EXIT SUB
 
    ' Draw the middle span here so we don't draw it twice in the main loop,
    ' which would be a problem with blending turned on.
    LINE (CX - X, CY)-(CX + X, CY), , BF
 
    WHILE X > Y
        RadiusError = RadiusError + Y * 2 + 1
        IF RadiusError >= 0 THEN
            IF X <> Y + 1 THEN
                LINE (CX - Y, CY - X)-(CX + Y, CY - X), , BF
                LINE (CX - Y, CY + X)-(CX + Y, CY + X), , BF
            END IF
            X = X - 1
            RadiusError = RadiusError - X * 2
        END IF
        Y = Y + 1
        LINE (CX - X, CY - Y)-(CX + X, CY - Y), , BF
        LINE (CX - X, CY + Y)-(CX + X, CY + Y), , BF
    WEND
END SUB
 

Ohpe! here is another, better not get me going on color, hahahah! This is simple demo of what I call plasma.

Code: QB64: [Select]

_TITLE "Scrolling Plasma Lines, press spacebar for new colors" 'B+ 2019-10-09
CONST xmax = 800, ymax = 600
SCREEN _NEWIMAGE(xmax, ymax, 32)
_SCREENMOVE 300, 40
DIM ln(0 TO ymax) AS _UNSIGNED LONG
r = RND ^ 2: g = RND ^ 2: b = RND ^ 2
WHILE 1
    IF INKEY$ = " " THEN r = RND ^ 2: g = RND ^ 2: b = RND ^ 2
    FOR i = UBOUND(ln) - 1 TO 0 STEP -1
        ln(i + 1) = ln(i)
        LINE (0, i)-STEP(xmax, 1), ln(i + 1), BF
    NEXT
    ln(0) = _RGB32(127 + 127 * SIN(r * c), 127 + 127 * SIN(g * c), 127 + 127 * SIN(b * c))
    c = c + 1
    _DISPLAY
    _LIMIT 60
WEND
 

carloscordeiro · « **Reply #8 on:** January 07, 2021, 06:18:11 pm »

Bplus, I couldn't find the numerals of each value corresponding to the colors in your two examples.

Would this be the way to know all the corresponding numbers of each _RGB32 () color values? Or do you have a better idea for showing all color values?
Carlos

Code: QB64: [Select]

SCREEN _NEWIMAGE(820, 700, 32)
 
FOR i = 1 TO 255
    COLOR _RGB32(i, 255, 255)
    PRINT "Carlos"; i;
 
    COLOR _RGB32(255, i, 255)
    PRINT "Carlos"; i;
 
    COLOR _RGB32(255, 255, i)
    PRINT "Carlos"; i;
 
    COLOR _RGB32(i, i, 255)
    PRINT "Carlos"; i;
 
    COLOR _RGB32(i, 255, i)
    PRINT "Carlos"; i;
 
    COLOR _RGB32(255, i, i)
    PRINT "Carlos"; i;
 
    _DELAY .1
NEXT
 
]

bplus · « **Reply #9 on:** January 07, 2021, 07:34:41 pm »

Ha! That's inspiring! ;-))

Here is the complete list:

Code: QB64: [Select]

_TITLE "ALL the colors, got a minute? hahaha!"
SCREEN _NEWIMAGE(800, 700, 32)
_DELAY .25
_SCREENMOVE _MIDDLE
x$ = SPC(80)
FOR r = 0 TO 255
    FOR g = 0 TO 255
        FOR b = 0 TO 255
            COLOR _RGB32(r, g, b)
            i = i + 1
            MID$(x$, 1, 80) = "This is color " + TS$(i) + ", _RGB32(" + TS$(r) + ", " + TS$(g) + ", " + TS$(b) + ")"
            PRINT x$
            _LIMIT 60
        NEXT
    NEXT
NEXT
SLEEP
 
FUNCTION TS$ (n AS LONG)
    TS$ = _TRIM$(STR$(n))
END FUNCTION
 
 

1000 times faster, all the colors /1000

Code: QB64: [Select]

_TITLE "ALL the colors / 1000, got a minute? hahaha!"
SCREEN _NEWIMAGE(800, 700, 32)
_DELAY .25
_SCREENMOVE _MIDDLE
x$ = SPC(80)
FOR r = 0 TO 255 STEP 10
    FOR g = 0 TO 255 STEP 10
        FOR b = 0 TO 255 STEP 10
            COLOR _RGB32(r, g, b)
            i = i + 1
            MID$(x$, 1, 80) = "This is color " + TS$(i) + ", _RGB32(" + TS$(r) + ", " + TS$(g) + ", " + TS$(b) + ")"
            PRINT x$
            _LIMIT 60
        NEXT
    NEXT
NEXT
SLEEP
 
FUNCTION TS$ (n AS LONG)
    TS$ = _TRIM$(STR$(n))
END FUNCTION
 
 

carloscordeiro · « **Reply #10 on:** January 07, 2021, 08:32:06 pm »

Okay, Bplus,
You have made a simple routine that I can use in the future. I thought that routines would be just complex. I see it can be done without advanced lines as you are used to doing them.

thank you very much

Carlos

News:

Author Topic: reduce numbers of: for. next (Read 4136 times)

carloscordeiro

reduce numbers of: for. next

bplus

Re: reduce numbers of: for. next

bplus

Re: reduce numbers of: for. next

carloscordeiro

Re: reduce numbers of: for. next

carloscordeiro

Re: reduce numbers of: for. next

bplus

Re: reduce numbers of: for. next

carloscordeiro

Re: reduce numbers of: for. next

bplus

Re: reduce numbers of: for. next

carloscordeiro

Re: reduce numbers of: for. next

bplus

Re: reduce numbers of: for. next

carloscordeiro

Re: reduce numbers of: for. next