Faux 3d Rotation!

[Cobalt]

Don't ask me I just blindfolded myself and typed this monstrosity up. Wacha think?

Code: QB64: [Select]

1. 'Faux 3d rotation thingy with (almost)no math
2. 'Cobalt 11/25/2020
3.  
4. '--------Obligitory Start Up stuff-----------
5. SCREEN 12
6. Layer1& = _NEWIMAGE(640, 480, 12)
7. layer2& = _NEWIMAGE(120, 64, 12)
8. _DEST layer2&
9. _FONT 8
10. PRINT "ESC to Quit"
11. PRINT "Up - Faster"
12. PRINT "Down - Slower"
13. _DEST Layer1&
14. _FONT 8
15. Limit%% = 24
16. ExitFlag%% = 0
17. '---------------------------------------------
18.  
19. '------------------Main Loop-------------------
20. DO
21.  _PUTIMAGE (0, 0), layer2&, Layer1& 'Place options on plate
22.  FOR n = 0 TO 75 'draw the thingy
23.   PSET (150 + n + n, 200)
24.   DRAW "TA" + STR$(C)
25.   DRAW "F" + STR$(n)
26.   DRAW "G" + STR$(n)
27.   DRAW "L" + STR$(n)
28.   DRAW "H" + STR$(n)
29.   DRAW "U" + STR$(n)
30.   DRAW "E" + STR$(n)
31.   DRAW "R" + STR$(n)
32.   DRAW "D" + STR$(n)
33.  NEXT
34.  _LIMIT Limit%% 'control our speed
35.  IF Limit%% = 120 THEN LOCATE 2, 16: COLOR 14: PRINT "Max Speed": COLOR 15 'you can stop pressing up now
36.  IF Limit%% = 12 THEN LOCATE 3, 16: COLOR 12: PRINT "Min Speed": COLOR 15 'you can stop pressing down now
37.  _PUTIMAGE , Layer1&, _DISPLAY 'move our buffoonery to the screen
38.  CLS 'clear the plate
39.  C = C + 1: IF C = 360 THEN C = 0 'rotation... its all about rotation!
40.  '--------------Controls---------------
41.  KBD& = _KEYHIT
42.  SELECT CASE KBD&
43.   CASE 27 'ESC key
44.    ExitFlag%% = -1
45.   CASE 18432 'Up Arrow
46.    Limit%% = Limit%% + 1
47.    IF Limit%% = 121 THEN Limit%% = 120
48.   CASE 20480 'Down Arrow
49.    Limit%% = Limit%% - 1
50.    IF Limit%% = 11 THEN Limit%% = 12
51.   CASE ELSE 'tricky little sod ain't he?
52.    IF KBD& > 0 THEN
53.     IF KBD& < 32736 THEN SOUND 32 + KBD&, 1 ELSE BEEP
54.    END IF
55.  END SELECT
56.  '-------------------------------------
57. LOOP UNTIL ExitFlag%% 'they just want it to be over!
58. '----------------------------------------------
59. _DEST _DISPLAY
60. 'All Done, Have a Nice Day

[Richard Frost]

Because midgets are cool, I shortened your code to under 30 lines.
Also, the brown color is absolutely essential.

Code: QB64: [Select]

1. ' faux 3D by Cobalt, modified by a Fuzzy Squirrel
2.  
3. SCREEN 12
4. Limit = 24
5. COLOR 6, 0 '                                        brown to fool cat
6.  
7. DO: _LIMIT Limit
8.     CLS
9.     PRINT "ESC to Quit": PRINT "Up - Faster": PRINT "Down - Slower"
10.     FOR n = 0 TO 75
11.         PSET (150 + n + n, 200)
12.         DRAW "TA" + STR$(c)
13.         FOR i = 1 TO 8
14.             DRAW MID$("FGLHUERD", i, 1) + STR$(n)
15.         NEXT i
16.     NEXT
17.     IF Limit = 120 THEN LOCATE 2, 16: PRINT "Max Speed"
18.     IF Limit = 12 THEN LOCATE 3, 16: PRINT "Min Speed"
19.     _DISPLAY
20.     c = (c + 1) MOD 360
21.     KBD& = _KEYHIT
22.     SELECT CASE KBD&
23.         CASE 27: END
24.         CASE 18432: Limit = Limit + 1 + (Limit = 120)
25.         CASE 20480: Limit = Limit - 1 - (Limit = 12)
26.         CASE ELSE
27.             IF KBD& > 0 THEN
28.                 IF KBD& < 32736 THEN SOUND 32 + KBD&, 1 ELSE BEEP
29.             END IF
30.     END SELECT
31. LOOP

[SMcNeill]

Code: [Select]

         CASE 18432: Limit = Limit + 1 + (Limit = 120)
        CASE 20480: Limit = Limit - 1 - (Limit = 12)
I like this code.  I'm going to shamelessly steal this logic for my own programs from now on.  👍

[Richard Frost]

You weren't already doing that method of bounds checking/correcting?  I was doing it for brevity
even before I learned of branchless coding, which helps modern CPUs go faster.

Someday I'll need to look at the keyboard in a time critical section of code, and will use _KEYHIT. 
We dinosaurs use INKEY$, which is slow, but a mite friendlier (no arcane keycode values).

[SMcNeill]

You weren't already doing that method of bounds checking/correcting?  I was doing it for brevity
even before I learned of branchless coding, which helps modern CPUs go faster.

Someday I'll need to look at the keyboard in a time critical section of code, and will use _KEYHIT. 
We dinosaurs use INKEY$, which is slow, but a mite friendlier (no arcane keycode values).

INKEY$ uses the exact same codes as _KEYHIT.  The only difference is one is ASC and the other is CHR$.

INKEY$ "A" = _KEYHIT 65.
ASC("A") = 65
"A" = CHR$(65)

Even arrow keys and such map out equally.  In INKEY$, up is CHR$(0) + "I"  (if my memory is correct.)  Convert that string value to an integer, and it'll perfectly match _KEYHIT's value.

It won't be hard for an old dinosaur to swap over, if they ever decide they want to.  ;)

[bplus]

vidmate arrays and List<T>

There's something I don't hear about every day. :-))

Internet says vidmate is APK is Android video streaming array?, List<t> C# and other, just a list strongly typed and ordered were some adjs for the structure.

Ha, ha! doesn't sound very Basic to me.

[SierraKen]

Awesome guys! I was wondering if this was possible with DRAW, I should have tested it. :)

[bplus]

Awesome guys! I was wondering if this was possible with DRAW, I should have tested it. :)

?? Originally done with DRAW  ;-))

[SierraKen]

B+, I think you misunderstood me. I meant I thought of the same thing around a week ago, to use DRAW to make a 3D looking rotation. But I never experimented with it. Am glad they did.

[Pete]

Looks like someone ran over, knocked down, and dented a once perfectly good line drawn hexagonic road cone then left it rolling around on the pavement.

Other than that, all I can say is yippie kai yay...

Pete