Tumblr page viewer

[loudar]

Hey everyone!

Since I personally love having a little board of inspiration up sometimes, I always wanted a way to display many images at once, organized in a grid. I know the image handling is far from optimal, but it's the best I came up with for today.

Just put in the subdomain-name (name.tumblr.com), then the program will use wget (make sure you have it installed, I've attached it) to fetch the images.
 

wget.exe

Scroll through! :D

Code: QB64: [Select]

1. 'Tumblr viewer
2. maxblogs = 50
3. DIM SHARED bn$(maxblogs)
4. DIM SHARED lu$(maxblogs)
5. DIM SHARED foldername$
6.  
7. SCREEN _NEWIMAGE(250, 200, 32)
8. _SCREENMOVE (_DESKTOPWIDTH / 2) - (_WIDTH / 2), (_DESKTOPHEIGHT / 2) - (_HEIGHT / 2)
9.  
10. maxpages = 5
11.  
12. INPUT "blogname: ", blogname$
13.  
14. folder$ = _STARTDIR$
15. IF _FILEEXISTS(folder$ + "\view\lastupdate.txt") = 0 THEN OPEN folder$ + "\view\lastupdate.txt" FOR OUTPUT AS #1: CLOSE #1
16. OPEN folder$ + "\view\lastupdate.txt" FOR INPUT AS #1
17. IF LOF(1) > 0 THEN
18.     DO
19.         b = b + 1
20.         INPUT #1, bn$(b), lu$(b)
21.         IF bn$(b) = blogname$ AND lu$(b) = DATE$ THEN
22.             dontupdate = 1
23.         END IF
24.     LOOP UNTIL EOF(1) = -1
25. END IF
26. maxb = b
27. CLOSE #1
28.  
29. LOCATE 3, 1
30. PRINT "Downloading..."
31. PRINT "[" + CHR$(176) + longchar$(" ", 9) + "] 0%"
32.  
33. IF dontupdate = 0 THEN
34.     OPEN folder$ + "\view\lastupdate.txt" FOR OUTPUT AS #1
35.     b = 0
36.     found = 0
37.     IF maxb > 0 THEN
38.         DO
39.             b = b + 1
40.             IF bn$(b) = blogname$ THEN
41.                 found = 1
42.                 lu$(b) = DATE$
43.             END IF
44.             WRITE #1, bn$(b), lu$(b)
45.         LOOP UNTIL b = maxb
46.     END IF
47.     IF found = 0 THEN
48.         WRITE #1, blogname$, DATE$
49.     END IF
50.     CLOSE #1
51.     url$ = "https://" + blogname$ + ".tumblr.com/"
52.     formats$ = "jpg"
53.     foldername$ = "view\" + blogname$
54.     options$ = "-nd -rH -p -D64.media.tumblr.com -A " + formats$ + " -e robots=off " + url$ + " -P " + folder$ + "\" + foldername$
55.     SHELL "wget " + options$
56.  
57.     baseurl$ = "https://" + blogname$ + ".tumblr.com/page/"
58.     pagecount = 1: DO: pagecount = pagecount + 1
59.         LOCATE 3, 1
60.         PRINT "Downloading page " + LTRIM$(STR$(pagecount)) + "..."
61.         PRINT "[" + longchar$(CHR$(219), (pagecount - 1) / maxpages * 10) + CHR$(176) + longchar$(" ", (maxpages - pagecount) / maxpages * 10) + "] " + LTRIM$(STR$((pagecount - 1) / maxpages * 100)) + "%"
62.  
63.         url$ = baseurl$ + LTRIM$(STR$(pagecount)) + "/"
64.         formats$ = "jpg"
65.         options$ = "-nd -rH -p -D64.media.tumblr.com -A " + formats$ + " -e robots=off " + url$ + " -P " + folder$ + "\" + foldername$
66.  
67.         IF pagecount < maxpages THEN
68.             SHELL _DONTWAIT "wget " + options$
69.         ELSE
70.             SHELL "wget " + options$
71.         END IF
72.     LOOP WHILE pagecount < maxpages
73. ELSE
74.     foldername$ = "view\" + blogname$
75. END IF
76.  
77. maxx = _DESKTOPWIDTH
78. maxy = _DESKTOPHEIGHT
79. SCREEN _NEWIMAGE(maxx, maxy, 32)
80. DO: LOOP UNTIL _SCREENEXISTS
81. _SCREENMOVE (_DESKTOPWIDTH / 2) - (_WIDTH / 2), (_DESKTOPHEIGHT / 2) - (_HEIGHT / 2)
82.  
83. maximages = 500
84. DIM SHARED image&(maximages)
85. DIM SHARED posx(-5 TO maximages)
86. DIM SHARED posy(-5 TO maximages)
87. DIM SHARED columns
88. DIM SHARED pwidth
89. DIM SHARED autoscroll
90.  
91. columns = 5
92. pwidth = maxx / columns
93. autoscroll = 0
94.  
95. spec$ = _STARTDIR$ + "\" + foldername$
96. file$ = DiR$(spec$) 'use a file spec ONCE to find the last file name listed
97. IF DiRCount% > 1 THEN
98.     posx(0) = pwidth * (columns - 1)
99.     i = 0: DO
100.         file$ = _STARTDIR$ + "\" + foldername$ + "\" + DiR$("") 'use an empty string parameter to return a list of files!
101.         IF file$ <> _STARTDIR$ + "\" + foldername$ + "\" AND MID$(file$, LEN(file$) - 6, 3) <> "500" THEN
102.             i = i + 1
103.             image&(i) = _LOADIMAGE(file$, 32)
104.             'IF image&(i) < -1 THEN
105.             posx(i) = posx(i - 1) + pwidth
106.             IF posx(i) > pwidth * (columns - 1) THEN
107.                 posx(i) = 0
108.             END IF
109.             IF i > 4 THEN
110.                 posy(i) = posy(i - columns) + (_HEIGHT(image&(i - columns)) * (pwidth / _WIDTH(image&(i - columns))))
111.             ELSE
112.                 posy(i) = 0
113.             END IF
114.             _PUTIMAGE (posx(i), posy(i))-(posx(i) + pwidth, posy(i) + (_HEIGHT(image&(i)) * (pwidth / _WIDTH(image&(i))))), image&(i)
115.             IF highest < posy(i) + (_HEIGHT(image&(i)) * (pwidth / _WIDTH(image&(i)))) THEN
116.                 highest = posy(i) + (_HEIGHT(image&(i)) * (pwidth / _WIDTH(image&(i))))
117.             END IF
118.             'ELSE
119.             '    i = i - 1
120.             'END IF
121.         ELSEIF file$ <> _STARTDIR$ + "\" + foldername$ + "\" THEN
122.             KILL file$
123.         END IF
124.     LOOP UNTIL file$ = _STARTDIR$ + "\" + foldername$ + "\" OR i = maximages - 1 'file list ends with an empty string
125.     maxi = i - 1
126. END IF
127.  
128. DO
129.     Taste$ = INKEY$
130.     IF Taste$ = CHR$(0) + CHR$(133) THEN
131.         IF _FULLSCREEN = 0 THEN
132.             _FULLSCREEN _SQUAREPIXELS
133.         ELSE
134.             _FULLSCREEN _OFF
135.         END IF
136.     END IF
137.     'IF Taste$ = "a" THEN
138.     '    IF autoscroll = 1 THEN autoscroll = 0 ELSE autoscroll = 1
139.     'END IF
140.     IF autoscroll = 1 THEN
141.         IF (TIMER MOD 1) MOD 0.05 = 0 THEN
142.             change = 1
143.             IF scrollpos + _HEIGHT < posy(maxi) + (_HEIGHT(image&(maxi)) * (pwidth / _WIDTH(image&(maxi)))) THEN
144.                 scrollpos = scrollpos + 1
145.             ELSE
146.                 scrollpos = 0
147.             END IF
148.         END IF
149.     ELSE
150.         mouseinput = _MOUSEINPUT
151.         mousewheel = _MOUSEWHEEL
152.         IF mouseinput = -1 THEN
153.             IF mousewheel = -1 THEN
154.                 change = 1
155.                 IF scrollpos + _HEIGHT < posy(maxi) + (_HEIGHT(image&(maxi)) * (pwidth / _WIDTH(image&(maxi)))) THEN
156.                     scrollpos = scrollpos + (maxy / 10)
157.                 END IF
158.             ELSEIF mousewheel = 1 THEN
159.                 change = 1
160.                 IF scrollpos > 0 THEN
161.                     scrollpos = scrollpos - (maxy / 10)
162.                 END IF
163.             END IF
164.         END IF
165.     END IF
166.     IF change = 1 AND maxi > 0 THEN
167.         change = 0
168.         CLS
169.         FOR i = 1 TO maxi
170.             IF posy(i) - scrollpos < maxy AND posy(i) + (_HEIGHT(image&(i)) * (pwidth / _WIDTH(image&(i)))) - scrollpos > -1 THEN
171.                 _PUTIMAGE (posx(i), posy(i) - scrollpos)-(posx(i) + pwidth, posy(i) + (_HEIGHT(image&(i)) * (pwidth / _WIDTH(image&(i)))) - scrollpos), image&(i)
172.             END IF
173.         NEXT
174.         _DISPLAY
175.     END IF
176.     '_LIMIT 60
177. LOOP UNTIL Taste$ = CHR$(27)
178. SYSTEM
179.  
180. FUNCTION DiR$ (spec$)
181.     CONST TmpFile$ = "DiR$iNF0.iNF", ListMAX% = 500 'change maximum to suit your needs
182.     SHARED DiRCount% 'returns file count if desired
183.     STATIC Ready%, index%, DirList$()
184.     IF NOT Ready% THEN REDIM DirList$(ListMAX%): Ready% = -1 'DiM array first use
185.     IF spec$ > "" THEN 'get file names when a spec is given
186.         SHELL _HIDE "DiR " + spec$ + " /b > " + TmpFile$
187.         index% = 0: DirList$(index%) = "": ff% = FREEFILE
188.         OPEN TmpFile$ FOR APPEND AS #ff%
189.         size& = LOF(ff%)
190.         CLOSE #ff%
191.         IF size& = 0 THEN KILL TmpFile$: EXIT FUNCTION
192.         OPEN TmpFile$ FOR INPUT AS #ff%
193.         DO WHILE NOT EOF(ff%) AND index% < ListMAX%
194.             index% = index% + 1
195.             LINE INPUT #ff%, DirList$(index%)
196.         LOOP
197.         DiRCount% = index% 'SHARED variable can return the file count
198.         CLOSE #ff%
199.         KILL TmpFile$
200.     ELSE IF index% > 0 THEN index% = index% - 1 'no spec sends next file name
201.     END IF
202.     DiR$ = DirList$(index%)
203. END FUNCTION
204.  
205. FUNCTION longchar$ (char$, length) 'returns a string consisting of one character repeated (length) times
206.     temp$ = ""
207.     IF length > 0 THEN
208.         l = 0: DO: l = l + 1
209.             temp$ = temp$ + char$
210.         LOOP UNTIL l = length
211.     END IF
212.     longchar$ = temp$
213. END FUNCTION

[SpriggsySpriggs]

Nice!