PLAY string$ visualizer

[FellippeHeitor]

I mentioned in another thread that I'd written this program but it was lost. I now found it in Pete's forum (dated October 2017): https://www.tapatalk.com/groups/qbasic/viewtopic.php?p=211344#p211344

Here's a copy of the original post I made there:
Hey there,

I'm writing a music visualizer for PLAY string commands. It's still in its infancy, but right now it does the following:

* Parse a string for PLAY commands.
* Draw the notes on screen accordingly, similar to midi sequencing programs out there.
* Mouse wheel (or up/down arrows) can be used to change zoom factor.
* Left/right arrow keys can be used to navigate the rendered "song"
* Click (or spacebar) to play the song.

I have some more plans for this, but for now it's just for fun, really. Hope you guys enjoy it.

I have included some sample songs and sound bits in there. Credit is in the code. Just uncomment the song line you want to visualize/hear.

Code: QB64: [Select]

1. '--------------------------------------------------------------------
2. SCREEN _NEWIMAGE(800, 620, 32)
3. _TITLE "PLAY string$ visualizer"
4. 'lovestory comes from an old lost .net post
5. 'gorilla and gorilla2 come from programs/samples/misc/gor64.bas
6. 'happynewyear, frosty and galleonschord come from the wiki
7.  
8.  
9. REM Uncomment the lines of "PLAY string" below you want to visualize:
10. gorilla: playString$ = "MBT160O1L8CDEDCDL4ECC"
11. 'gorilla2: playString$ = "MF t120o1l16b9n0baan0bn0bn0baaan0b9n0baan0b o2l16e-9n0e-d-d-n0e-n0e-n0e-d-d-d-n0e-9n0e-d-d-n0e- o2l16g-9n0g-een0g-n0g-n0g-eeen0g-9n0g-een0g- o2l16b9n0baan0g-n0g-n0g-eeen0o1b9n0baan0b T160O0L32EFGEFDC T160O0L32EFGEFDC T160O0L32EFGEFDC T160O0L32EFGEFDC"
12. 'galleonschord: playString$ = "v10l1c,l4egl2o5c,o4l4eg"
13. 'frosty: playString$ = "t140o2p4g2e4.f8g4o3c2o2b8o3c8d4c4o2b4a8g2. o2b8o3c8d4c4o2b4a8a8g8o3c4o2e8e4g8a8g4f4e4f4g2. g2e4.f8g4o3c2o2b8o3c8d4c4o2b4a8g2. o2b8o3c8d4c4o2b4a8a8g8o3c4o2e8e4g8a8g4f4e4d4c2. c4a4a4o3c4c4o2b4a4g4e4f4a4g4f4e2. e8e8d4d4g4g4b4b4o3d4d8o2b8o3d4c4o2b4a4g4p4 g2g2e4.f8g4o3c2o2b8o3c8d4c4o2b4a8g8g2. o2b8o3c8d4c4o2b4a8a8g8o3c4o2e8e4g8a8g4f4e4d4c2.p4 t180g8g8g4g4g4a8g8g4g4g4a4g4e4g4d1 t180g8g8g4g4g4a8g8g4g4g4g8g8g4a4b4o3c2c4p1"
14. 'lovestory: playString$ = "O2 L8 B- D D B- ML L2 B- L8 B- MN D D B- B- D E- D C C C A ML L2 A L8 A MN C C A A C D C < B- B- B- > G L2 G P8 L8 < B- B- > G G < B- > C < B- A A A > F# ML L2 F# L4 F# MN G A F# ML L2 D D MN P1 L8 B- D D B- ML L2 B- L8 B- MN D D B- B- D E- D C C C A ML L2 A L8 A MN C C A A C D C < B- B- B- > G L2 G P8 L8 < B- B- > G G < B- > C < B- A A A > F# ML L2 F# L4 F# MN G A F# ML L1 B L4 B MN > C D < G > L2 ML E- L8 E- MN < L8 G B- G G A ML L4 A L8 A MN > C E- C ML L2 D L8 D MN < F > D < F F G ML L4 G L8 G MN B- > D < B- > ML L2 C L8 C MN < A > C < A L4 B- L8 B- > D < G B- > D ML L2 E- L8 E- MN < G G B- L4 B- ML A L2 A MN L8 B- > C < E- ML L2 D L8 D MN D E F# L4 A ML L4 G L8 G MN G L8 F# E D ML L2 C# L8 C# MN L8 E G E ML L2 F# F# MN P1 L8 B- D D B- ML L2 B- L8 B- MN D D B- B- D E- D C C C A ML L2 A L8 A MN C C A A C D C < B- B- B- > G L2 G P8 L8 < B- B- > G G < B- > C < B- A A A > F# ML L2 F# L4 F# MN G A F# ML L2 G G MN P1"
15. 'happynewyear: playString$ = " o3 l4 t 0120c ml<f1 ,a 1, >c 1, mnf .e 8f am l< e1 ,g 1, >c 1, mn g. f8 ga 8g 8m l< f2.,a2., >c 2. ,m nf .f 8a ml<f ,a,>c,mn >cd2.,<f2 .,d2 .,<b -2 .m lb -,>d,f,mn>d ml <c 1, <a 1, f1 ,m n> >c .< a8 af ml c1 ,< e1 ,g 1,m n> g.f8ga8g8m l< f1 ,d1, <b -1 ,m n> >f .d 8d c< f2 ., a2 ., c2 .,>f2. ml < b- ,> d, f, mn>dml <c 1,< a1 ,f 1, mn >> c. <a 8a fm lc 2.,< e2 .,g2 .,mn >g .f8 gml<b-,>d, f, mn >d ml <<f2.,a2., > c2.,m n> c.<a 8a ml <e, g, >c ,m n>cm l< <b -2 ., >d 2. ,f 2.,mn> d2.ml< <b -, >d ,f ,m n>dm l<<f1, a1,>c1,mn >c.<a 8a fmlc 1, <e1,g1,mn>g .f 8g a8 g8ml << b- 1, >d 1, f1 ,mn>f.d8dc l1 ml f, c, <a ,f"
16.  
17.  
18. DIM i AS INTEGER
19. DIM SHARED noteHeight AS INTEGER
20. DIM SHARED octave AS SINGLE, noteLength AS SINGLE, length AS SINGLE
21. DIM SHARED tempo AS SINGLE, note AS SINGLE, volume AS SINGLE
22. DIM SHARED pause AS SINGLE, pauseBetween AS SINGLE, theresMore AS _BYTE
23. DIM SHARED x AS INTEGER, zoom AS INTEGER
24.  
25. 'defaults:
26. octave = 4
27. tempo = 120
28. pauseBetween = 1
29. volume = 50
30. length = 4
31.  
32. noteHeight = 7
33. zoom = 20
34. maxZoom = 50
35. reDraw:
36. playString$ = FormatPlayString$(playString$)
37. i = 1
38. x = 1 + leftOffset
39. _DISPLAY
40. CLS
41. DrawGrid
42. DO
43.     IF i > LEN(playString$) THEN EXIT DO
44.     SELECT CASE LCASE$(MID$(playString$, i, 1))
45.         CASE "c", "d", "e", "f", "g", "a", "b"
46.             note = FindNote(LCASE$(MID$(playString$, i, 1)))
47.             noteLength = length
48.             SELECT CASE LCASE$(MID$(playString$, i + 1, 1))
49.                 CASE "+", "#"
50.                     note = note + 1
51.                 CASE "-"
52.                     note = note - 1
53.                 CASE "."
54.                     IF MID$(playString$, i + 2, 1) = "." THEN
55.                         i = i + 1
56.                         noteLength = noteLength + (3 / 4)
57.                     ELSE
58.                         noteLength = noteLength + (1 / 2)
59.                     END IF
60.                 CASE "0" TO "9"
61.                     noteLength = GetNumber(playString$, i)
62.                     SELECT CASE LCASE$(MID$(playString$, i + 1, 1))
63.                         CASE "."
64.                             i = i + 1
65.                             IF LCASE$(MID$(playString$, i + 1, 1)) = "." THEN
66.                                 i = i + 1
67.                                 noteLength = noteLength + (3 / 4)
68.                             ELSE
69.                                 noteLength = noteLength + (1 / 2)
70.                             END IF
71.                     END SELECT
72.             END SELECT
73.             SELECT CASE LCASE$(MID$(playString$, i + 1, 1))
74.                 CASE ","
75.                     theresMore = -1
76.                     i = i + 1
77.             END SELECT
78.             DrawNote
79.             'IF NOT theresMore THEN
80.             ' playstring$ = LEFT$(playstring$, i + 1) + " " + MID$(playstring$, i + 2)
81.             ' i = i + 1
82.             'END IF
83.             theresMore = 0
84.         CASE "m"
85.             SELECT CASE LCASE$(MID$(playString$, i + 1, 1))
86.                 CASE "s"
87.                     'staccato
88.                     pauseBetween = 2
89.                     i = i + 1
90.                 CASE "n"
91.                     'normal
92.                     pauseBetween = 1
93.                     i = i + 1
94.                 CASE "l"
95.                     'legato
96.                     pauseBetween = 0
97.                     i = i + 1
98.                 CASE "f"
99.                     'foreground play
100.                     i = i + 1
101.                 CASE "b"
102.                     'background play
103.                     i = i + 1
104.             END SELECT
105.         CASE "o"
106.             octave = GetNumber(playString$, i)
107.         CASE ">"
108.             octave = octave + 1
109.         CASE "<"
110.             octave = octave - 1
111.         CASE "t"
112.             tempo = GetNumber(playString$, i)
113.         CASE "n"
114.             note = GetNumber(playString$, i)
115.             DrawNote
116.         CASE "p"
117.             pause = GetNumber(playString$, i)
118.             noteLength = -pause
119.             IF noteLength = 0 THEN noteLength = -length
120.             'playstring$ = LEFT$(playstring$, i) + " " + MID$(playstring$, i + 1)
121.             'i = i + 1
122.             DrawNote
123.         CASE "l"
124.             length = GetNumber(playString$, i)
125.         CASE "v"
126.             volume = GetNumber(playString$, i)
127.     END SELECT
128.     i = i + 1
129. LOOP
130. maxDrawnLength = x - leftOffset
131. LINE (0, 84 * noteHeight + 1)-STEP(_WIDTH - 1, 10), _RGB32(255, 255, 255), B
132. _FONT 8
133. COLOR _RGB32(233, 211, 94)
134. _PRINTSTRING (0, _HEIGHT - _FONTHEIGHT * 1.5), "mousewheel (or up/down arrows) to change zoom factor; left/right arrows to scroll; click to play;"
135. _AUTODISPLAY
136.  
137. prevZoom = zoom
138. DO
139.     WHILE _MOUSEINPUT: zoom = zoom + _MOUSEWHEEL: WEND
140.     IF zoom < 1 THEN zoom = 1
141.     IF zoom > maxZoom THEN zoom = maxZoom
142.     IF zoom <> prevZoom THEN prevZoom = zoom: GOTO reDraw
143.  
144.     IF _MOUSEBUTTON(1) THEN
145.         PLAY "MB" + playString$
146.         WHILE _MOUSEBUTTON(1): i = _MOUSEINPUT: WEND
147.     END IF
148.  
149.     k = _KEYHIT
150.     SELECT CASE k
151.         CASE 32
152.             PLAY "MB" + playString$
153.             DO: k = _KEYHIT: LOOP UNTIL k = -32
154.         CASE 19712 'right
155.             leftOffset = leftOffset - 50
156.             IF leftOffset < _WIDTH - maxDrawnLength THEN leftOffset = _WIDTH - maxDrawnLength
157.             GOTO reDraw
158.         CASE 19200 'left
159.             leftOffset = leftOffset + 50
160.             IF leftOffset > 0 THEN leftOffset = 0
161.             GOTO reDraw
162.         CASE 18432 'up
163.             IF zoom < maxZoom THEN zoom = zoom + 1
164.         CASE 20480 'down
165.             IF zoom > 1 THEN zoom = zoom - 1
166.     END SELECT
167. LOOP
168.  
169. FUNCTION GetNumber# (text$, position%)
170.     DO
171.         position% = position% + 1
172.         IF position% > LEN(text$) THEN EXIT DO
173.         IF ASC(text$, position%) < 48 OR ASC(text$, position%) > 57 THEN position% = position% - 1: EXIT DO
174.         tempNum$ = tempNum$ + MID$(text$, position%, 1)
175.     LOOP
176.     GetNumber# = VAL(tempNum$)
177. END FUNCTION
178.  
179. SUB DrawGrid
180.     LINE (0, 0)-(_WIDTH - 1, 84 * noteHeight), _RGB32(28, 28, 28), BF
181.     FOR i = 0 TO 83
182.         LINE (0, i * noteHeight)-STEP(_WIDTH - 1, noteHeight), _RGB32(44, 44, 44), B
183.     NEXT
184. END SUB
185.  
186. SUB DrawNote
187.     i = 83 - note
188.     IF noteLength < 0 THEN m = -1 ELSE m = 1
189.     nl = (zoom * zoom) / (noteLength * m)
190.     IF m > 0 THEN
191.         LINE (x, i * noteHeight + 1)-STEP(nl, noteHeight - 2), _RGB32(100, 172, 100), BF
192.         LINE (x, i * noteHeight + 1)-STEP(nl, noteHeight - 2), _RGB32(11, 17, 11), B
193.         IF theresMore THEN EXIT SUB
194.     END IF
195.     x = x + nl + pauseBetween * zoom
196. END SUB
197.  
198. FUNCTION FindNote (__n$)
199.     n$ = LCASE$(__n$)
200.     o% = 33 + (octave - 2) * 12 - 9
201.     SELECT CASE n$
202.         CASE "c"
203.             FindNote = 0 + o%
204.         CASE "d"
205.             FindNote = 2 + o%
206.         CASE "e"
207.             FindNote = 4 + o%
208.         CASE "f"
209.             FindNote = 5 + o%
210.         CASE "g"
211.             FindNote = 7 + o%
212.         CASE "a"
213.             FindNote = 9 + o%
214.         CASE "b"
215.             FindNote = 11 + o%
216.     END SELECT
217. END FUNCTION
218.  
219. FUNCTION FormatPlayString$ (__s$)
220.     s$ = __s$
221.     FOR i = 1 TO LEN(s$)
222.         IF ASC(s$, i) <> 32 THEN n$ = n$ + MID$(s$, i, 1)
223.     NEXT
224.  
225.     'remove MF and MB, and convert N0 to P
226.     s$ = ""
227.     FOR i = 1 TO LEN(n$)
228.         IF LCASE$(MID$(n$, i, 2)) = "mf" OR LCASE$(MID$(n$, i, 2)) = "mb" THEN i = i + 1: _CONTINUE
229.         IF LCASE$(MID$(n$, i, 2)) = "n0" THEN i = i + 1: s$ = s$ + "p": _CONTINUE
230.         s$ = s$ + MID$(n$, i, 1)
231.     NEXT
232.  
233.     FormatPlayString$ = s$
234. END FUNCTION
235. '--------------------------------------------------------------------