My Best Clock

[bplus]

Pete thought it looked like an umbrella before; now I think it looks like my doggy’s water bowl.  LOL!

Let me know how it does with water. :-))

[Pete]

Let me know how it does with water. :-))

You want what? A watered down version? Sorry. You need FreeBASIC for that!

[SierraKen]

Dang that's genius bplus! Amazing job you did there. I'll put this one on my website instead. It's apps like this that make me wish I could put the .exe online without Windows having a fit saying I am an unknown programmer with their security stuff. There's a way around that but it sure scares people downloading. So for now the code will go as a .txt file on my website and that will be good enough. I think Microsoft charges programmers a lot of money to be "known". Although I'm not sure if the $19 fee for Windows Store apps would apply to that or not. Anyways, thanks again B+.  Oh and if I ever do put the .exe online, I won't charge a penny for it so no worries.

[SierraKen]

LOL I was confused over this code B+, until you say at the bottom that it's part of your own project you are working on. lol

PS I was a little bit off with the arm ends near center of the clock, this code:

Code: QB64: [Select]

1. xPlus120 = xCenter + r * COS(_D2R(a + 120))
2. yPlus120 = yCenter + r * SIN(_D2R(a + 120))
3.  
4. xMinus120 = xCenter + r * COS(_D2R(a - 120))
5. yMinus120 = yCenter + r * SIN(_D2R(a - 120))
6.  

Draws the base of the iso Triangle on the same side of clock center as the pointed end. I intended to put the points of the base iso triangle on the other side of the clock center than the arm point, to do that, r had to be negative (equivalent to subtracting PI, I think):

Code: QB64: [Select]

1. xPlus120 = xCenter - r * COS(_D2R(a + 120))
2. yPlus120 = yCenter - r * SIN(_D2R(a + 120))
3.  
4. xMinus120 = xCenter - r * COS(_D2R(a - 120))
5. yMinus120 = yCenter - r * SIN(_D2R(a - 120))
6.  

Also I did the angles in radians, = in terms of PI, since this is mostly gobblely-gook to Ken :)
Oh wait, the arms code is all Ken's except my mod of seconds hand back to a line, still Ken's numbers... I redrew my own alarm clock with this clockface and my own arms code, testing what I said above. Still need to install the lovely chimes Ken has going here!. :)

[bplus]

Re: About the iso triangle base for the arms

Man! I had it right the first time with the +r, dang it!

Code: QB64: [Select]

1. xPlus120 = xCenter + r * COS(_D2R(a + 120))
2. yPlus120 = yCenter + r * SIN(_D2R(a + 120))
3.  
4. xMinus120 = xCenter + r * COS(_D2R(a - 120))
5. yMinus120 = yCenter + r * SIN(_D2R(a - 120))

Is correct as written.

I was rereading Ken's last post and redid the geometry, -r doesn't make sense!

It was pure luck that it worked (in my other program the -r) because I was working in radians NOT degrees and I needed to convert the 120 degrees to 2*Pi/3 Radians which I hadn't, although strangely -r does work with 120 degrees unconverted to radians??? another life miracle :)

@Ken
About that 19$ for something from MS, doesn't sound like you know what you are getting, I sure don't.
As for strangers running your exe's, I would advise posting source code and links to downloading QB64 so your audience can do these exe's for themselves AND with QB64 working on different platforms, you potentially have a wider base with source bas code than with exe's. I know Linux people are much more Do-It-Yourselfers than MS users, generally speaking. 


 

[SierraKen]

Thanks bplus. Well I only partly know about the $19 in that it lets programmers put stuff in the Windows Store. The things I don't know about is what kind of things they accept and what containers to use, and of course if it requires even more money to verify me as a known programmer. So, I'm not going to do it anytime soon. And I can't just put a .zip of an .exe on my website because of the warnings Windows gives. Windows even gives a warning for a .bas file that's zipped up and from the Internet. But that isn't as bad. That is why I try to put almost all my programs as .txt files for people to copy/paste to their QB64 language. The reason I brought all of this up is because I have a lot of friends and family that I would love to share my creations with. But since they don't know anything about programming and don't want to, all I can do is make photos and videos of them. But that's OK, it's just my hobby and I'm fine with that. Plus I got this forum. :). 
Oh and one more thing about websites, it costs a lot of money to be a verified website with its files as well. Some websites cost in the $100's every few years just to keep it secure and known by Microsoft. So I can't do that on mine. How I miss the 90's... :) But on the other hand, I understand their reasoning with so many hackers out there these days.

