Collision

[johnno56]

I am attempting to convert an old Naalaa Pong game  to QB64 (bplus... stop laughing...) and figured I had best use a decent collision detection routine. I decided to go with AABB as the ball size is quite small.

The following routine works but I would appreciate any advice that would make it more efficient.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2.  
3. box1top = 190
4. box1bottom = 290
5. box1left = 270
6. box1right = 370
7.  
8. _MOUSEHIDE
9.  
10. DO
11.     CLS
12.  
13.     k = _KEYHIT
14.  
15.     DO WHILE _MOUSEINPUT
16.     LOOP
17.  
18.     mx = _MOUSEX
19.     my = _MOUSEY
20.  
21.     box2left = mx - 50
22.     box2top = my - 50
23.     box2right = mx + 50
24.     box2bottom = my + 50
25.  
26.     COLOR _RGB32(255, 128, 0)
27.     LINE (box2left, box2top)-(box2right, box2bottom), , B
28.  
29.     IF collide(box1bottom, box1top, box1left, box1right, box2bottom, box2top, box2left, box2right) = 1 THEN
30.         COLOR _RGB32(255, 255, 0)
31.         LINE (box1left, box1top)-(box1right, box1bottom), , BF
32.         COLOR _RGB32(255, 128, 0)
33.         LINE (box2left, box2top)-(box2right, box2bottom), , BF
34.     ELSE
35.         COLOR _RGB32(255, 255, 0)
36.         LINE (box1left, box1top)-(box1right, box1bottom), , B
37.         COLOR _RGB32(255, 128, 0)
38.         LINE (box2left, box2top)-(box2right, box2bottom), , B
39.     END IF
40.  
41.     _DISPLAY
42. LOOP UNTIL k = 27
43. CLS
44. END
45.  
46. '====================================================
47. '
48. '   Axis Aligned Bounding Box Collision Detection
49. '
50. FUNCTION collide (box1bottom, box1top, box1left, box1right, box2bottom, box2top, box2left, box2right)
51.     IF (box1bottom < box2top) OR (box1top > box2bottom) OR (box1left > box2right) OR (box1right < box2left) THEN
52.         collide = 0
53.     ELSE
54.         collide = 1
55.     END IF
56. END FUNCTION
57. '====================================================
58.  

I know. I know. Pong. Why bother? It's not the game per se but to find out if I can successfully convert it...
SDLBasic and RCBasic conversions worked... Now it's QB64's turn... Moo ha ha...

[bplus]

@johnno56

Do you intend a square ball?

Collision routine for round ball should be all that is needed for Ping Pong, should be much simpler. Paddles are usually vertical or horizontal, same with walls so when the ball is less than it's radius away from either, it should be considered collided and sent in the opposite direction.

