Author Topic: Bouncing Balls over a Plasma sky (Read 6007 times)

Dav · « **on:** December 25, 2020, 10:03:06 pm »

Playing around with some old source code, trying to turn it into something more interesting. Here are bouncing balls combined with a plasma background. Runs kind of slow on my PC, but maybe not on yours...

- Dav

Code: QB64: [Select]

'Balls&Plasma.bas
 
SCREEN _NEWIMAGE(700, 700, 32)
 
f = _LOADFONT("cyberbit.ttf", 30): _FONT f
_PRINTMODE _KEEPBACKGROUND
 
balls = 50: size = 40: speed = 10
 
DIM BallX(balls), BallY(balls)
DIM BallXdir(balls), BallYdir(balls)
DIM BallSpeed(balls), BallSize(balls)
 
w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
 
'Generate random ball data
FOR B = 1 TO balls
    BallX(B) = RND * w: BallY(B) = RND * h
    BallSpeed(B) = RND * speed + 1
    BallSize(B) = 40 + (RND * 50)
NEXT
 
DO
    CLS
    'compute ball movement
    FOR t = 1 TO balls
        IF BallX(t) > w - BallSize(t) THEN BallXdir(t) = 0
        IF BallX(t) < BallSize(t) THEN BallXdir(t) = 1
        IF BallXdir(t) THEN BallX(t) = BallX(t) + BallSpeed(t) ELSE BallX(t) = BallX(t) - BallSpeed(t)
        IF BallY(t) > h - BallSize(t) THEN BallYdir(t) = 0
        IF BallY(t) < BallSize(t) THEN BallYdir(t) = 1
        IF BallYdir(t) THEN BallY(t) = BallY(t) + BallSpeed(t) ELSE BallY(t) = BallY(t) - BallSpeed(t)
    NEXT
    'draw plasma
    t = TIMER
    FOR x = 0 TO w
        FOR y = 0 TO h STEP 2
            r = SIN(1.1 * t) * h2 - y + h2
            g = SIN(.9 * t) * w2 - x + w2
            B = SIN(x / w2 + t + y / h2) * r
            PSET (x, y), _RGB(r, g, B)
        NEXT
        t = t + .01
    NEXT
    'draw balls
    FOR i = 1 TO balls
        ball BallX(i), BallY(i), BallSize(i), 255 - (4 * i), (4 * i), (5 * i)
        _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), STR$(i)
    NEXT
    _DISPLAY: _LIMIT 60
LOOP
 
 
SUB ball (BallX, BallY, size, r, g, b)
    FOR s = 1 TO size STEP .5
        CIRCLE (BallX, BallY), s, _RGB(r, g, b)
        r = r - 1: g = g - 1: b = b - 1
    NEXT
END SUB
 

TempodiBasic · « **Reply #1 on:** December 26, 2020, 12:56:13 pm »

Cool!
On my i3 Toshiba with HDD runs very well, maybe on another faster machine we need a _limit in the loop.

NOVARSEG · « **Reply #2 on:** December 26, 2020, 08:05:08 pm »

Tried to get a realistic collision between balls. Not that easy. Calculated the distance between balls.

The code will print out the distance and will delay 1 second when there is a collision.

Code: QB64: [Select]

'Balls&Plasma.bas
 
SCREEN _NEWIMAGE(700, 700, 32)
 
f = _LOADFONT("cyberbit.ttf", 30): _FONT f
_PRINTMODE _KEEPBACKGROUND
 
balls = 2: size = 40: speed = 10
 
DIM BallX(balls), BallY(balls)
DIM BallXdir(balls), BallYdir(balls)
DIM BallSpeed(balls), BallSize(balls)
 
w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
 
'Generate random ball data
FOR B = 1 TO balls
    BallX(B) = RND * w: BallY(B) = RND * h
    BallSpeed(B) = RND * speed + 1
    BallSize(B) = 40 '+ (RND * 50)
NEXT
 
DO
    CLS
    'compute ball movement
    FOR t = 1 TO balls
 
 
        d% = ((BallX(1) - BallX(2)) ^ 2 + (BallY(1) - BallY(2)) ^ 2) ^ .5
        PRINT d%
 
        'IF d% <= 80 THEN _DELAY 1
 
 
        IF BallX(t) > w - BallSize(t) THEN BallXdir(t) = 1
        IF BallX(t) < BallSize(t) THEN BallXdir(t) = 0
 
        IF BallY(t) > h - BallSize(t) THEN BallYdir(t) = 1
        IF BallY(t) < BallSize(t) THEN BallYdir(t) = 0
 
        IF BallXdir(t) = 0 THEN BallX(t) = BallX(t) + BallSpeed(t)
        IF BallXdir(t) = 1 THEN BallX(t) = BallX(t) - BallSpeed(t)
 
        IF BallYdir(t) = 0 THEN BallY(t) = BallY(t) + BallSpeed(t)
        IF BallYdir(t) = 1 THEN BallY(t) = BallY(t) - BallSpeed(t)
 
 
 
        ' IF BallYdir(t) = 0 THEN BallY(t) = BallY(t) + BallSpeed(t) ELSE BallY(t) = BallY(t) - BallSpeed(t)
    NEXT
    'draw plasma
    t = TIMER
    FOR x = 0 TO w
        FOR y = 0 TO h STEP 2
            r = SIN(1.1 * t) * h2 - y + h2
            g = SIN(.9 * t) * w2 - x + w2
            B = SIN(x / w2 + t + y / h2) * r
            PSET (x, y), _RGB(r, g, B)
        NEXT
        t = t + .01
    NEXT
    'draw balls
    FOR i = 1 TO balls
        ball BallX(i), BallY(i), BallSize(i), 255 - (4 * i), (4 * i), (5 * i)
        _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), STR$(i)
    NEXT
    _DISPLAY: _LIMIT 60
    IF d% <= 80 THEN _DELAY 1
LOOP
 
 
SUB ball (BallX, BallY, size, r, g, b)
    FOR s = 1 TO size STEP .5
        CIRCLE (BallX, BallY), s, _RGB(r, g, b)
        r = r - 1: g = g - 1: b = b - 1
    NEXT
END SUB
 

Dav · « **Reply #3 on:** December 26, 2020, 08:50:57 pm »

@TempodiBasic : Thanks for trying it out!

@NOVARSEG : That's pretty good. I may have to borrow that method for something. Thanks for trying the code out.

I tried to make a little game out of this, clicking away the balls in order, starting at ball 1. Not perfect as I'm reading squares of mouse x/y input data, and the balls are in circles. Messy code here warning, but it's a start at least. I tweaked the plasma code to made it smoother on my slow laptop.

- Dav

Code: QB64: [Select]