[Petr]

Solution for smooth movement seconds:

Code: QB64: [Select]

1.  
2.  
3. SCREEN _NEWIMAGE(800, 600, 32)
4. CX = 400
5. CY = 300
6. R = 150
7.  
8. DO
9.     GETTIME Hours, minutes, seconds, miliseconds
10.     IF Hours > 12 THEN Hours = Hours - 12
11.     IF seconds = 0 THEN seconds = 60
12.     Hx = CX + COS(-_PI / 2 + _PI(2) / 12 * Hours) * R * .85
13.     Hy = CY + SIN(-_PI / 2 + _PI(2) / 12 * Hours) * R * .85
14.     Mx = CX + COS(-_PI / 2 + _PI(2) / 60 * minutes) * R * .8
15.     My = CY + SIN(-_PI / 2 + _PI(2) / 60 * minutes) * R * .8
16.     Sx = CX + COS(-_PI / 2 + _PI(2) / 60 * (miliseconds / 100 + seconds)) * R * .8
17.     Sy = CY + SIN(-_PI / 2 + _PI(2) / 60 * (miliseconds / 100 + seconds)) * R * .8
18.  
19.     CLS
20.     CIRCLE (CX, CY), R
21.     stp = 0
22.     FOR D = 0 TO _PI(2) STEP _PI(2) / 60
23.         IF stp MOD 5 = 0 THEN dd = 10 ELSE dd = 5
24.         Dx = CX + COS(-_PI / 2 + D) * R
25.         Dy = CY + SIN(-_PI / 2 + D) * R
26.         Dx2 = CX + COS(-_PI / 2 + D) * (R - dd)
27.         Dy2 = CY + SIN(-_PI / 2 + D) * (R - dd)
28.         LINE (Dx, Dy)-(Dx2, Dy2)
29.         stp = stp + 1
30.     NEXT
31.  
32.  
33.     LINE (CX, CY)-(Hx, Hy)
34.     LINE (CX, CY)-(Mx, My), &HFFFFFF00
35.     LINE (CX, CY)-(Sx, Sy), &HFFFF0000
36.  
37.     _DISPLAY
38.     _LIMIT 30
39. LOOP
40.  
41. SUB GETTIME (Hodina, Minuta, Sekunda, Setina)
42.     hodnota = TIMER
43.     IF hodnota < 60 THEN hodin = 0: minut = 0: sekund = hodnota: GOTO a1
44.     IF hodnota > 60 AND hodnota < 3600 THEN hodin = 0: minut = hodnota / 60: GOTO a2
45.     Hodina = hodnota / 3600
46.     hodin$ = STR$(Hodina)
47.     tecka = INSTR(0, hodin$, ".")
48.     Minuta = (VAL("0." + RIGHT$(hodin$, LEN(hodin$) - tecka)) * 0.6) * 100
49.     a2:
50.     minut$ = STR$(Minuta)
51.     tecka = INSTR(0, STR$(Minuta), ".")
52.     sekund = (VAL("0." + RIGHT$(minut$, LEN(minut$) - tecka)) * 0.6) * 100
53.     a1:
54.     sekund$ = STR$(sekund)
55.     tecka = INSTR(0, sekund$, ".")
56.     Setina = (VAL("0." + RIGHT$(sekund$, LEN(sekund$) - tecka)) * 1) * 100
57.  
58.     Minuta = INT(Minuta)
59.     Sekunda = INT(sekund)
60.     IF Sekunda = 60 THEN Sekunda = 0
61. END SUB
62.  

[SierraKen]

Thanks Petr! All I needed from your code there was _LIMIT 30. But how did you figure out how to use 30? I also removed the _DELAY command so now the second hand is smooth and doesn't move every second, instead it always moves.
I hope you guys like this.. B+ what do you think? I'll put it on my website soon after a couple more tests. So far I've only tested it for 2 minutes.

Code: QB64: [Select]

