Function: StrReplace

[Qbee]

I made this function, because it seemed it's functionality is needed and there is no entry in the wiki.
Hope it will be useful.

Code: QB64: [Select]

1. _TITLE "StrReplace"
2. ' done 2019-12-16
3. ' by Myself (Karsten Maske)
4. '
5. ' StrReplace$ replaces oldChars by newChars in sourceString
6. '
7. ' SYNTAX:
8. ' newString = StrReplace(oldChars, newChars, sourceString)
9. '
10. ' sourceString: string to change
11. ' oldChars: 0 to length of sourceString; longer string returns sourceString
12. ' newChars: 0 to whatever fits
13. '
14. ' Examples:
15. '
16. a$ = "Hello world!"
17. b$ = StrReplace$("e", "a", a$)
18. PRINT b$
19.  
20. a$ = "The quick brown fox jumps over the lazy dog."
21. b$ = StrReplace$("fox", "duck", a$)
22. PRINT b$
23.  
24. b$ = StrReplace$(" ", "", a$)
25. PRINT b$
26.  
27.  
28. FUNCTION StrReplace$ (oldChars AS STRING, newChars AS STRING, sourceString AS STRING)
29.     DIM o AS INTEGER, n AS INTEGER, i AS INTEGER
30.  
31.     n = LEN(sourceString)
32.     o = LEN(oldChars)
33.     IF n < 1 THEN
34.         StrReplace$ = ""
35.         EXIT FUNCTION
36.     END IF
37.  
38.     IF o > n THEN
39.         StrReplace$ = sourceString
40.         EXIT FUNCTION
41.     END IF
42.  
43.     IF n = o THEN
44.         IF sourceString = oldChars THEN
45.             StrReplace$ = newChars
46.             EXIT FUNCTION
47.         END IF
48.     END IF
49.  
50.     StrReplace$ = ""
51.     FOR i = 1 TO n
52.         IF i + o <= n THEN
53.             IF MID$(sourceString, i, o) = oldChars THEN
54.                 StrReplace$ = StrReplace$ + newChars
55.                 i = i + o - 1
56.             ELSE
57.                 StrReplace$ = StrReplace$ + MID$(sourceString, i, 1)
58.             END IF
59.         ELSE
60.             StrReplace$ = StrReplace$ + MID$(sourceString, i)
61.             EXIT FUNCTION
62.         END IF
63.     NEXT
64.  
65. END FUNCTION
66.  

[commandvom]

great!

[Petr]

Thank you, it is very usefull for me! Somewhere is very small bug - last character in source string is not replaced. My solution? I add one more space to end the source string and then it work very well!

Thanks!

[bplus]

Hi, I think there is something simpler:

Code: QB64: [Select]

1.  
2. _TITLE "strReplace$ test" 'b+ 2019-12-28
3. PRINT strReplace$("hello all", "l", "llllll")
4.  
5. FUNCTION strReplace$ (s$, replace$, new$) 'case sensitive
6.     strReplace$ = s$
7.     p = INSTR(s$, replace$)
8.     WHILE p
9.         strReplace$ = MID$(strReplace$, 1, p - 1) + new$ + MID$(strReplace$, p + LEN(replace$))
10.         p = INSTR(p + LEN(new$), strReplace$, replace$)
11.     WEND
12. END FUNCTION
13.  

[Pete]

I actually do this type of work extensively in some html replacement projects. To make it easier, I just feed in the entire document to the program, as a single string then parse the crap out of it until all the replacements are made. Here is the simplest of the methods I have used. It's case sensitive, but this cut-down version will not allow for non-replacement actions on larger words, which contain the search word. Most of the code is actually here just to display it nicely to your screen. The function to replace is only 5-lines.

Pete

Code: QB64: [Select]

1. WIDTH 80, 25
2. lmargin = 10
3. rmargin = _WIDTH - 10
4.  
5. a$ = "Steve is a great coder who can accomplish some pretty amazing feats, and some even think of Steve as a god. Well, Steve really isn't a god, he's much better. You see a god has to waste too much of his time on mortals, while Steve can use all his time to create amazing Steve creations that are totally Steveriffic!"
6.  
7. PRINT: GOSUB printit: PRINT: _DELAY 5
8.  
9. srch$ = "Steve"
10. replace$ = "Pete"
11. DO WHILE INSTR(a$, srch$)
12.     a$ = MID$(a$, 1, INSTR(a$, srch$) - 1) + replace$ + MID$(a$, INSTR(a$, srch$) + LEN(srch$))
13. LOOP
14.  
15. GOSUB printit
16.  
17. END
18.  
19. printit:
20. IF RIGHT$(a$, 1) <> " " THEN a$ = a$ + " "
21. seed = 1
22. DO UNTIL INSTR(seed, a$, " ") = 0
23.     z$ = MID$(a$, seed, rmargin - lmargin + 2)
24.     IF lmargin = rmargin THEN z$ = MID$(z$, 1, LEN(z$) - 1)
25.     IF RIGHT$(z$, 1) = " " THEN
26.         x = LEN(z$)
27.     ELSE
28.         x = _INSTRREV(z$, " ")
29.     END IF
30.     IF x = 0 THEN x = rmargin - lmargin + 1
31.     LOCATE , lmargin
32.     PRINT RTRIM$(MID$(a$, seed, x))
33.     seed = seed + x
34. LOOP
35. RETURN
36.