'ClickAwayBalls.bas
'by Dav, DEC/2020
 
'Click on balls in order, starting at 1 untill all gone.
 
 
SCREEN _NEWIMAGE(700, 700, 32)
 
f = _LOADFONT("cyberbit.ttf", 30): _FONT f
_PRINTMODE _KEEPBACKGROUND
 
balls = 15: size = 40: speed = 10
 
DIM BallX(balls), BallY(balls)
DIM BallXdir(balls), BallYdir(balls)
DIM BallSpeed(balls), BallSize(balls)
DIM BallShow(balls)
 
w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
 
'Generate random ball data
FOR B = 1 TO balls
    BallX(B) = RND * w: BallY(B) = RND * h
    BallSpeed(B) = RND * speed + 1
    BallSize(B) = 40 + (RND * 50)
    BallShow(B) = 1
NEXT
 
curball = 1
 
DO
    CLS
    'compute ball movement
    FOR t = 1 TO balls
        IF BallX(t) > w - BallSize(t) THEN BallXdir(t) = 0
        IF BallX(t) < BallSize(t) THEN BallXdir(t) = 1
        IF BallXdir(t) THEN BallX(t) = BallX(t) + BallSpeed(t) ELSE BallX(t) = BallX(t) - BallSpeed(t)
        IF BallY(t) > h - BallSize(t) THEN BallYdir(t) = 0
        IF BallY(t) < BallSize(t) THEN BallYdir(t) = 1
        IF BallYdir(t) THEN BallY(t) = BallY(t) + BallSpeed(t) ELSE BallY(t) = BallY(t) - BallSpeed(t)
    NEXT
    'draw background
    t = TIMER
    FOR x = 0 TO w
        FOR y = 0 TO h
            r = SIN(1.1 * t) * h2 - y + h2
            PSET (x, y), _RGB(r, r - y, -r)
        NEXT
        t = t + .01
        GOSUB GetMouseClick
    NEXT
 
    IF gameover = 1 THEN
        PLAY "o2l16cegagfefgabgc3l4"
        END
    END IF
 
    'draw balls
    FOR i = 1 TO balls
        IF BallShow(i) = 1 THEN
            ball BallX(i), BallY(i), BallSize(i), 255 - (4 * i), (4 * i), (5 * i)
            _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), STR$(i)
        END IF
    NEXT
 
    LOCATE 1, 1: PRINT "Click ball.."; curball;
    _DISPLAY: _LIMIT 60
 
    'If click on only one ball (no overlayed ones) remove it
    IF found = 1 THEN
        IF firstball = curball THEN
            'erase ball
            ball BallX(firstball), BallY(firstball), BallSize(firstball), 255, 200, 200
            BallShow(firstball) = 0
            PLAY "mbl32o2ceg"
            _DISPLAY: _DELAY .05
            curball = curball + 1
            found = 0
        ELSE
            found = found + 1
            lastfound = firstball
        END IF
    END IF
 
    'If clicked over several balls, highlight the top most one
    IF found > 1 THEN
        'BallShow(lastfound) = 0
        ball BallX(lastfound), BallY(lastfound), BallSize(lastfound), 255, 200, 100
        _PRINTSTRING (BallX(lastfound) - 15, BallY(lastfound) - 15), STR$(lastfound)
        _DISPLAY: PLAY "mbl32o2bo3fo2b"
        found = 0
        _DELAY .1
    END IF
 
    'check if all calls clicked away
    anyleft = 0
    FOR c = 1 TO balls
        IF BallShow(c) = 1 THEN anyleft = anyleft + 1
    NEXT
    IF anyleft = 0 THEN
        gameover = 1
    END IF
 
LOOP
 
END
 
'==============
GetMouseClick:
'==============
 
mi = _MOUSEINPUT
IF _MOUSEBUTTON(1) = 0 THEN done = 0
IF _MOUSEBUTTON(1) AND done = 0 THEN
    mx = _MOUSEX: my = _MOUSEY
    found = 0
    FOR m = 1 TO balls
        IF BallShow(m) = 1 THEN
            IF mx > (BallX(m) - BallSize(m)) AND mx < (BallX(m) + BallSize(m)) THEN
                IF my > (BallY(m) - BallSize(m)) AND my < (BallY(m) + BallSize(m)) THEN
                    IF found = 0 THEN firstball = m
                    found = found + 1
                    IF found > 1 THEN
                        lastfound = m
                    END IF
                END IF
            END IF
        END IF
    NEXT
    done = 1
END IF
 
RETURN
 
 
SUB ball (BallX, BallY, size, r, g, b)
    FOR s = 1 TO size STEP .4
        CIRCLE (BallX, BallY), s, _RGB(r, g, b)
        r = r - 1: g = g - 1: b = b - 1
    NEXT
END SUB
 

NOVARSEG · « **Reply #4 on:** December 26, 2020, 10:23:33 pm »

Having trouble with PRINT

Quote

d% = ((BallX(1) - BallX(2)) ^ 2 + (BallY(1) - BallY(2)) ^ 2) ^ .5

LOCATE 10, 10: PRINT d%

IF d% <= 80 THEN _DELAY 1

So run the code and find that 80 or less than 80 is never printed to the screen when the balls FIRST collide.

Code: QB64: [Select]

'Balls&Plasma.bas
 
SCREEN _NEWIMAGE(700, 700, 32)
 
f = _LOADFONT("cyberbit.ttf", 30): _FONT f
'_PRINTMODE _KEEPBACKGROUND
 
balls = 2: size = 40: speed = 10
 
DIM BallX(balls), BallY(balls)
DIM BallXdir(balls), BallYdir(balls)
DIM BallSpeed(balls), BallSize(balls)
 
w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
 
'Generate random ball data
FOR B = 1 TO balls
    BallX(B) = RND * w: BallY(B) = RND * h
    BallSpeed(B) = RND * speed + 1
    BallSize(B) = 40 '+ (RND * 50)
NEXT
 
