Single Channel IRC client QB64

[amigojapan]

Code: QB64: [Select]

1. server$ = "irc.freenode.net"
2. nick$ = "your_nick_here"
3. channel$ = "#QB64"
4. client = _OPENCLIENT("TCP/IP:6667:" + server$)
5. line$ = "nick " + nick$ + CHR$(13) + CHR$(10) + "user a a a a" + CHR$(13) + CHR$(10)
6. PUT #client, , line$: SLEEP 2
7. line$ = "join " + channel$ + CHR$(13) + CHR$(10)
8. PUT #client, , line$: SLEEP 2
9.  
10. DO
11.     _DELAY 0.05 ' 50ms delay (20 checks per second)
12.     GET #client, , buff$
13.     IF buff$ <> "" THEN
14.         PRINT buff$
15.         PRINT ""
16.         PRINT user_input$;
17.         IF INSTR(1, buff$, "PING") = 1 THEN 'handle PING
18.             s$ = MID$(buff$, 5, LEN(buff$)) 'get orwell.freenode.net
19.             line$ = "PONG" + s$ + CHR$(13) + CHR$(10)
20.             PRINT "pong reached", line$
21.             PUT #client, , line$: SLEEP 2
22.         END IF
23.     END IF
24.     k$ = INKEY$
25.     IF k$ <> "" THEN
26.         IF k$ = CHR$(8) THEN
27.             user_input$ = MID$(user_input$, 1, LEN(user_input$) - 1)
28.             PRINT ""
29.             PRINT user_input$;
30.         ELSE IF k$ = CHR$(13) THEN
31.                 line$ = "privmsg " + channel$ + " :" + user_input$ + CHR$(13) + CHR$(10)
32.                 PUT #client, , line$: SLEEP 2
33.                 user_input$ = ""
34.                 PRINT ""
35.             ELSE
36.                 user_input$ = user_input$ + k$
37.                 PRINT k$; 'echo user input ; eliminates new lines
38.             END IF
39.         END IF
40.     END IF
41. LOOP
42. CLOSE client
43.  

[SierraKen]

Pretty cool! But backspace didn't work for some reason. But good job!

[amigojapan]

Thanks, yeah backspace would require a bit more work, I guess I will do that, since it is pretty important

[SMcNeill]

Thanks, yeah backspace would require a bit more work, I guess I will do that, since it is pretty important

...
        ELSEIF k$ = CHR$(8) THEN 'backspace key
            user_input$ = LEFT$(user_input$, LEN(user_input$)-1)
            PRINT k$; 'echo user input ; eliminates new lines
        ELSE
            user_input$ = user_input$ + k$
            PRINT k$; 'echo user input ; eliminates new lines
        END IF
...

[amigojapan]

yeah, did pretty much that, also made it easier to see what you are typing after a new commend comes in

[luke]

Messages in IRC are properly terminated by CR LF; that is, CHR$(13) + CHR$(10), not the reverse.

[amigojapan]

thanks