HOW do i sample (not play) audio?

[Parkland]

It works in windows, I'll try the linux sfml library. Didn't even consider that being an issue. I'm not the sharpest board in the metal shop.

Is there a way to live sample mic ? Or do you have to record samples then analyze data from the recorded sample?

[Parkland]

I tried to use this program to load the buffer and keep displaying it live, seems like the waveform does'nt match up though so I'm probably doing it wrong

[Petr]

Hi. Try this:

Code: QB64: [Select]

1. DECLARE LIBRARY "SFML_Audio_Wrapper", "sfml\libsfml-audio"
2.     SUB Mic_Start (BYVAL SampleRate&)
3.     SUB Mic_End
4.     SUB Mic_Play
5.     SUB Mic_Pause
6.     SUB Mic_Stop
7.     SUB Mic_Save (Filename$)
8.     FUNCTION Mic_Get_SampleCount&
9.     FUNCTION Mic_Get_Sample% (BYVAL SampleNum&)
10.     FUNCTION Sound_Load (FileName$)
11.     FUNCTION Sound_Num_Samples
12.     FUNCTION Sound_Get_Sample% (BYVAL SampleNum&)
13.     SUB SNDRAW_Save (RawSnd%, BYVAL NumSamples&, BYVAL SampleRate&, BYVAL Channels&, FileName$)
14.     FUNCTION Sound_Num_Channels&
15. END DECLARE
16.  
17. SCREEN _NEWIMAGE(800, 600, 256)
18.  
19. '// Record 5 seconds of audio @ 36000 samples per second
20. Mic_Start 44100
21. _DELAY 5
22.  
23. '// End the recording
24. Mic_End
25.  
26. '// Play the mic sound directly
27. Mic_Play
28. _DELAY 5
29. 'after this delay is record size: 44100 (microphone sample rate) * 5 seconds
30.  
31.  
32.  
33.  
34.  
35. '// Load the samples into an array
36. '// This is if you want to analyse the sound in anyway or distort it or something
37. NumSamples& = Mic_Get_SampleCount& - 1
38. DIM Sample(NumSamples&) AS INTEGER
39. FOR I& = 0 TO NumSamples&
40.     Sample(I&) = Mic_Get_Sample(I&)
41. NEXT
42.  
43.  
44. '// Play the samples stored in the array using sndraw - i dont now what you need to / or * the value by to get accurate
45. '// playback from sndraw
46.  
47. TYPE SND
48.     left AS SINGLE
49.     right AS SINGLE
50. END TYPE
51. size = NumSamples&
52. DIM S(size) AS SND
53.  
54.  
55.  
56. FOR I& = 0 TO NumSamples& - 1 STEP 2
57.     _SNDRAW Sample(I&) / 65535, Sample(I& + 1) / 65535
58.     S(j).left = Sample(I&) / 65535
59.     S(j).right = Sample(I& + 1) / 65535
60.     j = j + 1
61.  
62.     X = X + 1: IF X > _WIDTH THEN CLS: X = 1
63.     OYl = Yl
64.     Yl = 200 + S(j&).left * 200
65.     OYr = Yr
66.     Yr = 400 + S(j&).right * 200
67.     LINE (X - 1, OYl)-(X, Yl)
68.     LINE (X - 1, OYr)-(X, Yr)
69.  
70.     DO WHILE _SNDRAWLEN > 0: LOOP
71.     j& = j& + 1
72. NEXT
73.  
74. SAVESOUND16S S(), "next_test.wav"
75.  
76.  
77.  
78. REM Mic_Save ("microphone.wav")
79.  
80. SUB SAVESOUND16S (arr() AS SND, file AS STRING)
81. TYPE head16
82.     chunk AS STRING * 4 '       4 bytes  (RIFF)
83.     size AS LONG '              4 bytes  (file size)
84.     fomat AS STRING * 4 '       4 bytes  (WAVE)
85.     sub1 AS STRING * 4 '        4 bytes  (fmt )
86.     subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
87.     format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
88.     channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
89.     rate AS LONG '              4 bytes  (sample rate, standard is 44100)
90.     ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
91.     Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
92.     Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
93.     subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
94.     lenght AS LONG '            4 bytes  Data block size
95. END TYPE '                     44 bytes  total
96. DIM H16 AS head16
97. ch = FREEFILE
98.  
99. H16.chunk = "RIFF"
100. H16.size = 44 + UBOUND(arr) * 4 'two channels, it create 16 bit, stereo wav file, one sample use 2 bytes to one channel
101.  
102. H16.fomat = "WAVE"
103. H16.sub1 = "fmt "
104. H16.subchunksize = 16
105. H16.format = 1
106. H16.channels = 2
107. H16.rate = 44100
108. H16.ByteRate = 44100 * 2 * 16 / 8
109. H16.Block = 4
110. H16.Bits = 16
111. H16.subchunk2 = "data"
112. H16.lenght = UBOUND(arr) * 4
113. IF _FILEEXISTS(file$) THEN KILL file$
114.  
115. OPEN file$ FOR BINARY AS #ch
116. PUT #ch, , H16
117. DIM LeftChannel AS INTEGER, RightChannel AS INTEGER
118.  
119. FOR audiodata = 0 TO UBOUND(arr)
120.     LeftChannel = arr(audiodata).left * 32768
121.     RightChannel = arr(audiodata).right * 32768
122.  
123.     PUT #ch, , LeftChannel
124.     PUT #ch, , RightChannel
125. NEXT
126. CLOSE ch
127. END SUB
128.  