DO
    CLS
 
 
 
    'compute ball movement
    FOR t = 1 TO balls
 
        LL:
        IF BallX(t) > w - BallSize(t) THEN BallXdir(t) = 1
        IF BallX(t) < BallSize(t) THEN BallXdir(t) = 0
 
        IF BallY(t) > h - BallSize(t) THEN BallYdir(t) = 1
        IF BallY(t) < BallSize(t) THEN BallYdir(t) = 0
 
        IF BallXdir(t) = 0 THEN BallX(t) = BallX(t) + BallSpeed(t)
        IF BallXdir(t) = 1 THEN BallX(t) = BallX(t) - BallSpeed(t)
 
        IF BallYdir(t) = 0 THEN BallY(t) = BallY(t) + BallSpeed(t)
        IF BallYdir(t) = 1 THEN BallY(t) = BallY(t) - BallSpeed(t)
 
 
    NEXT
 
 
 
    'draw plasma
    ' t = TIMER
    ' FOR x = 0 TO w
    ' FOR y = 0 TO h STEP 2
    ' r = SIN(1.1 * t) * h2 - y + h2
    ' g = SIN(.9 * t) * w2 - x + w2
    ' B = SIN(x / w2 + t + y / h2) * r
    ' PSET (x, y), _RGB(r, g, B)
    ' NEXT
    ' t = t + .01
    ' NEXT
    'draw balls
 
 
 
 
    FOR i = 1 TO balls
        ball BallX(i), BallY(i), BallSize(i), 255 - (4 * i), (4 * i), (5 * i)
        _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), STR$(i)
    NEXT
 
 
    d% = ((BallX(1) - BallX(2)) ^ 2 + (BallY(1) - BallY(2)) ^ 2) ^ .5
 
    LOCATE 10, 10: PRINT d%
 
    IF d% <= 80 THEN _DELAY 1
 
 
    _DISPLAY: _LIMIT 60
 
 
LOOP
 
 
SUB ball (BallX, BallY, size, r, g, b)
    FOR s = 1 TO size STEP .5
        CIRCLE (BallX, BallY), s, _RGB(r, g, b)
        r = r - 1: g = g - 1: b = b - 1
    NEXT
END SUB

bplus · « **Reply #5 on:** December 26, 2020, 10:44:35 pm »

Quote

Having trouble with PRINT

No you are having trouble with _DISPLAY!

When you use that, you have to say _DISPLAY every where you want to see PRINT immediately.

You can turn off _DISPLAY with _AUTODISPLAY or just say _DISPLAY again after the PRINT.

@Dav LINE with BF might be alittle bit faster than PSET according to @SMcNeill.

NOVARSEG · « **Reply #6 on:** December 26, 2020, 11:11:14 pm »

bplus you are right . I put a _DISPLAY right after the PRINT and it works.

NOVARSEG · « **Reply #7 on:** December 26, 2020, 11:35:49 pm »

Got the code tp print distance and relative direction.

Code: QB64: [Select]

'Balls&Plasma.bas
 
SCREEN _NEWIMAGE(700, 700, 32)
 
f = _LOADFONT("cyberbit.ttf", 30): _FONT f
'_PRINTMODE _KEEPBACKGROUND
 
balls = 2: size = 40: speed = 1
 
DIM BallX(balls), BallY(balls)
DIM BallXdir(balls), BallYdir(balls)
DIM BallSpeed(balls), BallSize(balls)
 
w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
 
'Generate random ball data
FOR B = 1 TO balls
    BallX(B) = RND * w: BallY(B) = RND * h
    BallSpeed(B) = RND * speed + 1
    BallSize(B) = 40 '+ (RND * 50)
NEXT
 
DO
    CLS
 
 
    'compute ball movement
    FOR t = 1 TO balls
 
        LL:
        IF BallX(t) > w - BallSize(t) THEN BallXdir(t) = 1
        IF BallX(t) < BallSize(t) THEN BallXdir(t) = 0
 
        IF BallY(t) > h - BallSize(t) THEN BallYdir(t) = 1
        IF BallY(t) < BallSize(t) THEN BallYdir(t) = 0
 
        IF BallXdir(t) = 0 THEN BallX(t) = BallX(t) + BallSpeed(t)
        IF BallXdir(t) = 1 THEN BallX(t) = BallX(t) - BallSpeed(t)
 
        IF BallYdir(t) = 0 THEN BallY(t) = BallY(t) + BallSpeed(t)
        IF BallYdir(t) = 1 THEN BallY(t) = BallY(t) - BallSpeed(t)
 
 
    NEXT
 
 
 
    'draw plasma
    ' t = TIMER
    ' FOR x = 0 TO w
    ' FOR y = 0 TO h STEP 2
    ' r = SIN(1.1 * t) * h2 - y + h2
    ' g = SIN(.9 * t) * w2 - x + w2
    ' B = SIN(x / w2 + t + y / h2) * r
    ' PSET (x, y), _RGB(r, g, B)
    ' NEXT
    ' t = t + .01
    ' NEXT
    'draw balls
 
 
 
 
    FOR i = 1 TO balls
        ball BallX(i), BallY(i), BallSize(i), 255 - (4 * i), (4 * i), (5 * i)
        _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), STR$(i)
    NEXT
 
    d% = ((BallX(1) - BallX(2)) ^ 2 + (BallY(1) - BallY(2)) ^ 2) ^ .5
 
 
    LOCATE 10, 10: PRINT "Distance"
    LOCATE 11, 10: PRINT d%
    LOCATE 12, 10: PRINT
    LOCATE 13, 10: PRINT "Relative"
    LOCATE 14, 10: PRINT "Direction"
    LOCATE 15, 10: PRINT (BallX(1) - BallX(2)) / (BallY(1) - BallY(2))
 
    _DISPLAY
    IF d% <= 80 THEN _DELAY 1
 
    _DISPLAY
    _LIMIT 60
 
 
LOOP
 
 
SUB ball (BallX, BallY, size, r, g, b)
    FOR s = 1 TO size STEP .5
        CIRCLE (BallX, BallY), s, _RGB(r, g, b)
        r = r - 1: g = g - 1: b = b - 1
    NEXT
END SUB

Dav · « **Reply #8 on:** December 27, 2020, 09:49:36 am »

Thanks, @bplus. I played around with that and put LINE in this new version.

Gave the game a little challenge now. Added a game timer, click them all in 20 seconds. speed increases as you go. Clicking the wrong ball restarts game. I lowered _LIMIT as @TempodiBasic suggested. Hope it doesn't run too fast now. Have a ball...

- Dav

Code: QB64: [Select]

'ClickAwayBalls.bas v1.1
'new: speed increases, added timer, clicking bad choice restarts.
'by Dav, DEC/2020
 
'Click on balls in order, starting at 1 untill all gone,
'before the timer runs out.  Clicking wrong number restarts.
 
 
SCREEN _NEWIMAGE(700, 700, 32)
 
f = _LOADFONT("cyberbit.ttf", 30): _FONT f
_PRINTMODE _KEEPBACKGROUND
 
balls = 15: size = 40: speed = 3
 
DIM BallX(balls), BallY(balls)
DIM BallXdir(balls), BallYdir(balls)
DIM BallSpeed(balls), BallSize(balls)
DIM BallShow(balls)
 
w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
 
restart:
 
'Generate random ball data
FOR B = 1 TO balls
    BallX(B) = RND * w: BallY(B) = RND * h
    BallSpeed(B) = RND * speed + 1
    BallSize(B) = 40 + (RND * 50)
    BallShow(B) = 1
