Get Weather with Online API!

[SpriggsySpriggs]

As @Dav suggested, here is a demo showing off how to get the weather forecast for a supplied location. You can put either city or zip. Go to weatherstack.com and get your API key! This demo is obviously very limited but if you comment out the "KILL" you can see the file and from there you can figure out what you want to return from the JSON response.
 

Code: QB64: [Select]

1. $CONSOLE:ONLY
2. _DEST _CONSOLE
3.  
4. PRINT GetWeather("47172", "forecast", "f")
5. SLEEP
6.  
7. FUNCTION GetWeather$ (location AS STRING, timing AS STRING, units AS STRING) 'timing can be either current or forecast for this demo
8.     DIM URL AS STRING
9.     DIM URLFile AS STRING
10.     DIM WeatherRequest AS STRING
11.     DIM a%
12.     DIM Request AS STRING
13.     URLFile = "weatherapirequest"
14.     URL = "http://api.weatherstack.com/" + timing + "?access_key=YOURAPIKEYHERE&query=" + FormatAsHTTP(location) + "&units=" + units
15.     a% = API_Request(URL, URLFile)
16.     DIM U AS INTEGER
17.     U = FREEFILE
18.     OPEN URLFile FOR BINARY AS #U
19.     IF LOF(U) <> 0 THEN
20.         Request = SPACE$(LOF(U))
21.         GET #U, , Request
22.     ELSE
23.         CLOSE #U
24.         KILL URLFile
25.         GetWeather = ""
26.         EXIT FUNCTION
27.     END IF
28.     CLOSE #U
29.     KILL URLFile
30.     IF timing = "forecast" THEN
31.         WeatherRequest = "Forecast for " + location + ": " + CHR$(10)
32.         WeatherRequest = WeatherRequest + "Temperature: " + _TRIM$(STR$(VAL(MID$(Request, INSTR(Request, "temperature") + 13, 3)))) + CHR$(10) + "Wind Speed: " + _TRIM$(STR$(VAL(MID$(Request, INSTR(Request, "wind_speed") + 12, 3))))
33.         GetWeather = WeatherRequest
34.     ELSE
35.     END IF
36. END FUNCTION
37.  
38. FUNCTION FormatAsHTTP$ (Request AS STRING)
39.     start% = 1
40.     DO
41.         position% = INSTR(start%, Request, " ")
42.         IF position% THEN
43.             MID$(Request, position%, 1) = "+"
44.             start% = position% + 1
45.         END IF
46.     LOOP UNTIL position% = 0
47.     FormatAsHTTP = Request
48. END FUNCTION
49.  
50. DECLARE DYNAMIC LIBRARY "urlmon"
51.     FUNCTION URLDownloadToFileA (BYVAL pCaller AS LONG, szURL AS STRING, szFileName AS STRING, BYVAL dwReserved AS LONG, BYVAL lpfnCB AS LONG)
52. END DECLARE
53.  
54. FUNCTION API_Request (URL AS STRING, File AS STRING)
55.     API_Request = URLDownloadToFileA(0, URL + CHR$(0), File + CHR$(0), 0, 0)
56. END FUNCTION

[SpriggsySpriggs]

I'll look into what @IronMan made in this post https://www.qb64.org/forum/index.php?topic=2343.msg115710#msg115710 and see about making a version which automatically grabs current location (based on public IP) then grabs the appropriate NOAA file for the correct zone, provided I can determine which zone is what using NOAA.

[IronMan]

Don't know if this will help you, but here is a list of zones I compiled for all the locations.

[SpriggsySpriggs]

@IronMan Absolutely fantastic. This will actually help me a lot.

[SpriggsySpriggs]

Well I'm down to the final stretch. I'm going to be able to finish this API today using ipify to get the public IP, using geo.ipify to get the zip code based on public IP, using smartystreets to get the county and state from the zip code returned from geo.ipify, then the correct text file from NOAA based on the two character state abbreviation returned form smartystreets and the county-zone correlation from @IronMan 's lst file. Piece of cake.

[SpriggsySpriggs]

