Isometric Mapping Demo

[bplus]

Problem gridsize of 10 fixed:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(1024, 720, 32)
2. _SCREENMOVE _MIDDLE
3.  
4. DIM SHARED GridSize AS INTEGER
5. DIM Kolor AS _UNSIGNED LONG
6. CONST Red = &HFFFFAACC, Green = &HFF00FF00
7. GridSize = 10 ' < 10 is causing problems with PAINT
8.  
9.  
10. DIM grid(9, 9) AS _BYTE 'create a grid to layout our map
11.  
12. FOR i = 0 TO 9 'and let's create that map.  It's just going to be 4 walls and a floor...
13.     grid(i, 0) = 1 'wall
14.     grid(i, 9) = 1
15.     grid(0, i) = 1
16.     grid(9, i) = 1
17. NEXT
18.  
19. FOR y = 1 TO 8
20.     FOR x = 1 TO 8
21.         grid(x, y) = 2 'floor
22.     NEXT
23. NEXT
24.  
25.  
26. 'Now, let's just draw grids one at a time to compare.
27. _PRINTSTRING (100, 80), "Normal 2D grid"
28. FOR y = 0 TO 9
29.     FOR x = 0 TO 9
30.         'normal grid first
31.         IF grid(x, y) = 1 THEN Kolor = Red ELSE Kolor = Green
32.         xpos = x * GridSize + 100: ypos = y * GridSize + 100
33.         xpos2 = xpos + GridSize: ypos2 = ypos + GridSize
34.         LINE (xpos, ypos)-(xpos2, ypos2), Kolor, BF
35.         LINE (xpos, ypos)-(xpos2, ypos2), &HFFFFFFFF, B
36.         'and that's all it takes for the normal grid.  Can't get any simpler for 2d maps!
37.     NEXT
38. NEXT
39.  
40. SLEEP
41.  
42. _PRINTSTRING (350, 80), "Normal 2D grid in Isometic Perspective"
43. FOR y = 0 TO 9
44.     FOR x = 0 TO 9
45.         'And now, let's do the same thing with our isometic map.
46.         IF grid(x, y) = 1 THEN Kolor = Red ELSE Kolor = Green
47.         xpos = x * GridSize + 100: ypos = y * GridSize + 100
48.         xpos2 = xpos + GridSize: ypos2 = ypos + GridSize
49.         IsoLine xpos, ypos, xpos2, ypos2, 500, 0, Kolor
50.         'And that's basically all the takes to rotate our map to make it a 2D isometic perspective
51.     NEXT
52. NEXT
53.  
54. SLEEP
55.  
56. _PRINTSTRING (350, 360), "Normal 2D grid in 3D Isometic Perspective"
57. FOR y = 0 TO 9
58.     FOR x = 0 TO 9
59.         'And here, I'm going to make it a 3D isometic map
60.         IF grid(x, y) = 1 THEN Kolor = Red ELSE Kolor = Green
61.         IF grid(x, y) = 1 THEN z = 16 ELSE z = 0 'Give my walls a height of 16, for a cube
62.  
63.         xpos = x * GridSize + 100: ypos = y * GridSize + 100
64.         xpos2 = xpos + GridSize: ypos2 = ypos + GridSize
65.         IsoLine3D xpos, ypos, xpos2, ypos2, z, 500, 300, Kolor
66.     NEXT
67. NEXT
68.  
69.  
70.  
71.  
72.  
73.  
74.  
75.  
76.  
77. FUNCTION CX2I (x AS LONG, y AS LONG) 'Convert Cartesian X To Isometic coordinates
78.     CX2I = x - y
79. END FUNCTION
80.  
81. FUNCTION CY2I (x AS LONG, y AS LONG) 'Convert Cartesian Y To Isometic coordinates
82.     CY2I = (x + y) / 2
83. END FUNCTION
84.  
85. SUB IsoLine (x, y, x2, y2, xoffset, yoffset, kolor AS _UNSIGNED LONG)
86.     'since we're drawing a diamond and not a square box, we can't use Line BF.
87.     'We have to manually down the 4 points of the line.
88.     LINE (CX2I(x, y) + xoffset, CY2I(x, y) + yoffset)-(CX2I(x2, y) + xoffset, CY2I(x2, y) + yoffset), kolor
89.     LINE -(CX2I(x2, y2) + xoffset, CY2I(x2, y2) + yoffset), kolor
90.     LINE -(CX2I(x, y2) + xoffset, CY2I(x, y2) + yoffset), kolor
91.     LINE -(CX2I(x, y) + xoffset, CY2I(x, y) + yoffset), kolor
92.     PAINT (CX2I(x, y) + xoffset, CY2I(x, y) + 4), kolor 'and fill the diamond solid
93.     LINE (CX2I(x, y) + xoffset, CY2I(x, y) + yoffset)-(CX2I(x2, y) + xoffset, CY2I(x2, y) + yoffset), &HFFFFFFFF
94.     LINE -(CX2I(x2, y2) + xoffset, CY2I(x2, y2) + yoffset), &HFFFFFFFF
95.     LINE -(CX2I(x, y2) + xoffset, CY2I(x, y2) + yoffset), &HFFFFFFFF
96.     LINE -(CX2I(x, y) + xoffset, CY2I(x, y) + yoffset), &HFFFFFFFF
97. END SUB
98.  
99. SUB IsoLine3D (x, y, x2, y2, z, xoffset, yoffset, kolor AS _UNSIGNED LONG)
100.     'Like IsoLine, we're going to have to draw our lines manually.
101.     'only in this case, we also need a Z coordinate to tell us how THICK/TALL/HIGH to make our tile
102.     r = _RED32(kolor): g = _GREEN32(kolor): b = _BLUE32(kolor)
103.     'Let's just do all the math first this time.
104.     'We need to turn those 4 normal points into 4 isometric points (x, y, x1, y1)
105.  
106.     TempX1 = CX2I(x, y) + xoffset: TempY1 = CY2I(x, y) + yoffset
107.     TempX2 = CX2I(x2, y) + xoffset: TempY2 = CY2I(x2, y) + yoffset
108.     TempX3 = CX2I(x2, y2) + xoffset: TempY3 = CY2I(x2, y2) + yoffset
109.     TempX4 = CX2I(x, y2) + xoffset: TempY4 = CY2I(x, y2) + yoffset
110.  
111.     'The top
112.     'LINE (TempX1, TempY1 - z)-(TempX2, TempY2 - z), kolor 'draw the diamond
113.     'LINE -(TempX3, TempY3 - z), kolor
114.     'LINE -(TempX4, TempY4 - z), kolor
115.     'LINE -(TempX1, TempY1 - z), kolor
116.     'PAINT (TempX1, TempY1 - z + 4), kolor 'and fill the diamond solid
117.     fquad TempX1, TempY1 - z, TempX2, TempY2 - z, TempX3, TempY3 - z, TempX4, TempY4 - z, kolor
118.     '
119.     'LINE (TempX1, TempY1 - z)-(TempX2, TempY2 - z), -1 'and redraw the grid
120.     'LINE -(TempX3, TempY3 - z), -1
121.     'LINE -(TempX4, TempY4 - z), -1
122.     'LINE -(TempX1, TempY1 - z), -1
123.  
124.     IF z <> 0 THEN 'no need to draw any height, if there isn't any.
125.         'the left side
126.         'LINE (TempX4, TempY4 - z)-(TempX4, TempY4), kolor 'draw it
127.         'LINE -(TempX3, TempY3), kolor
128.         'LINE -(TempX3, TempY3 - z), kolor
129.         'LINE -(TempX4, TempY4 - z), kolor
130.         'PAINT (TempX3 - 2, TempY3 - z + 2), kolor 'fill it
131.         fquad TempX4, TempY4 - z, TempX4, TempY4, TempX3, TempY3, TempX3, TempY3 - z, _RGB32(.25 * r, .5 * g, .75 * b)
132.         '
133.         'LINE (TempX4, TempY4 - z)-(TempX4, TempY4), -1 'redraw the grid lines
134.         'LINE -(TempX3, TempY3), -1
135.         'LINE -(TempX3, TempY3 - z), -1
136.         'LINE -(TempX4, TempY4 - z), -1
137.         'and then for the right side
138.         'LINE (TempX3, TempY3 - z)-(TempX3, TempY3), kolor 'draw it
139.         'LINE -(TempX2, TempY2), kolor
140.         'LINE -(TempX2, TempY2 - z), kolor
141.         'LINE -(TempX3, TempY3 - z), kolor
142.         'PAINT (TempX3 + 2, TempY3 - z + 2), kolor 'fill it
143.         fquad TempX3, TempY3 - z, TempX3, TempY3, TempX2, TempY2, TempX2, TempY2 - z, _RGB32(.75 * r, .3 * g, .3 * b)
144.  
145.         'LINE (TempX3, TempY3 - z)-(TempX3, TempY3), -1 'redraw the grid lines
146.         'LINE -(TempX2, TempY2), -1
147.         'LINE -(TempX2, TempY2 - z), -1
148.         'LINE -(TempX3, TempY3 - z), -1
149.     END IF
150.  
151.  
152. END SUB
153.  
154.  
155. 'this text was fetched
156. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
157.     DIM a&
158.     a& = _NEWIMAGE(1, 1, 32)
159.     _DEST a&
160.     PSET (0, 0), K
161.     _DEST 0
162.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
163.     _FREEIMAGE a& '<<< this is important!
164. END SUB
165.  
166. 'need 4 non linear points (not all on 1 line) list them clockwise so x2, y2 is diagonal of x4, y4
167. SUB fquad (x1, y1, x2, y2, x3, y3, x4, y4, K AS _UNSIGNED LONG)
168.     ftri x1, y1, x2, y2, x4, y4, K
169.     ftri x3, y3, x2, y2, x4, y4, K
170. END SUB
171.  
172.  
173.  

