Air Hockey

[bplus]

Beats Pong, you can control where you hit the puck if you are fast and accurate enough.

Code: QB64: [Select]

1. 'Air hockey 2.bas for QB64 fork (B+=MGA) 2017-09-05  (started)
2. ' the first version was a direct translation from SmallBASIC
3. ' now add some more graphic image handling, try new things
4.  
5. RANDOMIZE TIMER
6.  
7. CONST xmax = 1200
8. CONST ymax = 700
9.  
10. SCREEN _NEWIMAGE(xmax, ymax, 32)
11. _TITLE "Air Hockey by bplus"
12. _SCREENMOVE 100, 20
13.  
14. CONST pr = 16 'puck radius
15. CONST pr2 = 2 * pr 'puck diameter = bumper width = radius of strikers
16. CONST tl = xmax 'table length
17. CONST tw = tl / 2 'table width
18. CONST tw13 = .3333 * tw \ 1 'goal end point
19. CONST tw23 = .6667 * tw \ 1 'goal end point
20. CONST speed = 30 'puck speed also see _limit in main loop
21. CONST midC = 316 '(tl - 2 * pr2) \ 4 + pr2   'mid line of computer's sin field
22. CONST rangeC = 252 ' 316 - 252 = 64 (bumper + pr2)  316 + 252 = 568 (mid screen - pr2)
23.  
24. COMMON SHARED computer, player, px, py, pa, psx, psy, c1, csx, csy, strkr&
25.  
26. f& = _LOADFONT("C:\Windows\Fonts\arial.ttf", 25) 'normal style
27. _FONT f&
28.  
29. table& = _NEWIMAGE(xmax, tw, 32)
30. _DEST table&
31. drawTable
32. strkr& = _NEWIMAGE(2 * pr2, 2 * pr2, 32)
33. _DEST strkr&
34. striker pr2, pr2
35. _DEST 0
36. cp 7, "Air Hockey, first to score 21 goals wins!"
37. cp 9, "Player you will be defending the goal on the right (a black slot)."
38. cp 10, "Your goal is on the left, defended by the computer."
39. cp 12, "Press any when ready..."
40. SLEEP
41. _DELAY 1
42. computer = 0 'score
43. player = 0 'score
44. initball
45. WHILE player < 21 AND computer < 21
46.     CLS
47.     updateScore
48.     _PUTIMAGE (0, 0), table&, 0
49.     drawComputerStriker
50.     DO WHILE _MOUSEINPUT
51.         psx = _MOUSEX
52.         psy = _MOUSEY
53.     LOOP
54.     drawPlayerStriker
55.     drawPuck
56.     _DISPLAY
57.     _LIMIT 20 'slow down, speeed up as needed for good game
58. WEND
59.  
60. IF computer > player THEN
61.     s$ = "Game Won by Computer."
62.     tx = 450
63. ELSE
64.     s$ = "Game Won by Player!"
65.     tx = 470
66. END IF
67. COLOR _RGB(200, 240, 140)
68. _PRINTSTRING (tx, tw + 30), s$
69. _DISPLAY
70. _DELAY 3
71.  
72. SUB initball
73.     px = tl / 2: py = tw / 2: pa = _PI(1) + RND * _PI(.1)
74.     rnddir = (RND * 2) \ 1: IF rnddir THEN pa = _PI(1) - pa
75. END SUB
76.  
77. SUB updateScore
78.     COLOR _RGB(40, 255, 255)
79.     s$ = "Computer: " + STR$(computer) + SPACE$(67) + "Player: " + STR$(player)
80.     _PRINTSTRING (200, tw + 30), s$
81. END SUB
82.  
83. SUB drawTable
84.     FOR i = 0 TO pr2 STEP 4
85.         shade = 64 + i / pr2 * 100
86.         COLOR _RGB(shade, shade, shade)
87.         LINE (i, i)-(tl - i, tw - i), , BF
88.     NEXT
89.     LINE (pr2, pr2)-(tl - pr2, tw - pr2), _RGB(190, 230, 255), BF 'field
90.     LINE (pr, tw13)-(pr2, tw23), _RGB(60, 60, 60), BF
91.     LINE (tl - pr2, tw13)-(tl - pr, tw23), _RGB(60, 60, 60), BF
92.     LINE (tl \ 2 - 1, pr2)-(tl \ 2 + 1, tw - pr2), _RGB(128, 128, 128), BF
93. END SUB
94.  
95. SUB drawPlayerStriker
96.     IF psx - pr2 < tl / 2 THEN psx = tl / 2 + pr2
97.     IF psx + pr2 > tl - pr2 THEN psx = tl - 2 * pr2
98.     IF psy - pr2 < pr2 THEN psy = 2 * pr2
99.     IF psy + pr2 > tw - pr2 THEN psy = tw - 2 * pr2
100.     _PUTIMAGE (psx - pr2, psy - pr2), strkr&, 0
101. END SUB
102.  
103. SUB drawComputerStriker
104.     c1 = c1 + _PI(1 / 80)
105.     csx = midC + rangeC * SIN(c1)
106.     IF px > csx THEN csy = py + pr2 * 1.5 * SIN(c1)
107.     IF csy - pr2 < pr2 THEN csy = 2 * pr2
108.     IF csy + pr2 > tw - pr2 THEN csy = tw - 2 * pr2
109.     _PUTIMAGE (csx - pr2, csy - pr2), strkr&, 0
110. END SUB
111.  
112. SUB drawPuck
113.     'update ball x, y and see if hit anything
114.     px = px + speed * COS(pa)
115.     py = py + speed * SIN(pa)
116.  
117.     IF px - pr < pr2 THEN
118.         IF tw13 < py - pr AND py + pr < tw23 THEN
119.             player = player + 1
120.             CLS
121.             updateScore
122.             drawTable
123.             striker csx, csy
124.             striker psx, psy
125.             puck pr, py
126.             FOR i = 0 TO pr STEP 4
127.                 shade = 64 + i / pr2 * 100
128.                 COLOR _RGB(shade, shade, shade)
129.                 LINE (i, t13)-(pr, tw23), , BF
130.             NEXT
131.             snd 1200, 200
132.             snd 2200, 300
133.             _DISPLAY
134.             initball
135.             _DELAY .5
136.             EXIT SUB
137.         ELSE
138.             snd 2600, 8
139.             pa = _PI(1) - pa
140.             px = pr2 + pr
141.         END IF
142.     END IF
143.  
144.     IF px + pr > tl - pr2 THEN
145.         IF tw13 < py - pr AND py + pr < tw23 THEN
146.             computer = computer + 1
147.             CLS
148.             updateScore
149.             drawTable
150.             striker csx, csy
151.             striker psx, psy
152.             puck tl - pr, py
153.             FOR i = 0 TO pr STEP 4
154.                 shade = 64 + i / pr2 * 100
155.                 COLOR _RGB(shade, shade, shade)
156.                 LINE (tl - pr, t13)-(tl - i, tw23), , BF
157.             NEXT
158.             snd 2200, 300
159.             snd 1200, 200
160.             _DISPLAY
161.             initball
162.             _DELAY .5
163.             EXIT SUB
164.         ELSE
165.             snd 2600, 5
166.             pa = _PI(1) - pa
167.             px = tl - pr2 - pr
168.         END IF
169.     END IF
170.  
171.     IF py - pr < pr2 THEN
172.         snd 2600, 8
173.         pa = -pa
174.         py = pr2 + pr
175.     END IF
176.  
177.     IF py + pr > tw - pr2 THEN
178.         snd 2600, 8
179.         pa = -pa
180.         py = tw - pr2 - pr
181.     END IF
182.  
183.     IF SQR((px - psx) ^ 2 + (py - psy) ^ 2) < (pr + pr2) THEN
184.         pa = _ATAN2(py - psy, px - psx)
185.         'boost puck away
186.         px = px + .5 * speed * COS(pa)
187.         py = py + .5 * speed * SIN(pa)
188.         snd 2200, 4
189.     END IF
190.     IF SQR((px - csx) ^ 2 + (py - csy) ^ 2) < (pr + pr2) THEN
191.         pa = _ATAN2(py - csy, px - csx)
192.         'boost puck away
193.         px = px + .5 * speed * COS(pa)
194.         py = py + .5 * speed * SIN(pa)
195.         snd 2200, 4
196.     END IF
197.     puck px, py
198. END SUB
199.  
200. SUB puck (x, y)
201.     COLOR _RGB(90, 90, 90)
202.     fillcirc x, y, pr
203.     COLOR _RGB(190, 100, 0)
204.     fillcirc x, y, pr - 4
205. END SUB
206.  
207. SUB striker (x, y)
208.     FOR i = pr2 TO pr STEP -1
209.         shade = 164 - 90 * SIN(i * _PI(2) / pr)
210.         COLOR _RGB(shade, shade, shade)
211.         fillcirc x, y, i
212.     NEXT
213.     FOR i = pr TO 0 STEP -1
214.         shade = 185 + 70 * (pr - i) / pr
215.         COLOR _RGB(shade, shade, shade)
216.         fillcirc x, y, i
217.     NEXT
218. END SUB
219.  
220. 'Steve McNeil's  copied from his forum   note: Radius is too common a name
221. SUB fillcirc (CX AS LONG, CY AS LONG, R AS LONG)
222.     DIM subRadius AS LONG, RadiusError AS LONG
223.     DIM X AS LONG, Y AS LONG
224.  
225.     subRadius = ABS(R)
226.     RadiusError = -subRadius
227.     X = subRadius
228.     Y = 0
229.  
230.     IF subRadius = 0 THEN PSET (CX, CY): EXIT SUB
231.  
232.     ' Draw the middle span here so we don't draw it twice in the main loop,
233.     ' which would be a problem with blending turned on.
234.     LINE (CX - X, CY)-(CX + X, CY), , BF
235.  
236.     WHILE X > Y
237.         RadiusError = RadiusError + Y * 2 + 1
238.         IF RadiusError >= 0 THEN
239.             IF X <> Y + 1 THEN
240.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), , BF
241.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), , BF
242.             END IF
243.             X = X - 1
244.             RadiusError = RadiusError - X * 2
245.         END IF
246.         Y = Y + 1
247.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), , BF
248.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), , BF
249.     WEND
250. END SUB
251.  
252. SUB snd (frq, dur)
253.     SOUND frq / 2.2, dur * .01
254. END SUB
255.  
256. SUB cp (lineNum, s$)
257.     '1200 pixels / 85 characters = 14.11 pixels/char wide
258.     '700 pixels / 28 lines = 18.42 pixels / char high
259.     x = (xmax - 11 * LEN(s$)) \ 2
260.     y = lineNum * 25
261.     _PRINTSTRING (x, y), s$
262. END SUB
263.  
264.  

 