NEXT
 
curball = 1
 
gametime = TIMER
 
timelimit = 20
 
DO
    CLS
    'compute ball movement
    FOR t = 1 TO balls
        IF BallX(t) > w - BallSize(t) THEN BallXdir(t) = 0
        IF BallX(t) < BallSize(t) THEN BallXdir(t) = 1
        IF BallXdir(t) THEN BallX(t) = BallX(t) + BallSpeed(t) ELSE BallX(t) = BallX(t) - BallSpeed(t)
        IF BallY(t) > h - BallSize(t) THEN BallYdir(t) = 0
        IF BallY(t) < BallSize(t) THEN BallYdir(t) = 1
        IF BallYdir(t) THEN BallY(t) = BallY(t) + BallSpeed(t) ELSE BallY(t) = BallY(t) - BallSpeed(t)
    NEXT
    'draw background
    t = TIMER
    FOR x = 0 TO w
        FOR y = 0 TO h
            r = SIN(1.1 * t) * h2 - y + h2
            'PSET (x, y), _RGB(r, r - y, -r)
            LINE (x, y)-(x, y), _RGB(r, r - y, -r), BF
        NEXT
        t = t + .01
        GOSUB GetMouseClick
    NEXT
 
    IF gameover = 1 THEN
        PLAY "o2l16cegagfefgabgc3l4"
        SLEEP 3
        GOTO restart
    END IF
 
    'draw balls
    FOR i = 1 TO balls
        IF BallShow(i) = 1 THEN
            ball BallX(i), BallY(i), BallSize(i), 255 - (4 * i), (4 * i), (5 * i)
            _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), STR$(i)
        END IF
    NEXT
 
    LOCATE 1, 1: PRINT "Click ball.."; curball;
    LOCATE 2, 1: PRINT timelimit - INT(TIMER - gametime);
    _DISPLAY: _LIMIT 30
 
    'If click on one ball (no overlayed oned) remove it
    IF found = 1 THEN
        IF firstball = curball THEN
            'erase ball
            ball BallX(firstball), BallY(firstball), BallSize(firstball), 255, 200, 200
            BallShow(firstball) = 0
            PLAY "mbl32o2ceg"
            _DISPLAY: _DELAY .05
            curball = curball + 1
            found = 0
 
            'Increase spped of balls
            FOR s = 1 TO balls
                BallSpeed(s) = BallSpeed(s) + 1
            NEXT
 
        ELSE
            found = found + 1
            lastfound = firstball
        END IF
    END IF
 
    'If click over several balls, remove top one
    IF found > 1 THEN
        'BallShow(lastfound) = 0
        ball BallX(lastfound), BallY(lastfound), BallSize(lastfound), 255, 200, 100
        _PRINTSTRING (BallX(lastfound) - 15, BallY(lastfound) - 15), STR$(lastfound)
        _DISPLAY: PLAY "mbl16o2fbfbl8f"
        found = 0
        _DELAY .5
        GOTO restart
    END IF
 
    'check if all clicked
    anyleft = 0
    FOR c = 1 TO balls
        IF BallShow(c) = 1 THEN anyleft = anyleft + 1
    NEXT
    IF anyleft = 0 THEN
        gameover = 1
    END IF
 
    IF TIMER - gametime > timelimit THEN
        PLAY "mbo1l4dl8ddl4dl8feeddc#l2d"
        SLEEP 3
        GOTO restart
    END IF
 
LOOP
 
END
 
'==============
GetMouseClick:
'==============
 
mi = _MOUSEINPUT
IF _MOUSEBUTTON(1) = 0 THEN done = 0
IF _MOUSEBUTTON(1) AND done = 0 THEN
    mx = _MOUSEX: my = _MOUSEY
    found = 0
    FOR m = 1 TO balls
        IF BallShow(m) = 1 THEN
            IF mx > (BallX(m) - BallSize(m)) AND mx < (BallX(m) + BallSize(m)) THEN
                IF my > (BallY(m) - BallSize(m)) AND my < (BallY(m) + BallSize(m)) THEN
                    IF found = 0 THEN firstball = m
                    found = found + 1
                    IF found > 1 THEN
                        lastfound = m
                    END IF
                END IF
            END IF
        END IF
    NEXT
    done = 1
END IF
 
RETURN
 
 
SUB ball (BallX, BallY, size, r, g, b)
    FOR s = 1 TO size STEP .4
        CIRCLE (BallX, BallY), s, _RGB(r, g, b)
        r = r - 1: g = g - 1: b = b - 1
    NEXT
END SUB
 

bplus · « **Reply #9 on:** December 27, 2020, 12:47:15 pm »

I tried game and not enough variation of direction, a couple times the higher balls overlapped smaller the whole 20 secs

FellippeHeitor · « **Reply #10 on:** December 27, 2020, 12:57:04 pm »

Fun game, Dav. I love the plasma effect, I think I'd seen this bit before in one of your previously shared pieces.

Dav · « **Reply #11 on:** December 27, 2020, 01:33:25 pm »

@bplus. Yes, i agree. Happens to me too. I'll figure something out there. I wonder how I can get mouse x/y in a circle instead of a rectangle? I'm gonna think on it.

@FellippeHeitor, i think I did post that little plasma things before.

- Dav

bplus · « **Reply #12 on:** December 27, 2020, 02:35:33 pm »

Some more variation in ball movement, center screen, more time, no so big balls but more colors can almost get them all heh heh..

Code: QB64: [Select]

'ClickAwayBalls.bas v1.1
'new: speed increases, added timer, clicking bad choice restarts.
'by Dav, DEC/2020
 
'Click on balls in order, starting at 1 untill all gone,
'before the timer runs out.  Clicking wrong number restarts.
 
RANDOMIZE TIMER
SCREEN _NEWIMAGE(800, 600, 32)
_DELAY .25
_SCREENMOVE _MIDDLE
 
f = _LOADFONT("cyberbit.ttf", 30): _FONT f
_PRINTMODE _KEEPBACKGROUND
 
balls = 15: size = 40: speed = 3
 
REDIM BallX(balls), BallY(balls), BallDx(balls), BallDy(balls), BallSize(balls), BallShow(balls), BallC(balls) AS _UNSIGNED LONG
 
w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
 
restart:
 
'Generate random ball data
FOR B = 1 TO balls
    BallSize(B) = 40 + (RND * 30)
    BallX(B) = BallSize(B) + RND * (w - 2 * BallSize(B)): BallY(B) = BallSize(B) + RND * (h - 2 * BallSize(B))
    a = RND * _PI(2): Ballspeed = 7 + RND * 14
    BallDx(B) = Ballspeed * COS(a): BallDy(B) = Ballspeed * SIN(a)
    BallShow(B) = 1: BallC(B) = _RGB32(RND * 255, RND * 255, RND * 255)