@IronMan @Dav Finally, here is a version of the weather API that will grab your location automatically then grab the appropriate NOAA weather statement file using IronMan's lst file cross referencing the County and State with the Zone needed and then displays it in the window. Enjoy!
P.S. I made sure I removed those annoying periods at the beginning of the new lines since I know IronMan doesn't like them :)
EDIT: Realized I was getting rid of some necessary line feeds with my Remove function. I've put in the String.Replace function so when I remove the period I put the line feed back in so now it displays better.

 

Code: QB64: [Select]

1. $CONSOLE:ONLY
2. _DEST _CONSOLE
3.  
4. PRINT GetWeather
5. SLEEP
6.  
7. FUNCTION GetWeather$
8.     DIM URL AS STRING
9.     DIM URLFile AS STRING
10.     DIM weather AS STRING
11.     DIM county AS STRING
12.     DIM a%
13.     URLFile = "weatherrequest"
14.     DIM state AS STRING
15.     state = LCASE$(GetStateFromZipCode)
16.     URL = "https://tgftp.nws.noaa.gov/data/forecasts/zone/" + state + "/" + CrossRefZoneState(UCASE$(state), GetCountyFromZipCode) + ".txt"
17.     a% = API_request(URL, URLFile)
18.     DIM U AS INTEGER
19.     U = FREEFILE
20.     OPEN URLFile FOR BINARY AS #U
21.     IF LOF(U) <> 0 THEN
22.         weather = SPACE$(LOF(U))
23.         GET #U, , weather
24.     ELSE
25.         CLOSE #U
26.         KILL URLFile
27.         GetWeather = ""
28.         EXIT FUNCTION
29.     END IF
30.     CLOSE #U
31.     KILL URLFile
32.     weather = String.Replace(weather, CHR$(10) + ".", CHR$(10))
33.     weather = String.Remove(weather, "$$")
34.     GetWeather = weather
35. END FUNCTION
36.  
37. FUNCTION CrossRefZoneState$ (state AS STRING, county AS STRING)
38.     DIM Z AS INTEGER
39.     Z = FREEFILE
40.     DIM zone AS STRING
41.     DIM zones AS STRING
42.     IF _FILEEXISTS("zones.lst") THEN
43.         OPEN "zones.lst" FOR BINARY AS #Z
44.         zones = SPACE$(LOF(Z))
45.         GET #Z, , zones
46.         zone = MID$(zones, INSTR(zones, state + "Z"))
47.         zone = MID$(zone, INSTR(zone, county) - 7, 6)
48.         CrossRefZoneState = LCASE$(zone)
49.     ELSE
50.         CrossRefZoneState = ""
51.         EXIT FUNCTION
52.     END IF
53. END FUNCTION
54.  
55. FUNCTION GetCountyFromZipCode$
56.     DIM URL AS STRING
57.     DIM URLFile AS STRING
58.     DIM county AS STRING
59.     DIM a%
60.     URLFile = "county"
61.     URL = "https://us-zipcode.api.smartystreets.com/lookup?auth-id=YOURAUTHIDHERE&auth-token=YOURAUTHTOKENHERE&zipcode=" + GetLocationVIAip
62.     a% = API_request(URL, URLFile)
63.     DIM U AS INTEGER
64.     U = FREEFILE
65.     OPEN URLFile FOR BINARY AS #U
66.     IF LOF(U) <> 0 THEN
67.         county = SPACE$(LOF(U))
68.         GET #U, , county
69.     ELSE
70.         CLOSE #U
71.         KILL URLFile
72.         GetCountyFromZipCode = ""
73.         EXIT FUNCTION
74.     END IF
75.     CLOSE #U
76.     KILL URLFile
77.     county = MID$(county, INSTR(county, "county_name") + 14)
78.     county = LEFT$(county, INSTR(county, CHR$(34)) - 1)
79.     GetCountyFromZipCode = county
80. END FUNCTION
81.  
82. FUNCTION GetStateFromZipCode$
83.     DIM URL AS STRING
84.     DIM URLFile AS STRING
85.     DIM state AS STRING
86.     DIM a%
87.     URLFile = "statebyzip"
88.     URL = "https://us-zipcode.api.smartystreets.com/lookup?auth-id=YOURAUTHIDHERE&auth-token=YOURAUTHTOKENHERE&zipcode=" + GetLocationVIAip
89.     a% = API_request(URL, URLFile)
90.     DIM U AS INTEGER
91.     U = FREEFILE
92.     OPEN URLFile FOR BINARY AS #U
93.     IF LOF(U) <> 0 THEN
94.         state = SPACE$(LOF(U))
95.         GET #U, , state
96.     ELSE
97.         CLOSE #U
98.         KILL URLFile
99.         GetStateFromZipCode = ""
100.         EXIT FUNCTION
101.     END IF
102.     CLOSE #U
103.     KILL URLFile
104.     state = MID$(state, INSTR(state, "state_abbreviation") + 21)
105.     state = LEFT$(state, INSTR(state, CHR$(34)) - 1)
106.     GetStateFromZipCode = state
107. END FUNCTION
108.  
109. FUNCTION GetLocationVIAip$
110.     DIM URL AS STRING
111.     DIM URLFile AS STRING
112.     DIM location AS STRING
113.     DIM a%
114.     URLFile = "location"
115.     URL = "https://geo.ipify.org/api/v1?apiKey=YOURAPIKEYHERE&ipAddress=" + GetPublicIP
116.     a% = API_request(URL, URLFile)
117.     DIM U AS INTEGER
118.     U = FREEFILE
119.     OPEN URLFile FOR BINARY AS #U
120.     IF LOF(U) <> 0 THEN
121.         location = SPACE$(LOF(U))
122.         GET #U, , location
123.     ELSE
124.         CLOSE #U
125.         KILL URLFile
126.         GetLocationVIAip = ""
127.         EXIT FUNCTION
128.     END IF
129.     CLOSE #U
130.     KILL URLFile
131.     location = MID$(location, INSTR(location, "postalCode") + 13)
132.     location = LEFT$(location, INSTR(location, CHR$(34)) - 1)
133.     GetLocationVIAip = location
134. END FUNCTION
135.  
136. FUNCTION GetPublicIP$
137.     DIM URL AS STRING
138.     DIM URLFile AS STRING
139.     DIM publicip AS STRING
140.     DIM a%
141.     URLFile = "publicip"
142.     URL = "https://api.ipify.org/"
143.     a% = API_request(URL, URLFile)
144.     DIM U AS INTEGER
145.     U = FREEFILE
146.     OPEN URLFile FOR BINARY AS #U
147.     IF LOF(U) <> 0 THEN
148.         LINE INPUT #U, publicip
149.     ELSE
150.         CLOSE #U
151.         KILL URLFile
152.         GetPublicIP = ""
153.         EXIT FUNCTION
154.     END IF
155.     CLOSE #U
156.     KILL URLFile
157.     GetPublicIP = publicip
158. END FUNCTION
159.  
160. FUNCTION String.Remove$ (a AS STRING, b AS STRING)
161.     DIM c AS STRING
162.     c = ""
163.     j = INSTR(a, b)
164.     IF j > 0 THEN
165.         r$ = LEFT$(a, j - 1) + c + String.Remove(RIGHT$(a, LEN(a) - j + 1 - LEN(b)), b)
166.     ELSE
167.         r$ = a
168.     END IF
169.     String.Remove = r$
170. END FUNCTION
171.  
172. FUNCTION String.Replace$ (a AS STRING, b AS STRING, c AS STRING)
173.     j = INSTR(a, b)
174.     IF j > 0 THEN
175.         r$ = LEFT$(a, j - 1) + c + String.Replace(RIGHT$(a, LEN(a) - j + 1 - LEN(b)), b, c)
176.     ELSE
177.         r$ = a
178.     END IF
179.     String.Replace = r$
180. END FUNCTION
181.  
182. DECLARE DYNAMIC LIBRARY "urlmon"
183.     FUNCTION URLDownloadToFileA (BYVAL pCaller AS LONG, szURL AS STRING, szFileName AS STRING, BYVAL dwReserved AS LONG, BYVAL lpfnCB AS LONG)
184. END DECLARE
185.  
186. FUNCTION API_request (URL AS STRING, File AS STRING)
187.     API_request = URLDownloadToFileA(0, URL + CHR$(0), File + CHR$(0), 0, 0)
188. END FUNCTION