Feel free to adjust the _LIMIT amount to your skill level.

[bplus]

Improved for 2020:

' 2020-03-11 v2-1 (QB64 v1.4 now) cleanup some code:
' Fix _MOUSEINPUT block too newbie ;)
' Fix flat spots on strikers how long have they been there?
' Increase frames per sec and slow puck speed for less double images.
' Oh that sped up the AI player! Nice.
' Do start shots to the side instead of directly at goal. MUCH BETTER!
' Update opening screen with this info. Now pause the puck at start.
' Ran OPTION _EXPLICIT and found a type-O that has been 0 all this time!

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. 'Air Hockey v2-1.bas for QB64
3. ' Started in QB64 Walter fork version (B+=MGA) 2017-09-05
4. ' The first version was a direct translation from SmallBASIC,
5. ' Now v2.0 add some more graphic image handling, try new things.
6. ' 2020-03-11 v2-1 (QB64 v1.4 now) cleanup some code:
7. ' Fix _MOUSEINPUT block too newbie ;)
8. ' Fix flat spots on strikers how long have they been there?
9. ' Increase frames per sec and slow puck speed for less double images.
10. ' Oh that sped up the AI player! Nice.
11. ' Do start shots to the side instead of directly at goal. MUCH BETTER!
12. ' Update opening screen with this info. Now pause the puck at start.
13. ' Ran OPTION _EXPLICIT and found a type-O that has been 0 all this time!
14.  
15. RANDOMIZE TIMER
16. CONST xmax = 1200, ymax = 700 'screen dimensions
17. SCREEN _NEWIMAGE(xmax, ymax, 32)
18. _TITLE "Air Hockey v2-1 by bplus"
19. _DELAY .25
20. _SCREENMOVE _MIDDLE
21.  
22. CONST pr = 16 '              puck radius
23. CONST pr2 = 2 * pr '         puck diameter = bumper width = radius of strikers
24. CONST tl = xmax '            table length
25. CONST tw = tl / 2 '          table width
26. CONST tw13 = .3333 * tw \ 1 'goal end point
27. CONST tw23 = .6667 * tw \ 1 'goal end point
28. CONST speed = 15 '           puck speed also see _limit in main loop
29. CONST midC = 316 '           (tl - 2 * pr2) \ 4 + pr2   'mid line of computer's sin field
30. CONST rangeC = 252 '         316 - 252 = 64 (bumper + pr2)  316 + 252 = 568 (mid screen - pr2)
31.  
32. COMMON SHARED f&, table&, computer, player, s$, tx, px, py, pa, psx, psy, c1, csx, csy, strkr&
33.  
34. f& = _LOADFONT("C:\Windows\Fonts\arial.ttf", 25) ' arial normal style  if you have windows
35. _FONT f& '                                         arial is pretty common if you don't have Windows
36.  
37. table& = _NEWIMAGE(xmax, tw, 32)
38. _DEST table&
39. drawTable
40.  
41. strkr& = _NEWIMAGE(2 * pr2 + 1, 2 * pr2 + 1, 32) ' more space to avoid right and bottom flat edges
42. _DEST strkr&
43. striker pr2, pr2
44.  
45. _DEST 0 '                                                    Opening screen
46. cp 7, "Air Hockey, first to score 21 goals wins!"
47. cp 9, "Player you will be defending the goal on the right (a black slot)."
48. cp 10, "Your goal is on the left, defended by the computer."
49. cp 12, "The puck will be started going up and down in the middle of"
50. cp 13, "the screen at slight angle towards a randomly selected goal."
51. cp 16, "Press any when ready..."
52. SLEEP
53. _DELAY 1
54. CLS
55. updateScore
56. _PUTIMAGE (0, 0), table&, 0
57. drawComputerStriker
58. WHILE _MOUSEINPUT: WEND
59. psx = _MOUSEX: psy = _MOUSEY
60. drawPlayerStriker
61. initball
62. WHILE player < 21 AND computer < 21 '        play until someone scores 21
63.     CLS
64.     updateScore
65.     _PUTIMAGE (0, 0), table&, 0
66.     drawComputerStriker
67.     WHILE _MOUSEINPUT: WEND
68.     psx = _MOUSEX: psy = _MOUSEY
69.     drawPlayerStriker
70.     drawPuck
71.     _DISPLAY
72.     _LIMIT 60 '<<<<<<<<<<<<<  slow down, speeed up as needed for good game
73. WEND
74. IF computer > player THEN '                                    last report
75.     s$ = "Game Won by Computer."
76.     tx = 450
77. ELSE
78.     s$ = "Game Won by Player!"
79.     tx = 470
80. END IF
81. COLOR _RGB(200, 240, 140)
82. _PRINTSTRING (tx, tw + 30), s$
83. _DISPLAY
84. _DELAY 3
85.  
86. SUB initball 'toss puck out to side slightly angled to one goal or the other
87.     DIM pao
88.     px = tl / 2: py = tw / 2: pao = _PI(1 / 10) * RND
89.     puck px, py
90.     _DISPLAY
91.     _DELAY .3
92.     IF RND < .5 THEN pa = _PI(.5) ELSE pa = _PI(1.5)
93.     IF RND < .5 THEN pa = pa + pao ELSE pa = pa - pao
94. END SUB
95.  
96. SUB updateScore
97.     COLOR _RGB(40, 255, 255)
98.     s$ = "Computer: " + STR$(computer) + SPACE$(67) + "Player: " + STR$(player)
99.     _PRINTSTRING (200, tw + 30), s$
100. END SUB
101.  
102. SUB drawTable
103.     DIM i, shade
104.     FOR i = 0 TO pr2 STEP 4
105.         shade = 64 + i / pr2 * 100
106.         COLOR _RGB(shade, shade, shade)
107.         LINE (i, i)-(tl - i, tw - i), , BF
108.     NEXT
109.     LINE (pr2, pr2)-(tl - pr2, tw - pr2), _RGB(190, 230, 255), BF 'field
110.     LINE (pr, tw13)-(pr2, tw23), _RGB(60, 60, 60), BF
111.     LINE (tl - pr2, tw13)-(tl - pr, tw23), _RGB(60, 60, 60), BF
112.     LINE (tl \ 2 - 1, pr2)-(tl \ 2 + 1, tw - pr2), _RGB(128, 128, 128), BF
113. END SUB
114.  
115. SUB drawPlayerStriker
116.     IF psx - pr2 < tl / 2 THEN psx = tl / 2 + pr2
117.     IF psx + pr2 > tl - pr2 THEN psx = tl - 2 * pr2
118.     IF psy - pr2 < pr2 THEN psy = 2 * pr2
119.     IF psy + pr2 > tw - pr2 THEN psy = tw - 2 * pr2
120.     _PUTIMAGE (psx - pr2, psy - pr2), strkr&, 0
121. END SUB
122.  
123. SUB drawComputerStriker
124.     c1 = c1 + _PI(1 / 80)
125.     csx = midC + rangeC * SIN(c1)
126.     IF px > csx THEN csy = py + pr2 * 1.5 * SIN(c1)
127.     IF csy - pr2 < pr2 THEN csy = 2 * pr2
128.     IF csy + pr2 > tw - pr2 THEN csy = tw - 2 * pr2
129.     _PUTIMAGE (csx - pr2, csy - pr2), strkr&, 0
130. END SUB
131.  
132. SUB drawPuck
133.     'update ball x, y and see if hit anything
134.     DIM i, shade
135.     px = px + speed * COS(pa)
136.     py = py + speed * SIN(pa)
137.  
138.     IF px - pr < pr2 THEN
139.         IF tw13 < py - pr AND py + pr < tw23 THEN 'through computer slot, player scores
140.             player = player + 1
141.             CLS
142.             updateScore
143.             drawTable
144.             striker csx, csy
145.             striker psx, psy
146.             puck pr, py
147.             FOR i = 0 TO pr STEP 4
148.                 shade = 64 + i / pr2 * 100
149.                 COLOR _RGB(shade, shade, shade)
150.                 LINE (i, tw13)-(pr, tw23), , BF ' wow tw13 has been 0
151.             NEXT
152.             snd 1200, 200
153.             snd 2200, 300
154.             _DISPLAY
155.             initball
156.             _DELAY .5
157.             EXIT SUB
158.         ELSE
159.             snd 2600, 8
160.             pa = _PI(1) - pa
161.             px = pr2 + pr
162.         END IF
163.     END IF
164.  
165.     IF px + pr > tl - pr2 THEN
166.         IF tw13 < py - pr AND py + pr < tw23 THEN
167.             computer = computer + 1
168.             CLS
169.             updateScore
170.             drawTable
171.             striker csx, csy
172.             striker psx, psy
173.             puck tl - pr, py
174.             FOR i = 0 TO pr STEP 4
175.                 shade = 64 + i / pr2 * 100
176.                 COLOR _RGB(shade, shade, shade)
177.                 LINE (tl - pr, tw13)-(tl - i, tw23), , BF 't13 again!
178.             NEXT
179.             snd 2200, 300
180.             snd 1200, 200
181.             _DISPLAY
182.             initball
183.             _DELAY .5
184.             EXIT SUB
185.         ELSE
186.             snd 2600, 5
187.             pa = _PI(1) - pa
188.             px = tl - pr2 - pr
189.         END IF
190.     END IF
191.  
192.     IF py - pr < pr2 THEN ' hit top boundry
193.         snd 2600, 8
194.         pa = -pa
195.         py = pr2 + pr
196.     END IF
197.  
198.     IF py + pr > tw - pr2 THEN ' hit bottom boundry
199.         snd 2600, 8
200.         pa = -pa
201.         py = tw - pr2 - pr
202.     END IF
203.  
204.     IF SQR((px - psx) ^ 2 + (py - psy) ^ 2) < (pr + pr2) THEN 'contact player striker
205.         pa = _ATAN2(py - psy, px - psx)
206.         'boost puck away
207.         px = px + .5 * speed * COS(pa)
208.         py = py + .5 * speed * SIN(pa)
209.         snd 2200, 4
210.     END IF
211.     IF SQR((px - csx) ^ 2 + (py - csy) ^ 2) < (pr + pr2) THEN 'contact computer striker
212.         pa = _ATAN2(py - csy, px - csx)
213.         'boost puck away
214.         px = px + .5 * speed * COS(pa)
215.         py = py + .5 * speed * SIN(pa)
216.         snd 2200, 4
217.     END IF
218.     puck px, py ' here it is!
219. END SUB
220.  
221. SUB puck (x, y)
222.     COLOR _RGB(90, 90, 90)
223.     fillcirc x, y, pr
224.     COLOR _RGB(190, 100, 0)
225.     fillcirc x, y, pr - 4
226. END SUB
227.  
228. SUB striker (x, y)
229.     DIM i, shade
230.     FOR i = pr2 TO pr STEP -1
231.         shade = 164 - 90 * SIN(i * _PI(2) / pr)
232.         COLOR _RGB(shade, shade, shade)
233.         fillcirc x, y, i
234.     NEXT
235.     FOR i = pr TO 0 STEP -1
236.         shade = 185 + 70 * (pr - i) / pr
237.         COLOR _RGB(shade, shade, shade)
238.         fillcirc x, y, i
239.     NEXT
240. END SUB
241.  
242. 'Steve McNeil's  copied from his forum   note: Radius is too common a name
243. SUB fillcirc (CX AS LONG, CY AS LONG, R AS LONG)
244.     DIM subRadius AS LONG, RadiusError AS LONG
245.     DIM X AS LONG, Y AS LONG
246.  
247.     subRadius = ABS(R)
248.     RadiusError = -subRadius
249.     X = subRadius
250.     Y = 0
251.  
252.     IF subRadius = 0 THEN PSET (CX, CY): EXIT SUB
253.  
254.     ' Draw the middle span here so we don't draw it twice in the main loop,
255.     ' which would be a problem with blending turned on.
256.     LINE (CX - X, CY)-(CX + X, CY), , BF
257.  
258.     WHILE X > Y
259.         RadiusError = RadiusError + Y * 2 + 1
260.         IF RadiusError >= 0 THEN
261.             IF X <> Y + 1 THEN
262.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), , BF
263.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), , BF
264.             END IF
265.             X = X - 1
266.             RadiusError = RadiusError - X * 2
267.         END IF
268.         Y = Y + 1
269.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), , BF
270.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), , BF
271.     WEND
272. END SUB
273.  
274. SUB snd (frq, dur)
275.     SOUND frq / 2.2, dur * .01
276. END SUB
277.  
278. SUB cp (lineNum, s$)
279.     DIM x, y
280.     '1200 pixels / 85 characters = 14.11 pixels/char wide
281.     '700 pixels / 28 lines = 18.42 pixels / char high
282.     x = (xmax - 11 * LEN(s$)) \ 2
283.     y = lineNum * 25
284.     _PRINTSTRING (x, y), s$
285. END SUB
286.  
287.  

