Vacuum Fluorescent Display (VFD) Alarm Clock Using LCD Font

[SierraKen]

Of course I found another problem LOL. Now when it is earlier than 10am or 10pm, the 1 digit moves over to the left and everything else moves over to the left too. So I did a very quick one-line fix on it, hopefully this does the trick. I just said this:

Code: QB64: [Select]

1.  IF h < 10 THEN hour$ = "0" + hour$
2.  

It seems to work fine so far.

Zip file has been deleted. Keep scrolling down.

[bplus]

Here is what I managed to work up for drawing 7 Segment characters, mostly digits:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "7 Segments Digital Date and Time Clock" ' b+ 2020-12-05
3. DIM SHARED xmax, ymax
4. xmax = 1074: ymax = 105
5. SCREEN _NEWIMAGE(xmax, ymax, 32)
6. _SCREENMOVE 60, 40
7. DIM ampm$, testHeight, offset, testColr AS _UNSIGNED LONG, shadow AS _UNSIGNED LONG, face AS LONG, t$, d$
8. testHeight = 100
9. offset = 15
10. shadow = &H17FFFFFF
11. testColr = &HFFEEEEFF
12. face = _NEWIMAGE(xmax, ymax, 32)
13. print7 "8888-88-88 A 88:88:88", offset, offset, testHeight, shadow
14. _PUTIMAGE , 0, face
15. WHILE _KEYDOWN(27) = 0
16.     _PUTIMAGE , face, 0
17.     t$ = TIME$
18.     d$ = RIGHT$(DATE$, 4) + "-" + LEFT$(DATE$, 2) + MID$(DATE$, 3, 3)
19.     IF VAL(MID$(t$, 1, 2)) > 12 THEN
20.         ampm$ = " P ": MID$(t$, 1, 2) = RIGHT$("00" + _TRIM$(STR$(VAL(MID$(t$, 1, 2)) - 12)), 2)
21.     ELSE
22.         ampm$ = " A "
23.     END IF
24.     print7 d$ + ampm$ + t$, offset, offset, testHeight, testColr
25.     _LIMIT 10
26.     _DISPLAY
27. WEND
28.  
29. SUB print7 (text$, x, y, height, c AS _UNSIGNED LONG)
30.     ' char cells will be like 8 x 16 scaled st 16 pixel height would fit into default char cell
31.  
32.     DIM f AS SINGLE, i AS LONG
33.     f = height / 16 ' proportion of height to standard height
34.  
35.     FOR i = 1 TO LEN(text$)
36.         draw7Segmented MID$(text$, i, 1), x + (i - 1) * f * 8, y, height, c
37.     NEXT
38. END SUB
39.  
40. SUB draw7Segmented (char$, x AS LONG, y AS LONG, height AS SINGLE, colr AS _UNSIGNED LONG) ' digit = 0, 1, 2... 9
41.     DIM f AS SINGLE, sr AS SINGLE, c AS _UNSIGNED LONG, digit AS LONG, c$, m AS LONG, i AS SINGLE
42.     f = height / 16
43.     sr = 11 / 5.5 * f
44.     IF INSTR("0123456789", char$) THEN
45.         digit = VAL(char$)
46.         c$ = MID$("1110111000001101111100011111100101110111011111101001001111111111011011", digit * 7 + 1, 7)
47.     ELSEIF INSTR(":-PA", char$) THEN
48.         c$ = MID$("0010100000100011110101111011", INSTR(":-PA", char$) * 7 - 6, 7)
49.     ELSE
50.         c$ = "0000000" 'draw a space
51.     END IF
52.     FOR m = 1 TO 7
53.         IF VAL(MID$(c$, m, 1)) THEN
54.             FOR i = .5 * sr TO 0 STEP -.25
55.                 c = Ink~&(colr, &H00000088, (i / (.5 * sr)) ^ .65)
56.                 SELECT CASE m
57.                     CASE 1: LINE (x + .5 * sr - i, y + .5 * sr + i)-(x + .5 * sr + i, y + 2.5 * sr - i), c, BF 'LT
58.                     CASE 2: LINE (x + .5 * sr - i, y + 2.5 * sr + i)-(x + .5 * sr + i, y + 5.0 * sr - i), c, BF 'LB
59.                     CASE 3: LINE (x + .5 * sr + i, y + .5 * sr + i)-(x + 2.5 * sr - 2 - i, y + .5 * sr - i), c, BF 'MT
60.                     CASE 4: LINE (x + .5 * sr + i, y + 2.5 * sr + i)-(x + 2.5 * sr - 2 - i, y + 2.5 * sr - i), c, BF 'MM
61.                     CASE 5: LINE (x + .5 * sr + i, y + 5.0 * sr + i)-(x + 2.5 * sr - 2 - i, y + 5.0 * sr - i), c, BF 'MB
62.                     CASE 6: LINE (x + 2.5 * sr - i, y + .5 * sr + i)-(x + 2.5 * sr + i, y + 2.5 * sr - i), c, BF 'RT
63.                     CASE 7: LINE (x + 2.5 * sr - i, y + 2.5 * sr + i)-(x + 2.5 * sr + i, y + 5.0 * sr - i), c, BF 'RB
64.                 END SELECT
65.             NEXT
66.         END IF
67.     NEXT
68. END SUB
69.  
70. SUB cAnalysis (c AS _UNSIGNED LONG, outRed, outGrn, outBlu, outAlp)
71.     outRed = _RED32(c): outGrn = _GREEN32(c): outBlu = _BLUE32(c): outAlp = _ALPHA32(c)
72. END SUB
73.  
74. FUNCTION Ink~& (c1 AS _UNSIGNED LONG, c2 AS _UNSIGNED LONG, fr##)
75.     DIM R1, G1, B1, A1, R2, G2, B2, A2
76.     cAnalysis c1, R1, G1, B1, A1
77.     cAnalysis c2, R2, G2, B2, A2
78.     Ink~& = _RGB32(R1 + (R2 - R1) * fr##, G1 + (G2 - G1) * fr##, B1 + (B2 - B1) * fr##, A1 + (A2 - A1) * fr##)
79. END FUNCTION
80.  

Tried for Neon Coloring:
 

[SierraKen]

Here is another fix. I just realized that TIME$ starts with hour 0, not hour 12. So I believe I fixed that.

There is another attachment below.

[SierraKen]

Yours is incredible B+. I like the neon glow look you added to it.

[Dav]

Woah...nice one, bplus.  That neon glowing effect looks just like a liquid crystal display clock. 

- Dav

[bplus]

Thanks guys, if you copy the 4 procedures you can port to your app and just:

Code: QB64: [Select]

1. print7 text$, x, y, height (pixels), color (for center line)

unless you are using Screen 0 ;-))