I also removed all the line drawing for edges and made slight change to red color

[SMcNeill]

Code: [Select]

SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
    STATIC a&
    D = _DEST
    IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
     _DEST a&
    PSET (0, 0), K
    _DEST D
    _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
END SUB
A few quick changes to the routine which should speed it up just a wee bit.  Speed is one of the primary concerns with any sort of fill routine.  ;)

(Also returned the _DEST to whatever it was previously, and not just the display screen by default.)

[bplus]

Code: [Select]

SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
    STATIC a&
    D = _DEST
    IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
     _DEST a&
    PSET (0, 0), K
    _DEST D
    _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
END SUB
A few quick changes to the routine which should speed it up just a wee bit.  Speed is one of the primary concerns with any sort of fill routine.  ;)

(Also returned the _DEST to whatever it was previously, and not just the display screen by default.)

With STATIC a&, you don't have to _FREEIMAGE a& ?

[SMcNeill]

With STATIC a&, you don't have to _FREEIMAGE a& ?

Nope.  You just make it once, leave it always available, and forget about it.  At its size, what is it?  4 bytes in memory + whatever the internal header structure uses?  Why reserve it, use it, free it, over and over, at that size?

[_vince]

Looking good, Steve!

[Cobalt]

Would it be possible to make a routine that would make each individual iso-box 1 at a time. like SUB ISOBOX(X,Y,SIZE,HEIGHT) and then you just have to call that over and over to create a grid. No that I think about that might as well name it CUBE.