NEXT
 
curball = 1
 
gametime = TIMER
 
timelimit = 30
 
DO
    CLS
    'compute ball movement
    FOR t = 1 TO balls
        BallX(t) = BallX(t) + BallDx(t) 'move ball then make sure in bounds
        BallY(t) = BallY(t) + BallDy(t)
        IF BallX(t) > w - BallSize(t) THEN BallDx(t) = -BallDx(t): BallX(t) = w - BallSize(t)
        IF BallX(t) < BallSize(t) THEN BallDx(t) = -BallDx(t): BallX(t) = BallSize(t)
        IF BallY(t) > h - BallSize(t) THEN BallDy(t) = -BallDy(t): BallY(t) = h - BallSize(t)
        IF BallY(t) < BallSize(t) THEN BallDy(t) = -BallDy(t): BallY(t) = BallSize(t)
    NEXT
    'draw background
    t = TIMER
    FOR x = 0 TO w
        FOR y = 0 TO h
            r = SIN(1.1 * t) * h2 - y + h2
            'PSET (x, y), _RGB(r, r - y, -r)
            LINE (x, y)-(x, y), _RGB(r, r - y, -r), BF
        NEXT
        t = t + .01
        GOSUB GetMouseClick
    NEXT
 
    IF gameover = 1 THEN
        PLAY "o2l16cegagfefgabgc3l4"
        SLEEP 3
        GOTO restart
    END IF
 
    'draw balls
    FOR i = 1 TO balls
        IF BallShow(i) = 1 THEN
            drawBall BallX(i), BallY(i), BallSize(i), BallC(i)
            _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), RIGHT$("0" + _TRIM$(STR$(i)), 2)
        END IF
    NEXT
 
    LOCATE 1, 1: PRINT "Click ball.."; curball;
    LOCATE 2, 1: PRINT timelimit - INT(TIMER - gametime);
    _DISPLAY: _LIMIT 30
 
    'If click on one ball (no overlayed oned) remove it
    IF found = 1 THEN
        IF firstball = curball THEN
            'erase ball
            drawBall BallX(firstball), BallY(firstball), BallSize(firstball), BallC(firstball)
            BallShow(firstball) = 0
            PLAY "mbl32o2ceg"
            _DISPLAY: _DELAY .05
            curball = curball + 1
            found = 0
 
 
        ELSE
            found = found + 1
            lastfound = firstball
        END IF
    END IF
 
    ''If click over several balls, remove top one
    'IF found > 1 THEN
    '    'BallShow(lastfound) = 0
    '    drawball BallX(lastfound), BallY(lastfound), BallSize(lastfound), 255, 200, 100
    '    _PRINTSTRING (BallX(lastfound) - 15, BallY(lastfound) - 15), STR$(lastfound)
    '    _DISPLAY: PLAY "mbl16o2fbfbl8f"
    '    found = 0
    '    _DELAY .5
    '    GOTO restart
    'END IF
 
    'check if all clicked
    anyleft = 0
    FOR c = 1 TO balls
        IF BallShow(c) = 1 THEN anyleft = anyleft + 1
    NEXT
    IF anyleft = 0 THEN
        gameover = 1
    END IF
 
    IF TIMER - gametime > timelimit THEN
        PLAY "mbo1l4dl8ddl4dl8feeddc#l2d"
        SLEEP 3
        GOTO restart
    END IF
 
LOOP
 
END
 
'==============
GetMouseClick:
'==============
 
mi = _MOUSEINPUT
IF _MOUSEBUTTON(1) = 0 THEN done = 0
IF _MOUSEBUTTON(1) AND done = 0 THEN
    mx = _MOUSEX: my = _MOUSEY
    found = 0
    FOR m = 1 TO balls
        IF BallShow(m) = 1 THEN
            IF mx > (BallX(m) - BallSize(m)) AND mx < (BallX(m) + BallSize(m)) THEN
                IF my > (BallY(m) - BallSize(m)) AND my < (BallY(m) + BallSize(m)) THEN
                    IF found = 0 THEN firstball = m
                    found = found + 1
                    IF found > 1 THEN
                        lastfound = m
                    END IF
                END IF
            END IF
        END IF
    NEXT
    done = 1
END IF
 
RETURN
 
 
SUB drawBall (x, y, r, c AS _UNSIGNED LONG)
    DIM rred AS LONG, grn AS LONG, blu AS LONG, rr AS LONG, f
    rred = _RED32(c): grn = _GREEN32(c): blu = _BLUE32(c)
    FOR rr = r TO 0 STEP -1
        f = 1 - rr / r
        fcirc x, y, rr, _RGB32(rred * f, grn * f, blu * f)
    NEXT
END SUB
 
SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
    DIM Radius AS INTEGER, RadiusError AS INTEGER
    DIM X AS INTEGER, Y AS INTEGER
    Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
    IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
    LINE (CX - X, CY)-(CX + X, CY), C, BF
    WHILE X > Y
        RadiusError = RadiusError + Y * 2 + 1
        IF RadiusError >= 0 THEN
            IF X <> Y + 1 THEN
                LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
                LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
            END IF
            X = X - 1
            RadiusError = RadiusError - X * 2
        END IF
        Y = Y + 1
        LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
        LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
    WEND
END SUB
 
 

Quote

I wonder how I can get mouse x/y in a circle instead of a rectangle?

Do you mean is mouse x, y is a ball radius away from ball middle?
if sqr((mx - bx)^2 + (my-by)^2))<= br then 'ball clicked

Code: QB64: [Select]

'ClickAwayBalls.bas v1.1
'new: speed increases, added timer, clicking bad choice restarts.
'by Dav, DEC/2020
 
'Click on balls in order, starting at 1 untill all gone,
'before the timer runs out.  Clicking wrong number restarts.
 
RANDOMIZE TIMER
SCREEN _NEWIMAGE(800, 600, 32)
_DELAY .25
_SCREENMOVE _MIDDLE
 
f = _LOADFONT("cyberbit.ttf", 30): _FONT f
_PRINTMODE _KEEPBACKGROUND
 
balls = 15: size = 40: speed = 3
 
REDIM BallX(balls), BallY(balls), BallDx(balls), BallDy(balls), BallSize(balls), BallShow(balls), BallC(balls) AS _UNSIGNED LONG
 
w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
 
restart:
 
