Simplest snake

[FellippeHeitor]

So there's this guy, Chris DeLeon, that makes these fast-coding videos to promote his online courses, and I recently watched the video in which he wrote a functional Snake game in 4 minutes and 30 seconds. Of course we're not counting the time he spent practicing it before hitting record on his camera, and I don't judge him if he has a cheat sheet right in front of him. The thing is, this is impressive because it's so simple and I wanted to port it over to QB64. Here's the result.

The video in which he writes this in 4m 30s:

Original code in JavaScript: https://pastebin.com/Z3zhb7cY

Code: QB64 $NOPREFIX: [Select]

1. $NOPREFIX
2. OPTION EXPLICIT
3.  
4. TYPE position
5.     x AS SINGLE
6.     y AS SINGLE
7. END TYPE
8.  
9. DIM canvas AS LONG
10. canvas = NEWIMAGE(400, 400, 32)
11.  
12. SCREEN canvas
13. TITLE "Simplest snake"
14.  
15. DIM px, py, gs, tc, ax, ay, xv, yv, tail, i
16. DIM trail(1000) AS position
17. px = 10
18. py = 10
19. gs = 20
20. tc = 20
21. ax = 15
22. ay = 15
23. tail = 1
24.  
25. FOR i = 0 TO tail - 1
26.     trail(i).x = px
27.     trail(i).y = py
28. NEXT
29.  
30. DO
31.     DIM k AS LONG
32.     k = KEYHIT
33.     SELECT CASE k
34.         CASE 18432 'up
35.             xv = 0
36.             yv = -1
37.         CASE 20480 'down
38.             xv = 0
39.             yv = 1
40.         CASE 19200 'left
41.             xv = -1
42.             yv = 0
43.         CASE 19712 'right
44.             xv = 1
45.             yv = 0
46.     END SELECT
47.  
48.     px = px + xv
49.     py = py + yv
50.  
51.     IF px < 0 THEN px = tc - 1
52.     IF px > tc - 1 THEN px = 0
53.     IF py < 0 THEN py = tc - 1
54.     IF py > tc - 1 THEN py = 0
55.  
56.     'bg
57.     LINE (0, 0)-(WIDTH, HEIGHT), RGB32(0), BF
58.  
59.     'snake
60.     FOR i = 0 TO tail - 1
61.         LINE (trail(i).x * gs, trail(i).y * gs)-STEP(gs - 2, gs - 2), RGB32(55, 161, 61), BF
62.         IF trail(i).x = px AND trail(i).y = py THEN tail = 5
63.     NEXT
64.  
65.     trail(tail).x = px
66.     trail(tail).y = py
67.     FOR i = 0 TO tail - 1
68.         trail(i) = trail(i + 1)
69.     NEXT
70.  
71.     'apple
72.     IF (ax = px AND ay = py) OR tail < 5 THEN
73.         tail = tail + 1
74.         ax = INT(RND * tc)
75.         ay = INT(RND * tc)
76.     END IF
77.  
78.     LINE (ax * gs, ay * gs)-STEP(gs - 2, gs - 2), RGB32(255, 0, 0), BF
79.  
80.     DISPLAY
81.     LIMIT 10
82. LOOP

[bplus]

Not too far from where Ron77 started from here: https://www.qb64.org/forum/index.php?topic=1106.0

[FellippeHeitor]

Can you spot the difference in approaches?

[bplus]

Like using Type and real graphics?

Inkey$ instead of keydown

Neither one checks to see if the new food is in snake body, I think.

[FellippeHeitor]

That too.

[bplus]

lines 24-28 odd?
 

Oh he is doing wrap arounds at boundries.

I should play the thing instead of read code, also looks like body starts at 5.

Doesn't look like snake dies if crashes into body, gets shorter back to 5

Dim k inside a do loop is dumb.

The snake is imortal it doesn't die going back on itself either.

Did I get them all?

Does gs stand for game scale?

Something is wrong with key response a slight delay by 1 frame.