MEANALYZ: Math Expressions Analyzer V.1.1

[adgarza]

A Math Expressions Analyzer. You can assign a string to evaluate with a Math expression and it will return the result. Supports variables. Attached you'll find the code to run in QB64. SUB and FUNCTION names are in Spanish, but the attached README.TXT file has detailed instructions how to take advantage of the functionality.

UPDATE: A new version 1.1 was issued on August 26, 2020. Please download it in a message below.

The most basic use is:

Code: QB64: [Select]

1.   Constructor  ' Must be executed before any other procedure
2.   setExpresion "5 + 3 * 8" ' Spaces don't matter
3.   PRINT "The result is: "; AnalizaExpr  ' Shows the results

And that's it! I'll look forward for your comments.

Saludos cordiales,

[bplus]

Hello @adgarza,

Evaluate is great achievement for coders!

I tried some of my test expressions on yours with mixed results:

Code: QB64: [Select]

1.     'e$ = "2*-3 - -4+-0.25" ' returns -2.25 good
2.     'e$ = "1 + 2 * (3 + ((4 * 5) + (6 * 7 * 8)) - 9) / 10" ' returns 71 good
3.     'e$ = " 1 + 2*(3 - 2*(3 - 2)*((2 - 4)*5 - 22/(7 + 2*(3 - 1)) - 1)) + 1" ' should return 60 , nope not 654
4.     e$ = "1+1+(1+(1+(1+(1+(1+(1+(1+(1+(1+(1+(1+(1+(1+1/15)/14)/13)/12)/11)/10)/9)/8)/7)/6)/5)/4)/3)/2" 'should be  2.718 281 828 458 995 but hangs
5.  

I don't even know if yours handles nested parenthesis but it got the 2nd test e$ correct. :)

[adgarza]

Thank you, bplus.


I will review the code to see what's happening here.


Saludos cordiales,

[Aurel]

   

'e$ = " 1 + 2*(3 - 2*(3 - 2)*((2 - 4)*5 - 22/(7 + 2*(3 - 1)) - 1)) + 1" ' should return 60 , nope not 654

yes i get 60 in microA...
anyway nice program !

[adgarza]

Hi, All.


I did the fixes to the code.


Bug1 Fixed: There was a bug in the code with the signs law that issued the wrong result in the third equation tested.
Bug2 Workaround: There seems to be a bug in QB64 environment where, in some cases, a number is forcibly converted into scientific notation by adding a number greater than zero in the far right of the decimals. So if I got the number 0.012, it is converted into 1.2000000000000001D-2. I tried to get rid through numeric rounds of the scientific notation, but the environment turned it back into scientific notation adding another number at the end (3 or 2 or other). This doesn't happen in QB45 nor VB-DOS where I was testing the code. I had a kind of nightmare trying to resolve this in QB64. Then, I had to do a workaround with string manipulation to get rid of this problem.


Feature added: If there are two operations or numbers inside parentheses with no operation sign between them (like (2)(3) or (1+1)(2+1)) the program will add automatically the "*".
Feature added: You can specify, in the COMMAND$, a filename. This needs to be a plain text file so the program will read the operations there and will execute all of them one after one. This way, you will need not to write once and again the formulas.


Thank you for testing the code. I appreciate so much your time to do it.


Code is as follows:

Code: QB64: [Select]