'Generate random ball data
FOR B = 1 TO balls
    BallSize(B) = 40 + (RND * 30)
    BallX(B) = BallSize(B) + RND * (w - 2 * BallSize(B)): BallY(B) = BallSize(B) + RND * (h - 2 * BallSize(B))
    a = RND * _PI(2): Ballspeed = 7 + RND * 14
    BallDx(B) = Ballspeed * COS(a): BallDy(B) = Ballspeed * SIN(a)
    BallShow(B) = 1: BallC(B) = _RGB32(RND * 255, RND * 255, RND * 255)
NEXT
 
curball = 1
 
gametime = TIMER
 
timelimit = 30
 
DO
    CLS
    'compute ball movement
    FOR t = 1 TO balls
        BallX(t) = BallX(t) + BallDx(t) 'move ball then make sure in bounds
        BallY(t) = BallY(t) + BallDy(t)
        IF BallX(t) > w - BallSize(t) THEN BallDx(t) = -BallDx(t): BallX(t) = w - BallSize(t)
        IF BallX(t) < BallSize(t) THEN BallDx(t) = -BallDx(t): BallX(t) = BallSize(t)
        IF BallY(t) > h - BallSize(t) THEN BallDy(t) = -BallDy(t): BallY(t) = h - BallSize(t)
        IF BallY(t) < BallSize(t) THEN BallDy(t) = -BallDy(t): BallY(t) = BallSize(t)
    NEXT
    'draw background
    t = TIMER
    FOR x = 0 TO w
        FOR y = 0 TO h
            r = SIN(1.1 * t) * h2 - y + h2
            'PSET (x, y), _RGB(r, r - y, -r)
            LINE (x, y)-(x, y), _RGB(r, r - y, -r), BF
        NEXT
        t = t + .01
        GOSUB GetMouseClick
    NEXT
 
    IF gameover = 1 THEN
        PLAY "o2l16cegagfefgabgc3l4"
        SLEEP 3
        GOTO restart
    END IF
 
    'draw balls
    FOR i = 1 TO balls
        IF BallShow(i) = 1 THEN
            drawBall BallX(i), BallY(i), BallSize(i), BallC(i)
            _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), RIGHT$("0" + _TRIM$(STR$(i)), 2)
        END IF
    NEXT
 
    LOCATE 1, 1: PRINT "Click ball.."; curball;
    LOCATE 2, 1: PRINT timelimit - INT(TIMER - gametime);
    _DISPLAY: _LIMIT 30
 
    'If click on one ball (no overlayed oned) remove it
    IF found = 1 THEN
        IF firstball = curball THEN
            'erase ball
            drawBall BallX(firstball), BallY(firstball), BallSize(firstball), BallC(firstball)
            BallShow(firstball) = 0
            PLAY "mbl32o2ceg"
            _DISPLAY: _DELAY .05
            curball = curball + 1
            found = 0
 
 
        ELSE
            found = found + 1
            lastfound = firstball
        END IF
    END IF
 
    ''If click over several balls, remove top one
    'IF found > 1 THEN
    '    'BallShow(lastfound) = 0
    '    drawball BallX(lastfound), BallY(lastfound), BallSize(lastfound), 255, 200, 100
    '    _PRINTSTRING (BallX(lastfound) - 15, BallY(lastfound) - 15), STR$(lastfound)
    '    _DISPLAY: PLAY "mbl16o2fbfbl8f"
    '    found = 0
    '    _DELAY .5
    '    GOTO restart
    'END IF
 
    'check if all clicked
    anyleft = 0
    FOR c = 1 TO balls
        IF BallShow(c) = 1 THEN anyleft = anyleft + 1
    NEXT
    IF anyleft = 0 THEN
        gameover = 1
    END IF
 
    IF TIMER - gametime > timelimit THEN
        PLAY "mbo1l4dl8ddl4dl8feeddc#l2d"
        SLEEP 3
        GOTO restart
    END IF
 
LOOP
 
END
 
'==============
GetMouseClick:
'==============
 
mi = _MOUSEINPUT
IF _MOUSEBUTTON(1) = 0 THEN done = 0
IF _MOUSEBUTTON(1) AND done = 0 THEN
    mx = _MOUSEX: my = _MOUSEY
    found = 0
    FOR m = 1 TO balls
        IF BallShow(m) = 1 THEN
            IF SQR((mx - BallX(m)) ^ 2 + (my - BallY(m)) ^ 2) < BallSize(m) THEN
                IF found = 0 THEN firstball = m
                found = found + 1
                IF found > 1 THEN
                    lastfound = m
                END IF
            END IF
        END IF
    NEXT
    done = 1
END IF
 
RETURN
 
 
SUB drawBall (x, y, r, c AS _UNSIGNED LONG)
    DIM rred AS LONG, grn AS LONG, blu AS LONG, rr AS LONG, f
    rred = _RED32(c): grn = _GREEN32(c): blu = _BLUE32(c)
    FOR rr = r TO 0 STEP -1
        f = 1 - rr / r
        fcirc x, y, rr, _RGB32(rred * f, grn * f, blu * f)
    NEXT
END SUB
 
SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
    DIM Radius AS INTEGER, RadiusError AS INTEGER
    DIM X AS INTEGER, Y AS INTEGER
    Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
    IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
    LINE (CX - X, CY)-(CX + X, CY), C, BF
    WHILE X > Y
        RadiusError = RadiusError + Y * 2 + 1
        IF RadiusError >= 0 THEN
            IF X <> Y + 1 THEN
                LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
                LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
            END IF
            X = X - 1
            RadiusError = RadiusError - X * 2
        END IF
        Y = Y + 1
        LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
        LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
    WEND
END SUB
 

bplus · « **Reply #13 on:** December 27, 2020, 02:59:22 pm »

Here it is with less time spent drawing plasma

Code: QB64: [Select]

'ClickAwayBalls.bas v1.1
'new: speed increases, added timer, clicking bad choice restarts.
'by Dav, DEC/2020
 
'Click on balls in order, starting at 1 untill all gone,
'before the timer runs out.  Clicking wrong number restarts.
 
RANDOMIZE TIMER
SCREEN _NEWIMAGE(800, 600, 32)
_DELAY .25
_SCREENMOVE _MIDDLE
 
f = _LOADFONT("cyberbit.ttf", 30): _FONT f
_PRINTMODE _KEEPBACKGROUND
 
balls = 15: size = 40: speed = 3
 
REDIM BallX(balls), BallY(balls), BallDx(balls), BallDy(balls), BallSize(balls), BallShow(balls), BallC(balls) AS _UNSIGNED LONG
 
w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
 
restart:
 
