Running numeric functions from a string

[bplus]

Sorta like Evaluate, here is a test very simple code$ = "X ^ 2" developed from Steve's suggestion for writing, compiling, running, killing code inside another running QB64 program.

Code: QB64: [Select]

1. _TITLE "Write Compile Run Kill test2 clip" 'b+ 2020-10-17
2.  
3. ' Can we "Evaluate" FUNCTIONs from just a string??? by writing, compiling, running and recording answer
4. ' then killing all the files involved?
5.  
6. ' Yes! sorta but the thrill is gone because it is so compromised by a big restriction and numerous delays.
7.  
8. ' BIG RESTRICTION:
9.  
10. ' !!!!   If QB64.exe is not in your PATH, you have to run this in the QB64.EXE Folder  !!!!
11.  
12.  
13. start = 1: finish = 10: increment = 1
14. FOR X = start TO finish STEP increment
15.     IF r$ = "" THEN
16.         r$ = _TRIM$(STR$(X ^ 2))
17.     ELSE
18.         r$ = r$ + CHR$(10) + _TRIM$(STR$(X ^ 2))
19.     END IF
20. NEXT
21. PRINT r$
22. PRINT: PRINT " and now the hard way ;-))"
23.  
24. DoCode$ = "X ^ 2"
25. REDIM result$(0)
26. forXEqual 1, 10, 1, DoCode$, result$()
27. FOR i = LBOUND(result$) TO UBOUND(result$)
28.     PRINT result$(i)
29. NEXT
30.  
31. SUB forXEqual (start, toFinish, incStep, DoCode$, outputArr$())
32.  
33.     ' write this:
34.  
35.     'FOR X = start TO finish STEP increment
36.     '    IF r$ = "" THEN
37.     '        'r$ = _trim$(str$(doCode$))
38.     '    ELSE
39.     '        'r$ = r$ + chr$(10)+ _trim$(str$(doCode$))
40.     '    END IF
41.     'NEXT
42.     '_CLIPBOARD$ = r$
43.  
44.     OPEN "temp.bas" FOR OUTPUT AS #1
45.     PRINT #1, "FOR X =" + STR$(start) + " TO" + STR$(toFinish) + " STEP" + STR$(incStep)
46.     PRINT #1, "IF r$ = " + CHR$(34) + CHR$(34) + " THEN"
47.     PRINT #1, "r$ = _TRIM$(STR$(" + DoCode$ + "))"
48.     PRINT #1, "ELSE"
49.     PRINT #1, "r$ = r$ + chr$(10) + _trim$(str$(" + DoCode$ + "))"
50.     PRINT #1, "END IF"
51.     PRINT #1, "NEXT"
52.     PRINT #1, "OPEN " + CHR$(34) + "clip.txt" + CHR$(34) + " FOR OUTPUT AS #5"
53.     PRINT #1, "PRINT #5, r$"
54.     PRINT #1, "CLOSE #5"
55.     CLOSE #1
56.  
57.     _DELAY 1 'make sure done with file writing
58.     SHELL _HIDE "qb64 -c " + CHR$(34) + "temp.bas" + CHR$(34)
59.     _DELAY 3 ' sometimes it compiles in time sometimes not, 3 reduces the nots
60.     SHELL _DONTWAIT "temp.exe"
61.     _DELAY 2 ' give it time to find and run
62.     SHELL _HIDE "taskkill /F /IM temp.exe"
63.     _DELAY .5 'give it time to close before kill
64.     IF _FILEEXISTS("temp.bas") THEN KILL "temp.bas"
65.     IF _FILEEXISTS("temp.exe") THEN KILL "temp.exe"
66.     IF _FILEEXISTS("clip.txt") THEN ' we got it written up
67.         OPEN "clip.txt" FOR INPUT AS #1 ' read out our answer
68.         WHILE NOT EOF(1)
69.             LINE INPUT #1, s$
70.             sAppend outputArr$(), s$
71.         WEND
72.         CLOSE #1
73.         KILL "clip.txt"
74.     END IF
75. END FUNCTION
76.  
77. ''append to the string array the string item
78. SUB sAppend (arr() AS STRING, addItem$)
79.     REDIM _PRESERVE arr(LBOUND(arr) TO UBOUND(arr) + 1) AS STRING
80.     arr(UBOUND(arr)) = addItem$
81. END SUB
82.  
83.  