would It be able to processes the cubes in stages? draw the outer shell, then fill then draw the inner lines? I added an Image of what I mean, as I am terrible at explaining!

thought if it was handled this way using paint might still be an easier and viable solution. might beable to add an option as to if the "back side" lines are drawn or not. (so the cube looks solid not semi transparent)

[SMcNeill]

Would it be possible to make a routine that would make each individual iso-box 1 at a time. like SUB ISOBOX(X,Y,SIZE,HEIGHT) and then you just have to call that over and over to create a grid. No that I think about that might as well name it CUBE.

would It be able to processes the cubes in stages? draw the outer shell, then fill then draw the inner lines? I added an Image of what I mean, as I am terrible at explaining!

thought if it was handled this way using paint might still be an easier and viable solution. might beable to add an option as to if the "back side" lines are drawn or not. (so the cube looks solid not semi transparent)

You can, as long as the colors are all the same on each side, but what do you do if they’re different?  (Brown dirt sides for a cliff, green grass on top, as an example.)

[bplus]

Would it be possible to make a routine that would make each individual iso-box 1 at a time. like SUB ISOBOX(X,Y,SIZE,HEIGHT) and then you just have to call that over and over to create a grid. No that I think about that might as well name it CUBE.

would It be able to processes the cubes in stages? draw the outer shell, then fill then draw the inner lines? I added an Image of what I mean, as I am terrible at explaining!