1. 'Clock by Ken G and b+. Also thank you to Petr from the QB64.org forum for smooth second hand movement.
2.  
3. _TITLE "Clock by Ken G., b+, and Petr" 'b+ mod 2019-12-03
4. CONST xmax = 360, ymax = 368, xCenter = xmax / 2, yCenter = ymax / 2, p = 3.14159265, p2 = p * 2, pd2 = p / 2
5. DIM SHARED clockFace&
6. SCREEN _NEWIMAGE(360, 368, 32)
7. clockFace& = _NEWIMAGE(xmax, ymax, 32)
8. _DEST clockFace&
9. drawClockFace
10. _DEST 0
11. DO
12.     _LIMIT 30
13.     CLS
14.     _PUTIMAGE , clockFace&, 0
15.  
16.     hours = TIMER \ 3600
17.     minutes = TIMER \ 60 - hours * 60
18.     seconds = (TIMER - hours * 3600 - minutes * 60)
19.     ho$ = LEFT$(TIME$, 2): hou = VAL(ho$)
20.     min$ = MID$(TIME$, 4, 2): minu = VAL(min$)
21.     seco$ = RIGHT$(TIME$, 2): secon = VAL(seco$)
22.  
23.     'Hours
24.     h = 360 - hours * 30 + 180
25.     xxx = INT(SIN(h / 180 * 3.141592) * 100) + 180
26.     yyy = INT(COS(h / 180 * 3.141592) * 100) + 184
27.     FOR b = -8 TO 8 STEP .1
28.         LINE (180 + b, 184)-(xxx, yyy), _RGB32(155, 0, 0)
29.         LINE (180, 184 + b)-(xxx, yyy), _RGB32(155, 0, 0)
30.     NEXT b
31.  
32.     'Minutes
33.     m = 180 - minutes * 6
34.     xx = INT(SIN(m / 180 * 3.141592) * 150) + 180
35.     yy = INT(COS(m / 180 * 3.141592) * 150) + 184
36.     FOR b = -5 TO 5 STEP .1
37.         LINE (180 + b, 184)-(xx, yy), _RGB32(155, 80, 40)
38.         LINE (180, 184 + b)-(xx, yy), _RGB32(155, 80, 40)
39.     NEXT b
40.  
41.     'Seconds
42.     s = (60 - seconds) * 6 + 180
43.     x = INT(SIN(s / 180 * 3.141592) * 165) + 180
44.     y = INT(COS(s / 180 * 3.141592) * 165) + 184
45.     'FOR b = -5 TO 5 STEP .1
46.     ' LINE (180 + b, 184)-(x, y), _RGB32(255, 164, 100)
47.     LINE (180, 184)-(x, y), _RGB32(255, 164, 84)
48.     'NEXT b
49.  
50.     'fix clock arms with knob
51.     FOR rrr = 6 TO 0 STEP -.25
52.         CIRCLE (180, 184), rrr, _RGB32(1.5 * (255 - 25 * rrr), 1.5 * (128 - 17 * rrr), 1.5 * (64 - 8 * rrr))
53.     NEXT
54.  
55.     'Chimes
56.     IF minu = 0 AND secon = 0 THEN
57.         hour2 = hou
58.         IF hour2 > 12 THEN hour2 = hour2 - 12
59.         IF hour2 = 0 THEN hour2 = 12
60.         FOR chimes = 1 TO hour2
61.             ttt = 0
62.             DO
63.                 'queue some sound
64.                 DO WHILE _SNDRAWLEN < 0.1 'you may wish to adjust this
65.                     sample = SIN(ttt * 340 * ATN(1) * 8) '340Hz sine wave (ttt * 440 * 2p)
66.                     sample = sample * EXP(-ttt * 3) 'fade out eliminates clicks after sound
67.                     _SNDRAW sample
68.                     ttt = ttt + 1 / _SNDRATE 'sound card sample frequency determines time
69.                 LOOP
70.                 'do other stuff, but it may interrupt sound
71.             LOOP WHILE ttt < 2 'play for 2 seconds
72.             DO WHILE _SNDRAWLEN > 0 'Finish any left over queued sound!
73.             LOOP
74.         NEXT chimes
75.     END IF
76.  
77.     two:
78.     _DISPLAY
79. LOOP
80.  
81. SUB drawClockFace
82.     DIM angle, r, n AS INTEGER, c AS _UNSIGNED LONG, x1, y1, x2, y2
83.     DIM level AS INTEGER, shade AS INTEGER, rr, gg, bb
84.     rr = 20: gg = 10: bb = 5
85.     CLS
86.     angle = p2 / 12: r = yCenter * .95
87.     FOR level = 0 TO 2
88.         x1 = xCenter + COS(0 - pd2) * r: y1 = yCenter + SIN(0 - pd2) * r
89.         FOR n = 1 TO 12
90.             x2 = xCenter + COS(n * angle - pd2) * r: y2 = yCenter + SIN(n * angle - pd2) * r
91.             IF n > 6 THEN shade = n - 6 ELSE shade = 6 - n
92.             IF n = 12 THEN shade = 6
93.             IF level = 1 THEN shade = 6 - shade
94.             c = _RGB32((level * 60) + rr + shade * 50, (level * 30) + gg + shade * 30, (level * 15) + bb + shade * 15)
95.             fillTriangle xCenter, yCenter, x1, y1, x2, y2, c
96.             x1 = x2: y1 = y2
97.         NEXT
98.         IF level = 0 THEN r = r - 15 ELSE r = r - 50
99.     NEXT
100. END SUB
101.  
102. SUB fillTriangle (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
103.     DIM d AS LONG
104.     STATIC a&
105.     d = _DEST
106.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
107.     _DEST a&
108.     PSET (0, 0), K
109.     _DEST d
110.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
111. END SUB
112.  

[Pete]

Now all it needs is a nightlight effect to tell if it's AM or PM... and dog repellent, in case Steve downloads it.

Hey, I gave it a try and saved it to my file archives. It has a lot of great components in a nice compact coding format. Hooray! A horse a committee put together, instead of a three-humped camel.

Pete ^^^:D

[SierraKen]

LOL Pete. I like how this clock runs in the background and gongs at me when the hour is up. So I don't even have to look at a clock if I don't want to.

[bplus]

B+ what do you think?

Hi Ken, Fine if you like it, great. :)