[SpriggsySpriggs]

I get the idea of compiling and running another instance and read back output from it but why not just make a program that accepts commands in SHELL that is already compiled? It would be much quicker.

[bplus]

I am evaluating string functions over a range neither of which are hard coded.

I can do X^2 or X^5+X^3+X for 1 to 10 or 500 to -1000 without having to write up a new function. I just say
DoCode$ = "X^5+X^3+X" or "X ^ 2" or any other function involving X.

BTW currently it doesn't work for string literals, need the string stored in a variable before making the call to
ForXEqual...

[bplus]

BTW this was just testing proof of concept and did not pass with flying colors.

It might be useful for something but not for plotting 20 different functions. I was hoping for a one liner tables generator  to run so many functions given by user at run time.

Actually I was hoping for more advanced code results like a built in Interpreter and string functions was just a stepping stone.

[bplus]

I get the idea of compiling and running another instance and read back output from it but why not just make a program that accepts commands in SHELL that is already compiled? It would be much quicker.

Yep! I am moving on to this, back to work on my Shorthand Basic project, then, I think I don't even need SHELL.

I seem to loose my _CLIPBOARD$ contents when I run something in SHELL and put something in _CLIPBOARD$. It's not there after SHELL.

[carloscordeiro]

Hi Bplus
Taking advantage of the post, I'm trying to make a percentage of a number to show the two digits after the comma. I got it with the LEFT $ command. So with CSNG you can show 4 digits after the comma, I believe you can do the same without using LEFT $.
Attached image shows better.

'Accurate percentage



DIM a(1 TO 4) AS _FLOAT
b = 2062
a(1) = 1273
a(2) = 1266
a(3) = 1260
a(4) = 1174

FOR i = 1 TO 4
    Porc = CSNG(a(i) / b) * 100
    PRINT (a(i) / b) * 100,
    PRINT CSNG(a(i) / b) * 100, ' Line using CSNG
    PRINT LEFT$(STR$(Porc), 6) + "%" '   Mude esta linha
NEXT

Carlos again. ;)

[bplus]

Going off on a tangent about rounding, Carlos you might like this:

Code: QB64: [Select]

1. PRINT "1 to 20  rounded to 5's;"
2. FOR i = 1 TO 20
3.     PRINT INT(i / 5) * 5
4. NEXT
5. PRINT "press any for 1 to 1000 rounded to 20's.."
6. SLEEP
7. PRINT:
8. FOR i = 1 TO 20
9.     r = INT(RND * 1000) + 1
10.     PRINT r, INT(r / 20) * 20
11. NEXT
12.  
13.  
14.  

One more, rounded to 1/100ths :

Code: QB64: [Select]

1. FOR i = 1 TO 20
2.     r = RND * 100
3.     PRINT r, INT((r + .005) * 100) / 100
4. NEXT
5.  

[carloscordeiro]

Very good Bplus
I really liked:

FOR i = 1 TO 20
    r = RND * 100
    PRINT r, INT((r + .005) * 100) / 100
NEXT

I'll use it on:

DIM a(1 TO 4) AS _FLOAT
b = 2062
a(1) = 1273
a(2) = 1266
a(3) = 1260
a(4) = 1174
FOR i = 1 TO 4
    Porc = (a(i) / b) * 100
    PRINT Porc, INT((Porc + .005) * 100) / 100
NEXT

Thank you
Carlos

[bplus]

OK now I have a much soooother operation with the Tabulator:

Code: QB64: [Select]