[johnno56]

This... looks familiar... Nice conversion!

[bplus]

Thanks Johnno, were you able to get Arial Font going on Linux?

I can give you the Arial font I use but any font will do that can be 25 pixels high and about 11 wide. I tried QB64's Cyberbit.ttf, a little too curly but worse, the bottoms of g, y, p, q letters with tails are getting cut off.

[johnno56]

Yes I did. I noticed your file reference and edited accordingly... Ran like a dream... I quit the game once the computer scored more than I did... lol

[bplus]

Thanks I had some pretty good battles myself last night. It wins because it never tires or gets distracted.

Angle bank shots to goal are best bet. Just getting puck past it is good too, it will often knock it in for you.

[Dimster]

Being an x-road hockey player, I love this game. Improved my slap shot and wrist shot all with the same motion. I could have been a contender if I could have mastered that shot in real life. Stick handling still sucked. I need some kind of magnet on the puck if I want to deke.

[bplus]

Hi Dimster,

Well I just learned a "deke" is a fake out while maintaining control of puck.

How about dribbling the puck along your side boundary to near the boundary line between opponents and then a bank shot to the goal.

[DANILIN]

I think we need a dark theme
for playing on a dark background that is pleasing for our eyes
choice: black or dark green or dark purple

[bplus]

I think we need a dark theme
for playing on a dark background that is pleasing for our eyes
choice: black or dark green or dark purple