Me, I am never satisfied, I'm up to this now for alarm clock that chimes the hour thanks to your clock!

Code: QB64: [Select]

1. OPTION _EXPLICIT 'B+ 2019-11-03   Alarm clock with Hour Chimes
2. 'variation on alarm clock 2019-06-22
3. 'designed for xmax = ymax = 320 but anything bigger should be OK
4. '2019-12-05 changed face again, changed arms by adding a trangle opposite point end
5. 'improved Alarm input screen and installed Ken's chimes to indicate the hour
6.  
7. CONST xmax = 500, ymax = 500, xCenter = xmax / 2, yCenter = ymax / 2, p = 3.14159265, p2 = p * 2, pd2 = p / 2
8. TYPE armType
9.     a AS SINGLE 'radian angle
10.     l AS SINGLE ' length
11.     iso AS SINGLE 'iso tri base, now for radius arm width perpedicular to point direction
12.     c AS _UNSIGNED LONG 'color
13. END TYPE
14. DIM SHARED clockFace&, alarm$
15.  
16. SCREEN _NEWIMAGE(xmax, ymax, 32)
17. _SCREENMOVE (_DESKTOPWIDTH - xmax) / 2, (_DESKTOPHEIGHT - ymax) / 2
18.  
19. DIM t$, h, m, s, chimes, sample, ttt
20.  
21. COLOR &HFF00DDDD
22. clockFace& = _NEWIMAGE(xmax, ymax, 32)
23. _DEST clockFace&
24. drawClockFace
25. _DEST 0
26.  
27. WHILE 1
28.     outputClock
29.     'Chimes
30.     t$ = TIME$
31.     h = VAL(MID$(t$, 1, 2))
32.     m = VAL(MID$(t$, 4, 2))
33.     s = VAL(MID$(t$, 7, 2))
34.     IF m = 0 AND s < 1 THEN
35.         IF h > 12 THEN h = h - 12
36.         IF h = 0 THEN h = 12
37.         FOR chimes = 1 TO h
38.             ttt = 0
39.             DO
40.                 'queue some sound
41.                 DO WHILE _SNDRAWLEN < 0.1 'you may wish to adjust this
42.                     sample = SIN(ttt * 340 * ATN(1) * 8) '340Hz sine wave (ttt * 440 * 2p)
43.                     sample = sample * EXP(-ttt * 3) 'fade out eliminates clicks after sound
44.                     _SNDRAW sample
45.                     ttt = ttt + 1 / _SNDRATE 'sound card sample frequency determines time
46.                 LOOP
47.                 'do other stuff, but it may interrupt sound
48.             LOOP WHILE ttt < 2 'play for 2 seconds
49.             DO WHILE _SNDRAWLEN > 0 'Finish any left over queued sound!
50.             LOOP
51.         NEXT chimes
52.     END IF
53.     IF UCASE$(INKEY$) = "A" THEN setAlarm
54.     _DISPLAY
55.     _LIMIT 60
56. WEND
57.  
58. SUB outputClock
59.     IF alarm$ = "" THEN _TITLE "<a> to Set Alarm Clock" ELSE _TITLE "Alarm Clock is Set"
60.     _PUTIMAGE , clockFace&, 0
61.     drawArms
62.     _PRINTSTRING (6, ymax - 21), TIME$
63.     IF alarm$ <> "" THEN
64.         _PRINTSTRING (xmax - 53, ymax - 21), "@" + alarm$
65.         IF MID$(TIME$, 1, 5) = alarm$ THEN
66.             _TITLE "Press any to stop beeping..."
67.             BEEP
68.         END IF
69.         IF LEN(INKEY$) THEN alarm$ = ""
70.     END IF
71. END SUB
72.  
73. SUB drawClockFace
74.     DIM angle, r, n AS INTEGER, c AS _UNSIGNED LONG, x1, y1, x2, y2
75.     DIM level AS INTEGER, shade AS INTEGER, rr, gg, bb
76.     rr = 10: gg = 5: bb = 2
77.     CLS
78.     angle = p2 / 60: r = yCenter * .95
79.     FOR level = 0 TO 10
80.         x1 = xCenter + COS(0 - pd2) * r: y1 = yCenter + SIN(0 - pd2) * r
81.         FOR n = 1 TO 60
82.             x2 = xCenter + COS(n * angle - pd2) * r: y2 = yCenter + SIN(n * angle - pd2) * r
83.             IF n > 30 THEN shade = n - 30 ELSE shade = 30 - n
84.             IF n = 60 THEN shade = 30
85.             IF level = 1 THEN shade = 30 - shade
86.             c = _RGB32(((level * 1.5) + rr + shade * 10), ((level * .75) + gg + shade * 5), ((level * .4) + bb + shade * 2.5))
87.             fillTriangle xCenter, yCenter, x1, y1, x2, y2, c
88.             x1 = x2: y1 = y2
89.         NEXT
90.         IF level = 0 THEN r = r - .1 * yCenter ELSE r = r - .02 * yCenter
91.     NEXT
92. END SUB
93.  
94. SUB drawArms
95.     DIM xPlus90, yPlus90, xMinus90, yMinus90, xop, yop, xPoint, yPoint, t AS DOUBLE, i AS INTEGER, rr, c AS _UNSIGNED LONG
96.     DIM arms(1 TO 3) AS armType
97.     arms(1).c = &HFF222211: arms(2).c = &HFF331111: arms(3).c = &HFF663322
98.     arms(1).l = yCenter * .6: arms(2).l = yCenter * .8: arms(3).l = yCenter * .84
99.     arms(1).iso = yCenter * .065: arms(2).iso = yCenter * .05: arms(3).iso = yCenter * .04 ' don't use in arm 3
100.     t = TIMER
101.     'the follwing angles are in radians with pd2 = Pi/2 subtracted
102.     arms(1).a = (t / 3600) / 12 * p2 - pd2
103.     arms(2).a = (t / 60 - 60 * INT(arms(1).a)) / 60 * p2 - pd2
104.     arms(3).a = (t - INT(arms(1).a) * 3600 - INT(arms(2).a) * 60) / 60 * p2 - pd2
105.     FOR i = 1 TO 3
106.         xPlus90 = xCenter + arms(i).iso * COS(arms(i).a + pd2)
107.         yPlus90 = yCenter + arms(i).iso * SIN(arms(i).a + pd2)
108.  
109.         xMinus90 = xCenter + arms(i).iso * COS(arms(i).a - pd2)
110.         yMinus90 = yCenter + arms(i).iso * SIN(arms(i).a - pd2)
111.  
112.         xPoint = xCenter + arms(i).l * COS(arms(i).a)
113.         yPoint = yCenter + arms(i).l * SIN(arms(i).a)
114.  
115.         xop = xCenter + 3 * arms(i).iso * COS(arms(i).a - p)
116.         yop = yCenter + 3 * arms(i).iso * SIN(arms(i).a - p)
117.  
118.         IF i < 3 THEN
119.             fillTriangle xPlus90, yPlus90, xMinus90, yMinus90, xPoint, yPoint, arms(i).c
120.             fillTriangle xPlus90, yPlus90, xMinus90, yMinus90, xop, yop, arms(i).c
121.         ELSEIF i = 3 THEN 'line works better here
122.             LINE (xop, yop)-(xPoint, yPoint), arms(i).c
123.         END IF
124.     NEXT
125.     FOR rr = 5 TO 1 STEP -1
126.         IF rr MOD 2 THEN c = &HFF663322 ELSE c = &HFF000000
127.         CIRCLE (xCenter, yCenter), rr, c
128.     NEXT
129. END SUB
130.  
131. SUB fillTriangle (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
132.     DIM d AS LONG
133.     STATIC a&
134.     d = _DEST
135.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
136.     _DEST a&
137.     PSET (0, 0), K
138.     _DEST d
139.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
140. END SUB
141.  
142. SUB setAlarm
143.     DIM s$
144.     s$ = "For time: hh = 00-23 : mm = 00-59"
145.     CLS
146.     _PRINTSTRING ((_WIDTH - 8 * LEN(s$)) / 2, _HEIGHT / 2 - 10), s$
147.     _DISPLAY
148.     s$ = "Enter hh:mm "
149.     inputG 8 * (_WIDTH / 8 - LEN(s$) - 8) / 2, _HEIGHT / 2 + 10, s$, alarm$, 8
150. END SUB
151.  
152. 'INPUT for Graphics screen
153. SUB inputG (x, y, prmpt$, var$, expectedLenVar%) 'input for a graphics screen x, y is where the prompt will start , returns through var$
154.     DIM tmp$, k$, saveAD
155.     saveAD = _AUTODISPLAY
156.     _KEYCLEAR
157.     _PRINTSTRING (x, y), prmpt$ + " {}"
158.     IF saveAD <> -1 THEN _DISPLAY
159.     DO
160.         k$ = INKEY$
161.         IF LEN(k$) = 1 THEN
162.             SELECT CASE ASC(k$)
163.                 CASE 13: var$ = tmp$: EXIT SUB
164.                 CASE 27: var$ = "": EXIT SUB
165.                 CASE 8 'backspace
166.                     IF LEN(tmp$) THEN
167.                         IF LEN(tmp$) = 1 THEN tmp$ = "" ELSE tmp$ = LEFT$(tmp$, LEN(tmp$) - 1)
168.                     END IF
169.                 CASE ELSE: IF ASC(k$) > 31 THEN tmp$ = tmp$ + k$
170.             END SELECT
171.             _PRINTSTRING (x, y), prmpt$ + " {" + tmp$ + "}" + SPACE$(expectedLenVar% - LEN(tmp$)) 'spaces needed at end to clear backspace chars
172.             IF saveAD <> -1 THEN _DISPLAY
173.         END IF
174.     LOOP
175. END SUB
176.  
177.  

[SierraKen]

That's one of the most amazing clocks I've ever seen on any computer B+. That's better than the stuff on Microsoft's Windows Store, seriously. LOL now I want to experiment more with the clock face. :) I might make a few clocks.