thought if it was handled this way using paint might still be an easier and viable solution. might beable to add an option as to if the "back side" lines are drawn or not. (so the cube looks solid not semi transparent)

I did just that with this: https://www.qb64.org/forum/index.php?topic=1905.0 and I even named it cube2 as cube was from other code I used for model.

There all sorts of cubes you can make. The one demo'd above fit in convenient square for front face 1 quarter of square for easy overlapping of psuedo 3D model, you can put the square face in any of 4 corners, or you can do regular hexagon shapes and grid them out like Hexagonal Life or Hexagonal Minesweeper.

You can use MAPTRIANGLE (2D) to add texture fills instead of ftri or fquad, which use MAPTRIANGLE too, and has to be much faster and more effective than PAINT eg transparent color fills!

[Cobalt]

You can, as long as the colors are all the same on each side, but what do you do if they’re different?  (Brown dirt sides for a cliff, green grass on top, as an example.)

what about using iso-boxes? have a horizontal one for top and bottom and then vertical ones for the sides? then each side could be a different color, or even alpha shaded? granted you would have 6 calls for each cube. I don't know, just fartin ideas that could keep it simple line\paint based routines.

You can use MAPTRIANGLE (2D) to add texture fills instead of ftri or fquad, which use MAPTRIANGLE too, and has to be much faster and more effective than PAINT eg transparent color fills!

I mean Maptri would be great for applying textures to the faces, but at sizes <32(or maybe even 24-pushing though) a texture is going to be very limited. I've used DirectQB's maptri function to texture walls in a '3D'ish type dungeon crawl, but I was using full screen 13, textured tris up to 256px hor, and 192px vert. my source texture was 256x256 even for that.(had to be ^2 for DQB though so some of that was lost[if i remember correctly, was over 20y/a now.])
I should try to port that to QB64 actually. Use higher res textures for 640x400 or 800x600.

[bplus]

Code: [Select]

SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
    STATIC a&
    D = _DEST
    IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
     _DEST a&
    PSET (0, 0), K
    _DEST D
    _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
END SUB
A few quick changes to the routine which should speed it up just a wee bit.  Speed is one of the primary concerns with any sort of fill routine.  ;)

(Also returned the _DEST to whatever it was previously, and not just the display screen by default.)

Hi Steve,