Code: QB64: [Select]

1. LINE (pr2, pr2)-(tl - pr2, tw - pr2), _RGB(190, 230, 255), BF 'field
2.  

This lovely shade of sky blue is virus free! Oh look this was from my early days with QB64, no _RGB32(), should be &HFFBBBBFF

Of course this being source code make the shade whatever pleases the eye. All hockey games on physical boards, I've seen were white, air hockey... don't remember shade

Here's what Google show's
https://www.google.com/search?q=70%27s+air+hockey+games&client=opera&hs=qbn&sxsrf=ALeKk02LbeoakD1bXPSQGXFru0vQ2sxf8g:1584979630804&source=lnms&tbm=isch&sa=X&ved=2ahUKEwjoz_qe_bDoAhXXXc0KHfKWDxUQ_AUoAnoECAsQBA&biw=1297&bih=667

Yeah, pretty much white! ;-))

[DANILIN]

replace line of listing 109
it's real include dark theme many variants of colors

'LINE (pr2, pr2)-(tl - pr2, tw - pr2), _RGB(190, 230, 255), BF 'field
'LINE (pr2, pr2)-(tl - pr2, tw - pr2), _RGB(0, 0, 0), BF 'field
'LINE (pr2, pr2)-(tl - pr2, tw - pr2), _RGB(0, 50, 50), BF 'field
'LINE (pr2, pr2)-(tl - pr2, tw - pr2), _RGB(50, 50, 0), BF 'field