[SierraKen]

I just attempted a way around making new fonts and used a double loop with POINT to match every pixel for the neon SUB we used. It just freezes up the computer. LOL For me anyway. hehe The funny thing is that it tried to do it, showing the time and date in neon, but then everything just stopped and the computer froze. lol

But thanks for making that B+. I saved it and will experiment with it I think soon.

[Dav]

Thanks guys, if you copy the 4 procedures you can port to your app and just:

Code: QB64: [Select]

1. print7 text$, x, y, height (pixels), color (for center line)

unless you are using Screen 0 ;-))

Cool. I think I would like to borrow this for a metronome I'm working on, if that would be okay...

- Dav

[bplus]

Cool. I think I would like to borrow this for a metronome I'm working on, if that would be okay...

- Dav

You don't have to ask but I like it :) definitely OK! BTW the segment font idea was borrowed and modified from Richard Frost, or possibly [banned user] or Petr, I suspect Richard Frost when we were doing clocks he picked up on plasma I the segmented digits.

[SMcNeill]

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2. f = _LOADFONT("LCD.ttf", 72, "monospace")
3. _FONT f
4. DO
5.     CLS
6.     COLOR &H77AAAA00, 0
7.     PRINT " 88:88:88"
8.     PRINT "88-88-8888"
9.     COLOR -1, 0
10.     LOCATE 1, 1
11.     PRINT " "; TIME$
12.     PRINT DATE$
13.     _DISPLAY
14.     _LIMIT 1
15. LOOP

Use font below.  All lines up and displays easily, as illustrated above.

I finally got home from watching mom, so this is the first chance I had to grab and test a decent LCD font.  ;)

[bplus]

Ah! I see they made same decision for colon as I.

I started to consider this for other text but 7 segments aren't enough. They do do digits really well though.

[SierraKen]

I should have used Lcd.ttf as monospace, but never tried it on that particular one. lol