I found problem with this modified routine of ftri plus a place where neither version of cSleep or your Pause worked.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "fTri Tests, click 4 points to draw transparent quad" 'b+ 2019-12-15 discovered a problem with fTri or using it with fQuad
3.  
4. CONST xmax = 800, ymax = 600
5. SCREEN _NEWIMAGE(xmax, ymax, 32)
6. _SCREENMOVE 300, 40
7. DIM pi, oldMouse
8. DIM mx(1 TO 4), my(1 TO 4)
9. DO
10.     CLS
11.     WHILE pi < 4 'get 4 mouse clicks
12.         _PRINTSTRING (5, 5), SPACE$(20)
13.         _PRINTSTRING (5, 5), "Need 4 clicks, have" + STR$(pi)
14.         WHILE _MOUSEINPUT: WEND
15.         IF _MOUSEBUTTON(1) AND oldMouse = 0 THEN 'new mouse down
16.             pi = pi + 1
17.             mx(pi) = _MOUSEX: my(pi) = _MOUSEY
18.             CIRCLE (mx(pi), my(pi)), 2
19.         END IF
20.         oldMouse = _MOUSEBUTTON(1)
21.         _DISPLAY
22.         _LIMIT 60
23.     WEND
24.     _PRINTSTRING (5, 5), "Sleeping, click or press key... or esc"
25.     fquad1 mx(1), my(1), mx(2), my(2), mx(3), my(3), mx(4), my(4), &H880000FF
26.     _DISPLAY
27.     ' cSleep 45   '<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< dang!! this is working either !!!!!!!!!!!!!!!!!!!!
28.     ' Pause 30 ' <<<<<<<<<<<<<<<<<<<< well this isn't working either!!!!!!!!!!!!!!
29.     SLEEP
30.     pi = 0 'point index
31. LOOP UNTIL _KEYDOWN(27)
32.  
33.  
34. ' my original fTri that never had a problem with
35. ' found at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]:    http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=14425.0
36. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
37.     DIM D AS LONG, a&
38.     D = _DEST
39.     a& = _NEWIMAGE(1, 1, 32)
40.     _DEST a&
41.     PSET (0, 0), K
42.     _DEST D
43.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
44.     _FREEIMAGE a& '<<< this is important!
45. END SUB
46.  
47. '2019-11-20 Steve saves some time with STATIC and saves and restores last dest
48. SUB ftri1 (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
49.     DIM D AS LONG
50.     STATIC a&
51.     D = _DEST
52.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
53.     _DEST a&
54.     PSET (0, 0), K
55.     _DEST D
56.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
57. END SUB
58.  
59. ' original fill quad that may be at fault using Steve's fTri version
60. 'need 4 non linear points (not all on 1 line) list them clockwise so x2, y2 is opposite of x4, y4
61. SUB fquad (x1, y1, x2, y2, x3, y3, x4, y4, K AS _UNSIGNED LONG)
62.     ftri1 x1, y1, x2, y2, x4, y4, K
63.     ftri1 x3, y3, x2, y2, x4, y4, K
64. END SUB
65.  
66. 'try a new quad   OK works fine with original fTri but not fTr1 Steves mod
67. SUB fquad1 (x1, y1, x2, y2, x3, y3, x4, y4, K AS _UNSIGNED LONG)
68.     ftri1 x1, y1, x2, y2, x3, y3, K
69.     ftri1 x3, y3, x4, y4, x1, y1, K
70. END SUB
71.  
72. 'now this original code is not working!
73. SUB cSleep (secsWait AS DOUBLE) 'wait for keypress or mouseclick, solves midnight problem nicely I think
74.     DIM wayt AS INTEGER, oldMouse AS INTEGER, k AS LONG, startTime AS DOUBLE
75.  
76.     startTime = TIMER
77.     wayt = 1
78.     _KEYCLEAR
79.     WHILE wayt
80.         WHILE _MOUSEINPUT: WEND
81.         IF _MOUSEBUTTON(1) AND oldMouse = 0 THEN wayt = 0
82.         oldMouse = _MOUSEBUTTON(1) ' <<< this is Steve's cool way to get clear of mouse click
83.         k = _KEYHIT: IF k > 0 THEN _KEYCLEAR: wayt = 0
84.         IF TIMER - startTime < 0 THEN 'past midnight
85.             IF TIMER + 24 * 60 * 60 - startTime > secsWait THEN wayt = 0
86.         ELSE
87.             IF TIMER - startTime >= secsWait THEN wayt = 0
88.         END IF
89.         _LIMIT 30
90.     WEND
91. END SUB
92.  
93. 'try Steve's Pause, nope doesn't work either!!!!
94. SUB Pause (time AS _FLOAT)
95.     DIM ExitTime AS _FLOAT, oldMouse AS INTEGER, k AS LONG
96.     _KEYCLEAR 'clear the keyboard buffer so we don't automatically exit the routine
97.     IF time <= 0 THEN ExitTime = 1.18E+1000 ELSE ExitTime = time + TIMER
98.     DO
99.         WHILE _MOUSEINPUT: WEND: IF _MOUSEBUTTON(1) AND NOT oldMouse THEN EXIT SUB
100.         k = _KEYHIT: IF k > 0 THEN _KEYCLEAR: EXIT SUB 'clear any stray key events so they don't mess with code outside the Pause.
101.         oldMouse = _MOUSEBUTTON(1)
102.         _LIMIT 10
103.     LOOP UNTIL ExitTime < TIMER
104. END SUB
105.  
106.  

[bplus]

Hi Steve,

This line added to both cSleep and Pause seems to fix the problem in the code above:

Code: QB64: [Select]

1. WHILE _MOUSEINPUT OR _MOUSEBUTTON(1): WEND
2.  

where we use _KEYCLEAR, we have to clear old mouse clicks also?

I have not tested updated code elsewhere yet.

[SMcNeill]

Hi Steve,

This line added to both cSleep and Pause seems to fix the problem in the code above:

Code: QB64: [Select]

1. WHILE _MOUSEINPUT OR _MOUSEBUTTON(1): WEND
2.  

where we use _KEYCLEAR, we have to clear old mouse clicks also?

I have not tested updated code elsewhere yet.

One thing I see is missing: oldmouse should be set to -1 before the loop starts.

WHILE _MOUSEINPUT: WEND
IF _MOUSEBUTTON(1) = -1 AND oldmouse = 0 THEN...

If we don’t set oldmouse to -1, we’d instantly kick out of the loop if the user had the button down to begin with.

By setting oldmouse to -1 at the start, we treat the routine as if the button was previously held down, and only accept a click once we get confirmation it’s been up, before being pressed down.

^There might be your error.

[bplus]

Hi Steve,

That Pause routine came from here:
https://www.qb64.org/forum/index.php?topic=1511.msg111606#msg111606
and was what I based cSleep on.


Setting oldMouse to -1 at start does seem better than my fix. I will test, thanks :)