[IronMan]

SpriggsySpriggs,


Job well done! It works great... :-))

your method of removing the extra $$ and .. is a lot more simple than the way I done it. I'm going to have to make a note of this for sure..

weather = STRING.Remove(weather, CHR$(10) + ".")
weather = STRING.Remove(weather, "$$")



My way:


OPEN "fetch1.txt" FOR INPUT AS #1
OPEN "fetch2.txt" FOR OUTPUT AS #2
WHILE NOT EOF(1)
    INPUT #1, LineTxt
    IF LEFT$(LineTxt, 1) = "." THEN
PRINT #2, " "PRINT #2, MID$(LineTxt, 2); " "
ELSE
PRINT #2, LineTxt 'write output to new file fetch2.txt
END IF
WEND
CLOSE #1
CLOSE #2

' Remove $$
OPEN "fetch3.txt" FOR INPUT AS #1
OPEN "forecast.txt" FOR OUTPUT AS #2
WHILE NOT EOF(1)
    INPUT #1, LineTxt2
    IF LineTxt2 = "$$" THEN
LineTxt2 = "  "
PRINT #2, "  "
ELSE
PRINT #2, LineTxt2 'write output to new file forecast.txt
END IF
WEND
CLOSE #1
CLOSE #2


Guess I just like taking the long way around, Hehehehe