1. _TITLE "Tabulator" ' B+ 2020-10-23  from Formula Saver
2. ' More Evaluate.txt bplus started 2020-05-10 inspired by honkytonk app
3. ' 2020-10-23 translate from JB but install latest Evaluate
4. ' copy of Evaluate subs used in this Forumla Saver Project Folder
5. ' Should be able to do all this without Word$ tools
6. ' OK everything seems to be working now start Tabulator
7. ' OK Had to rearrnge th eorder the formula string gets prepped, ie
8. ' put spaces around all the "words", replace variable for their values
9. ' or replace constants like pi and e. THEN running x in a FOR loop update
10. ' only the X variable with it's value.
11.  
12. ' The Tabulator.exe opens the file: TableIn.txt
13. ' reads lines formated as:
14. ' first line holds the start value of a FOR Loop
15. ' 2nd the end value of same FOR loop
16. ' 3rd the increament to STEP
17. ' 4th the formula eg, X ^ 2 + b * X + pi
18. ' 5th the dFlag use 0 for Radian units any other for Degrees units
19. ' 6+ the variables separated by CHR$(10) eg
20. ' a = 1
21. ' b = 6
22. ' c = 5
23. ' inches = 42
24.  
25. ' Tabulator runs the formula in a for loop and generates a table in the
26. ' file  TableOut.txt.
27.  
28. ' So you can edit TableIn.txt in your favorite Text Editor and Run Tabulator
29. ' and it will rewrite the TableOut.txt with the list of x and f(x).
30.  
31. ' Or you can use Calling the Tabulator sub to write the TableIn.txt file,
32. ' Shell and Run Tabulator then read the file into an array top use:
33. ' SUB forXEqual (start, toFinish, incStep, formula$, dFlag%, variablesCHR10$, outputArr$())
34. ' Calling the Tabulator.bas is a demo for the SUB mainly.
35.  
36. ' BTW Tabulator does everything in background you will have no idea the TableOut.txt file
37. ' has been rewritten or not!
38.  
39.  
40. 'evaluate$ and evalW setup
41. DIM SHARED evalErr$, pi, rad, deg, Dflag, vTopI AS INTEGER, debug
42. debug = 0 ' this is for checking the Evaluate stuff
43.  
44. pi = _PI: rad = pi / 180: deg = 180 / pi '<<<<<<<<<<< true constants
45. vTopI = 0 'track variables and functions we have changeable global variables change as needed
46.  
47. Dflag = 0 ' degrees flag
48. evalErr$ = ""
49. rad = _PI / 180.0
50. deg = 180 / _PI
51. REDIM SHARED fList(1 TO 1) AS STRING
52. Split "int, sin, cos, tan, asin, acos, atan, log, exp, sqr, rad, deg,", ", ", fList()
53. REDIM SHARED oList(1 TO 1) AS STRING
54. Split "^, %, /, *, -, +, =, <, >, <=, >=, <>, or, and, not", ", ", oList()
55.  
56. DIM SHARED varNames$(1 TO 100), varValues(1 TO 100)
57.  
58. IF _FILEEXISTS("TableIn.txt") THEN ' 5 lines max to read
59.     OPEN "TableIn.txt" FOR INPUT AS #1
60.     FOR i = 1 TO 5
61.         LINE INPUT #1, fline$
62.         SELECT CASE i '                     format first 5 lines set variables, more than 5 sets variable names and values
63.             CASE 1: start = VAL(fline$)
64.             CASE 2: finish = VAL(fline$)
65.             CASE 3: inc = VAL(fline$)
66.             CASE 4: frml$ = fline$
67.             CASE 5: Dflag = VAL(fline$)
68.         END SELECT
69.     NEXT
70.     WHILE NOT EOF(1) ' read in additional varaibles and values
71.         LINE INPUT #1, fline$
72.         IF INSTR(fline$, "=") THEN '                        collect variable names and values
73.             vTopI = vTopI + 1
74.             varNames$(vTopI) = _TRIM$(leftOf$(fline$, "=")): varValues(vTopI) = VAL(_TRIM$(rightOf$(fline$, "=")))
75.         END IF
76.     WEND
77.     CLOSE #1
78. ELSE
79.     PRINT " Sorry, TableIn.txt file is missing, goodbye!"
80.     END
81. END IF
82. OPEN "TableOut.txt" FOR OUTPUT AS #1
83. e$ = prepEval$(frml$)
84. IF evalErr$ = "" THEN 'debug
85.     'PRINT "prep formula: "; e$
86.     'INPUT " OK "; w$
87. ELSE
88.     PRINT #1, "Error: " + evalErr$
89.     CLOSE #1
90.     SYSTEM
91. END IF
92. preEvalSubst e$ 'OK inject variable values into formula
93. ' debug
94. 'PRINT "Replace variables with values, except x: "; e$
95. 'INPUT "After preEvalSubst OK "; w$
96.  
97. FOR x = start TO finish STEP inc
98.     REDIM ev$(1 TO 1)
99.     copy$ = e$
100.     Split copy$, " ", ev$()
101.     FOR i = LBOUND(ev$) TO UBOUND(ev$) 'look for x
102.         IF LCASE$(ev$(i)) = "x" THEN ev$(i) = _TRIM$(STR$(x))
103.     NEXT
104.     'rebuild eString$
105.     FOR i = LBOUND(ev$) TO UBOUND(ev$) ' rejoin as b$
106.         IF i = LBOUND(ev$) THEN b$ = ev$(1) ELSE b$ = b$ + " " + ev$(i)
107.     NEXT
108.     copy$ = b$
109.     result$ = _TRIM$(Evaluate$(copy$))
110.     IF evalErr$ = "" THEN
111.         PRINT #1, ts$(x); " "; result$
112.     ELSE
113.         PRINT #1, ts$(x); " Error: " + evalErr$
114.     END IF
115. NEXT
116. CLOSE #1
117. SYSTEM
118.  
119. FUNCTION value (vName$) ' find vName$ index to get value of variable
120.     FOR i = 1 TO vTopI
121.         IF _TRIM$(varNames$(i)) = _TRIM$(vName$) THEN
122.             value = varValues(i)
123.             EXIT FUNCTION
124.         END IF
125.     NEXT
126.     value = -99.11 ' no value found can't be -1 or 0 too common
127. END FUNCTION
128.  
129. SUB preEvalSubst (eString$) ' this is meant to modify eString$ inserting values for variables
130.     REDIM ev$(1 TO 1)
131.     Split eString$, " ", ev$()
132.     FOR i = LBOUND(ev$) TO UBOUND(ev$) 'replace variables for values
133.         IF LCASE$(ev$(i)) = "pi" THEN
134.             ev$(i) = ts$(_PI)
135.         ELSEIF LCASE$(ev$(i)) = "e" THEN
136.             ev$(i) = ts$(EXP(1))
137.         ELSEIF LCASE$(ev$(i)) <> "x" THEN
138.             v = value(ev$(i))
139.             IF v <> -99.11 THEN ev$(i) = ts$(v)
140.         END IF
141.     NEXT
142.     'rebuild eString$
143.     FOR i = LBOUND(ev$) TO UBOUND(ev$) ' rejoin as b$
144.         IF i = LBOUND(ev$) THEN b$ = ev$(1) ELSE b$ = b$ + " " + ev$(i)
145.     NEXT
146.     eString$ = b$
147. END SUB
148.  
149. FUNCTION leftOf$ (source$, of$)
150.     IF INSTR(source$, of$) > 0 THEN leftOf$ = MID$(source$, 1, INSTR(source$, of$) - 1)
151. END FUNCTION
152.  
153. FUNCTION rightOf$ (source$, of$)
154.     IF INSTR(source$, of$) > 0 THEN rightOf$ = MID$(source$, INSTR(source$, of$) + LEN(of$))
155. END FUNCTION
156.  
157. FUNCTION prepEval$ (e$)
158.     DIM b$, c$
159.     DIM i AS INTEGER, po AS INTEGER ', isolateNeg AS _BIT
160.     ' isolateNeg = 0
161.     b$ = "" 'rebuild string with padded spaces
162.     'this makes sure ( ) + * / % ^ are wrapped with spaces,  ??????????? on your own with - sign fixed?
163.     FOR i = 1 TO LEN(e$) 'filter chars and count ()
164.         c$ = LCASE$(MID$(e$, i, 1))
165.         IF c$ = ")" THEN
166.             po = po - 1: b$ = b$ + " ) "
167.         ELSEIF c$ = "(" THEN
168.             po = po + 1: b$ = b$ + " ( "
169.         ELSEIF INSTR("+*/%^", c$) > 0 THEN
170.             b$ = b$ + " " + c$ + " "
171.         ELSEIF c$ = "-" THEN
172.             IF LEN(b$) > 0 THEN
173.                 IF INSTR(".0123456789abcdefghijklmnopqrstuvwxyz)", RIGHT$(RTRIM$(b$), 1)) > 0 THEN
174.                     b$ = b$ + " " + c$ + " "
175.                 ELSE
176.                     b$ = b$ + " " + c$
177.                 END IF
178.             ELSE
179.                 b$ = b$ + " " + c$
180.             END IF
181.         ELSEIF INSTR(" .0123456789abcdefghijklmnopqrstuvwxyz<>=", c$) > 0 THEN
182.             b$ = b$ + c$
183.         END IF
184.         IF po < 0 THEN evalErr$ = "Too many )": EXIT FUNCTION
185.     NEXT
186.     IF po <> 0 THEN evalErr$ = "Unbalanced ()": EXIT FUNCTION
187.     prepEval$ = b$
188. END FUNCTION
189.  
190. ' ================================================================================ from Evaluate
191. 'this preps e$ string for actual evaluation function and makes call to it,
192. 'checks results for error returns that or string form of result calculation
193. 'the new goal is to do string functions along side math
194. FUNCTION Evaluate$ (e$)
195.     REDIM ev(1 TO 1) AS STRING
196.     Split e$, " ", ev()
197.     c$ = evalW$(ev())
198.     IF evalErr$ <> "" THEN Evaluate$ = evalErr$ ELSE Evaluate$ = c$
199. END FUNCTION
200.  
201. ' the recursive part of EVAL
202. FUNCTION evalW$ (a() AS STRING)
203.     IF evalErr$ <> "" THEN EXIT FUNCTION
204.  
205.     DIM fun$, test$, innerV$, m$, op$
206.     DIM pop AS INTEGER, lPlace AS INTEGER, i AS INTEGER, rPlace AS INTEGER
207.     DIM po AS INTEGER, p AS INTEGER, o AS INTEGER, index AS INTEGER
208.     DIM recurs AS INTEGER
209.     DIM innerVal AS _FLOAT, a AS _FLOAT, b AS _FLOAT
210.     IF debug THEN
211.         PRINT "evalW rec'd a() as:"
212.         FOR i = LBOUND(a) TO UBOUND(a)
213.             PRINT a(i); ", ";
214.         NEXT
215.         PRINT: INPUT "OK enter"; test$: PRINT
216.     END IF
217.     pop = find%(a(), "(") 'parenthesis open place
218.     WHILE pop > 0
219.         IF pop = 1 THEN
220.             fun$ = "": lPlace = 1
221.         ELSE
222.             test$ = a(pop - 1)
223.             IF find%(fList(), test$) > 0 THEN
224.                 fun$ = test$: lPlace = pop - 1
225.             ELSE
226.                 fun$ = "": lPlace = pop
227.             END IF
228.         END IF
229.         po = 1
230.         FOR i = pop + 1 TO UBOUND(a)
231.             IF a(i) = "(" THEN po = po + 1
232.             IF a(i) = ")" THEN po = po - 1
233.             IF po = 0 THEN rPlace = i: EXIT FOR
234.         NEXT
235.         REDIM inner(1 TO 1) AS STRING: index = 0: recurs = 0
236.         FOR i = (pop + 1) TO (rPlace - 1)
237.             index = index + 1
238.             REDIM _PRESERVE inner(1 TO index) AS STRING
239.             inner(index) = a(i)
240.             IF find%(oList(), a(i)) > 0 THEN recurs = -1
241.         NEXT
242.         IF recurs THEN innerV$ = evalW$(inner()) ELSE innerV$ = a(pop + 1)
243.         innerVal = VAL(innerV$)
244.  
245.         SELECT CASE fun$
246.             CASE "": m$ = innerV$
247.             CASE "int": m$ = ts$(INT(innerVal))
248.             CASE "sin": IF Dflag THEN m$ = ts$(SIN(rad * innerVal)) ELSE m$ = ts$(SIN(innerVal))
249.             CASE "cos": IF Dflag THEN m$ = ts$(COS(rad * innerVal)) ELSE m$ = ts$(COS(innerVal))
250.             CASE "tan": IF Dflag THEN m$ = ts$(TAN(rad * innerVal)) ELSE m$ = ts$(TAN(innerVal))
251.             CASE "asin": IF Dflag THEN m$ = ts$(_ASIN(rad * innerVal)) ELSE m$ = ts$(_ASIN(innerVal))
252.             CASE "acos": IF Dflag THEN m$ = ts$(_ACOS(rad * innerVal)) ELSE m$ = ts$(_ACOS(innerVal))
253.             CASE "atan": IF Dflag THEN m$ = ts$(ATN(rad * innerVal)) ELSE m$ = ts$(ATN(innerVal))
254.             CASE "log"
255.                 IF innerVal > 0 THEN
256.                     m$ = ts$(LOG(innerVal))
257.                 ELSE
258.                     evalErr$ = "LOG only works on numbers > 0.": EXIT FUNCTION
259.                 END IF
260.             CASE "exp" 'the error limit is inconsistent in JB
261.                 IF -745 <= innerVal AND innerVal <= 709 THEN 'your system may have different results
262.                     m$ = ts$(EXP(innerVal))
263.                 ELSE
264.                     'what the heck???? 708 works fine all alone as limit ?????
265.                     evalErr$ = "EXP(n) only works for n = -745 to 709.": EXIT FUNCTION
266.                 END IF
267.             CASE "sqr"
268.                 IF innerVal >= 0 THEN
269.                     m$ = ts$(SQR(innerVal))
270.                 ELSE
271.                     evalErr$ = "SQR only works for numbers >= 0.": EXIT FUNCTION
272.                 END IF
273.             CASE "rad": m$ = ts$(innerVal * rad)
274.             CASE "deg": m$ = ts$(innerVal * deg)
275.             CASE ELSE: evalErr$ = "Unidentified function " + fun$: EXIT FUNCTION
276.         END SELECT
277.         IF debug THEN
278.             PRINT "lPlace, rPlace"; lPlace, rPlace
279.         END IF
280.         arrSubst a(), lPlace, rPlace, m$
281.         IF debug THEN
282.             PRINT "After arrSubst a() is:"
283.             FOR i = LBOUND(a) TO UBOUND(a)
284.                 PRINT a(i); " ";
285.             NEXT
286.             PRINT: PRINT
287.         END IF
288.         pop = find%(a(), "(")
289.     WEND
290.  
291.     'all parenthesis cleared
292.     'ops$ = "% ^ / * + - = < > <= >= <> and or not" 'all () cleared, now for binary ops (not not binary but is last!)
293.     FOR o = 1 TO 15
294.         op$ = oList(o)
295.         p = find%(a(), op$)
296.         WHILE p > 0
297.             a = VAL(a(p - 1))
298.             b = VAL(a(p + 1))
299.             IF debug THEN
300.                 PRINT STR$(a) + op$ + STR$(b)
301.             END IF
302.             SELECT CASE op$
303.                 CASE "%"
304.                     IF b >= 2 THEN
305.                         m$ = ts$(INT(a) MOD INT(b))
306.                     ELSE
307.                         evalErr$ = "For a Mod b, b value < 2."
308.                         EXIT FUNCTION
309.                     END IF
310.                 CASE "^"
311.                     IF INT(b) = b OR a >= 0 THEN
312.                         m$ = ts$(a ^ b)
313.                     ELSE
314.                         evalErr$ = "For a ^ b, a needs to be >= 0 when b not integer."
315.                         EXIT FUNCTION
316.                     END IF
317.                 CASE "/"
318.                     IF b <> 0 THEN
319.                         m$ = ts$(a / b)
320.                     ELSE
321.                         evalErr$ = "Div by 0"
322.                         EXIT FUNCTION
323.                     END IF
324.                 CASE "*": m$ = ts$(a * b)
325.                 CASE "-": m$ = ts$(a - b)
326.                 CASE "+": m$ = ts$(a + b)
327.                 CASE "=": IF a = b THEN m$ = "-1" ELSE m$ = "0"
328.                 CASE "<": IF a < b THEN m$ = "-1" ELSE m$ = "0"
329.                 CASE ">": IF a > b THEN m$ = "-1" ELSE m$ = "0"
330.                 CASE "<=": IF a <= b THEN m$ = "-1" ELSE m$ = "0"
331.                 CASE ">=": IF a >= b THEN m$ = "-1" ELSE m$ = "0"
332.                 CASE "<>": IF a <> b THEN m$ = "-1" ELSE m$ = "0"
333.                 CASE "and": IF a <> 0 AND b <> 0 THEN m$ = "-1" ELSE m$ = "0"
334.                 CASE "or": IF a <> 0 OR b <> 0 THEN m$ = "-1" ELSE m$ = "0"
335.                 CASE "not": IF b = 0 THEN m$ = "-1" ELSE m$ = "0" 'use b as nothing should be left of not
336.             END SELECT
337.             arrSubst a(), p - 1, p + 1, m$
338.  
339.             IF debug THEN
340.                 PRINT "a() reloaded after " + op$ + " as:"
341.                 FOR i = LBOUND(a) TO UBOUND(a)
342.                     PRINT a(i); ", ";
343.                 NEXT
344.                 PRINT: PRINT
345.             END IF
346.  
347.             p = find%(a(), op$)
348.         WEND
349.     NEXT
350.     fun$ = ""
351.     FOR i = LBOUND(a) TO UBOUND(a)
352.         fun$ = fun$ + " " + a(i)
353.     NEXT
354.     evalW$ = LTRIM$(fun$)
355. END FUNCTION
356.  
357. SUB arrSubst (a() AS STRING, substLow AS LONG, substHigh AS LONG, subst AS STRING)
358.     DIM i AS LONG, index AS LONG
359.     a(substLow) = subst: index = substLow + 1
360.     FOR i = substHigh + 1 TO UBOUND(a)
361.         a(index) = a(i): index = index + 1
362.     NEXT
363.     REDIM _PRESERVE a(LBOUND(a) TO UBOUND(a) + substLow - substHigh)
364. END SUB
365.  
366. 'notes: REDIM the array(0) to be loaded before calling Split '<<<<<<<<<<<<<<<<<<<<<<< IMPORTANT!!!!
367. SUB Split (mystr AS STRING, delim AS STRING, arr() AS STRING)
368.     ' bplus modifications of Galleon fix of Bulrush Split reply #13
369.     ' http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=1612.0
370.     ' this sub further developed and tested here: \test\Strings\Split test.bas
371.     ' 2018-09-16 modified for base 1 arrays
372.     DIM copy AS STRING, p AS LONG, curpos AS LONG, arrpos AS LONG, lc AS LONG, dpos AS LONG
373.     copy = mystr 'make copy since we are messing with mystr
374.     'special case if delim is space, probably want to remove all excess space
375.     IF delim = " " THEN
376.         copy = RTRIM$(LTRIM$(copy))
377.         p = INSTR(copy, "  ")
378.         WHILE p > 0
379.             copy = MID$(copy, 1, p - 1) + MID$(copy, p + 1)
380.             p = INSTR(copy, "  ")
381.         WEND
382.     END IF
383.     REDIM arr(1 TO 1) 'clear it
384.     curpos = 1
385.     arrpos = 1
386.     lc = LEN(copy)
387.     dpos = INSTR(curpos, copy, delim)
388.     DO UNTIL dpos = 0
389.         arr(arrpos) = MID$(copy, curpos, dpos - curpos)
390.         arrpos = arrpos + 1
391.         REDIM _PRESERVE arr(1 TO arrpos + 1) AS STRING
392.         curpos = dpos + LEN(delim)
393.         dpos = INSTR(curpos, copy, delim)
394.     LOOP
395.     arr(arrpos) = MID$(copy, curpos)
396.     REDIM _PRESERVE arr(1 TO arrpos) AS STRING
397. END SUB
398.  
399. 'assume a() is base 1 array so if find comes back as 0 then found nothing
400. FUNCTION find% (a() AS STRING, s$)
401.     DIM i%
402.     FOR i% = LBOUND(a) TO UBOUND(a)
403.         IF a(i%) = s$ THEN find% = i%: EXIT FUNCTION
404.     NEXT
405. END FUNCTION
406.  
407. 'ltrim a number float
408. FUNCTION ts$ (n)
409.     ts$ = _TRIM$(STR$(n))
410. END FUNCTION
411.  
412.  