'Generate random ball data
FOR B = 1 TO balls
    BallSize(B) = 40 + (RND * 30)
    BallX(B) = BallSize(B) + RND * (w - 2 * BallSize(B)): BallY(B) = BallSize(B) + RND * (h - 2 * BallSize(B))
    a = RND * _PI(2): Ballspeed = 4 + RND * 8
    BallDx(B) = Ballspeed * COS(a): BallDy(B) = Ballspeed * SIN(a)
    BallShow(B) = 1: BallC(B) = _RGB32(RND * 255, RND * 255, RND * 255)
NEXT
 
curball = 1
 
gametime = TIMER
 
timelimit = 30
 
DO
    CLS
    'compute ball movement
    FOR t = 1 TO balls
        BallX(t) = BallX(t) + BallDx(t) 'move ball then make sure in bounds
        BallY(t) = BallY(t) + BallDy(t)
        IF BallX(t) > w - BallSize(t) THEN BallDx(t) = -BallDx(t): BallX(t) = w - BallSize(t)
        IF BallX(t) < BallSize(t) THEN BallDx(t) = -BallDx(t): BallX(t) = BallSize(t)
        IF BallY(t) > h - BallSize(t) THEN BallDy(t) = -BallDy(t): BallY(t) = h - BallSize(t)
        IF BallY(t) < BallSize(t) THEN BallDy(t) = -BallDy(t): BallY(t) = BallSize(t)
    NEXT
    'draw background
    t = TIMER
    FOR x = 0 TO w STEP 4
        FOR y = 0 TO h STEP 4
            r = SIN(1.1 * t) * h2 - y + h2
            'PSET (x, y), _RGB(r, r - y, -r)
            LINE (x, y)-STEP(3, 3), _RGB(r, r - y, -r), BF
        NEXT
        t = t + .01
        GOSUB GetMouseClick
    NEXT
 
    IF gameover = 1 THEN
        PLAY "o2l16cegagfefgabgc3l4"
        SLEEP 3
        GOTO restart
    END IF
 
    'draw balls
    FOR i = 1 TO balls
        IF BallShow(i) = 1 THEN
            drawBall BallX(i), BallY(i), BallSize(i), BallC(i)
            _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), RIGHT$("0" + _TRIM$(STR$(i)), 2)
        END IF
    NEXT
 
    LOCATE 1, 1: PRINT "Click ball.."; curball;
    LOCATE 2, 1: PRINT timelimit - INT(TIMER - gametime);
    _DISPLAY: _LIMIT 30
 
    'If click on one ball (no overlayed oned) remove it
    IF found = 1 THEN
        IF firstball = curball THEN
            'erase ball
            drawBall BallX(firstball), BallY(firstball), BallSize(firstball), BallC(firstball)
            BallShow(firstball) = 0
            PLAY "mbl32o2ceg"
            _DISPLAY: _DELAY .05
            curball = curball + 1
            found = 0
 
 
        ELSE
            found = found + 1
            lastfound = firstball
        END IF
    END IF
 
    ''If click over several balls, remove top one
    'IF found > 1 THEN
    '    'BallShow(lastfound) = 0
    '    drawball BallX(lastfound), BallY(lastfound), BallSize(lastfound), 255, 200, 100
    '    _PRINTSTRING (BallX(lastfound) - 15, BallY(lastfound) - 15), STR$(lastfound)
    '    _DISPLAY: PLAY "mbl16o2fbfbl8f"
    '    found = 0
    '    _DELAY .5
    '    GOTO restart
    'END IF
 
    'check if all clicked
    anyleft = 0
    FOR c = 1 TO balls
        IF BallShow(c) = 1 THEN anyleft = anyleft + 1
    NEXT
    IF anyleft = 0 THEN
        gameover = 1
    END IF
 
    IF TIMER - gametime > timelimit THEN
        PLAY "mbo1l4dl8ddl4dl8feeddc#l2d"
        SLEEP 3
        GOTO restart
    END IF
 
LOOP
 
END
 
'==============
GetMouseClick:
'==============
 
mi = _MOUSEINPUT
IF _MOUSEBUTTON(1) = 0 THEN done = 0
IF _MOUSEBUTTON(1) AND done = 0 THEN
    mx = _MOUSEX: my = _MOUSEY
    found = 0
    FOR m = 1 TO balls
        IF BallShow(m) = 1 THEN
            IF SQR((mx - BallX(m)) ^ 2 + (my - BallY(m)) ^ 2) < BallSize(m) THEN
                IF found = 0 THEN firstball = m
                found = found + 1
                IF found > 1 THEN
                    lastfound = m
                END IF
            END IF
        END IF
    NEXT
    done = 1
END IF
 
RETURN
 
 
SUB drawBall (x, y, r, c AS _UNSIGNED LONG)
    DIM rred AS LONG, grn AS LONG, blu AS LONG, rr AS LONG, f
    rred = _RED32(c): grn = _GREEN32(c): blu = _BLUE32(c)
    FOR rr = r TO 0 STEP -1
        f = 1 - rr / r
        fcirc x, y, rr, _RGB32(rred * f, grn * f, blu * f)
    NEXT
END SUB
 
SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
    DIM Radius AS INTEGER, RadiusError AS INTEGER
    DIM X AS INTEGER, Y AS INTEGER
    Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
    IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
    LINE (CX - X, CY)-(CX + X, CY), C, BF
    WHILE X > Y
        RadiusError = RadiusError + Y * 2 + 1
        IF RadiusError >= 0 THEN
            IF X <> Y + 1 THEN
                LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
                LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
            END IF
            X = X - 1
            RadiusError = RadiusError - X * 2
        END IF
        Y = Y + 1
        LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
        LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
    WEND
END SUB
 
 

edit: guess have to slow down balls now!

bplus · « **Reply #14 on:** December 27, 2020, 03:21:42 pm »

OK low numbered balls move slow, high numbered balls move fast, now you know what to look for besides number:

Code: QB64: [Select]

'ClickAwayBalls.bas v1.1
'new: speed increases, added timer, clicking bad choice restarts.
'by Dav, DEC/2020
 
'Click on balls in order, starting at 1 untill all gone,
'before the timer runs out.  Clicking wrong number restarts.
 
RANDOMIZE TIMER
SCREEN _NEWIMAGE(800, 600, 32)
_DELAY .25
_SCREENMOVE _MIDDLE
 
f = _LOADFONT("cyberbit.ttf", 30): _FONT f
_PRINTMODE _KEEPBACKGROUND
 
balls = 15: size = 40: speed = 3
 
REDIM BallX(balls), BallY(balls), BallDx(balls), BallDy(balls), BallSize(balls), BallShow(balls), BallC(balls) AS _UNSIGNED LONG
 
w = _WIDTH: h = _HEIGHT: w2 = _WIDTH / 2: h2 = _HEIGHT / 2
 
restart:
 