Any thoughts about fTri? It seems to retain the last transparent color when we use STATIC a& and not _FREEIMAGE.

[SMcNeill]

Hi Steve,

That Pause routine came from here:
https://www.qb64.org/forum/index.php?topic=1511.msg111606#msg111606
and was what I based cSleep on.


Setting oldMouse to -1 at start does seem better than my fix. I will test, thanks :)

Any thoughts about fTri? It seems to retain the last transparent color when we use STATIC a& and not _FREEIMAGE.

Several options; as I didn’t think about alpha blending with the static handle.

CLS, 0 could clear the old pixel first.
Or _DONTBLEND a& before using the PSET command (I’d probably just go this route, as DONTBLEND is a speed up over using blend.)

Edit: Went in and preset oldmouse to -1 in the Pause command so it shouldn’t have the previously down glitch anymore.  ;)

Code: [Select]

    IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32): _DONTBLEND a&
(The above should set a& to no blend mode and then leave it to that, fixing the alpha issue with it.)

[bplus]

Several options; as I didn’t think about alpha blending with the static handle.

CLS, 0 could clear the old pixel first.
Or _DONTBLEND a& before using the PSET command (I’d probably just go this route, as DONTBLEND is a speed up over using blend.)

Edit: Went in and preset oldmouse to -1 in the Pause command so it shouldn’t have the previously down glitch anymore.  ;)

Code: [Select]

    IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32): _DONTBLEND a&
(The above should set a& to no blend mode and then leave it to that, fixing the alpha issue with it.)

Hi Steve,

Reading about _DONTBLEND in help, it says that such will make the background opaque and block the background. When I use transparent colors with fTri, I usually want just a layer of see through color over what's behind. It's looking like I want to stick with original fTri that frees image to keep pure transparent layers going.

Update: confirmed the transparency is lost with _DONTBLEND

Thanks for your thoughts :)