Run this file in a folder you can play around with, it will tell you it can't find the TableIn.txt file. That's OK we just need the exe made so we can call it from a SHELL.

Now here is demo code for the SUB in it to make the TableIn.txt file place it in same test area folder as the Tabulator
and run the Tabulator in a SHELL, and then gets the lines generated and loads them in an array to be used as needed.

Code: QB64: [Select]

1. _TITLE "Calling the Tabulator" 'b+ 2020-10-23
2. ' mod "Write Compile Run Kill test2 clip.bas" 'b+ 2020-10-17
3.  
4. ' Can we "Evaluate" FUNCTIONs from just a string???
5.  
6. start = 1: finish = 10: increment = 1: a = 2: b = 6: c = _PI
7. FOR X = start TO finish STEP increment
8.     IF r$ = "" THEN
9.         r$ = TS$(X) + " " + TS$(a * X ^ 2 + b * X + c)
10.     ELSE
11.         r$ = r$ + CHR$(10) + TS$(X) + " " + TS$(a * X ^ 2 + b * X + c)
12.     END IF
13. NEXT
14. PRINT r$
15. PRINT " and now the hard way ;-))"
16.  
17. f$ = "a*X^2+b*X+pi" ' our formula
18. v$ = "a=2" + CHR$(10) + "b=6" + CHR$(10) + "c= pi" 'some variables
19. REDIM result$(0) ' output array, notice it's dynamic
20.  
21. '   Make the call...
22. ' start, finish, step increment, formula$, degreeFlag True (radians = 0 or False), variables list in formula$, outputArray$()
23. forXEqual 1, 10, 1, f$, 0, v$, result$()
24.  
25. ' show results
26. FOR i = LBOUND(result$) TO UBOUND(result$)
27.     PRINT result$(i)
28. NEXT
29. PRINT "Run is done."
30.  
31. SUB forXEqual (start, toFinish, incStep, formula$, dFlag%, variablesCHR10$, outputArr$())
32.     OPEN "TableIn.txt" FOR OUTPUT AS #1
33.     PRINT #1, TS$(start)
34.     PRINT #1, TS$(toFinish)
35.     PRINT #1, TS$(incStep)
36.     PRINT #1, formula$
37.     PRINT #1, TS$(dFlag)
38.     PRINT #1, variablesCHR10$
39.     CLOSE #1
40.     REDIM outputArr$(0)
41.     SHELL _HIDE "Tabulator.exe"
42.     _DELAY .5 ' sometimes it compiles in time sometimes not, 3 reduces the nots
43.     IF _FILEEXISTS("TableOut.txt") THEN
44.         OPEN "TableOut.txt" FOR INPUT AS #1
45.         WHILE NOT EOF(1)
46.             LINE INPUT #1, fline$
47.             sAppend outputArr$(), fline$
48.         WEND
49.     END IF
50. END SUB
51.  
52. ''append to the string array the string item
53. SUB sAppend (arr() AS STRING, addItem$)
54.     REDIM _PRESERVE arr(LBOUND(arr) TO UBOUND(arr) + 1) AS STRING
55.     arr(UBOUND(arr)) = addItem$
56. END SUB
57.  
58. FUNCTION TS$ (n)
59.     TS$ = _TRIM$(STR$(n))
60. END FUNCTION
61.  

Now you can run functions in code and generate arrays of values without having to write a separate code for each function. How 'bout them apples?

BTW c=pi does not work, must use number literals on the right side of = sign. But pi will work in the Formula string.