There are several ways to proceed: Do you want a program that allows you to move left - right to view the painted curve, or, a simpler program - to make a BMP output file that will have a resolution (for example) of 50000 * 600 and will contain the resulting curves?

[MB]

Parkland,

When I do this code (running under 32-bit windows):

   Mic_Start 22000
   _DELAY 2
   Mic_End

I collect 33673 samples, my first 10515 samples are all zeros. samples 10516 through 44188 have data.

Every time I sample my hardware lags for around 10k samples when using the 22000 sample rate.

Do a simpler test of just running this codet:

   Mic_Start 22000
   _DELAY 5
   Mic_End
   Mic_Save ("test.raw") ' change .raw to a format you use on your platform.

just as a sanity check to see how much lag/(if any) you have before data begins to accumulate.

- MB

[Unseen Machine]

Is there a way to live sample mic ? Or do you have to record samples then analyze data from the recorded sample?

There is (well almost) but this library doesnt support it. I know that in SFML 2.5 you can get samples back whilst a mic is still recording and i think i remember every 100mili seconds or something. I'll have a look into it and see if i can put something together in the next day or so.

As for the rest of the questions...i got no idea i wrote the wrapper the best part of a decade ago and have never used it since, i look forward to seeing what you guys make with it...

Unseen

[MB]

Parkland,

This is the code I used to see the leading dead space, file "rec2sav.bas" attached.

Code just tells you amount of samples where about the empty buffer ends and the noise floor begins. Then the total samples.


Unseen, I love that you made this wrapper... as I only need to record samples and analyze data, this is a neat tool in my books!

- MB

[Parkland]

I don't know how well this approach works, but it may do what I need. (see attached file)  [ You are not allowed to view this attachment ]  

[Parkland]

By chance does anyone have any idea / experience with what method is used to figure out frequencies?
Possibly similar to FFT?

I tried measuring every time the wave crosses 0, but that only works for the loudest frequency.
I tried measuring every peak and valley, but that only works for the smallest frequency.

Wondering what process would normally be employed if you want to know strengths of certain frequencies in the sound.

[MB]

By chance does anyone have any idea / experience with what method is used to figure out frequencies?
Possibly similar to FFT?

I tried measuring every time the wave crosses 0, but that only works for the loudest frequency.
I tried measuring every peak and valley, but that only works for the smallest frequency.

Wondering what process would normally be employed if you want to know strengths of certain frequencies in the sound.

Crossing zero only works well with a single cycle style of waveform. 

I have been porting over some of my own code that I made in C for one of my "Teensy 4.0" microprocessor into QB64; however, it is far from being ready to share as is it implements the Laplace Transform.

QB64 user "_vince" made a real nice clean sample of a fast algorithm for computing the DFT for N=2^k in QB64. He also list a optimization for real only input FFT in the same thread, take a look at his post in this link:

https://www.qb64.org/forum/index.php?topic=1938.msg111661;topicseen#msg111661

-MB

[_vince]

I've revised that FFT post to address some of this interest, particularly the last example

Code: QB64: [Select]