LINE (pr2, pr2)-(tl - pr2, tw - pr2), _RGB(50, 0, 50), BF 'field

[bplus]

Can you still see puck with darker fields?

Oh maybe a puck that light's up! and glows!!!

The goals could have a line of blinking lights and blow up into fireworks when someone wins a game!

[bplus]

Nice color DANILIN, thanks for tip! updated circle fill with color and lightened edge around puck.

It helps contrast the edges of puck, Strikers and the field.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. 'Air Hockey v2-1.bas for QB64
3. ' Started in QB64 Walter fork version (B+=MGA) 2017-09-05
4. ' The first version was a direct translation from SmallBASIC,
5. ' Now v2.0 add some more graphic image handling, try new things.
6. ' 2020-03-11 v2-1 (QB64 v1.4 now) cleanup some code:
7. ' Fix _MOUSEINPUT block too newbie ;)
8. ' Fix flat spots on strikers how long have they been there?
9. ' Increase frames per sec and slow puck speed for less double images.
10. ' Oh that sped up the AI player! Nice.
11. ' Do start shots to the side instead of directly at goal. MUCH BETTER!
12. ' Update opening screen with this info. Now pause the puck at start.
13. ' Ran OPTION _EXPLICIT and found a type-O that has been 0 all this time!
14.  
15. ' v2020-03-23 Dark Theme as suggested by Danlin also fix fill circle with color
16. ' also lighten color around the puck, oh fix the rest of the _rgb to rgb32.
17.  
18. RANDOMIZE TIMER
19. CONST xmax = 1200, ymax = 700 'screen dimensions
20. SCREEN _NEWIMAGE(xmax, ymax, 32)
21. _TITLE "Air Hockey v2020-03-23 Dark Theme"
22. _DELAY .25
23. _SCREENMOVE _MIDDLE
24.  
25. CONST pr = 16 '              puck radius
26. CONST pr2 = 2 * pr '         puck diameter = bumper width = radius of strikers
27. CONST tl = xmax '            table length
28. CONST tw = tl / 2 '          table width
29. CONST tw13 = .3333 * tw \ 1 'goal end point
30. CONST tw23 = .6667 * tw \ 1 'goal end point
31. CONST speed = 15 '           puck speed also see _limit in main loop
32. CONST midC = 316 '           (tl - 2 * pr2) \ 4 + pr2   'mid line of computer's sin field
33. CONST rangeC = 252 '         316 - 252 = 64 (bumper + pr2)  316 + 252 = 568 (mid screen - pr2)
34.  
35. COMMON SHARED f&, table&, computer, player, s$, tx, px, py, pa, psx, psy, c1, csx, csy, strkr&
36.  
37. f& = _LOADFONT("C:\Windows\Fonts\arial.ttf", 25) ' arial normal style  if you have windows
38. _FONT f& '                                         arial is pretty common if you don't have Windows
39.  
40. table& = _NEWIMAGE(xmax, tw, 32)
41. _DEST table&
42. drawTable
43.  
44. strkr& = _NEWIMAGE(2 * pr2 + 1, 2 * pr2 + 1, 32) ' more space to avoid right and bottom flat edges
45. _DEST strkr&
46. striker pr2, pr2
47.  
48. _DEST 0 '                                                    Opening screen
49. cp 7, "Air Hockey, first to score 21 goals wins!"
50. cp 9, "Player you will be defending the goal on the right (a black slot)."
51. cp 10, "Your goal is on the left, defended by the computer."
52. cp 12, "The puck will be started going up and down in the middle of"
53. cp 13, "the screen at slight angle towards a randomly selected goal."
54. cp 16, "Press any when ready..."
55. SLEEP
56. _DELAY 1
57. _MOUSEHIDE
58. CLS
59. updateScore
60. _PUTIMAGE (0, 0), table&, 0
61. drawComputerStriker
62. WHILE _MOUSEINPUT: WEND
63. psx = _MOUSEX: psy = _MOUSEY
64. drawPlayerStriker
65. initball
66. WHILE player < 21 AND computer < 21 '        play until someone scores 21
67.     CLS
68.     updateScore
69.     _PUTIMAGE (0, 0), table&, 0
70.     drawComputerStriker
71.     WHILE _MOUSEINPUT: WEND
72.     psx = _MOUSEX: psy = _MOUSEY
73.     drawPlayerStriker
74.     drawPuck
75.     _DISPLAY
76.     _LIMIT 60 '<<<<<<<<<<<<<  slow down, speeed up as needed for good game
77. WEND
78. IF computer > player THEN '                                    last report
79.     s$ = "Game Won by Computer."
80.     tx = 450
81. ELSE
82.     s$ = "Game Won by Player!"
83.     tx = 470
84. END IF
85. COLOR _RGB32(200, 240, 140)
86. _PRINTSTRING (tx, tw + 30), s$
87. _DISPLAY
88. _DELAY 3
89.  
90. SUB initball 'toss puck out to side slightly angled to one goal or the other
91.     DIM pao
92.     px = tl / 2: py = tw / 2: pao = _PI(1 / 10) * RND
93.     puck px, py
94.     _DISPLAY
95.     _DELAY .3
96.     IF RND < .5 THEN pa = _PI(.5) ELSE pa = _PI(1.5)
97.     IF RND < .5 THEN pa = pa + pao ELSE pa = pa - pao
98. END SUB
99.  
100. SUB updateScore
101.     COLOR _RGB32(40, 255, 255)
102.     s$ = "Computer: " + STR$(computer) + SPACE$(67) + "Player: " + STR$(player)
103.     _PRINTSTRING (200, tw + 30), s$
104. END SUB
105.  
106. SUB drawTable
107.     DIM i, shade
108.     FOR i = 0 TO pr2 STEP 4
109.         shade = 64 + i / pr2 * 100
110.         COLOR _RGB32(shade, shade, shade)
111.         LINE (i, i)-(tl - i, tw - i), , BF
112.     NEXT
113.     LINE (pr2, pr2)-(tl - pr2, tw - pr2), _RGB32(190, 230, 255), BF 'field
114.     LINE (pr2, pr2)-(tl - pr2, tw - pr2), _RGB32(50, 0, 50), BF 'field
115.     LINE (pr, tw13)-(pr2, tw23), _RGB32(60, 60, 60), BF
116.     LINE (tl - pr2, tw13)-(tl - pr, tw23), _RGB32(60, 60, 60), BF
117.     LINE (tl \ 2 - 1, pr2)-(tl \ 2 + 1, tw - pr2), _RGB32(128, 128, 128), BF
118. END SUB
119.  
120. SUB drawPlayerStriker
121.     IF psx - pr2 < tl / 2 THEN psx = tl / 2 + pr2
122.     IF psx + pr2 > tl - pr2 THEN psx = tl - 2 * pr2
123.     IF psy - pr2 < pr2 THEN psy = 2 * pr2
124.     IF psy + pr2 > tw - pr2 THEN psy = tw - 2 * pr2
125.     _PUTIMAGE (psx - pr2, psy - pr2), strkr&, 0
126. END SUB
127.  
128. SUB drawComputerStriker
129.     c1 = c1 + _PI(1 / 80)
130.     csx = midC + rangeC * SIN(c1)
131.     IF px > csx THEN csy = py + pr2 * 1.5 * SIN(c1)
132.     IF csy - pr2 < pr2 THEN csy = 2 * pr2
133.     IF csy + pr2 > tw - pr2 THEN csy = tw - 2 * pr2
134.     _PUTIMAGE (csx - pr2, csy - pr2), strkr&, 0
135. END SUB
136.  
137. SUB drawPuck
138.     'update ball x, y and see if hit anything
139.     DIM i, shade
140.     px = px + speed * COS(pa)
141.     py = py + speed * SIN(pa)
142.  
143.     IF px - pr < pr2 THEN
144.         IF tw13 < py - pr AND py + pr < tw23 THEN 'through computer slot, player scores
145.             player = player + 1
146.             CLS
147.             updateScore
148.             drawTable
149.             striker csx, csy
150.             striker psx, psy
151.             puck pr, py
152.             FOR i = 0 TO pr STEP 4
153.                 shade = 64 + i / pr2 * 100
154.                 COLOR _RGB32(shade, shade, shade)
155.                 LINE (i, tw13)-(pr, tw23), , BF ' wow tw13 has been 0
156.             NEXT
157.             snd 1200, 200
158.             snd 2200, 300
159.             _DISPLAY
160.             initball
161.             _DELAY .5
162.             EXIT SUB
163.         ELSE
164.             snd 2600, 8
165.             pa = _PI(1) - pa
166.             px = pr2 + pr
167.         END IF
168.     END IF
169.  
170.     IF px + pr > tl - pr2 THEN
171.         IF tw13 < py - pr AND py + pr < tw23 THEN
172.             computer = computer + 1
173.             CLS
174.             updateScore
175.             drawTable
176.             striker csx, csy
177.             striker psx, psy
178.             puck tl - pr, py
179.             FOR i = 0 TO pr STEP 4
180.                 shade = 64 + i / pr2 * 100
181.                 COLOR _RGB32(shade, shade, shade)
182.                 LINE (tl - pr, tw13)-(tl - i, tw23), , BF 't13 again!
183.             NEXT
184.             snd 2200, 300
185.             snd 1200, 200
186.             _DISPLAY
187.             initball
188.             _DELAY .5
189.             EXIT SUB
190.         ELSE
191.             snd 2600, 5
192.             pa = _PI(1) - pa
193.             px = tl - pr2 - pr
194.         END IF
195.     END IF
196.  
197.     IF py - pr < pr2 THEN ' hit top boundry
198.         snd 2600, 8
199.         pa = -pa
200.         py = pr2 + pr
201.     END IF
202.  
203.     IF py + pr > tw - pr2 THEN ' hit bottom boundry
204.         snd 2600, 8
205.         pa = -pa
206.         py = tw - pr2 - pr
207.     END IF
208.  
209.     IF SQR((px - psx) ^ 2 + (py - psy) ^ 2) < (pr + pr2) THEN 'contact player striker
210.         pa = _ATAN2(py - psy, px - psx)
211.         'boost puck away
212.         px = px + .5 * speed * COS(pa)
213.         py = py + .5 * speed * SIN(pa)
214.         snd 2200, 4
215.     END IF
216.     IF SQR((px - csx) ^ 2 + (py - csy) ^ 2) < (pr + pr2) THEN 'contact computer striker
217.         pa = _ATAN2(py - csy, px - csx)
218.         'boost puck away
219.         px = px + .5 * speed * COS(pa)
220.         py = py + .5 * speed * SIN(pa)
221.         snd 2200, 4
222.     END IF
223.     puck px, py ' here it is!
224. END SUB
225.  
226. SUB puck (x, y)
227.     fillcirc x, y, pr, _RGB32(160, 160, 160)
228.     fillcirc x, y, pr - 4, _RGB32(190, 100, 0)
229. END SUB
230.  
231. SUB striker (x, y)
232.     DIM i, shade
233.     FOR i = pr2 TO pr STEP -1
234.         shade = 164 - 90 * SIN(i * _PI(2) / pr)
235.         fillcirc x, y, i, _RGB32(shade, shade, shade)
236.     NEXT
237.     FOR i = pr TO 0 STEP -1
238.         shade = 185 + 70 * (pr - i) / pr
239.         fillcirc x, y, i, _RGB32(shade, shade, shade)
240.     NEXT
241. END SUB
242.  
243. 'Steve McNeil's  copied from his forum   note: Radius is too common a name
244. SUB fillcirc (CX AS LONG, CY AS LONG, R AS LONG, C AS _UNSIGNED LONG)
245.     DIM subRadius AS LONG, RadiusError AS LONG
246.     DIM X AS LONG, Y AS LONG
247.  
248.     subRadius = ABS(R)
249.     RadiusError = -subRadius
250.     X = subRadius
251.     Y = 0
252.  
253.     IF subRadius = 0 THEN PSET (CX, CY), C: EXIT SUB
254.  
255.     ' Draw the middle span here so we don't draw it twice in the main loop,
256.     ' which would be a problem with blending turned on.
257.     LINE (CX - X, CY)-(CX + X, CY), C, BF
258.  
259.     WHILE X > Y
260.         RadiusError = RadiusError + Y * 2 + 1
261.         IF RadiusError >= 0 THEN
262.             IF X <> Y + 1 THEN
263.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
264.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
265.             END IF
266.             X = X - 1
267.             RadiusError = RadiusError - X * 2
268.         END IF
269.         Y = Y + 1
270.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
271.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
272.     WEND
273. END SUB
274.  
275. SUB snd (frq, dur)
276.     SOUND frq / 2.2, dur * .01
277. END SUB
278.  
279. SUB cp (lineNum, s$)
280.     DIM x, y
281.     '1200 pixels / 85 characters = 14.11 pixels/char wide
282.     '700 pixels / 28 lines = 18.42 pixels / char high
283.     x = (xmax - 11 * LEN(s$)) \ 2
284.     y = lineNum * 25
285.     _PRINTSTRING (x, y), s$
286. END SUB
287.  
288.  

EDIT: fix the rest of the _RGB's