1.  
2. ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' '
3. ' Math Expressions Analyzer V.1.1                         '
4. '                                                         '
5. ' Module to get a string, analyze it mathematically and   '
6. ' issuing a result from the operation. If you are using   '
7. ' QuickBASIC with a project, please ensure to include the '
8. ' FUNCTION declarations at the top of each file on it.    '
9. ' Failing to do so can bring no results in the analysis.  '
10. '                                                         '
11. ' Originally created in Visual Basic 4.0 and translated   '
12. ' into QBASIC/QB/VB-DOS/QB64 by A. David Garza Marin.     '
13. ' e-mail: adgarza@yahoo.com                               '
14. ' PRO-3, Mexico                                           '
15. ' ******************************************************* '
16. ' You are free to use and modify this code to adapt it    '
17. ' to your own needs. But, please, don't remove my credit. '
18. ' It took many hours for its creation and I think I       '
19. ' deserve such credit.                                    '
20. '                                                         '
21. ' Please, send to me an email to adgarza@yahoo.com to     '
22. ' report errors or commends about this code.              '
23. ' ******************************************************* '
24. ' MODIFICATIONS:                                          '
25. '                                                         '
26. ' Date(d/m/y)| Revision                                   '
27. ' --------+---------------------------------------------- '
28. ' 01/01/97| Development started.                          '
29. ' 16/06/97| Added an Error member data that takes control '
30. '         | of runtime errors in the methods.             '
31. ' 18/06/97| Error code 8, "Cannot divide by zero" added.  '
32. ' 14/12/98| Bugs corrected on operations with signed nums.'
33. ' 15/12/98| CalculaFormula method added. This method gets '
34. '         | rid of spaces and verifies the sign-law.      '
35. '         | This addition was done by Alejandro Juarez B. '
36. ' 15/12/98| Function CalculaFormula made private.         '
37. '         | (adgarza).                                    '
38. ' 21/05/99| Translation into QBASIC and QuickBASIC.       '
39. '         | (adgarza).                                    '
40. ' 12/08/20| Translation into QB64                         '
41. ' 13/08/20| Fixed calculation problem with long expression'
42. '         |  starting with a blank space.                 '
43. ' 26/08/20| Fixed a logical error where a long result in  '
44. '         |  an operation would bring an unexpected       '
45. '         |  scientific notation that crashed the program.'
46. '         | Fixed a logical error when multiplying or     '
47. '         |  dividing two negative numbers the + sign was '
48. '         |  missing.                                     '
49. '         | Added * signs when a parentheses is trailed   '
50. '         |  or followed directly with a number or with a '
51. '         |  closing parentheses following by an open one '
52. '         |  and vice-versa                               '
53. '         | There is an apparent error in QB64 where some '
54. '         |  floating point numbers assigned to variables '
55. '         |  of type DOUBLE are forcibly converted to     '
56. '         |  scientific notation by adding a decimal      '
57. '         |  number distinct to zero at the end of the    '
58. '         |  decimals. This was worked around with a      '
59. '         |  sub-process that removes the scientific      '
60. '         |  notation through string manipulation, as     '
61. '         |  there is no way to remove it numerically.    '
62. '
63. ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' ' '
64.  
65.  
66. $NOPREFIX
67. OPTION EXPLICIT
68. ' $DYNAMIC
69. DEFINT A-Z
70.  
71.  
72. ' -----Copy these declarations in your modules ----
73. DECLARE SUB Constructor ()
74. DECLARE SUB Destructor ()
75. DECLARE SUB doLimpiaVar ()
76. DECLARE SUB doRemVar (Variable AS STRING)
77. DECLARE SUB getObtieneVar ()
78. DECLARE SUB setExpresion (strCualExpresionEvaluar AS STRING)
79. DECLARE SUB setNuevaVar (strNombre AS STRING)
80. DECLARE SUB setNuevoValor (varVariable AS STRING, varValor AS DOUBLE)
81. DECLARE FUNCTION AnalizaExpr# ()
82. DECLARE FUNCTION Expresion$ ()
83. DECLARE FUNCTION CErr% ()
84. DECLARE FUNCTION CuentaVar% ()
85. DECLARE FUNCTION DErr$ ()
86. DECLARE FUNCTION NombreVar$ (iCualVariable AS INTEGER)
87. DECLARE FUNCTION Valor# (varVariable AS STRING)
88. ' -----Copy should be up to here. It is not necessary to copy the rest of the declarations
89.  
90.  
91. ' ******** Local Functions *********************
92. DECLARE FUNCTION SinAcentos% (strCadena AS STRING)
93. DECLARE FUNCTION BuscaVar% (CualVar AS STRING)
94. DECLARE FUNCTION LimpiaFormula# (strFormula AS STRING)
95. DECLARE FUNCTION CalculaFormula# (strFormula AS STRING)
96. DECLARE FUNCTION NumDer# (strCadena AS STRING, iPos AS INTEGER, iPosD AS INTEGER)
97. DECLARE FUNCTION NumIzq# (strCadena AS STRING, iPos AS INTEGER, iPosI AS INTEGER)
98. DECLARE FUNCTION SustituyeVars$ ()
99. DECLARE FUNCTION VerificaVar% ()
100. ' ************************************************
101.  
102.  
103. ' 32-bit value
104. TYPE RegistroVar
105.     Nombre AS STRING * 24
106.     Valor AS STRING * 8
107. END TYPE
108.  
109.  
110. DIM aregVariables(0 TO 0) AS RegistroVar ' Operation variables
111. DIM strExpresion AS STRING ' String to analyze
112. DIM iError AS INTEGER ' The error happened
113.  
114.  
115. ' Constants
116. CONST FALSE = 0
117. CONST TRUE = NOT FALSE
118. CONST Debug = FALSE
119.  
120.  
121.  
122.  
123. ' ********* Main program cycle ********
124. DIM strCadena AS STRING
125. DIM t AS STRING
126. DIM i AS INTEGER
127. DIM x AS INTEGER
128. DIM c AS INTEGER
129. DIM tf AS INTEGER
130. DIM dblValor AS DOUBLE
131.  
132.  
133. CLS ' Clean screen
134.  
135.  
136. ' Run the following procedure before any other
137. Constructor
138.  
139.  
140. IF COMMAND$ <> "" THEN
141.     strCadena = COMMAND$
142.     c = TRUE
143.     ' Sees if it is a test file
144.     '  THIS ONLY WORKS IN QB64
145.     IF FILEEXISTS("TESTMEA.TXT") THEN
146.         tf = TRUE
147.         OPEN "TESTMEA.TXT" FOR INPUT AS #1
148.     ELSE
149.         tf = FALSE
150.     END IF
151.  
152.  
153. END IF
154.  
155.  
156. ' Repeat until you get an N
157. PRINT "This program interprets simple mathematical expressions. Write"
158. PRINT "one at the prompt and press Enter to see the results. Read the"
159. PRINT "file README.TXT for further details. You can use"
160. PRINT "variables in the expression."
161. PRINT
162. DO
163.     doLimpiaVar ' Clean variables
164.     IF tf THEN
165.         IF NOT EOF(1) THEN
166.             LINE INPUT #1, strCadena
167.         ELSE
168.             strCadena = ""
169.             tf = FALSE
170.             CLOSE #1
171.         END IF
172.     ELSE
173.         INPUT "Expression to evaluate"; strCadena ' Gets the string
174.     END IF
175.  
176.  
177.     IF strCadena <> "" THEN
178.         setExpresion strCadena ' Assigns the string to the module
179.         getObtieneVar ' Gets variables
180.         x = CuentaVar ' Count how many variables the expression has
181.  
182.         IF x > 0 THEN ' If variables found, ask for their values.
183.             FOR i = 1 TO x ' Loop for each variable found.
184.                 PRINT "Value of " + NombreVar(i); ' Show the variable name to request its value
185.                 INPUT dblValor ' Capture the value
186.                 setNuevoValor LTRIM$(STR$(i)), dblValor ' Assign the value to the variable
187.             NEXT i
188.         END IF
189.         IF c OR tf THEN
190.             PRINT "Result of: "; strCadena
191.         END IF
192.         PRINT USING "###,###,###,###.####"; AnalizaExpr ' Show the result
193.  
194.  
195.         IF CErr > 0 THEN ' Is any error happened?
196.             PRINT "Error" + STR$(CErr) + ": " + DErr ' Show the error message
197.             PRINT
198.         END IF
199.     END IF
200.  
201.  
202.     IF NOT tf THEN
203.         PRINT "Again? (Y/N)" ' Want to try again?
204.         PRINT
205.         DO
206.             t = INKEY$
207.         LOOP UNTIL UCASE$(t) = "Y" OR UCASE$(t) = "N" ' Get Y or N
208.     ELSE
209.         t = "Y"
210.     END IF
211. LOOP UNTIL UCASE$(t) = "N"
212.  
213.  
214. ' Even though is not strictly necessary, it is advised to
215. '  free the resources used by the module
216. Destructor
217. PRINT "End of program" ' End of the program execution
218. END
219.  
220.  
221. REM $STATIC
222. DEFSNG A-Z
223. ' Public procedure to set if the formula analysis should be done.
224. FUNCTION AnalizaExpr# ()
225.     ' Var
226.     DIM strFormula AS STRING
227.     SHARED iError AS INTEGER
228.     SHARED strExpresion AS STRING
229.  
230.  
231.     iError = 0
232.     IF strExpresion <> "" THEN
233.         strExpresion = RTRIM$(LTRIM$(strExpresion)) ' Removes spaces
234.         IF SinAcentos(strExpresion) THEN
235.             IF CuentaVar% = 0 THEN ' Just if there are no variables
236.                 getObtieneVar ' Verifies if there are variables, just in case
237.             END IF
238.             IF VerificaVar THEN
239.                 strFormula = SustituyeVars ' Substitues variables
240.                 AnalizaExpr = LimpiaFormula(strFormula)
241.             ELSE
242.                 iError = 4
243.                 AnalizaExpr = 0
244.             END IF
245.         END IF
246.     ELSE
247.         iError = 5
248.         AnalizaExpr = 0
249.     END IF
250. END FUNCTION
251.  
252.  
253. FUNCTION BuscaVar% (CualVar AS STRING)
254.     ' Var
255.     DIM i AS INTEGER
256.     DIM x AS INTEGER
257.     DIM strCualVar AS STRING
258.     SHARED aregVariables() AS RegistroVar
259.  
260.  
261.     strCualVar = UCASE$(CualVar)
262.     i = 0
263.     x = UBOUND(aregVariables)
264.     IF x > 0 THEN
265.         DO
266.             i = i + 1
267.         LOOP UNTIL UCASE$(RTRIM$(aregVariables(i).Nombre)) = strCualVar OR i = x
268.  
269.  
270.         IF UCASE$(RTRIM$(aregVariables(i).Nombre)) <> strCualVar THEN
271.             i = 0
272.         END IF
273.     END IF
274.  
275.  
276.     BuscaVar = i
277. END FUNCTION
278.  
279.  
280. ' Do the formula analysis
281. FUNCTION CalculaFormula# (strFormula AS STRING)
282.     ' Var
283.     DIM dblNum1 AS DOUBLE
284.     DIM dblNum2 AS DOUBLE
285.     DIM dblRes AS FLOAT, strRes AS STRING
286.     DIM iOperacion AS INTEGER
287.     DIM strOperacion AS STRING * 1
288.     DIM strSigno AS STRING * 2
289.     DIM strSubFormula AS STRING
290.     DIM strCar AS STRING
291.     DIM iPos AS INTEGER, iPosI AS INTEGER, iPosD AS INTEGER
292.     DIM iPosParI AS INTEGER, iPosParD AS INTEGER
293.     DIM iPosParI2 AS INTEGER, iCuantosI AS INTEGER
294.     DIM iOper1 AS INTEGER, iOper2 AS INTEGER
295.     DIM iNC AS INTEGER, strNC AS STRING, iNCPD AS INTEGER
296.     DIM strASuma AS STRING
297.     SHARED iError AS INTEGER
298.     CONST strSimbolo = "^^*/+-" ' Recognized symbols (From most important to least important)
299.  
300.  
301.     ' Calculates the formula
302.     iError = 0
303.     DIM iPosParI2(1 TO 10) AS INTEGER
304.     DO
305.         strCar = ""
306.         IF iCuantosI > 0 THEN
307.             iPosParI = INSTR(iPosParI2(iCuantosI) + 1, strFormula, "(")
308.             iPosParD = INSTR(iPosParI2(iCuantosI) + 1, strFormula, ")")
309.         ELSE
310.             iPosParI = INSTR(strFormula, "(")
311.             iPosParD = INSTR(strFormula, ")")
312.         END IF
313.  
314.  
315.         ' Runs the code according the parentheses location
316.         IF iPosParI < iPosParD AND iPosParI > 0 THEN
317.             iCuantosI = iCuantosI + 1
318.             IF UBOUND(iPosParI2) < iCuantosI THEN
319.                 REDIM PRESERVE iPosParI2(1 TO iCuantosI + 9) AS INTEGER
320.             END IF
321.  
322.  
323.             ' Validates if the previous character of the opening parentheses is a number
324.             '  if so, then add the asterisc
325.             IF iPosParI > 1 THEN
326.                 strCar = MID$(strFormula, iPosParI - 1, 1)
327.             END IF
328.             IF strCar <> "" THEN
329.                 IF INSTR("0123456789)", strCar) > 0 THEN
330.                     strFormula = LEFT$(strFormula, iPosParI - 1) + "*" + MID$(strFormula, iPosParI)
331.                     iPosParI = iPosParI + 1
332.                 END IF
333.             END IF
334.             iPosParI2(iCuantosI) = iPosParI
335.         ELSEIF iPosParD > 0 THEN
336.             IF iCuantosI > 0 THEN
337.                 strCar = MID$(strFormula, iPosParD + 1, 1)
338.                 ' Validates if the following character of the closing parentheses is a number. if so
339.                 '   then adds an asterisc.
340.                 IF strCar <> "" THEN
341.                     IF INSTR("0123456789(", strCar) > 0 THEN
342.                         strFormula = LEFT$(strFormula, iPosParD) + "*" + MID$(strFormula, iPosParD + 1)
343.                     END IF
344.                 END IF
345.  
346.  
347.                 IF iPosParI2(iCuantosI) > 0 THEN
348.                     strSubFormula = MID$(strFormula, iPosParI2(iCuantosI) + 1, iPosParD - iPosParI2(iCuantosI) - 1)
349.                     IF Debug THEN
350.                         PRINT "strFormula="; strFormula
351.                         PRINT "strSubFormula="; strSubFormula
352.                     END IF
353.                     GOSUB HazLaOperacion
354.                     strFormula = LEFT$(strFormula, iPosParI2(iCuantosI) - 1) + strSubFormula + MID$(strFormula, iPosParD + 1)
355.                     iCuantosI = iCuantosI - 1
356.                 ELSE
357.                     iError = 6 ' Parentheses mismatch
358.                     EXIT FUNCTION
359.                 END IF
360.             ELSE
361.                 iError = 6 ' Parentheses mismatch
362.                 EXIT FUNCTION
363.             END IF
364.         ELSEIF iPosParI > 0 AND iPosParD = 0 THEN
365.             iError = 6 ' Parentheses mismatch
366.             EXIT FUNCTION
367.         ELSEIF iPosParI = 0 AND iPosParD = 0 THEN
368.             strSubFormula = strFormula
369.             IF Debug THEN
370.                 PRINT "strFormula="; strFormula
371.                 PRINT "strSubFormula="; strSubFormula
372.             END IF
373.             GOSUB HazLaOperacion
374.             strFormula = strSubFormula
375.             iCuantosI = 0
376.         END IF
377.     LOOP UNTIL iPosParI = 0 AND iPosParD = 0
378.  
379.  
380.     CalculaFormula = VAL(strFormula)
381.  
382.  
383.     EXIT FUNCTION
384.  
385.  
386.     HazLaOperacion:
387.     ' Do the operation
388.     iOperacion = 1
389.     DO
390.         strSigno = MID$(strSimbolo, (2 * (iOperacion - 1) + 1), 2)
391.  
392.  
393.         ' If one of these operators ( ^^ */ +- ) is inside the operation
394.         iOper1 = INSTR(strSubFormula, LEFT$(strSigno, 1))
395.         iOper2 = INSTR(strSubFormula, RIGHT$(strSigno, 1))
396.         IF iOper1 > 0 OR iOper2 > 0 THEN
397.  
398.  
399.             ' If the first operator exists (^*+) and is before the second one (^/-)
400.             IF iOper1 <= iOper2 AND iOper1 > 0 THEN
401.                 iPos = iOper1
402.                 strOperacion = LEFT$(strSigno, 1)
403.  
404.  
405.                 ' If the second operator (^/-) exists
406.             ELSEIF iOper2 = 0 THEN
407.                 iPos = iOper1
408.                 strOperacion = LEFT$(strSigno, 1)
409.  
410.  
411.                 ' If the second operator (^*+) exists and is after the second (^/-)
412.             ELSEIF iOper1 > iOper2 AND iOper2 > 0 THEN
413.  
414.  
415.                 ' If the first character on the formula is a negative sign, do the operation with the operator at the left (^*+)
416.                 IF LEFT$(strSubFormula, 1) = "-" THEN
417.                     iPos = iOper1
418.                     strOperacion = LEFT$(strSigno, 1)
419.                 ELSE ' Else, do the operation with the operator at the right (^/-)
420.                     iPos = iOper2
421.                     strOperacion = RIGHT$(strSigno, 1)
422.                 END IF
423.             ELSE
424.                 ' The operation will be done with the right-side operator (^/-)
425.                 strOperacion = RIGHT$(strSigno, 1)
426.  
427.  
428.                 ' But if the first character is a negative sign, do the operation with the operator at the right-side (^/-)
429.                 IF iOper2 = 1 THEN
430.                     iPos = INSTR(iOper2 + 1, strSubFormula, strOperacion)
431.                 ELSE
432.                     iPos = iOper2
433.                 END IF
434.             END IF
435.  
436.  
437.             ' If it is 1 is very likely that is a number with negative sign
438.             strASuma = ""
439.             IF iPos > 1 THEN
440.                 dblNum1 = NumIzq(strSubFormula, iPos, iPosI)
441.                 dblNum2 = NumDer(strSubFormula, iPos, iPosD)
442.                 IF Debug THEN
443.                     PRINT "dblNum1: "; dblNum1; "dblNum2: "; dblNum2
444.                 END IF
445.                 SELECT CASE strOperacion
446.                     CASE "^": dblRes = dblNum1 ^ dblNum2
447.                     CASE "*"
448.                         dblRes = dblNum1 * dblNum2
449.                         IF SGN(dblNum1) = -1 AND SGN(dblNum2) = -1 THEN
450.                             strASuma = "+"
451.                         END IF
452.                     CASE "/"
453.                         IF dblNum2 = 0 THEN
454.                             iError = 8
455.                             dblRes = 0
456.                         ELSE
457.                             dblRes = dblNum1 / dblNum2
458.                         END IF
459.                         IF SGN(dblNum1) = -1 AND SGN(dblNum2) = -1 THEN
460.                             strASuma = "+"
461.                         END IF
462.                     CASE "+": dblRes = dblNum1 + dblNum2
463.                     CASE "-": dblRes = dblNum1 - dblNum2
464.                 END SELECT
465.  
466.  
467.                 ' Removes scientific notation if any
468.                 dblRes = CDBL(CLNG(dblRes * 1000000) / 1000000)
469.                 strRes = LTRIM$(STR$(dblRes))
470.                 iNC = INSTR(strRes, "D")
471.                 IF iNC > 0 THEN
472.                     GOSUB RemoverNotacionCientifica
473.                     IF Debug THEN PRINT "I removed the scientific notation."
474.                 END IF
475.  
476.  
477.                 IF Debug THEN
478.                     PRINT "dblRes:"; dblRes; "strRes: "; strRes
479.                     IF INSTR(strRes, "D") THEN
480.                         WHILE INKEY$ = "": WEND
481.                     END IF
482.                 END IF
483.  
484.  
485.                 ' If the first character is a negative sign and the operation is an addition
486.                 IF LEFT$(strSubFormula, 1) = "-" AND strOperacion = "+" THEN
487.                     ' If the operator position is greater than 1
488.                     IF iPosI > 1 THEN ' There is a negative number at left-side, so it is needed to force the addition adding the opperator
489.                         strSubFormula = LEFT$(strSubFormula, iPosI - 1) + strOperacion + strRes + MID$(strSubFormula, iPosD + 1)
490.                     ELSE
491.                         strSubFormula = LEFT$(strSubFormula, iPosI - 1) + strRes + MID$(strSubFormula, iPosD + 1)
492.                     END IF
493.                 ELSE
494.                     strSubFormula = LEFT$(strSubFormula, iPosI - 1) + strASuma + strRes + MID$(strSubFormula, iPosD + 1)
495.                 END IF
496.  
497.  
498.                 IF Debug THEN
499.                     PRINT "strSubFormula="; strSubFormula
500.                     IF INSTR(strSubFormula, "D") > 0 THEN
501.                         PRINT "strFormula="; strFormula
502.                         WHILE INKEY$ = "": WEND
503.                     END IF
504.                 END IF
505.  
506.  
507.             ELSE
508.                 iOperacion = iOperacion + 1
509.             END IF
510.         ELSE
511.             iOperacion = iOperacion + 1
512.         END IF
513.     LOOP UNTIL iOperacion > 3
514.     RETURN
515.  
516.  
517.     RemoverNotacionCientifica:
518.     iNC = INSTR(strRes, "D")
519.     IF iNC = 0 THEN
520.         iNC = INSTR(strRes, "E")
521.     END IF
522.     IF iNC > 0 THEN
523.         strNC = LEFT$(strRes, iNC - 1)
524.         iNC = VAL(MID$(strRes, iNC + 1))
525.         iNCPD = INSTR(strNC, ".")
526.         strNC = LEFT$(strNC, iNCPD - 1) + MID$(strNC, iNCPD + 1)
527.         iNCPD = iNCPD + iNC
528.         IF iNCPD < 0 THEN
529.             strNC = "." + STRING$(iNCPD, "0") + strNC
530.         ELSEIF iNCPD > LEN(strNC) THEN
531.             strNC = strNC + STRING$(iNCPD - LEN(strNC), "0") + "."
532.         ELSE
533.             strNC = LEFT$(strNC, iNCPD) + "." + MID$(strNC, iNCPD)
534.         END IF
535.         strRes = strNC
536.     END IF
537.     RETURN
538. END FUNCTION
539.  
540.  
541. FUNCTION CErr% ()
542.     ' Var
543.     SHARED iError AS INTEGER
544.  
545.  
546.     CErr = iError
547. END FUNCTION
548.  
549.  
550. SUB Constructor ()
551.     ' Var
552.     SHARED iError AS INTEGER
553.     SHARED strExpresion AS STRING
554.     SHARED aregVariables() AS RegistroVar
555.  
556.  
557.     ' Initializes the string value
558.     strExpresion = ""
559.     iError = 0
560.     REDIM aregVariables(0 TO 0) AS RegistroVar
561. END SUB
562.  
563.  
564. ' Returns how many variables are in memory
565. FUNCTION CuentaVar% ()
566.     ' Var
567.     SHARED aregVariables() AS RegistroVar
568.  
569.  
570.     CuentaVar = UBOUND(aregVariables)
571. END FUNCTION
572.  
573.  
574. FUNCTION DErr$ ()
575.     ' Var
576.     DIM strError AS STRING ' The string with the description of the error
577.     SHARED iError AS INTEGER
578.  
579.  
580.     ' Returns the text with the error description
581.     SELECT CASE iError
582.         CASE 0: strError = "Operation succeed"
583.         CASE 1: strError = "Special characters not allowed"
584.         CASE 2: strError = "Variable name doesn't exist"
585.         CASE 3: strError = "Only numeric values accepted"
586.         CASE 4: strError = "There are uninitialized variables"
587.         CASE 5: strError = "No expression to evaluate"
588.         CASE 6: strError = "Parentheses pairs don't match"
589.         CASE 7: strError = "Variable name aleady exists"
590.         CASE 8: strError = "Cannot divide by zero"
591.         CASE 9: strError = "Haven't executed the constructor"
592.     END SELECT
593.  
594.     DErr = strError
595. END FUNCTION
596.  
597.  
598. SUB Destructor ()
599.     ' Var
600.     SHARED iError AS INTEGER
601.  
602.  
603.     ' Cleans the variables of the list and others. This is not strictly
604.     '  needed, but is a good programming practice to free the resources.
605.     setExpresion ""
606.     iError = 0
607.     doLimpiaVar
608. END SUB
609.  
610.  
611. ' Gets rid of all variables in the buffer
612. SUB doLimpiaVar ()
613.     ' Var
614.     SHARED aregVariables() AS RegistroVar
615.  
616.  
617.     ERASE aregVariables
618.     REDIM aregVariables(0 TO 0) AS RegistroVar
619. END SUB
620.  
621.  
622. ' Gets rid of the indicated variable in the varVariable parameter
623. SUB doRemVar (varVariable AS STRING)
624.     ' Var
625.     DIM i AS INTEGER
626.     DIM j AS INTEGER
627.     DIM x AS INTEGER
628.     DIM l AS INTEGER
629.     REDIM aregX(0 TO 0) AS RegistroVar
630.     SHARED iError AS INTEGER
631.     SHARED aregVariables() AS RegistroVar
632.  
633.  
634.     iError = 0
635.     i = VAL(varVariable)
636.     IF i = 0 THEN
637.         i = BuscaVar(varVariable)
638.     END IF
639.  
640.  
641.     IF i > 0 THEN
642.         x = UBOUND(aregVariables)
643.         REDIM aregX(0 TO x - 1) AS RegistroVar
644.         l = 0
645.         FOR j = 1 TO x
646.             IF j <> i THEN
647.                 l = l + 1
648.                 aregX(l) = aregVariables(j)
649.             END IF
650.         NEXT j
651.         x = x - 1
652.         REDIM aregVariables(0 TO x) AS RegistroVar
653.         FOR j = 1 TO x
654.             aregVariables(j) = aregX(j)
655.         NEXT j
656.         ERASE aregX
657.     ELSE
658.         iError = 2
659.     END IF
660. END SUB
661.  
662.  
663. FUNCTION Expresion$ ()
664.     ' Var
665.     SHARED strExpresion AS STRING
666.  
667.  
668.     ' Gets the string to evaluate
669.     Expresion = strExpresion
670. END FUNCTION
671.  
672.  
673. ' In this procedure are gathered the strings with the variable names
674. '  included in the provided formula.
675. '  This procedure will find those variables that
676. '  fulfill the requirements of a variable name, although it will
677. '  limit the names to 24 characters:
678. '  MyData, Data1, Numeric_Value.
679. ' It will reject special characters, like accented letters and ñ. If any, this procedure
680. '  will issue an error.
681. SUB getObtieneVar ()
682.     ' Var
683.     DIM strVariable AS STRING
684.     DIM strCaracter AS STRING * 1
685.     DIM iIniVar AS INTEGER
686.     DIM iInicio AS INTEGER
687.     DIM iFinal AS INTEGER
688.     DIM bFinVar AS INTEGER
689.     SHARED iError AS INTEGER
690.     SHARED strExpresion AS STRING
691.     SHARED aregVariables() AS RegistroVar
692.  
693.     iError = 0
694.     IF SinAcentos(strExpresion) THEN
695.         ' Check the string to find variable names
696.         iInicio = 1
697.         iIniVar = 0
698.         iFinal = 1
699.         DO WHILE iInicio <= LEN(strExpresion)
700.             strCaracter = UCASE$(MID$(strExpresion, iInicio, 1))
701.             IF strCaracter >= "A" AND strCaracter <= "Z" AND iIniVar = 0 THEN
702.                 ' It found a letter... Now, find where it ends for the variable name.
703.                 iFinal = iInicio + 1
704.                 bFinVar = FALSE
705.                 DO
706.                     IF iFinal <= LEN(strExpresion) THEN
707.                         strCaracter = UCASE$(MID$(strExpresion, iFinal, 1))
708.                         IF (strCaracter >= "A" AND strCaracter <= "Z") OR (strCaracter >= "0" AND strCaracter <= "9") OR strCaracter = "_" THEN
709.                             iFinal = iFinal + 1
710.                         ELSE
711.                             bFinVar = TRUE
712.                         END IF
713.                     ELSE
714.                         bFinVar = TRUE
715.                     END IF
716.                 LOOP UNTIL bFinVar
717.        
718.                 ' Get the variable name
719.                 strVariable = MID$(strExpresion, iInicio, iFinal - iInicio)
720.        
721.                 ' Add the variable to the variable list
722.                 setNuevaVar strVariable
723.                 iError = 0
724.                 iInicio = iFinal
725.                 iIniVar = 0
726.             ELSE
727.                 IF (strCaracter >= "0" AND strCaracter <= "9") OR strCaracter = "." THEN
728.                     IF iIniVar = 0 THEN
729.                         iIniVar = iInicio
730.                     END IF
731.                 ELSE
732.                     iIniVar = 0
733.                 END IF
734.                 iInicio = iInicio + 1
735.             END IF
736.         LOOP
737.     END IF
738. END SUB
739.  
740.  
741. ' Private procedure to calculate the formula,
742. '  includes the verification of the law of the signs (Alejandro Juarez).
743. FUNCTION LimpiaFormula# (strFormula AS STRING)
744.     DIM iPos AS INTEGER
745.     DIM i AS INTEGER
746.     DIM strSignos AS STRING
747.     DIM strLey AS STRING
748.    
749.     ' Gets rid of blank spaces to test the law of signs
750.     DO
751.         iPos = INSTR(strFormula, SPACE$(1))
752.         IF iPos > 0 THEN
753.             strFormula = MID$(strFormula, 1, iPos - 1) + MID$(strFormula, iPos + 1)
754.         END IF
755.     LOOP UNTIL iPos = 0
756.    
757.     ' Do the modifications according the law of signs ( - by + equals - ), etcetera.
758.     strSignos = "+++--+--"
759.     FOR i = 1 TO 4
760.         strLey = MID$(strSignos, 1, 2)
761.         DO
762.             iPos = INSTR(strFormula, strLey)
763.             IF iPos > 0 THEN
764.                 SELECT CASE strLey
765.                     CASE "++", "--"
766.                         strFormula = MID$(strFormula, 1, iPos - 1) + "+" + MID$(strFormula, iPos + 2)
767.                     CASE "+-", "-+"
768.                         strFormula = MID$(strFormula, 1, iPos - 1) + "-" + MID$(strFormula, iPos + 2)
769.                 END SELECT
770.             END IF
771.         LOOP UNTIL iPos = 0
772.         strSignos = MID$(strSignos, 3)
773.     NEXT
774.     LimpiaFormula = CalculaFormula(strFormula)
775. END FUNCTION
776.  
777.  
778. ' Returns the name of the variable in the indicated possition
779. FUNCTION NombreVar$ (iCualVariable AS INTEGER)
780.     ' Var
781.     SHARED iError AS INTEGER
782.     SHARED aregVariables() AS RegistroVar
783.  
784.     iError = 0
785.     IF iCualVariable > 0 AND iCualVariable <= UBOUND(aregVariables) THEN
786.         NombreVar = RTRIM$(aregVariables(iCualVariable).Nombre)
787.     ELSE
788.         iError = 2
789.         NombreVar = ""
790.     END IF
791.  
792. END FUNCTION
793.  
794.  
795. ' Gets the number at the right of the sign
796. FUNCTION NumDer# (strCadena AS STRING, iPos AS INTEGER, iPosD AS INTEGER)
797.     ' Var
798.     DIM strCar AS STRING * 1
799.     DIM bNumero AS INTEGER
800.     DIM strNumDer AS STRING
801.  
802.     iPosD = iPos + 1
803.     bNumero = FALSE
804.     strNumDer = ""
805.     IF iPosD <= LEN(strCadena) THEN
806.         DO
807.             strCar = MID$(strCadena, iPosD, 1)
808.             IF (strCar >= "0" AND strCar <= "9") OR strCar = "." OR strCar = " " OR strCar = "-" OR strCar = "+" THEN
809.                 'IF (strCar >= "0" AND strCar <= "9") OR strCar = "." OR strCar = " " OR strCar = "-" THEN
810.                 IF (strCar >= "0" AND strCar <= "9") OR strCar = "." THEN
811.                     bNumero = TRUE
812.                 END IF
813.        
814.                 IF iPosD < LEN(strCadena) THEN
815.                     IF (strCar = "-" OR strCar = "+") AND NOT bNumero THEN
816.                         ' IF strCar = "-" AND NOT bNumero THEN
817.                         iPosD = iPosD + 1
818.                         bNumero = TRUE
819.                         strNumDer = strNumDer + strCar
820.                     ELSEIF strCar <> "-" AND strCar <> "+" THEN
821.                         iPosD = iPosD + 1
822.                         strNumDer = strNumDer + strCar
823.                     ELSEIF strCar = "-" OR strCar = "+" THEN
824.                         iPosD = iPosD - 1
825.                         EXIT DO
826.                     END IF
827.                 ELSE
828.                     strNumDer = strNumDer + strCar
829.                     EXIT DO
830.                 END IF
831.             ELSE
832.                 iPosD = iPosD - 1
833.                 EXIT DO
834.             END IF
835.         LOOP
836.  
837.  
838.         NumDer = CDBL(VAL(strNumDer))
839.         ' NumDer = VAL(LTRIM$(RTRIM$(MID$(strCadena, iPos + 1, iPosD - iPos))))
840.     ELSE
841.         NumDer = 0
842.     END IF
843.  
844.  
845. END FUNCTION
846.  
847.  
848. ' Gets the number at the left of the sign
849. FUNCTION NumIzq# (strCadena AS STRING, iPos AS INTEGER, iPosI AS INTEGER)
850.     ' Var
851.     DIM strCar AS STRING * 1
852.  
853.  
854.     iPosI = iPos - 1
855.  
856.  
857.     IF iPosI > 0 THEN
858.         DO
859.             strCar = MID$(strCadena, iPosI, 1)
860.             IF (strCar >= "0" AND strCar <= "9") OR strCar = "." OR strCar = " " OR strCar = "-" THEN
861.                 IF iPosI > 1 THEN
862.                     IF (INSTR(strCadena, "^") > 0 OR INSTR(strCadena, "*") > 0 OR INSTR(strCadena, "/") > 0 OR INSTR(strCadena, "+") > 0) AND strCar = "-" THEN
863.                         '***** CODIGO CORREGIDO ******'
864.                         IF strCar = "-" THEN
865.                             EXIT DO
866.                         END IF
867.                         iPosI = iPosI - 1
868.                     ELSEIF strCar <> "-" THEN
869.                         iPosI = iPosI - 1
870.                     ELSE
871.                         EXIT DO
872.                     END IF
873.                 ELSE
874.                     EXIT DO
875.                 END IF
876.             ELSE
877.                 iPosI = iPosI + 1
878.                 EXIT DO
879.             END IF
880.         LOOP
881.  
882.  
883.         NumIzq = VAL(LTRIM$(MID$(strCadena, iPosI, iPos - iPosI)))
884.     ELSE
885.         NumIzq = 0
886.     END IF
887. END FUNCTION
888.  
889.  
890. ' Set the string to evaluate
891. SUB setExpresion (strCualExpresionEvaluar AS STRING)
892.     ' Var
893.     SHARED strExpresion AS STRING
894.  
895.  
896.     strExpresion = strCualExpresionEvaluar
897. END SUB
898.  
899.  
900. ' Ads a variable to the context.
901. ' If the variable already exists, it will not add it
902. '  and returns an error.
903. SUB setNuevaVar (strNombre AS STRING)
904.     ' Var
905.     DIM i AS INTEGER
906.     DIM j AS INTEGER
907.     REDIM aregX(0 TO 0) AS RegistroVar
908.     SHARED iError AS INTEGER
909.     SHARED aregVariables() AS RegistroVar
910.          
911.     ' Check if this variable name already exists
912.     iError = 0
913.     IF SinAcentos(strNombre) THEN
914.         i = BuscaVar(strNombre)
915.  
916.  
917.         IF i = 0 THEN
918.             i = UBOUND(aregVariables) + 1
919.             REDIM aregX(0 TO i) AS RegistroVar
920.             FOR j = 1 TO i - 1
921.                 aregX(j) = aregVariables(j)
922.             NEXT j
923.             REDIM aregVariables(0 TO i) AS RegistroVar
924.             FOR j = 1 TO i - 1
925.                 aregVariables(j) = aregX(j)
926.             NEXT j
927.             aregVariables(i).Nombre = strNombre
928.             aregVariables(i).Valor = ""
929.             ERASE aregX
930.         ELSE
931.             iError = 7
932.         END IF
933.     END IF
934. END SUB
935.  
936.  
937. ' Sets a new value (varValor) to the indicated variable name (varVariable)
938. SUB setNuevoValor (varVariable AS STRING, varValor AS DOUBLE)
939.     ' Var
940.     DIM i AS INTEGER
941.     SHARED iError AS INTEGER
942.     SHARED aregVariables() AS RegistroVar
943.  
944.  
945.     iError = 0
946.     i = VAL(varVariable)
947.     IF i = 0 THEN
948.         i = BuscaVar(varVariable)
949.     END IF
950.  
951.  
952.     IF i > 0 AND i <= UBOUND(aregVariables) THEN
953.         LSET aregVariables(i).Valor = MKD$(varValor)
954.     END IF
955. END SUB
956.  
957.  
958. ' This function determines if the string has accents or strange characters
959. FUNCTION SinAcentos% (strCadena AS STRING)
960.     DIM i AS INTEGER
961.     DIM strCaracter AS STRING * 1
962.     DIM bCorrecto AS INTEGER
963.     SHARED iError AS INTEGER
964.  
965.     ' Evaluate if there are characters beyond 127 in the string
966.     iError = 0
967.     bCorrecto = TRUE
968.     i = 127
969.     DO WHILE bCorrecto AND i < 256
970.         strCaracter = CHR$(i)
971.         IF INSTR(strCadena, strCaracter) > 0 THEN
972.             iError = 1
973.             bCorrecto = FALSE
974.         END IF
975.         i = i + 1
976.     LOOP
977.     SinAcentos = bCorrecto
978. END FUNCTION
979.  
980.  
981. ' Substitues variable names with values in the string
982. FUNCTION SustituyeVars$ ()
983.     ' Var
984.     DIM strMalos AS STRING
985.     DIM iEncontrado AS INTEGER
986.     DIM strVariable AS STRING
987.     DIM strCaracter AS STRING * 1
988.     DIM bCorrecto AS INTEGER
989.     DIM j AS INTEGER
990.     DIM x AS INTEGER
991.     DIM strCadena AS STRING
992.     SHARED strExpresion AS STRING
993.     SHARED aregVariables() AS RegistroVar
994.  
995.  
996.     strCadena = UCASE$(strExpresion)
997.     strMalos = "ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789_"
998.     x = UBOUND(aregVariables)
999.     FOR j = 1 TO x
1000.         strVariable = UCASE$(RTRIM$(aregVariables(j).Nombre))
1001.         iEncontrado = 1
1002.         DO
1003.             iEncontrado = INSTR(iEncontrado, strCadena, strVariable)
1004.             IF iEncontrado > 0 THEN
1005.                 bCorrecto = TRUE
1006.                 IF iEncontrado > 1 THEN
1007.                     strCaracter = MID$(strCadena, iEncontrado - 1, 1)
1008.                     bCorrecto = (INSTR(strMalos, strCaracter) = 0)
1009.                 END IF
1010.  
1011.  
1012.                 IF bCorrecto THEN
1013.                     strCaracter = MID$(strCadena, iEncontrado + LEN(strVariable), 1)
1014.                     bCorrecto = (INSTR(strMalos, strCaracter) = 0)
1015.                 END IF
1016.  
1017.  
1018.                 IF bCorrecto THEN
1019.                     strCadena = LEFT$(strCadena, iEncontrado - 1) + LTRIM$(STR$(Valor(strVariable))) + MID$(strCadena, iEncontrado + LEN(strVariable))
1020.                     iEncontrado = 1
1021.                 ELSE
1022.                     iEncontrado = iEncontrado + 1
1023.                 END IF
1024.             ELSE
1025.                 iEncontrado = 1
1026.             END IF
1027.         LOOP UNTIL INSTR(iEncontrado, strCadena, strVariable) = 0
1028.     NEXT j
1029.  
1030.  
1031.     SustituyeVars = strCadena
1032. END FUNCTION
1033.  
1034.  
1035. ' Gets the value of the variable indicated in varVariable
1036. FUNCTION Valor# (varVariable AS STRING)
1037.     ' Var
1038.     DIM i AS INTEGER
1039.     SHARED aregVariables() AS RegistroVar
1040.     SHARED iError AS INTEGER
1041.  
1042.  
1043.     iError = 0
1044.     i = VAL(varVariable)
1045.     IF i = 0 THEN
1046.         i = BuscaVar(varVariable)
1047.     END IF
1048.  
1049.  
1050.     IF i > 0 AND i <= UBOUND(aregVariables) THEN
1051.         IF RTRIM$(aregVariables(i).Valor) <> "" THEN
1052.             Valor = CVD(aregVariables(i).Valor)
1053.         ELSE
1054.             Valor = 0
1055.             iError = 4
1056.         END IF
1057.     ELSE
1058.         Valor = 0
1059.         iError = 2
1060.     END IF
1061.  
1062.  
1063. END FUNCTION
1064.  
1065.  
1066. ' Verifies if all assigned variables have values
1067. FUNCTION VerificaVar% ()
1068.     ' Var
1069.     DIM bCorrecto AS INTEGER
1070.     DIM x AS INTEGER
1071.     DIM i AS INTEGER
1072.     SHARED iError AS INTEGER
1073.     SHARED aregVariables() AS RegistroVar
1074.  
1075.  
1076.     iError = 0
1077.     bCorrecto = TRUE
1078.     x = UBOUND(aregVariables)
1079.     IF x > 0 THEN
1080.         FOR i = 1 TO x
1081.             IF RTRIM$(aregVariables(i).Valor) = "" THEN
1082.                 iError = 4
1083.                 bCorrecto = FALSE
1084.                 EXIT FOR
1085.             END IF
1086.         NEXT i
1087.     END IF
1088.     VerificaVar = bCorrecto
1089. END FUNCTION
1090.  
1091.  
1092.  