[SierraKen]

Here's a template for anyone to use of just clock hands with no clock face background. I'm thinking of making one where the user can press the space bar to change to a few different kinds of backgrounds within the same app. But here is the template I will use. I adjusted the center-point to be in the exact center and added a tiny blue pin in the middle. Feel free to change the colors and sizes of course. I also shrank the hour hand to half the size and am using a non-stop second hand. This also includes the gong sounds on top of every hour.

Code: QB64: [Select]

1. 'Use this template however you see fit. This was made by Ken G. with help from the QB64.org forum.
2. _TITLE "Clock Hands"
3. SCREEN _NEWIMAGE(350, 350, 32)
4. i = _NEWIMAGE(350, 350, 32)
5. ' ----------------------------------------
6. ' Draw clock here and use  _DEST i and _DEST 0
7. '_DEST i
8.  
9.  
10.  
11. '_DEST 0
12. '-----------------------------------------
13.  
14. DO
15.     _LIMIT 30
16.     hours = TIMER \ 3600
17.     minutes = TIMER \ 60 - hours * 60
18.     seconds = (TIMER - hours * 3600 - minutes * 60)
19.     ho$ = LEFT$(TIME$, 2): hou = VAL(ho$)
20.     min$ = MID$(TIME$, 4, 2): minu = VAL(min$)
21.     seco$ = RIGHT$(TIME$, 2): secon = VAL(seco$)
22.     'Seconds
23.     s = (60 - seconds) * 6 + 180
24.     x = INT(SIN(s / 180 * 3.141592) * 125) + 175
25.     y = INT(COS(s / 180 * 3.141592) * 125) + 175
26.     FOR b = -5 TO 5 STEP .1
27.         LINE (175 + b, 175)-(x, y), _RGB32(155, 83, 155)
28.         LINE (175, 175 + b)-(x, y), _RGB32(155, 83, 155)
29.     NEXT b
30.     'Minutes
31.     m = 180 - minutes * 6
32.     xx = INT(SIN(m / 180 * 3.141592) * 120) + 175
33.     yy = INT(COS(m / 180 * 3.141592) * 120) + 175
34.     FOR b = -5 TO 5 STEP .1
35.         LINE (175 + b, 175)-(xx, yy), _RGB32(0, 255, 255)
36.         LINE (175, 175 + b)-(xx, yy), _RGB32(0, 255, 255)
37.     NEXT b
38.     'Hours
39.     h = 360 - hours * 30 + 180
40.     xxx = INT(SIN(h / 180 * 3.141592) * 50) + 175
41.     yyy = INT(COS(h / 180 * 3.141592) * 50) + 175
42.     FOR b = -5 TO 5 STEP .1
43.         LINE (175 + b, 175)-(xxx, yyy), _RGB32(0, 255, 0)
44.         LINE (175, 175 + b)-(xxx, yyy), _RGB32(0, 255, 0)
45.     NEXT b
46.     FOR sz = .25 TO 5 STEP .25
47.         CIRCLE (175, 175), sz, _RGB32(0, 105, 255)
48.     NEXT sz
49.  
50.     'Chimes
51.     IF minu = 0 AND secon = 0 THEN
52.         hour2 = hou
53.         IF hour2 > 12 THEN hour2 = hour2 - 12
54.         IF hour2 = 0 THEN hour2 = 12
55.         FOR chimes = 1 TO hour2
56.             ttt = 0
57.             DO
58.                 'queue some sound
59.                 DO WHILE _SNDRAWLEN < 0.1 'you may wish to adjust this
60.                     sample = SIN(ttt * 340 * ATN(1) * 8) '340Hz sine wave (ttt * 440 * 2p)
61.                     sample = sample * EXP(-ttt * 3) 'fade out eliminates clicks after sound
62.                     _SNDRAW sample
63.                     ttt = ttt + 1 / _SNDRATE 'sound card sample frequency determines time
64.                 LOOP
65.                 'do other stuff, but it may interrupt sound
66.             LOOP WHILE ttt < 2 'play for 2 seconds
67.             DO WHILE _SNDRAWLEN > 0 'Finish any left over queued sound!
68.             LOOP
69.         NEXT chimes
70.     END IF
71.     two:
72.     _DISPLAY
73.     CLS
74.     _PUTIMAGE (0, 0), i
75. LOOP
76.  

[SierraKen]

I decided to make 10 clocks in 1 if I can. Every minute it will change to a different clock face. I got 4 done so far. :) Might take a few days but when I'm done I'll post it here. It's coming out really cool, can't wait until I show it.

[bplus]

Hey nice idea!