1. 'defdbl a-z
2.  
3. const sw = 1024
4. const sh = 600
5.  
6. dim shared pi as double
7. 'pi = 2*asin(1)
8. pi = 4*atn(1)
9.  
10. declare sub rfft(xx_r(), xx_i(), x_r(), n)
11. declare sub fft(xx_r(), xx_i(), x_r(), x_i(), n)
12. declare sub dft(xx_r(), xx_i(), x_r(), x_i(), n)
13.  
14.  
15. dim x_r(sw-1), x_i(sw-1)
16. dim xx_r(sw-1), xx_i(sw-1)
17. dim t as double
18.  
19. for i=0 to sw-1
20.         x_r(i) = 100*sin(2*pi*(sw*2000/44000)*i/sw) + (100*rnd - 50)
21. next
22.  
23.  
24. 'screenres sw, sh, 32
25. screen _newimage(sw, sh, 32)
26.  
27. 'plot signal
28. pset (0, sh/4 - x_r(0))
29. for i=0 to sw-1
30.         line -(i, sh/4 - x_r(i)), _rgb(255,0,0)
31. next
32. line (0, sh/4)-step(sw,0), _rgb(255,0,0),,&h5555
33.  
34. _printstring (0, 0), "2000 kHz signal with RND noise sampled at 44 kHz in 1024 samples"
35.  
36.  
37. rfft xx_r(), xx_i(), x_r(), sw
38.  
39. 'plot its fft
40. pset (0, 50+3*sh/4 - 0.005*sqr(xx_r(0)*xx_r(0) + xx_i(0)*xx_i(0)) ), _rgb(255,255,0)
41. for i=0 to sw/2
42.         line -(i*2, 50+3*sh/4 - 0.005*sqr(xx_r(i)*xx_r(i) + xx_i(i)*xx_i(i)) ), _rgb(255,255,0)
43. next
44. line (0, 50+3*sh/4)-step(sw,0), _rgb(255,255,0),,&h5555
45.  
46.  
47. 'find peak
48. dim max as double, d as double
49. max = 0
50. m = 0
51. for i=0 to sw/2
52.         d = 0.01*sqr(xx_r(i)*xx_r(i) + xx_i(i)*xx_i(i))
53.         if d > max then
54.                 max = d
55.                 m = i
56.         end if
57. next
58.  
59. _printstring (0, sh/2), "m_peak ="+str$(m)
60. _printstring (0, sh/2 + 16), "f_peak = m_peak * 44 kHz / 1024 samples = "+str$(m*44000/1024)+" Hz"
61.  
62. 'apply frequency correction, only works for some signals
63. dim c as double
64. dim u_r as double, u_i as double
65. dim v_r as double, v_i as double
66.  
67. u_r = xx_r(m - 1) - xx_r(m + 1)
68. u_i = xx_i(m - 1) - xx_i(m + 1)
69. v_r = 2*xx_r(m) - xx_r(m - 1) - xx_r(m + 1)
70. v_i = 2*xx_i(m) - xx_i(m - 1) - xx_i(m + 1)
71. c = (u_r*v_r + u_i*v_i)/(v_r*v_r + v_i*v_i)
72.  
73. _printstring (0, sh/2 + 2*16), "f_corrected = "+str$((m+c)*44000/1024)+" Hz"
74.  
75. sleep
76. system
77.  
78.  
79. sub rfft(xx_r(), xx_i(), x_r(), n)
80.         dim w_r as double, w_i as double, wm_r as double, wm_i as double
81.         dim u_r as double, u_i as double, v_r as double, v_i as double
82.  
83.         log2n = log(n/2)/log(2)
84.  
85.         for i=0 to n/2 - 1
86.                 rev = 0
87.                 for j=0 to log2n - 1
88.                         if i and (2^j) then rev = rev + (2^(log2n - 1 - j))
89.                 next
90.  
91.                 xx_r(i) = x_r(2*rev)
92.                 xx_i(i) = x_r(2*rev + 1)
93.         next
94.  
95.         for i=1 to log2n
96.                 m = 2^i
97.                 wm_r = cos(-2*pi/m)
98.                 wm_i = sin(-2*pi/m)
99.  
100.                 for j=0 to n/2 - 1 step m
101.                         w_r = 1
102.                         w_i = 0
103.  
104.                         for k=0 to m/2 - 1
105.                                 p = j + k
106.                                 q = p + (m \ 2)
107.  
108.                                 u_r = w_r*xx_r(q) - w_i*xx_i(q)
109.                                 u_i = w_r*xx_i(q) + w_i*xx_r(q)
110.                                 v_r = xx_r(p)
111.                                 v_i = xx_i(p)
112.  
113.                                 xx_r(p) = v_r + u_r
114.                                 xx_i(p) = v_i + u_i
115.                                 xx_r(q) = v_r - u_r
116.                                 xx_i(q) = v_i - u_i
117.  
118.                                 u_r = w_r
119.                                 u_i = w_i
120.                                 w_r = u_r*wm_r - u_i*wm_i
121.                                 w_i = u_r*wm_i + u_i*wm_r
122.                         next
123.                 next
124.         next
125.  
126.         xx_r(n/2) = xx_r(0)
127.         xx_i(n/2) = xx_i(0)
128.  
129.         for i=1 to n/2 - 1
130.                 xx_r(n/2 + i) = xx_r(n/2 - i)
131.                 xx_i(n/2 + i) = xx_i(n/2 - i)
132.         next
133.  
134.         dim xpr as double, xpi as double
135.         dim xmr as double, xmi as double
136.  
137.         for i=0 to n/2 - 1
138.                 xpr = (xx_r(i) + xx_r(n/2 + i)) / 2
139.                 xpi = (xx_i(i) + xx_i(n/2 + i)) / 2
140.  
141.                 xmr = (xx_r(i) - xx_r(n/2 + i)) / 2
142.                 xmi = (xx_i(i) - xx_i(n/2 + i)) / 2
143.  
144.                 xx_r(i) = xpr + xpi*cos(2*pi*i/n) - xmr*sin(2*pi*i/n)
145.                 xx_i(i) = xmi - xpi*sin(2*pi*i/n) - xmr*cos(2*pi*i/n)
146.         next
147.  
148.         'symmetry, complex conj
149.         for i=0 to n/2 - 1
150.                 xx_r(n/2 + i) = xx_r(n/2 - 1 - i)
151.                 xx_i(n/2 + i) =-xx_i(n/2 - 1 - i)
152.         next
153. end sub
154.  

[Parkland]

Wow! very awesome.
Thanks everyone.

Also attached is the most recent version of what I glued together for live sampling