[adgarza]

yes i get 60 in microA...
anyway nice program !

Thank you, Aurel. Please, try the new version 1.1 that I just uploaded. I hope everything runs ok.


Saludos cordiales,
Tron.BAS

[bplus]

So if I got the number 0.012, it is converted into 1.2000000000000001D-2. I tried to get rid through numeric rounds of the scientific notation, but the environment turned it back into scientific notation adding another number at the end (3 or 2 or other). This doesn't happen in QB45 nor VB-DOS where I was testing the code. I had a kind of nightmare trying to resolve this in QB64. Then, I had to do a workaround with string manipulation to get rid of this problem.

Ha! yeah, since you posted originally I had devised my own set of String math routines. It seems scientific notation system is constantly getting in the way of display of accurate results.

[adgarza]

Ha! yeah, since you posted originally I had devised my own set of String math routines. It seems scientific notation system is constantly getting in the way of display of accurate results.

Had to do a very tricky workaround to address it.

[SMcNeill]

Had to do a very tricky workaround to address it.

Code: [Select]

FUNCTION N2S$ (EXP$) 'scientific Notation to String
 
    'PRINT "Before notation:"; exp$
 
    t$ = LTRIM$(RTRIM$(EXP$))
    IF LEFT$(t$, 1) = "-" OR LEFT$(t$, 1) = "N" THEN sign$ = "-": t$ = MID$(t$, 2)
 
    dp = INSTR(t$, "D+"): dm = INSTR(t$, "D-")
    ep = INSTR(t$, "E+"): em = INSTR(t$, "E-")
    check1 = SGN(dp) + SGN(dm) + SGN(ep) + SGN(em)
    IF check1 < 1 OR check1 > 1 THEN N2S = EXP$: EXIT SUB 'If no scientic notation is found, or if we find more than 1 type, it's not SN!
 
    SELECT CASE l 'l now tells us where the SN starts at.
        CASE IS < dp: l = dp
        CASE IS < dm: l = dm
        CASE IS < ep: l = ep
        CASE IS < em: l = em
    END SELECT
 
    l$ = LEFT$(t$, l - 1) 'The left of the SN
    r$ = MID$(t$, l + 1): r&& = VAL(r$) 'The right of the SN, turned into a workable long
 
 
    IF INSTR(l$, ".") THEN 'Location of the decimal, if any
        IF r&& > 0 THEN
            r&& = r&& - LEN(l$) + 2
        ELSE
            r&& = r&& + 1
        END IF
        l$ = LEFT$(l$, 1) + MID$(l$, 3)
    END IF
 
    SELECT CASE r&&
        CASE 0 'what the heck? We solved it already?
            'l$ = l$
        CASE IS < 0
            FOR i = 1 TO -r&&
                l$ = "0" + l$
            NEXT
            l$ = "0." + l$
        CASE ELSE
            FOR i = 1 TO r&&
                l$ = l$ + "0"
            NEXT
    END SELECT
 
    N2S$ = sign$ + l$
    'PRINT "After notation:"; N2S$