Congratulations again on a great job.

[SpriggsySpriggs]

@IronMan I couldn't have done it nearly as quick without your list of the Zones and how they reference the counties! I was scouring the web trying to find some kind of list like that somewhere because I had no clue what zone my county was without looking at some PDF of my state.

[Dav]

Nice job, @SpriggsySpriggs ! You sure did that quickly. 

- Dav

[SpriggsySpriggs]

I'm starting to wonder how this would be using Dav's espeak library.....

[SpriggsySpriggs]

Ok, for a good laugh, run this and hear the most terrible AI voice speak out your local weather report! @Dav , eSpeak is a wonderful library! (Check the post below for a true weather report experience)

Code: QB64: [Select]

1. $CONSOLE:ONLY
2. _DEST _CONSOLE
3.  
4. DIM Weather AS STRING
5. Weather = GetWeather
6. PRINT Weather
7. Weather = MID$(Weather, INSTR(Weather, "OVERNIGHT"))
8. eSpeak Weather
9. SLEEP
10.  
11. FUNCTION GetWeather$
12.     DIM URL AS STRING
13.     DIM URLFile AS STRING
14.     DIM weather AS STRING
15.     DIM county AS STRING
16.     DIM a%
17.     URLFile = "weatherrequest"
18.     DIM state AS STRING
19.     state = LCASE$(GetStateFromZipCode)
20.     URL = "https://tgftp.nws.noaa.gov/data/forecasts/zone/" + state + "/" + CrossRefZoneState(UCASE$(state), GetCountyFromZipCode) + ".txt"
21.     a% = API_request(URL, URLFile)
22.     DIM U AS INTEGER
23.     U = FREEFILE
24.     OPEN URLFile FOR BINARY AS #U
25.     IF LOF(U) <> 0 THEN
26.         weather = SPACE$(LOF(U))
27.         GET #U, , weather
28.     ELSE
29.         CLOSE #U
30.         KILL URLFile
31.         GetWeather = ""
32.         EXIT FUNCTION
33.     END IF
34.     CLOSE #U
35.     KILL URLFile
36.     weather = String.Replace(weather, CHR$(10) + ".", CHR$(10))
37.     weather = String.Remove(weather, "$$")
38.     GetWeather = weather
39. END FUNCTION
40.  
41. FUNCTION CrossRefZoneState$ (state AS STRING, county AS STRING)
42.     DIM Z AS INTEGER
43.     Z = FREEFILE
44.     DIM zone AS STRING
45.     DIM zones AS STRING
46.     IF _FILEEXISTS("zones.lst") THEN
47.         OPEN "zones.lst" FOR BINARY AS #Z
48.         zones = SPACE$(LOF(Z))
49.         GET #Z, , zones
50.         zone = MID$(zones, INSTR(zones, state + "Z"))
51.         zone = MID$(zone, INSTR(zone, county) - 7, 6)
52.         CrossRefZoneState = LCASE$(zone)
53.     ELSE
54.         CrossRefZoneState = ""
55.         EXIT FUNCTION
56.     END IF
57. END FUNCTION
58.  
59. FUNCTION GetCountyFromZipCode$
60.     DIM URL AS STRING
61.     DIM URLFile AS STRING
62.     DIM county AS STRING
63.     DIM a%
64.     URLFile = "county"
65.     URL = "https://us-zipcode.api.smartystreets.com/lookup?auth-id=YOURAUTHIDHERE&auth-token=YOURAUTHTOKENHERE&zipcode=" + GetLocationVIAip
66.     a% = API_request(URL, URLFile)
67.     DIM U AS INTEGER
68.     U = FREEFILE
69.     OPEN URLFile FOR BINARY AS #U
70.     IF LOF(U) <> 0 THEN
71.         county = SPACE$(LOF(U))
72.         GET #U, , county
73.     ELSE
74.         CLOSE #U
75.         KILL URLFile
76.         GetCountyFromZipCode = ""
77.         EXIT FUNCTION
78.     END IF
79.     CLOSE #U
80.     KILL URLFile
81.     county = MID$(county, INSTR(county, "county_name") + 14)
82.     county = LEFT$(county, INSTR(county, CHR$(34)) - 1)
83.     GetCountyFromZipCode = county
84. END FUNCTION
85.  
86. FUNCTION GetStateFromZipCode$
87.     DIM URL AS STRING
88.     DIM URLFile AS STRING
89.     DIM state AS STRING
90.     DIM a%
91.     URLFile = "statebyzip"
92.     URL = "https://us-zipcode.api.smartystreets.com/lookup?auth-id=YOURAUTHIDHERE&auth-token=YOURAUTHTOKENHERE&zipcode=" + GetLocationVIAip
93.     a% = API_request(URL, URLFile)
94.     DIM U AS INTEGER
95.     U = FREEFILE
96.     OPEN URLFile FOR BINARY AS #U
97.     IF LOF(U) <> 0 THEN
98.         state = SPACE$(LOF(U))
99.         GET #U, , state
100.     ELSE
101.         CLOSE #U
102.         KILL URLFile
103.         GetStateFromZipCode = ""
104.         EXIT FUNCTION
105.     END IF
106.     CLOSE #U
107.     KILL URLFile
108.     state = MID$(state, INSTR(state, "state_abbreviation") + 21)
109.     state = LEFT$(state, INSTR(state, CHR$(34)) - 1)
110.     GetStateFromZipCode = state
111. END FUNCTION
112.  
113. FUNCTION GetLocationVIAip$
114.     DIM URL AS STRING
115.     DIM URLFile AS STRING
116.     DIM location AS STRING
117.     DIM a%
118.     URLFile = "location"
119.     URL = "https://geo.ipify.org/api/v1?apiKey=YOURAPIKEYHERE&ipAddress=" + GetPublicIP
120.     a% = API_request(URL, URLFile)
121.     DIM U AS INTEGER
122.     U = FREEFILE
123.     OPEN URLFile FOR BINARY AS #U
124.     IF LOF(U) <> 0 THEN
125.         location = SPACE$(LOF(U))
126.         GET #U, , location
127.     ELSE
128.         CLOSE #U
129.         KILL URLFile
130.         GetLocationVIAip = ""
131.         EXIT FUNCTION
132.     END IF
133.     CLOSE #U
134.     KILL URLFile
135.     location = MID$(location, INSTR(location, "postalCode") + 13)
136.     location = LEFT$(location, INSTR(location, CHR$(34)) - 1)
137.     GetLocationVIAip = location
138. END FUNCTION
139.  
140. FUNCTION GetPublicIP$
141.     DIM URL AS STRING
142.     DIM URLFile AS STRING
143.     DIM publicip AS STRING
144.     DIM a%
145.     URLFile = "publicip"
146.     URL = "https://api.ipify.org/"
147.     a% = API_request(URL, URLFile)
148.     DIM U AS INTEGER
149.     U = FREEFILE
150.     OPEN URLFile FOR BINARY AS #U
151.     IF LOF(U) <> 0 THEN
152.         LINE INPUT #U, publicip
153.     ELSE
154.         CLOSE #U
155.         KILL URLFile
156.         GetPublicIP = ""
157.         EXIT FUNCTION
158.     END IF
159.     CLOSE #U
160.     KILL URLFile
161.     GetPublicIP = publicip
162. END FUNCTION
163.  
164. FUNCTION String.Remove$ (a AS STRING, b AS STRING)
165.     DIM c AS STRING
166.     c = ""
167.     j = INSTR(a, b)
168.     IF j > 0 THEN
169.         r$ = LEFT$(a, j - 1) + c + String.Remove(RIGHT$(a, LEN(a) - j + 1 - LEN(b)), b)
170.     ELSE
171.         r$ = a
172.     END IF
173.     String.Remove = r$
174. END FUNCTION
175.  
176. FUNCTION String.Replace$ (a AS STRING, b AS STRING, c AS STRING)
177.     j = INSTR(a, b)
178.     IF j > 0 THEN
179.         r$ = LEFT$(a, j - 1) + c + String.Replace(RIGHT$(a, LEN(a) - j + 1 - LEN(b)), b, c)
180.     ELSE
181.         r$ = a
182.     END IF
183.     String.Replace = r$
184. END FUNCTION
185.  
186. DECLARE DYNAMIC LIBRARY "urlmon"
187.     FUNCTION URLDownloadToFileA (BYVAL pCaller AS LONG, szURL AS STRING, szFileName AS STRING, BYVAL dwReserved AS LONG, BYVAL lpfnCB AS LONG)
188. END DECLARE
189.  
190. FUNCTION API_request (URL AS STRING, File AS STRING)
191.     API_request = URLDownloadToFileA(0, URL + CHR$(0), File + CHR$(0), 0, 0)
192. END FUNCTION
193.  
194. DECLARE LIBRARY
195.     FUNCTION WinExec (lpCmdLine AS STRING, BYVAL nCmdShow AS LONG)
196. END DECLARE
197.  
198. SUB eSpeak (lines$)
199.     Filename$ = "espeak.exe -v en " + CHR$(34) + lines$ + CHR$(34)
200.     x = WinExec(Filename$ + CHR$(0), 0)
201. END SUB

