QB64 Simon by TerryRitchie

[bplus]

QB64 Simon

Author: @TerryRitchie
Source: qb64.org Forum
URL: https://www.qb64.org/forum/index.php?topic=2263
Version: 1.0 written March, 2015
Tags: [Retro] [Sim]

Description:
An exact replica of the Simon game from the 1980's (with added QB64 bee graphic).
Game play can be done with keyboard, mouse, or both. Press F1 for a help screen.

Source:

Code: QB64: [Select]

1. '*
2. '*                                    ------------------
3. '*                                    --- QB64 Simon ---
4. '*                                    ------------------
5. '*
6. '*                                     By Terry Ritchie
7. '*
8. '*                       Written from March 22nd to March 28th, 2015
9. '*                                       Version 1.0
10. '*
11.  
12. '--------------------------------
13. '- VARIABLE DECLARATION SECTION -
14. '--------------------------------
15.  
16. CONST FALSE = 0 '        boolean: false indicator
17. CONST TRUE = NOT FALSE ' boolean: true indicator
18. CONST MOUSE% = 200 '     call PADPRESS with mouse button
19.  
20. DIM Pad&(3, 1) '         color pads: 0,x=BLUE, 1,x=RED, 2,x=GREEN, 3,x=YELLOW
21. DIM PadXY%(3, 1) '       x,y locations of color pads
22. DIM Tone&(4) '           game sounds: 0=BLUE, 1=RED, 2=GREEN, 3=YELLOW, 4=LOSE
23. DIM Simon& '             simon graphics image
24. DIM SimonHelp& '         simon help screen
25. DIM Keys&(3, 1) '        keyboard key images 0=Q, 1=W, 2=S, 3=A
26. DIM Bslider& '           blue slider switch image
27. DIM Rslider& '           red slider switch image
28. DIM OnOff& '             on/off slider switch
29. DIM KeysXY%(3, 1) '      location of keyboard key images on play screen
30. DIM GameOver% '          boolean: true when game has ended
31. DIM Game% '              the position the blue slider switch is in (0-2)
32. DIM Skill% '             the position the red slider switch is in (0-3)
33. DIM GameDir% '           the direction blue slider switch will move (1, -1)
34. DIM SkillDir% '          the direction red slider switch will move (1, -1)
35. DIM Longest$ '           the longest tune correctly played by a player
36. DIM Last$ '              the last tune played by the player
37. DIM Count% '             generic counter
38. DIM KeyPress$ '          any keys pressed by the player
39. DIM Pcolor~&(3) '        color pad base colors: 0=BLUE, 1=RED, 2=GREEN, 3=YELLOW
40.  
41. '----------------
42. '- MAIN PROGRAM -
43. '----------------
44.  
45. INITIALIZE '                                                       prepare graphics, sounds and variables
46. SCREEN _NEWIMAGE(640, 640, 32) '                                   create game screen
47. _TITLE "QB64 SIMON" '                                              give game screen a title
48. _SCREENMOVE _MIDDLE '                                              move game screen to middle of desktop
49. _DELAY .5 '                                                        light delay to move to middle of screen
50. CLS '                                                              remove black transparency
51. DO '                                                               BEGIN MAIN GAME LOOP
52.     GameOver% = FALSE '                                            reset game over flag
53.     PRESSPAD 0, 0 '                                                reset game board
54.     _DISPLAY
55.     DO '                                                           BEGIN PLAY GAME LOOP
56.         _LIMIT 120 '                                               limit to 120 loops per second
57.         WHILE _MOUSEINPUT: WEND '                                  get to last mouse event
58.         IF _MOUSEBUTTON(1) THEN '                                  did player click left mouse button?
59.             IF POINTER%(232 + Game% * 10, 323, 289 + Game% * 10, 345) THEN ' test blue slider area?
60.                 IF Game% = 0 OR Game% = 2 THEN '                   yes, is blue slider at its limit?
61.                     GameDir% = -GameDir% '                         yes, reverse blue slider direction
62.                 END IF
63.                 Game% = Game% + GameDir% '                         change game level
64.                 PRESSPAD 0, .125 '                                 display change on screen
65.                 WAIT4RELEASE
66.             ELSEIF POINTER%(319 + Skill% * 10, 323, 375 + Skill% * 10, 345) THEN ' test red slider area?
67.                 IF Skill% = 0 OR Skill% = 3 THEN '                 yes, is red slider at its limit?
68.                     SkillDir% = -SkillDir% '                       yes, reverse red slider direction
69.                 END IF
70.                 Skill% = Skill% + SkillDir% '                      change skill level
71.                 PRESSPAD 1, .125 '                                 display change on screen
72.                 WAIT4RELEASE
73.             ELSEIF POINTER%(254, 371, 271, 388) THEN '             test last button area?
74.                 WAIT4RELEASE
75.                 FOR Count% = 1 TO LEN(Last$) '                     cycle through last tune string
76.                     PRESSPAD VAL(MID$(Last$, Count%, 1)), .5 '     play each individual tone
77.                     _DELAY .125 '                                  pause for 1/8 second
78.                 NEXT Count%
79.             ELSEIF POINTER%(371, 371, 388, 388) THEN '             test longest button area?
80.                 Count% = 0 '                                       yes, reset 1/120 counter
81.                 DO '                                               BEGIN MOUSE RELEASE LOOP
82.                     _LIMIT 120 '                                   don't hog CPU while looping
83.                     WHILE _MOUSEINPUT: WEND '                      get to last mouse event
84.                     Count% = Count% + 1 '                          increment 1/120 second counter
85.                     IF Count% > 360 THEN '                         have 3 seconds elapsed?
86.                         FOR Count% = 0 TO 3 '                      yes, cycle through all four color pads
87.                             PRESSPAD Count%, .125 '                light pad and play tone quickly
88.                         NEXT Count%
89.                         Longest$ = "" '                            reset longest tune string
90.                         SIMONFILE 2 '                              delete simon.sav file
91.                     END IF
92.                 LOOP UNTIL NOT _MOUSEBUTTON(1) '                   END MOUSE RELEASE LOOP when left button released
93.                 FOR Count% = 1 TO LEN(Longest$) '                  cycle through longest tune string
94.                     PRESSPAD VAL(MID$(Longest$, Count%, 1)), .5 '  play each individual tone
95.                     _DELAY .125 '                                  pause 1/8 second
96.                 NEXT Count%
97.             ELSEIF POINTER%(314, 371, 331, 388) THEN '             test start button area?
98.                 _DELAY .5 '                                        1/2 second delay before game start
99.                 PLAYGAME '                                         play game
100.             ELSEIF POINTER%(321, 408, 332, 419) THEN '             test power button slider area?
101.                 ENDGAME '                                          yes, end the game
102.             END IF
103.         END IF
104.         KeyPress$ = INKEY$ '                                       get any key player may have pressed
105.         IF KeyPress$ = CHR$(0) + CHR$(59) THEN '                   did player press the F1 key?
106.             DISPLAYHELP '                                          yes, display help screen to player
107.         END IF
108.     LOOP UNTIL GameOver% '                                         END PLAY GAME LOOP
109. LOOP '                                                             MAIN GAME LOOP end
110.  
111. '--------------------
112. '- END MAIN PROGRAM -
113. '--------------------
114.  
115. '---------------------------
116. '- SUBROUTINES & FUNCTIONS -
117. '---------------------------
118.  
119. '----------------------------------------------------------------------------------------------------------------------
120. '                                                                                                           DISPLAYHELP
121. SUB DISPLAYHELP ()
122.  
123.     '---------------------------------------
124.     '- Display the help screen to the player
125.     '---------------------------------------
126.  
127.     SHARED SimonHelp& ' simon help screen
128.  
129.     _PUTIMAGE (0, 0), SimonHelp& '                display help screen
130.     _DISPLAY '                                    update screen with change
131.     DO '                                          BEGIN KEY/MOUSE LOOP
132.         _LIMIT 120 '                              don't hog the CPU
133.         WHILE _MOUSEINPUT: WEND '                 get latest mouse events
134.     LOOP UNTIL INKEY$ <> "" OR _MOUSEBUTTON(1) '  END KEY/MOUSE LOOP when left button clicked or key pressed
135.     PRESSPAD 0, 0 '                               restore game screen
136.  
137. END SUB
138.  
139. '----------------------------------------------------------------------------------------------------------------------
140. '                                                                                                          WAIT4RELEASE
141. SUB WAIT4RELEASE ()
142.  
143.     '--------------------------------------------
144.     '- Waits for left mouse button to be released
145.     '--------------------------------------------
146.  
147.     DO '                             BEGIN MOUSE RELEASE LOOP
148.         _LIMIT 120 '                 don't hog the CPU
149.         WHILE _MOUSEINPUT: WEND '    get to last mouse event
150.     LOOP UNTIL NOT _MOUSEBUTTON(1) ' END MOUSE RELEASE LOOP when left button released
151.  
152. END SUB
153.  
154. '----------------------------------------------------------------------------------------------------------------------
155. '                                                                                                             SIMONFILE
156. SUB SIMONFILE (Task%)
157.  
158.     '------------------------------------------
159.     '- Loads, updates, or deletes the save file
160.     '-
161.     '- Task%: 0 - load file
162.     '-        1 - update file
163.     '-        2 - delete file
164.     '------------------------------------------
165.  
166.     SHARED Longest$ ' the longest tune correctly played by a player
167.  
168.     SELECT CASE Task% '                            load, update, or delete?
169.         CASE 0 '                                   load file
170.             IF _FILEEXISTS("simon.sav") THEN '     does the save file exist?
171.                 OPEN "simon.sav" FOR INPUT AS #1 ' yes, open the file for reading
172.                 LINE INPUT #1, Longest$ '          get the longest tune ever played
173.                 CLOSE #1 '                         close the file
174.             END IF
175.         CASE 1 '                                   update file
176.             OPEN "simon.sav" FOR OUTPUT AS #1 '    open the file for output
177.             PRINT #1, Longest$ '                   write the longest tune ever played
178.             CLOSE #1 '                             close the file
179.         CASE 2 '                                   delete file
180.             IF _FILEEXISTS("simon.sav") THEN '     does the save file exist?
181.                 KILL "simon.sav" '                 yes, delete it
182.             END IF
183.     END SELECT
184.  
185. END SUB
186.  
187. '----------------------------------------------------------------------------------------------------------------------
188. '                                                                                                              POINTER%
189. FUNCTION POINTER% (x1%, y1%, x2%, y2%)
190.  
191.     '------------------------------------------------------------------------------
192.     '- Returns TRUE if the mouse pointer falls within x1%,y1% - x2%,y2% coordinates
193.     '-
194.     '- x1%: upper left  hand corner x coordinate of box area
195.     '- y1%: upper left  hand corner y coordinate of box area
196.     '- x2%: lower right hand corner x coordinate of box area
197.     '- y2%: lower right hand corner y coordinate of box area
198.     '------------------------------------------------------------------------------
199.  
200.     DIM mx% ' current mouse pointer x coordinate
201.     DIM my% ' current mouse pointer y coordinate
202.  
203.     POINTER% = FALSE '                assume pointer does not fall within coordinates
204.     WHILE _MOUSEINPUT: WEND '         get latest mouse event
205.     mx% = _MOUSEX '                   get current mouse pointer x coordinate
206.     my% = _MOUSEY '                   get current mouse pointer y coordinate
207.     IF mx% >= x1% THEN '              could pointer be within x coordinates?
208.         IF mx% <= x2% THEN '          yes, is pointer within x coordinates?
209.             IF my% >= y1% THEN '      yes, could pointer be within y coordinates?
210.                 IF my% <= y2% THEN '  yes, is pointer within y coordinates?
211.                     POINTER% = TRUE ' yes, report back that pointer falls within coordinates
212.                 END IF
213.             END IF
214.         END IF
215.     END IF
216.  
217. END FUNCTION
218.  
219. '----------------------------------------------------------------------------------------------------------------------
220. '                                                                                                              PLAYGAME
221. SUB PLAYGAME ()
222.  
223.     '-----------------------
224.     '- Plays a game of simon
225.     '-----------------------
226.  
227.     SHARED GameOver% ' boolean: true when game has ended
228.     SHARED Game% '     the position the blue slider switch is in (0-2)
229.     SHARED Skill% '    the position the red slider switch is in (0-3)
230.     SHARED Longest$ '  the longest tune correctly played by a player
231.     SHARED Last$ '     the last tune played by the player
232.  
233.     DIM Tune$ '        string of random tunes generated during game play
234.     DIM KeyPress& '    contains value of any key pressed
235.     DIM PlaySpeed! '   speed that simon plays notes
236.     DIM Count% '       generic counter
237.     DIM Notes% '       player note counter
238.     DIM PadPress% '    value of colored pad pressed by player
239.     DIM Plongest$ '    current player's longest tune
240.     DIM Win% '         number of correct tones to win
241.  
242.     '-------------
243.     '- MAIN CODE -
244.     '-------------
245.  
246.     PRESSPAD 0, 0 '                                                 reset game screen
247.     PlaySpeed! = 1 '                                                reset game speed
248.     Win% = 12 + Skill% * 6 '                                        calculate number of tones to win
249.     Tune$ = "" '                                                    reset random tune string
250.     DO '                                                            BEGIN PLAY GAME LOOP
251.         FOR Count% = 1 TO Game% + 1 '                               number of notes to add
252.             Tune$ = Tune$ + LTRIM$(RTRIM$(STR$(INT(RND(1) * 4)))) ' add a random tone
253.             IF LEN(Tune$) MOD 3 = 0 THEN '                          divisible evenly by 3?
254.                 PlaySpeed! = PlaySpeed! - .125 '                    yes, increase speed of play
255.                 IF PlaySpeed! < .125 THEN PlaySpeed! = .125 '       keep play speed at certain minimum
256.             END IF
257.         NEXT Count%
258.         FOR Count% = 1 TO LEN(Tune$) '                              cycle through the tones
259.             PRESSPAD VAL(MID$(Tune$, Count%, 1)), PlaySpeed! '      play the tone
260.             _DELAY PlaySpeed! / 4 '                                 pause between tones
261.         NEXT Count%
262.         Notes% = 0 '                                                reset player note count
263.         DO '                                                        BEGIN PLAY ROUND LOOP
264.             DO '                                                    BEGIN BUFFER CLEAR LOOP
265.                 _LIMIT 120 '                                        don't hog CPU
266.                 KeyPress& = _KEYHIT '                               get keypress from keyboard buffer
267.             LOOP WHILE KeyPress& '                                  END BUFFER CLEAR LOOP when buffer clear
268.             Notes% = Notes% + 1 '                                   increment player note count
269.             PadPress% = PLAYERINPUT% '                              get player's next color pad press
270.             IF PadPress% <> VAL(MID$(Tune$, Notes%, 1)) THEN '      did the player press the right color pad?
271.                 GameOver% = TRUE '                                  no, set game over flag
272.                 PRESSPAD 4, 2 '                                     play loser sound and light up simon
273.             END IF
274.         LOOP UNTIL Notes% = LEN(Tune$) OR GameOver% '               END PLAY ROUND LOOP when player success or game over
275.         IF NOT GameOver% THEN Plongest$ = Tune$ '                   remember last attempt as player's longest
276.         IF Notes% = Win% THEN '                                     did player win?
277.             GameOver% = TRUE '                                      yes, set game over
278.             FOR Win% = 1 TO 6 '                                     cycle 6 times
279.                 FOR Count% = 0 TO 3 '                               cycle through all color pads
280.                     PRESSPAD Count%, .125 '                         press color pad
281.                 NEXT Count%
282.             NEXT Win%
283.         END IF
284.         _DELAY PlaySpeed! * 2 '                                     slight delay between rounds
285.     LOOP UNTIL GameOver% '                                          END PLAY GAME LOOP when game over
286.     Last$ = Tune$ '                                                 remember the entire last tune played
287.     IF LEN(Plongest$) > LEN(Longest$) THEN '                        did player set a new longest record?
288.         Longest$ = Plongest$ '                                      yes, remember the new longest tune
289.         SIMONFILE 1 '                                               update simon.sav with new longest tune
290.     END IF
291.  
292. END SUB
293.  
294. '----------------------------------------------------------------------------------------------------------------------
295. '                                                                                                          PLAYERINPUT%
296. FUNCTION PLAYERINPUT% ()
297.  
298.     ' -----------------------------------------------------------------------
299.     ' Waits for player input then returns the color pad pressed by the player
300.     ' -----------------------------------------------------------------------
301.  
302.     SHARED Pcolor~&() ' color pad base colors: 0=BLUE, 1=RED, 2=GREEN, 3=YELLOW
303.  
304.     DIM PadPress% '     the color pad that was pressed
305.     DIM KeyPress& '     a key the player has pressed
306.     DIM mx% '           current mouse pointer x coordinate
307.     DIM my% '           current mouse pointer y coordinate
308.     DIM Clr~& '         color of pixel clicked on
309.  
310.     PadPress% = -1 '                                                      reset pad press indicator
311.     DO '                                                                  BEGIN INPUT LOOP
312.         _LIMIT 120 '                                                      don't hog the CPU
313.         KeyPress& = _KEYHIT '                                             get the latest key status
314.         WHILE _MOUSEINPUT: WEND '                                         get the latest mouse status
315.         IF KeyPress& THEN '                                               was a key pressed?
316.             SELECT CASE KeyPress& '                                       yes, which one?
317.                 CASE 81, 113 '                                            Q or q key
318.                     PRESSPAD 0, KeyPress& '                               press blue pad on simon
319.                     PadPress% = 0 '                                       remember blue pad pressed
320.                 CASE 87, 119 '                                            W or w key
321.                     PRESSPAD 1, KeyPress& '                               press red pad on simon
322.                     PadPress% = 1 '                                       remember red pad pressed
323.                 CASE 83, 115 '                                            S or s key
324.                     PRESSPAD 2, KeyPress& '                               press green pad on simon
325.                     PadPress% = 2 '                                       remember green pad pressed
326.                 CASE 65, 97 '                                             A or a key
327.                     PRESSPAD 3, KeyPress& '                               press yellow pad on simon
328.                     PadPress% = 3 '                                       remember yellow pad pressed
329.             END SELECT
330.         ELSEIF _MOUSEBUTTON(1) THEN '                                     no, was the left mouse button clicked?
331.             mx% = _MOUSEX '                                               yes, get x location of mouse pointer
332.             my% = _MOUSEY '                                               get y location of mouse pointer
333.             Clr~& = POINT(mx%, my%)
334.             IF mx% < 320 AND my% < 320 AND Clr~& = Pcolor~&(0) THEN '     pointer in blue area?
335.                 PRESSPAD 0, MOUSE% '                                      yes, press blue pad on simon
336.                 PadPress% = 0 '                                           remember blue pad pressed
337.             ELSEIF mx% > 319 AND my% < 320 AND Clr~& = Pcolor~&(1) THEN ' no, pointer in red area?
338.                 PRESSPAD 1, MOUSE% '                                      yes, press red pad on simon
339.                 PadPress% = 1 '                                           remember red pad pressed
340.             ELSEIF mx% > 319 AND my% > 319 AND Clr~& = Pcolor~&(2) THEN ' no, pointer in green area?
341.                 PRESSPAD 2, MOUSE% '                                      yes, press green pad on simon
342.                 PadPress% = 2 '                                           remember green pad pressed
343.             ELSEIF mx% < 320 AND my% > 319 AND Clr~& = Pcolor~&(3) THEN ' no, pointer in yellow area?
344.                 PRESSPAD 3, MOUSE% '                                      yes, press yellow pad on simon
345.                 PadPress% = 3 '                                           remember yellow pad pressed
346.             END IF
347.         END IF
348.     LOOP UNTIL PadPress% <> -1 '                                          END INPUT LOOP when simon pad pressed
349.     PLAYERINPUT% = PadPress% '                                            return the pad that was pressed
350.  
351. END FUNCTION
352.  
353. '----------------------------------------------------------------------------------------------------------------------
354. '                                                                                                              PRESSPAD
355. SUB PRESSPAD (PadNum%, Behavior!)
356.  
357.     ' -----------------------------------------------------------------------------------------
358.     ' Simulates pressing a colored pad by lighting it up and playing its corresponding sound
359.     '
360.     ' PadNum%   - The colored pad to press: 0=BLUE, 1=RED, 2=GREEN, 3=YELLOW, 4=ALL
361.     ' Behavior! - If value is less than 5 then sound plays for this duration
362.     '           - If value is less than 120 then sound plays until scancode of key is released
363.     '           - if value > 120 then sound plays until left mouse button is released
364.     '           - if value is zero then game board is redrawn only
365.     ' -----------------------------------------------------------------------------------------
366.  
367.     SHARED Tone&() '   game sounds
368.     SHARED Pad&() '    color pads: 0,x=BLUE, 1,x=RED, 2,x=GREEN, 3,x=YELLOW
369.     SHARED PadXY%() '  x,y locations of color pads
370.     SHARED Simon& '    simon graphics image
371.     SHARED Keys&() '   keyboard key images 0=Q, 1=W, 2=S, 3=A
372.     SHARED KeysXY%() ' location of keyboard key images
373.     SHARED Bslider& '  blue slider switch image
374.     SHARED Rslider& '  red slider switch image
375.     SHARED OnOff& '    on/off slider switch
376.     SHARED Game% '     the position the blue slider switch is in (0-2)
377.     SHARED Skill% '    the position the red slider switch is in (0-3)
378.  
379.     DIM KeyPress& '    key press value
380.     DIM KeyStatus% '   0=no key animation, 1=key animation
381.  
382.     '-------------
383.     '- MAIN CODE -
384.     '-------------
385.  
386.     KeyStatus% = 1 '                                                                           assume key animation
387.     IF Behavior! THEN '                                                                        just a board redraw?
388.         IF Behavior! = MOUSE% OR Behavior! < 5 THEN '                                          turn key animation off?
389.             KeyStatus% = 0 '                                                                   yes, turn animation off
390.         END IF
391.         IF PadNum% <> 4 THEN '                                                                 single color pad selected?
392.             _PUTIMAGE (PadXY%(PadNum%, 0), PadXY%(PadNum%, 1)), Pad&(PadNum%, 1) '             yes, light color pad
393.             _PUTIMAGE (KeysXY%(PadNum%, 0), KeysXY%(PadNum%, 1)), Keys&(PadNum%, KeyStatus%) ' animate key if needed
394.         ELSE '                                                                                 no, all color pads selected
395.             FOR Count% = 0 TO 3 '                                                              cycle through all color pads
396.                 _PUTIMAGE (PadXY%(Count%, 0), PadXY%(Count%, 1)), Pad&(Count%, 1) '            light color pad
397.                 _PUTIMAGE (KeysXY%(Count%, 0), KeysXY%(Count%, 1)), Keys&(Count%, 0) '         set keys to raised position
398.             NEXT Count%
399.         END IF
400.         _PUTIMAGE (200, 200), Simon& '                                                         place round simon image
401.         _PUTIMAGE (232 + Game% * 10, 323), Bslider& '                                          place blue slider
402.         _PUTIMAGE (319 + Skill% * 10, 323), Rslider& '                                         place red slider
403.         _PUTIMAGE (321, 408), OnOff& '                                                         place power button slider
404.         _DISPLAY '                                                                             update screen with changes
405.         _SNDLOOP Tone&(PadNum%) '                                                              sound into continuous loop
406.         SELECT CASE Behavior! '                                                                how was SUB called?
407.             CASE IS < 5 '                                                                      computer pressing color pad
408.                 _DELAY Behavior! '                                                             use value as a delay
409.             CASE IS < 120 '                                                                    player is pressing a key
410.                 _DELAY .125 '                                                                  pause for 1/8 second
411.                 DO '                                                                           BEGIN KEYBOARD SCAN LOOP
412.                     _LIMIT 120 '                                                               don't hog CPU
413.                     KeyPress% = _KEYHIT '                                                      get value of key pressed
414.                 LOOP UNTIL KeyPress% = -Behavior! '                                            END LOOP when key released
415.             CASE ELSE '                                                                        player using mouse button
416.                 _DELAY .125 '                                                                  pause for 1/8 second
417.                 WAIT4RELEASE '                                                                 wait left button released
418.         END SELECT
419.         _SNDSTOP Tone&(PadNum%) '                                                              stop the sound
420.     END IF
421.     FOR Count% = 0 TO 3 '                                                                      cycle through all color pads
422.         _PUTIMAGE (PadXY%(Count%, 0), PadXY%(Count%, 1)), Pad&(Count%, 0) '                    unlight color pad
423.         _PUTIMAGE (KeysXY%(Count%, 0), KeysXY%(Count%, 1)), Keys&(Count%, 0) '                 set keys to raised position
424.     NEXT Count%
425.     _PUTIMAGE (200, 200), Simon& '                                                             place round simon image
426.     _PUTIMAGE (232 + Game% * 10, 323), Bslider& '                                              place blue slider
427.     _PUTIMAGE (319 + Skill% * 10, 323), Rslider& '                                             place red slider
428.     _PUTIMAGE (321, 408), OnOff& '                                                             place power button slider
429.     _DISPLAY '                                                                                 update screen with changes
430.  
431. END SUB
432.  
433. '----------------------------------------------------------------------------------------------------------------------
434. '                                                                                                            INITIALIZE
435. SUB INITIALIZE ()
436.  
437.     ' --------------------------------------------------------------------------------------------
438.     ' Initialize all variables, create color pad images, load sounds and load spritesheet graphics
439.     ' --------------------------------------------------------------------------------------------
440.  
441.     SHARED Pad&() '     color pads: 0,x=BLUE, 1,x=RED, 2,x=GREEN, 3,x=YELLOW
442.     SHARED PadXY%() '   x,y locations of color pads
443.     SHARED Tone&() '    game sounds
444.     SHARED Simon& '     simon graphics image
445.     SHARED SimonHelp& ' simon help screen
446.     SHARED Keys&() '    keyboard key images 0=Q, 1=W, 2=S, 3=A
447.     SHARED Bslider& '   blue slider switch image
448.     SHARED Rslider& '   red slider switch image
449.     SHARED OnOff& '     on/off slider switch
450.     SHARED KeysXY%() '  location of keyboard key images
451.     SHARED Game% '      the position the blue slider switch is in (0-2)
452.     SHARED Skill% '     the position the red slider switch is in (0-3)
453.     SHARED GameDir% '   the direction blue slider switch will move (1, -1)
454.     SHARED SkillDir% '  the direction red slider switch will move (1, -1)
455.     SHARED Pcolor~&() ' color pad base colors: 0=BLUE, 1=RED, 2=GREEN, 3=YELLOW
456.  
457.     DIM Sheet& '        sprite sheet containing game graphics
458.     DIM Mask& '         color pad mask image
459.     DIM Count% '        increasing color brightness counter
460.     DIM Pcount% '       pad counter
461.     DIM x% '            x location of pad circles
462.     DIM y% '            y location of pad circles
463.     DIM Clr~& '         temporary color pad color holder
464.  
465.     '-------------
466.     '- MAIN CODE -
467.     '-------------
468.  
469.     RANDOMIZE TIMER '                                            seed random number generator
470.     Tone&(0) = _SNDOPEN("SimonB209.ogg", "VOL,SYNC") '           load blue   sound 209 Hz
471.     Tone&(1) = _SNDOPEN("SimonR310.ogg", "VOL,SYNC") '           load red    sound 310 Hz
472.     Tone&(2) = _SNDOPEN("SimonG415.ogg", "VOL,SYNC") '           load green  sound 415 Hz
473.     Tone&(3) = _SNDOPEN("SimonY252.ogg", "VOL,SYNC") '           load yellow sound 252 Hz
474.     Tone&(4) = _SNDOPEN("SimonL042.ogg", "VOL,SYNC") '           load lose   sound  42 Hz
475.     Simon& = _NEWIMAGE(242, 242, 32) '                           simon image holder
476.     Bslider& = _NEWIMAGE(57, 22, 32) '                           blue slider image holder
477.     Rslider& = _NEWIMAGE(57, 22, 32) '                           red slider image holder
478.     OnOff& = _NEWIMAGE(11, 11, 32) '                             power button slider image holder
479.     Sheet& = _LOADIMAGE("SimonGFX.png", 32) '                    load simon sprite sheet of images
480.     SimonHelp& = _LOADIMAGE("SimonHELP.png", 32) '               load simon help screen
481.     _PUTIMAGE (0, 0), Sheet&, Simon&, (0, 94)-(241, 335) '       extract simon from spritesheet
482.     _PUTIMAGE (0, 0), Sheet&, Bslider&, (200, 0)-(256, 21) '     extract blue slider from spritesheet
483.     _PUTIMAGE (0, 0), Sheet&, Rslider&, (200, 22)-(256, 43) '    extract red slider from spritesheet
484.     _PUTIMAGE (0, 0), Sheet&, OnOff&, (200, 44)-(210, 54) '      extract power button slider from spritesheet
485.     FOR Count% = 0 TO 3 '                                        cycle through 4 color pads
486.         Pad&(Count%, 0) = _NEWIMAGE(320, 320, 32) '              create color pad off image
487.         Pad&(Count%, 1) = _NEWIMAGE(320, 320, 32) '              create color pad on  image
488.         Keys&(Count%, 0) = _NEWIMAGE(50, 47, 32) '               create q,w,s,a raised key image holders
489.         Keys&(Count%, 1) = _NEWIMAGE(50, 47, 32) '               create q,w,s,a pressed key image holders
490.         _PUTIMAGE (0, 0), Sheet&, Keys&(Count%, 0), (Count% * 50, 0)-(Count% * 50 + 49, 46) '  extract key raised images
491.         _PUTIMAGE (0, 0), Sheet&, Keys&(Count%, 1), (Count% * 50, 47)-(Count% * 50 + 49, 93) ' extract key pressed images
492.     NEXT Count%
493.     PadXY%(0, 0) = 0 '                                           color pad locations
494.     PadXY%(0, 1) = 0
495.     PadXY%(1, 0) = 320
496.     PadXY%(1, 1) = 0
497.     PadXY%(2, 0) = 320
498.     PadXY%(2, 1) = 320
499.     PadXY%(3, 0) = 0
500.     PadXY%(3, 1) = 320
501.     KeysXY%(0, 0) = 20 '                                         keyboard key image locations
502.     KeysXY%(0, 1) = 20
503.     KeysXY%(1, 0) = 570
504.     KeysXY%(1, 1) = 20
505.     KeysXY%(2, 0) = 570
506.     KeysXY%(2, 1) = 573
507.     KeysXY%(3, 0) = 20
508.     KeysXY%(3, 1) = 573
509.     Pcolor~&(0) = _RGB32(0, 0, 128) '                            blue color of pad in off condition
510.     Pcolor~&(1) = _RGB32(128, 0, 0) '                            red color of pad in off condition
511.     Pcolor~&(2) = _RGB32(0, 128, 0) '                            green color of pad in off condition
512.     Pcolor~&(3) = _RGB32(128, 128, 0) '                          yellow color of pad in off condition
513.     Game% = 0 '                                                  set initial game level
514.     Skill% = 0 '                                                 set initial skill level
515.     GameDir% = -1 '                                              set intial blue slider direction
516.     SkillDir% = -1 '                                             set initial red slider direction
517.     SIMONFILE 0 '                                                load longest tune ever played if available
518.     '*
519.     '* Create the eight semi-circle color pads, four off, four on
520.     '*
521.     FOR Pcount% = 0 TO 3 '                                       cycle through four color pads
522.         _DEST Pad&(Pcount%, 0) '                                 set color pad off image as destination
523.         CLS '                                                    remove black transparency
524.         SELECT CASE Pcount% '                                    which color pad is being worked on?
525.             CASE 0 '                                             blue color pad
526.                 x% = 319: y% = 319 '                             set x,y coordinates of circles
527.             CASE 1 '                                             red color pad
528.                 x% = 0: y% = 319 '                               set x,y coordinates of circles
529.             CASE 2 '                                             green color pad
530.                 x% = 0: y% = 0 '                                 set x,y coordinates of circles
531.             CASE 3 '                                             yellow color pad
532.                 x% = 319: y% = 0 '                               set x,y coordinate of circles
533.         END SELECT
534.         CIRCLE (x%, y%), 319, _RGB32(16, 16, 16) '               draw simon outer circle segment
535.         PAINT (x%, y%), _RGB32(16, 16, 16), _RGB32(16, 16, 16) ' paint simon color
536.         CIRCLE (x%, y%), 300, Pcolor~&(Pcount%) '                draw color pad outer circle segment
537.         CIRCLE (x%, y%), 140, Pcolor~&(Pcount%) '                draw color pad inner circle segment
538.         PAINT (159, 159), Pcolor~&(Pcount%), Pcolor~&(Pcount%) ' paint color pad circle segment interior
539.         LINE (x%, y%)-(ABS(319 - x%), ABS(10 - y%)), _RGB32(16, 16, 16), BF ' separate color pads horizontally
540.         LINE (x%, y%)-(ABS(10 - x%), ABS(319 - y%)), _RGB32(16, 16, 16), BF ' separate color pads vertically
541.         CIRCLE (x%, y%), 319, _RGB32(32, 32, 32) '               highlight edge of simon
542.         Mask& = _COPYIMAGE(Pad&(Pcount%, 0)) '                   create an image mask
543.         _DEST Mask& '                                            set the mask as the destination
544.         _CLEARCOLOR Pcolor~&(Pcount%) '                          set circle segment as transparent
545.         _DEST Pad&(Pcount%, 1) '                                 set color pad on image as destination
546.         CLS '                                                    remove black transparency
547.         Clr~& = Pcolor~&(Pcount%) '                              remember color being worked on
548.         LINE (0, 0)-(319, 319), Clr~&, BF '                      fill entire image with color pad color
549.         FOR Count% = 129 TO 255 '                                cycle 126 times
550.             SELECT CASE Pcount% '                                which color pad is being worked on?
551.                 CASE 0 '                                         blue color pad
552.                     Clr~& = Clr~& + 1 '                          increase blue component
553.                 CASE 1 '                                         red color pad
554.                     Clr~& = Clr~& + 65536 '                      increase red component
555.                 CASE 2 '                                         green color pad
556.                     Clr~& = Clr~& + 256 '                        increase green component
557.                 CASE 3 '                                         yellow color pad
558.                     Clr~& = Clr~& + 65792 '                      increase red and green component (yellow)
559.             END SELECT
560.             CIRCLE (159, 159), (255 - Count%) * 2, Clr~& '       draw circle with new color component
561.             PAINT (159, 159), Clr~&, Clr~& '                     paint inside circle new color component
562.         NEXT Count%
563.         _PUTIMAGE (0, 0), Mask& '                                place mask over circles
564.     NEXT Pcount%
565.     _FREEIMAGE Mask& '                                           remove mask image from RAM (no longer needed)
566.     _FREEIMAGE Sheet& '                                          remove spritesheet from RAM (no longer needed)
567.  
568. END SUB
569.  
570. '----------------------------------------------------------------------------------------------------------------------
571. '                                                                                                               ENDGAME
572. SUB ENDGAME ()
573.  
574.     '--------------------------------------------------------------------
575.     '- Removes game's assets from RAM and returns to the operating system
576.     '--------------------------------------------------------------------
577.  
578.     SHARED Pad&() '     color pads: 0,x=BLUE, 1,x=RED, 2,x=GREEN, 3,x=YELLOW
579.     SHARED Tone&() '    game sounds
580.     SHARED Simon& '     simon graphics image
581.     SHARED SimonHelp& ' simon help screen
582.     SHARED Keys&() '    keyboard key images 0=Q, 1=W, 2=S, 3=A
583.     SHARED Bslider& '   blue slider switch image
584.     SHARED Rslider& '   red slider switch image
585.     SHARED OnOff& '     on/off slider switch
586.  
587.     DIM Count% '        generic counter
588.  
589.     LINE (321, 408)-(331, 418), _RGB32(0, 0, 0), BF ' clear power button
590.     _PUTIMAGE (313, 408), OnOff& '                    place power button in new position
591.     _DISPLAY '                                        update screen with changes
592.     FOR Count% = 0 TO 3 '                             cycle through assets
593.         _SNDCLOSE Tone&(Count%) '                     close sound files
594.         _FREEIMAGE Keys&(Count%, 0) '                 remove key raised images
595.         _FREEIMAGE Keys&(Count%, 1) '                 remove key pressed images
596.         _FREEIMAGE Pad&(Count%, 0) '                  remove color pad unlit images
597.         _FREEIMAGE Pad&(Count%, 1) '                  remove color pad lit images
598.     NEXT Count%
599.     _SNDCLOSE Tone&(4) '                              close last sound file
600.     _FREEIMAGE Simon& '                               remove simon image
601.     _FREEIMAGE SimonHelp& '                           remove simon help screen image
602.     _FREEIMAGE Bslider& '                             remove blue slider switch image
603.     _FREEIMAGE Rslider& '                             remove red slider switch image
604.     _FREEIMAGE OnOff& '                               remove on/off power switch image
605.     _DELAY 1 '                                        pause for 1 second
606.     SYSTEM '                                          return control to the operating system
607.  
608. END SUB
609.