END SUB
One of the functions from my math evaluator; it converts scientific notation into a string for string processing.

[adgarza]

FUNCTION N2S$ (EXP$) 'scientific Notation to String
One of the functions from my math evaluator; it converts scientific notation into a string for string processing.

Wow! I think I will integrate your code in my code (with the corresponding credit, for sure).

[bplus]

Code: [Select]

FUNCTION N2S$ (EXP$) 'scientific Notation to String
 
    'PRINT "Before notation:"; exp$
 
    t$ = LTRIM$(RTRIM$(EXP$))
    IF LEFT$(t$, 1) = "-" OR LEFT$(t$, 1) = "N" THEN sign$ = "-": t$ = MID$(t$, 2)
 
    dp = INSTR(t$, "D+"): dm = INSTR(t$, "D-")
    ep = INSTR(t$, "E+"): em = INSTR(t$, "E-")
    check1 = SGN(dp) + SGN(dm) + SGN(ep) + SGN(em)
    IF check1 < 1 OR check1 > 1 THEN N2S = EXP$: EXIT SUB 'If no scientic notation is found, or if we find more than 1 type, it's not SN!
 
    SELECT CASE l 'l now tells us where the SN starts at.
        CASE IS < dp: l = dp
        CASE IS < dm: l = dm
        CASE IS < ep: l = ep
        CASE IS < em: l = em
    END SELECT
 
    l$ = LEFT$(t$, l - 1) 'The left of the SN
    r$ = MID$(t$, l + 1): r&& = VAL(r$) 'The right of the SN, turned into a workable long
 
 
    IF INSTR(l$, ".") THEN 'Location of the decimal, if any
        IF r&& > 0 THEN
            r&& = r&& - LEN(l$) + 2
        ELSE
            r&& = r&& + 1
        END IF
        l$ = LEFT$(l$, 1) + MID$(l$, 3)
    END IF
 
    SELECT CASE r&&
        CASE 0 'what the heck? We solved it already?
            'l$ = l$
        CASE IS < 0
            FOR i = 1 TO -r&&
                l$ = "0" + l$
            NEXT
            l$ = "0." + l$
        CASE ELSE
            FOR i = 1 TO r&&
                l$ = l$ + "0"
            NEXT
    END SELECT
 
    N2S$ = sign$ + l$
    'PRINT "After notation:"; N2S$
END SUB
One of the functions from my math evaluator; it converts scientific notation into a string for string processing.

That does look handy!

[SMcNeill]

You guys might want to take a look at it here sometime:  https://www.qb64.org/forum/index.php?topic=1555.msg112989#msg112989

It deals with type symbols (%,!,#,##,&,&&,%% -- even the unsigned ~ types), scientific notation, string addition, math, multiplication, orders of precedence, duplicate symbols (-- becomes +, +- becomes -, ect), tons of possible error messages...

There's a lot of useful little functions and routines in it.  Feel free to use whatever you'd like from it.  Believe it or not, you've used it countless times already, and have probably contributed to stress-testing and error-checking of it already.  All you have to do is look in QB64.BAS, and you'll see Steve's Math Evaluator is what we use internally to calculate values anytime you enter a formula into a CONST...  ;D

[adgarza]

You guys might want to take a look at it here sometime:  https://www.qb64.org/forum/index.php?topic=1555.msg112989#msg112989

I will... I am sure I will learn from your code...