[SpriggsySpriggs]

And with a more advanced Text To Speech library that sounds far more natural!:
Run my attached exe "weatherapi.exe" to hear how it sounds. It has my API keys inside it so please don't run it 250 times LOL
You may notice I had to change the spelling in the string that gets sent to the TTS. That's because it kept mispronouncing those specific words.

Code: QB64: [Select]

1. 'OPTION _EXPLICIT
2. $CONSOLE:ONLY
3. _DEST _CONSOLE
4.  
5. DIM Weather AS STRING
6. Weather = GetWeather
7. PRINT Weather
8.  
9. 'eSpeak Weather
10.  
11. TTS FormatForTTS(Weather)
12.  
13. SLEEP
14.  
15. FUNCTION GetWeather$
16.     DIM URL AS STRING
17.     DIM URLFile AS STRING
18.     DIM weather AS STRING
19.     DIM county AS STRING
20.     DIM a%
21.     URLFile = "weatherrequest"
22.     DIM state AS STRING
23.     state = LCASE$(GetStateFromZipCode)
24.     URL = "https://tgftp.nws.noaa.gov/data/forecasts/zone/" + state + "/" + CrossRefZoneState(UCASE$(state), GetCountyFromZipCode) + ".txt"
25.     a% = API_request(URL, URLFile)
26.     DIM U AS INTEGER
27.     U = FREEFILE
28.     OPEN URLFile FOR BINARY AS #U
29.     IF LOF(U) <> 0 THEN
30.         weather = SPACE$(LOF(U))
31.         GET #U, , weather
32.     ELSE
33.         CLOSE #U
34.         KILL URLFile
35.         GetWeather = ""
36.         EXIT FUNCTION
37.     END IF
38.     CLOSE #U
39.     KILL URLFile
40.     weather = String.Replace(weather, CHR$(10) + ".", CHR$(10))
41.     weather = String.Remove(weather, "$$")
42.     GetWeather = weather
43. END FUNCTION
44.  
45. FUNCTION CrossRefZoneState$ (state AS STRING, county AS STRING)
46.     DIM Z AS INTEGER
47.     Z = FREEFILE
48.     DIM zone AS STRING
49.     DIM zones AS STRING
50.     IF _FILEEXISTS("zones.lst") THEN
51.         OPEN "zones.lst" FOR BINARY AS #Z
52.         zones = SPACE$(LOF(Z))
53.         GET #Z, , zones
54.         zone = MID$(zones, INSTR(zones, state + "Z"))
55.         zone = MID$(zone, INSTR(zone, county) - 7, 6)
56.         CrossRefZoneState = LCASE$(zone)
57.     ELSE
58.         CrossRefZoneState = ""
59.         EXIT FUNCTION
60.     END IF
61. END FUNCTION
62.  
63. FUNCTION GetCountyFromZipCode$
64.     DIM URL AS STRING
65.     DIM URLFile AS STRING
66.     DIM county AS STRING
67.     DIM a%
68.     URLFile = "county"
69.     URL = "https://us-zipcode.api.smartystreets.com/lookup?auth-id=YOURAUTHIDHERE&auth-token=YOURAUTHTOKENHERE&zipcode=" + GetLocationVIAip
70.     a% = API_request(URL, URLFile)
71.     DIM U AS INTEGER
72.     U = FREEFILE
73.     OPEN URLFile FOR BINARY AS #U
74.     IF LOF(U) <> 0 THEN
75.         county = SPACE$(LOF(U))
76.         GET #U, , county
77.     ELSE
78.         CLOSE #U
79.         KILL URLFile
80.         GetCountyFromZipCode = ""
81.         EXIT FUNCTION
82.     END IF
83.     CLOSE #U
84.     KILL URLFile
85.     county = MID$(county, INSTR(county, "county_name") + 14)
86.     county = LEFT$(county, INSTR(county, CHR$(34)) - 1)
87.     GetCountyFromZipCode = county
88. END FUNCTION
89.  
90. FUNCTION GetStateFromZipCode$
91.     DIM URL AS STRING
92.     DIM URLFile AS STRING
93.     DIM state AS STRING
94.     DIM a%
95.     URLFile = "statebyzip"
96.     URL = "https://us-zipcode.api.smartystreets.com/lookup?auth-id=YOURAUTHIDHERE&auth-token=YOURAUTHTOKENHERE&zipcode=" + GetLocationVIAip
97.     a% = API_request(URL, URLFile)
98.     DIM U AS INTEGER
99.     U = FREEFILE
100.     OPEN URLFile FOR BINARY AS #U
101.     IF LOF(U) <> 0 THEN
102.         state = SPACE$(LOF(U))
103.         GET #U, , state
104.     ELSE
105.         CLOSE #U
106.         KILL URLFile
107.         GetStateFromZipCode = ""
108.         EXIT FUNCTION
109.     END IF
110.     CLOSE #U
111.     KILL URLFile
112.     state = MID$(state, INSTR(state, "state_abbreviation") + 21)
113.     state = LEFT$(state, INSTR(state, CHR$(34)) - 1)
114.     GetStateFromZipCode = state
115. END FUNCTION
116.  
117. FUNCTION GetLocationVIAip$
118.     DIM URL AS STRING
119.     DIM URLFile AS STRING
120.     DIM location AS STRING
121.     DIM a%
122.     URLFile = "location"
123.     URL = "https://geo.ipify.org/api/v1?apiKey=YOURAPIKEYHERE&ipAddress=" + GetPublicIP
124.     a% = API_request(URL, URLFile)
125.     DIM U AS INTEGER
126.     U = FREEFILE
127.     OPEN URLFile FOR BINARY AS #U
128.     IF LOF(U) <> 0 THEN
129.         location = SPACE$(LOF(U))
130.         GET #U, , location
131.     ELSE
132.         CLOSE #U
133.         KILL URLFile
134.         GetLocationVIAip = ""
135.         EXIT FUNCTION
136.     END IF
137.     CLOSE #U
138.     KILL URLFile
139.     location = MID$(location, INSTR(location, "postalCode") + 13)
140.     location = LEFT$(location, INSTR(location, CHR$(34)) - 1)
141.     GetLocationVIAip = location
142. END FUNCTION
143.  
144. FUNCTION GetPublicIP$
145.     DIM URL AS STRING
146.     DIM URLFile AS STRING
147.     DIM publicip AS STRING
148.     DIM a%
149.     URLFile = "publicip"
150.     URL = "https://api.ipify.org/"
151.     a% = API_request(URL, URLFile)
152.     DIM U AS INTEGER
153.     U = FREEFILE
154.     OPEN URLFile FOR BINARY AS #U
155.     IF LOF(U) <> 0 THEN
156.         LINE INPUT #U, publicip
157.     ELSE
158.         CLOSE #U
159.         KILL URLFile
160.         GetPublicIP = ""
161.         EXIT FUNCTION
162.     END IF
163.     CLOSE #U
164.     KILL URLFile
165.     GetPublicIP = publicip
166. END FUNCTION
167.  
168. FUNCTION String.Remove$ (a AS STRING, b AS STRING)
169.     DIM c AS STRING
170.     DIM j
171.     DIM r
172.     DIM r$
173.     c = ""
174.     j = INSTR(a, b)
175.     IF j > 0 THEN
176.         r$ = LEFT$(a, j - 1) + c + String.Remove(RIGHT$(a, LEN(a) - j + 1 - LEN(b)), b)
177.     ELSE
178.         r$ = a
179.     END IF
180.     String.Remove = r$
181. END FUNCTION
182.  
183. FUNCTION String.Replace$ (a AS STRING, b AS STRING, c AS STRING)
184.     DIM j
185.     DIM r$
186.     j = INSTR(a, b)
187.     IF j > 0 THEN
188.         r$ = LEFT$(a, j - 1) + c + String.Replace(RIGHT$(a, LEN(a) - j + 1 - LEN(b)), b, c)
189.     ELSE
190.         r$ = a
191.     END IF
192.     String.Replace = r$
193. END FUNCTION
194.  
195. DECLARE DYNAMIC LIBRARY "urlmon"
196.     FUNCTION URLDownloadToFileA (BYVAL pCaller AS LONG, szURL AS STRING, szFileName AS STRING, BYVAL dwReserved AS LONG, BYVAL lpfnCB AS LONG)
197. END DECLARE
198.  
199. FUNCTION API_request (URL AS STRING, File AS STRING)
200.     API_request = URLDownloadToFileA(0, URL + CHR$(0), File + CHR$(0), 0, 0)
201. END FUNCTION
202.  
203. DECLARE LIBRARY
204.     FUNCTION WinExec (lpCmdLine AS STRING, BYVAL nCmdShow AS LONG)
205. END DECLARE
206.  
207. SUB eSpeak (lines AS STRING)
208.     DIM Filename AS STRING
209.     DIM x
210.     Filename = "espeak.exe -v en " + CHR$(34) + lines$ + CHR$(34)
211.     x = WinExec(Filename$ + CHR$(0), 0)
212. END SUB
213.  
214. SUB TTS (lines AS STRING)
215.     DIM x
216.     x = WinExec("voice -r 2 -d " + lines + CHR$(0), 0)
217. END SUB
218.  
219. FUNCTION FormatForTTS$ (lines AS STRING)
220.     IF INSTR(lines, "OVERNIGHT") THEN
221.         lines = MID$(lines, INSTR(lines, "OVERNIGHT"))
222.     ELSEIF INSTR(lines, "TODAY") THEN
223.         lines = MID$(lines, INSTR(lines, "TODAY"))
224.     ELSEIF INSTR(lines, "TONIGHT") AND INSTR(lines, "TODAY") = 0 THEN
225.         lines = MID$(lines, INSTR(lines, "TONIGHT"))
226.     END IF
227.     lines = String.Remove(lines, CHR$(10))
228.     lines = String.Replace(lines, "wind", "wend")
229.     lines = String.Replace(lines, "mph", "miles per hour")
230.     lines = String.Replace(lines, "thunderstorms", "thunnderstorms")
231.     FormatForTTS = lines
232. END FUNCTION