Your collision for rectangles is excellent and I've still got code (from YOU!) years ago doing nearly same as yours above.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Bounding Box Collision Detection"
3. ' 2020-03-03 update for Toolbox
4. ' 2019-08-30 rewrite this so mouse box never gets inside the sides of box for maze study
5.  
6. '
7. '   Collision - Test 1  orig by johnno copied and mod b+ 2018-06-10
8. '
9. '   Bounding Box
10. '
11. ' 2018-06-10 mod by B+ change for x, y, w, h of images
12. ' by readjusting all the variables and use STEP for box drawing
13. ' Generalize the specific gosub routine from this one app so can reuse IN ANY APP using sprites / tiles / images
14.  
15. ' 2020-08-28 WTH happened to this code? OH! If collision = 1 not -1 or just If Collision... fixed
16.  
17. CONST box1Width = 400, box1Height = 100, box1Left = 400 - box1Width / 2, box1Top = 300 - box1Height / 2 ' center box
18. CONST mouseboxWidth = 50, mouseboxHeight = 40 ' mouse controled box
19.  
20. SCREEN _NEWIMAGE(800, 600, 32) '<<< something more standard center is 400, 300
21. DIM hey$(5), k$, ombx, omby, mouseBoxX, mouseBoxY, r$, f&, b&, lim
22. hey$(0) = "Hey!"
23. hey$(1) = "I beg your pardon."
24. hey$(2) = "Bang!"
25. hey$(3) = "Yikes!"
26. hey$(4) = "Ouch!"
27. hey$(5) = "Watch where you are going."
28. DO
29.     k$ = INKEY$
30.     WHILE _MOUSEINPUT: WEND '<<< this is all the loop needed for mouse input
31.     CLS
32.     LINE (box1Left, box1Top)-STEP(box1Width, box1Height), _RGB32(255, 255, 255), BF
33.  
34.     ombx = mouseBoxX: omby = mouseBoxY 'old mouse x, y
35.  
36.     mouseBoxX = _MOUSEX - mouseboxWidth / 2
37.     mouseBoxY = _MOUSEY - mouseboxHeight / 2
38.  
39.     IF collision%(box1Left, box1Top, box1Width, box1Height, mouseBoxX, mouseBoxY, mouseboxWidth, mouseboxHeight) THEN
40.         BEEP
41.         COLOR _RGB32(100, 0, 85), _RGB32(255, 255, 255)
42.         r$ = hey$(INT(RND * 6))
43.         _PRINTSTRING (box1Left + (box1Width - LEN(r$) * 8) / 2, 292), r$
44.         COLOR f&, b&
45.         mouseBoxX = ombx: mouseBoxY = omby
46.         lim = 1
47.     ELSE
48.         lim = 200
49.     END IF
50.     LINE (mouseBoxX, mouseBoxY)-STEP(mouseboxWidth, mouseboxHeight), _RGB32(255, 128, 0), BF '<<< use step with width and height
51.     _DISPLAY
52.     _LIMIT lim '<<< save the fan
53. LOOP UNTIL k$ = CHR$(27)
54.  
55. ' Description:
56. ' Check for the collison of 2 rectangles given their top left x, y and width, height.
57. ' Returns true value -1, if they overlap and false 0 if they don't.
58. FUNCTION collision% (b1x, b1y, b1w, b1h, b2x, b2y, b2w, b2h)
59.     ' x, y represent the box left most x and top most y
60.     ' w, h represent the box width and height which is the usual way sprites / tiles / images are described
61.     ' such that boxbottom = by + bh
62.     '        and boxright = bx + bw
63.     'so the specific gosub above is generalized to a function procedure here!
64.     IF (b1y + b1h < b2y) OR (b1y > b2y + b2h) OR (b1x > b2x + b2w) OR (b1x + b1w < b2x) THEN
65.         collision% = 0
66.     ELSE
67.         collision% = -1 ' Collsion is true
68.     END IF
69. END FUNCTION
70.  
71.  

[bplus]

If you haven't seen Infinite Pong the Movie, here is the trailer:

Code: QB64: [Select]

1. _TITLE "Infinite Pong the Movie.bas for QB64 B+ 2018-09-16"
2. p1y = 1: p2y = 25 'paddle y
3. bx = 30: by = 10: bdx = 2: bdy = 1 'ball x, y, dx, dy
4. WHILE 1
5.     CLS
6.     FOR row = 2 TO 24
7.         LOCATE row, 5: PRINT "|";
8.         LOCATE row, 75: PRINT "|";
9.     NEXT
10.     p1x = bx - 5: _PRINTSTRING (p1x, p1y), "1111111111" ' draw paddle 1
11.     p2x = bx - 5: _PRINTSTRING (p2x, p2y), "2222222222" ' draw paddle 2
12.     IF bx + bdx < 6 THEN bdx = bdx * -1 + INT(RND * 3) - 1
13.     IF bx + bdx > 74 THEN bdx = bdx * -1 + INT(RND * 3) - 1
14.     IF by + bdy < 2 THEN bdy = bdy * -1: bdx = bdx + INT(RND * 3) - 1
15.     IF by + bdy > 24 THEN bdy = bdy * -1: bdx = bdx + INT(RND * 3) - 1
16.     bx = bx + bdx: by = by + bdy
17.     _PRINTSTRING (bx, by), "O"
18.     _LIMIT 10
19. WEND
20.  

[johnno56]

Those players have 'amazing' eye and hand co-ordination! lol