'Generate random ball data
FOR B = 1 TO balls
    BallSize(B) = 40 + (RND * 30)
    BallX(B) = BallSize(B) + RND * (w - 2 * BallSize(B)): BallY(B) = BallSize(B) + RND * (h - 2 * BallSize(B))
    a = RND * _PI(2): Ballspeed = 2 + B
    BallDx(B) = Ballspeed * COS(a): BallDy(B) = Ballspeed * SIN(a)
    BallShow(B) = 1: BallC(B) = _RGB32(RND * 255, RND * 255, RND * 255)
NEXT
 
curball = 1
 
gametime = TIMER
 
timelimit = 30
 
DO
    CLS
    'compute ball movement
    FOR t = 1 TO balls
        BallX(t) = BallX(t) + BallDx(t) 'move ball then make sure in bounds
        BallY(t) = BallY(t) + BallDy(t)
        IF BallX(t) > w - BallSize(t) THEN BallDx(t) = -BallDx(t): BallX(t) = w - BallSize(t)
        IF BallX(t) < BallSize(t) THEN BallDx(t) = -BallDx(t): BallX(t) = BallSize(t)
        IF BallY(t) > h - BallSize(t) THEN BallDy(t) = -BallDy(t): BallY(t) = h - BallSize(t)
        IF BallY(t) < BallSize(t) THEN BallDy(t) = -BallDy(t): BallY(t) = BallSize(t)
    NEXT
    'draw background
    t = TIMER
    FOR x = 0 TO w STEP 4
        FOR y = 0 TO h STEP 4
            r = SIN(1.1 * t) * h2 - y + h2
            'PSET (x, y), _RGB(r, r - y, -r)
            LINE (x, y)-STEP(3, 3), _RGB(r, r - y, -r), BF
        NEXT
        t = t + .01
        GOSUB GetMouseClick
    NEXT
 
    IF gameover = 1 THEN
        PLAY "o2l16cegagfefgabgc3l4"
        SLEEP 3
        GOTO restart
    END IF
 
    'draw balls
    FOR i = 1 TO balls
        IF BallShow(i) = 1 THEN
            drawBall BallX(i), BallY(i), BallSize(i), BallC(i)
            _PRINTSTRING (BallX(i) - 15, BallY(i) - 15), RIGHT$("0" + _TRIM$(STR$(i)), 2)
        END IF
    NEXT
 
    LOCATE 1, 1: PRINT "Click ball.."; curball;
    LOCATE 2, 1: PRINT timelimit - INT(TIMER - gametime);
    _DISPLAY: _LIMIT 30
 
    'If click on one ball (no overlayed oned) remove it
    IF found = 1 THEN
        IF firstball = curball THEN
            'erase ball
            drawBall BallX(firstball), BallY(firstball), BallSize(firstball), BallC(firstball)
            BallShow(firstball) = 0
            PLAY "mbl32o2ceg"
            _DISPLAY: _DELAY .05
            curball = curball + 1
            found = 0
 
 
        ELSE
            found = found + 1
            lastfound = firstball
        END IF
    END IF
 
    ''If click over several balls, remove top one
    'IF found > 1 THEN
    '    'BallShow(lastfound) = 0
    '    drawball BallX(lastfound), BallY(lastfound), BallSize(lastfound), 255, 200, 100
    '    _PRINTSTRING (BallX(lastfound) - 15, BallY(lastfound) - 15), STR$(lastfound)
    '    _DISPLAY: PLAY "mbl16o2fbfbl8f"
    '    found = 0
    '    _DELAY .5
    '    GOTO restart
    'END IF
 
    'check if all clicked
    anyleft = 0
    FOR c = 1 TO balls
        IF BallShow(c) = 1 THEN anyleft = anyleft + 1
    NEXT
    IF anyleft = 0 THEN
        gameover = 1
    END IF
 
    IF TIMER - gametime > timelimit THEN
        PLAY "mbo1l4dl8ddl4dl8feeddc#l2d"
        SLEEP 3
        GOTO restart
    END IF
 
LOOP
 
END
 
'==============
GetMouseClick:
'==============
 
mi = _MOUSEINPUT
IF _MOUSEBUTTON(1) = 0 THEN done = 0
IF _MOUSEBUTTON(1) AND done = 0 THEN
    mx = _MOUSEX: my = _MOUSEY
    found = 0
    FOR m = 1 TO balls
        IF BallShow(m) = 1 THEN
            IF SQR((mx - BallX(m)) ^ 2 + (my - BallY(m)) ^ 2) < BallSize(m) THEN
                IF found = 0 THEN firstball = m
                found = found + 1
                IF found > 1 THEN
                    lastfound = m
                END IF
            END IF
        END IF
    NEXT
    done = 1
END IF
 
RETURN
 
 
SUB drawBall (x, y, r, c AS _UNSIGNED LONG)
    DIM rred AS LONG, grn AS LONG, blu AS LONG, rr AS LONG, f
    rred = _RED32(c): grn = _GREEN32(c): blu = _BLUE32(c)
    FOR rr = r TO 0 STEP -1
        f = 1 - rr / r
        fcirc x, y, rr, _RGB32(rred * f, grn * f, blu * f)
    NEXT
END SUB
 
SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
    DIM Radius AS INTEGER, RadiusError AS INTEGER
    DIM X AS INTEGER, Y AS INTEGER
    Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
    IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
    LINE (CX - X, CY)-(CX + X, CY), C, BF
    WHILE X > Y
        RadiusError = RadiusError + Y * 2 + 1
        IF RadiusError >= 0 THEN
            IF X <> Y + 1 THEN
                LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
                LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
            END IF
            X = X - 1
            RadiusError = RadiusError - X * 2
        END IF
        Y = Y + 1
        LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
        LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
    WEND
END SUB
 
 
 

News:

Author Topic: Bouncing Balls over a Plasma sky (Read 6007 times)

Dav

Bouncing Balls over a Plasma sky

TempodiBasic

Re: Bouncing Balls over a Plasma sky

NOVARSEG

Re: Bouncing Balls over a Plasma sky

Dav

Re: Bouncing Balls over a Plasma sky

NOVARSEG

Re: Bouncing Balls over a Plasma sky

bplus

Re: Bouncing Balls over a Plasma sky

NOVARSEG

Re: Bouncing Balls over a Plasma sky

NOVARSEG

Re: Bouncing Balls over a Plasma sky

Dav

Re: Bouncing Balls over a Plasma sky

bplus

Re: Bouncing Balls over a Plasma sky

FellippeHeitor

Re: Bouncing Balls over a Plasma sky

Dav

Re: Bouncing Balls over a Plasma sky

bplus

Re: Bouncing Balls over a Plasma sky

bplus

Re: Bouncing Balls over a Plasma sky

bplus

Re: Bouncing Balls over a Plasma sky