Paint Image

[Petr]

Hi Steve,
I'd love to look at your concept, but it won't be right away. I have a visit that I have to give attention. So maybe in two days there will be time. May it all go well with your wife and she will soon be home. P.

[TempodiBasic]

@Bplus

And it looks to me like where PAINT does work, your Border Color is full Alpha 255 and where it doesn't work your Border Color is not full Alpha

yes this code confirm the theory of 255 alpha goodness!

Code: QB64: [Select]

1. CONST r1 = _RGBA32(200, 0, 0, 255), r2 = _RGBA32(199, 0, 0, 200)
2. CONST r3 = _RGBA32(200, 0, 0, 255), r4 = _RGBA32(199, 0, 0, 230), r5 = _RGBA32(180, 0, 0, 255)
3. ' r1 r3 r5 are 255Alpha, r4 230Alpha and r2 200Alpha
4.  
5. SCREEN _NEWIMAGE(800, 600, 32)
6.  
7. CIRCLE (100, 100), 100, r1
8. PAINT (100, 100), r2, r1 '<- r1 255Alpha  / r2 200Alpha THIS WORKS
9. LOCATE 20, 1: PRINT "circle color r1 255 alpha, fill r2 200 alpha"
10. SLEEP 2
11. CLS
12. SLEEP 1
13. LINE (200, 200)-STEP(50, 70), r3, B
14. PAINT STEP(-10, -10), r4, r3 '<---r3 255Alpha / r4 230Alpha   THIS WORKS
15. LOCATE 20, 1: PRINT "box color r3 255 alpha, fill r4 230 alpha"
16. SLEEP 2
17. LINE (100, 100)-(150, 170), r5, BF
18. SLEEP 2
19. LINE (200, 200)-STEP(50, 70), r5, B
20. PAINT (1, 1), r3, r5 '<-- r5 255Alpha/ r3 255Alpha       THIS WORKS
21. LOCATE 22, 1: PRINT "box color r5 255 alpha, fill r3 255 alpha"
22. SLEEP 2
23. CLS
24. LINE (300, 100)-(404, 404), r4, B
25. PAINT (400, 400), r2, r4 ' <-- r4 230Alpha / r2 200Alpha   THIS  DOESN'T WORK
26. LOCATE 20, 1: PRINT "box color r4 230 alpha, fill r2 200 alpha"
27. SLEEP 2
28. CLS
29. LINE (300, 100)-(404, 404), r2, B
30. PAINT (400, 400), r4, r2 ' <-- r4 230Alpha / r2 200Alpha THIS DOESN'T WORK
31. LOCATE 20, 1: PRINT "box color r2 200 alpha, fill r4 230 alpha"
32. SLEEP 2
33. CLS
34. 'LINE (300, 100)-(404, 404), r1, B
35. CIRCLE (400, 400), 50, r1
36. PAINT (400, 400), r2, r1 ' <-- r1 255Alpha / r2 200Alpha THIS WORKS
37. LOCATE 20, 1: PRINT "box color r1 255 alpha, fill r2 200 alpha"
38.  
39. SLEEP 2
40. CLS
41. CIRCLE (400, 400), 50, r2
42. PAINT (400, 400), r2, r2 ' <-- r2 200Alpha / r2 200Alpha THIS DOESN'T WORK
43. LOCATE 20, 1: PRINT "box color r2 200 alpha, fill r2 200 alpha"
44.  

[TempodiBasic]

Hi Bplus
about the idea to use _DONTBLEND
here is a workaround that must be coded in a function that stores and then draws back the frame of the area to be painted.

Code: QB64: [Select]

1. 'CONST r1 = &HFFBB0000, r2 = &HFF00BB00 'OK paint works right with line box
2. 'CONST r1 = _RGB32(200, 0, 0), r2 = _RGB32(0, 128, 0) ' <<<<<<<  screws up doesn't even draw box!!!
3. SCREEN _NEWIMAGE(800, 600, 32)
4. _SCREENMOVE 300, 40
5.  
6. DIM r1 AS _UNSIGNED LONG, r2 AS _UNSIGNED LONG, back AS _UNSIGNED LONG
7.  
8. ' ok normal paint working
9. r1 = _RGB32(200, 0, 0)
10. r2 = _RGB32(0, 128, 0)
11.  
12. ' and alpha paint NOT working
13. 'CLS '<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< might work now, nope!
14.  
15. r1 = _RGBA32(200, 0, 0, 1) 'try nearly invisible color
16. r2 = _RGBA32(0, 128, 0, 200)
17. back = _RGBA(0, 0, 0, 255)
18. CLS , back
19. _DONTBLEND '<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< OK now????  YES   but _DONTBLEND ruins transparency to make border lines invisible.
20. LINE (103, 103)-STEP(100, 100), r1, B '<- this must be converted in a function that stores the frame of the area to paint
21. PRINT POINT(103, 103); "  "; POINT(110, 110)
22. SLEEP 1
23. PAINT (109, 109), r2, r1
24. PRINT POINT(103, 103); "  "; POINT(110, 110)
25. _BLEND ' reactivate alpha
26. LINE (103, 103)-STEP(100, 100), back, B '<- here the function that draws  back the frame
27. PRINT POINT(103, 103); "  "; POINT(110, 110)
28. LOCATE 15, 1: PRINT r1, r2, back

this can be an alternative idea to Paint method.

[SMcNeill]

Non-Recursive PaintFill.  At this point, it's slower than heck, but it works!

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2.  
3.  
4. LINE (100, 100)-(300, 300), -1, BF
5. CIRCLE (300, 300), 100, -1
6. PAINT (301, 301), -1
7.  
8.  
9. fill 200, 200, &HFFFF0000, 0
10.  
11.  
12.  
13.  
14.  
15.  
16.  
17.  
18. SUB fill (x, y, kolor AS _UNSIGNED LONG, backkolor AS _UNSIGNED LONG)
19.     DIM Array(-1 TO _WIDTH, -1 TO _HEIGHT)
20.     pass = 1
21.     Array(x, y) = pass
22.     DO
23.         finished = -1
24.         FOR x = 0 TO _WIDTH - 1
25.             FOR y = 0 TO _HEIGHT - 1
26.                 IF Array(x, y) = pass THEN
27.                     IF x - 1 >= 0 THEN
28.                         IF Array(x - 1, y) = 0 AND POINT(x - 1, y) <> backkolor THEN Array(x - 1, y) = pass + 1: finished = 0
29.                     END IF
30.                     IF x + 1 < _WIDTH THEN
31.                         IF Array(x + 1, y) = 0 AND POINT(x + 1, y) <> backkolor THEN Array(x + 1, y) = pass + 1: finished = 0
32.                     END IF
33.                     IF y - 1 >= 0 THEN
34.                         IF Array(x, y - 1) = 0 AND POINT(x, y - 1) <> backkolor THEN Array(x, y - 1) = pass + 1: finished = 0
35.                     END IF
36.                     IF y + 1 <= _HEIGHT THEN
37.                         IF Array(x, y + 1) = 0 AND POINT(x, y + 1) <> backkolor THEN Array(x, y + 1) = pass + 1: finished = 0
38.                     END IF
39.                 END IF
40.             NEXT
41.         NEXT
42.         pass = pass + 1
43.     LOOP UNTIL finished
44.  
45.     FOR x = 0 TO _WIDTH
46.         FOR y = 0 TO _HEIGHT
47.             IF Array(x, y) THEN PSET (x, y), kolor
48.         NEXT
49.     NEXT
50. END SUB

This may not be so impossible to make use of, once it's optimized for _MEM.  As it is now, it's good for a one time "change it and save it" type routine, but I definitely wouldn't rely on it for anything performance heavy.

[TempodiBasic]

@Steve
Good Luck with illness of your wife!
I wish you'll come back at home together  soon safe and healthy !

PS I find your idea genial and I think that we must adapt it for any kind of shape!

[bplus]

Non-Recursive PaintFill.  At this point, it's slower than heck, but it works!

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2.  
3.  
4. LINE (100, 100)-(300, 300), -1, BF
5. CIRCLE (300, 300), 100, -1
6. PAINT (301, 301), -1
7.  
8.  
9. fill 200, 200, &HFFFF0000, 0
10.  
11.  
12.  
13.  
14.  
15.  
16.  
17.  
18. SUB fill (x, y, kolor AS _UNSIGNED LONG, backkolor AS _UNSIGNED LONG)
19.     DIM Array(-1 TO _WIDTH, -1 TO _HEIGHT)
20.     pass = 1
21.     Array(x, y) = pass
22.     DO
23.         finished = -1
24.         FOR x = 0 TO _WIDTH - 1
25.             FOR y = 0 TO _HEIGHT - 1
26.                 IF Array(x, y) = pass THEN
27.                     IF x - 1 >= 0 THEN
28.                         IF Array(x - 1, y) = 0 AND POINT(x - 1, y) <> backkolor THEN Array(x - 1, y) = pass + 1: finished = 0
29.                     END IF
30.                     IF x + 1 < _WIDTH THEN
31.                         IF Array(x + 1, y) = 0 AND POINT(x + 1, y) <> backkolor THEN Array(x + 1, y) = pass + 1: finished = 0
32.                     END IF
33.                     IF y - 1 >= 0 THEN
34.                         IF Array(x, y - 1) = 0 AND POINT(x, y - 1) <> backkolor THEN Array(x, y - 1) = pass + 1: finished = 0
35.                     END IF
36.                     IF y + 1 <= _HEIGHT THEN
37.                         IF Array(x, y + 1) = 0 AND POINT(x, y + 1) <> backkolor THEN Array(x, y + 1) = pass + 1: finished = 0
38.                     END IF
39.                 END IF
40.             NEXT
41.         NEXT
42.         pass = pass + 1
43.     LOOP UNTIL finished
44.  
45.     FOR x = 0 TO _WIDTH
46.         FOR y = 0 TO _HEIGHT
47.             IF Array(x, y) THEN PSET (x, y), kolor
48.         NEXT
49.     NEXT
50. END SUB

This may not be so impossible to make use of, once it's optimized for _MEM.  As it is now, it's good for a one time "change it and save it" type routine, but I definitely wouldn't rely on it for anything performance heavy.

And guess what guys, POINT fails us, try Steve's code with a transparent color for border color.

I just came up with similar non recursive and it fails because POINT fails. I tried border colors with _RGBA32 and with &H and even used the POINT color at the border of a box to be filled, they all fail to stop the fill.

[bplus]

Here is my test code:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Fill test Steve" 'mod b+ 2019-11-22
3.  
4. CONST xmax = 800, ymax = 600
5. SCREEN _NEWIMAGE(xmax, ymax, 32)
6. _SCREENMOVE 300, 40
7. RANDOMIZE TIMER
8. DIM i, ptGreen AS _UNSIGNED LONG
9.  
10. CLS
11.  
12. 'try each one of these, solids work transparents don't!
13. ptGreen = _RGBA32(0, 128, 0, 255) 'solid
14. 'ptGreen = _RGBA32(0, 128, 0, 5) 'transparent
15. 'ptGreen = &HFF008000 'solid
16. 'ptGreen = &HF0008000 'transparent
17.  
18.  
19. LINE (510, 510)-(520, 520), ptGreen, B
20. 'ptGreen = POINT(510, 510)  '<<<<<<<<try with or without comment
21. sfill 515, 515, &HFFFF0000, ptGreen
22.  
23. 'FOR i = 100 TO 100.75 STEP .25
24. CIRCLE (100, 100), 100, &HFFFFFFFF
25. 'NEXT
26. sfill 100, 100, &HFFFF0000, &HFFFFFFFF
27.  
28. PRINT "done"
29.  
30. SUB sfill (x, y, kolor AS _UNSIGNED LONG, backkolor AS _UNSIGNED LONG)
31.     DIM Array(-1 TO _WIDTH, -1 TO _HEIGHT)
32.     DIM pass, finished
33.     pass = 1
34.     Array(x, y) = pass
35.     DO
36.         finished = -1
37.         FOR x = 0 TO _WIDTH - 1
38.             FOR y = 0 TO _HEIGHT - 1
39.                 IF Array(x, y) = pass THEN
40.                     IF x - 1 >= 0 THEN
41.                         IF Array(x - 1, y) = 0 AND POINT(x - 1, y) <> backkolor THEN Array(x - 1, y) = pass + 1: finished = 0
42.                     END IF
43.                     IF x + 1 < _WIDTH THEN
44.                         IF Array(x + 1, y) = 0 AND POINT(x + 1, y) <> backkolor THEN Array(x + 1, y) = pass + 1: finished = 0
45.                     END IF
46.                     IF y - 1 >= 0 THEN
47.                         IF Array(x, y - 1) = 0 AND POINT(x, y - 1) <> backkolor THEN Array(x, y - 1) = pass + 1: finished = 0
48.                     END IF
49.                     IF y + 1 <= _HEIGHT THEN
50.                         IF Array(x, y + 1) = 0 AND POINT(x, y + 1) <> backkolor THEN Array(x, y + 1) = pass + 1: finished = 0
51.                     END IF
52.                 END IF
53.             NEXT
54.         NEXT
55.         pass = pass + 1
56.     LOOP UNTIL finished
57.  
58.     FOR x = 0 TO _WIDTH
59.         FOR y = 0 TO _HEIGHT
60.             IF Array(x, y) THEN PSET (x, y), kolor
61.         NEXT
62.     NEXT
63. END SUB
64.  
65.  

PS This was same test code I was using with my non recursive Fill but mine was leaking through diagonal neighbors so CIRCLE had to be triple walled or it leaked whereas B option in LINE worked without renenforced walls.

[bplus]

This glitch with POINT is most curious as I just got done this morning proving to myself it was healthy???

So our attempts at using an alternate routine for PAINT fill are futile until we get POINT figured out.

[SMcNeill]

Point isn’t failing; your bordercolor fails.

PSET (x,y), _RGBA32(255,255,255,128)

Now, PSET that over a white background, a red background, and a black background.  Is the color on your screen going to still be _RGBA32(255,255,255,128), or is it going to be a blended version of that color?  Bright white (barely toned down), Pink, and then dull white/gray are going to be your screen colors.  Using that value as a paint border isn’t going to work as that color doesn’t actually exist on your screen.

One important thing will *always* keep it from existing: the visible display doesn’t allow any alpha less than 255.  At least, it hasn’t in any of my past testing.

[bplus]

Point isn’t failing; your bordercolor fails.

PSET (x,y), _RGBA32(255,255,255,128)

Now, PSET that over a white background, a red background, and a black background.  Is the color on your screen going to still be _RGBA32(255,255,255,128), or is it going to be a blended version of that color?  Bright white (barely toned down), Pink, and then dull white/gray are going to be your screen colors.  Using that value as a paint border isn’t going to work as that color doesn’t actually exist on your screen.

One important thing will *always* keep it from existing: the visible display doesn’t allow any alpha less than 255.  At least, it hasn’t in any of my past testing.

Then why are we making something to replace PAINT? I thought it was so we could use transparent border colors.

I was trying to be careful that the border was always over black.

[SMcNeill]

Then why are we making something to replace PAINT? I thought it was so we could use transparent border colors.

I was trying to be careful that the border was always over black.

I thought it was so could paint an image/texture over something, which is an ability PAINT doesn’t offer.  (Or was just looking for a speedier alternative?)

[bplus]

OK maybe if we could Fill the border along with the fill of the innards, that would do very nicely.

What do you think? possible?

[bplus]

New and improved use of paintImage, look ma, no Border lines!!!

Code: QB64: [Select]

1. _TITLE "Brick Pattern Tile, click a spot to spray paint a brick image."
2. CONST xmax = 800, ymax = 600
3. SCREEN _NEWIMAGE(xmax, ymax, 32)
4. _SCREENMOVE 300, 40
5. 'make brick pattern
6. brickpat& = _NEWIMAGE(16, 16, 32)
7. _DEST brickpat&
8. LINE (0, 0)-(_WIDTH(brickpat&) - 1, _HEIGHT(brickpat&) - 1), _RGB32(128, 0, 0), BF
9. LINE (0, 0)-(_WIDTH(brickpat&) - 1, 0), _RGB32(200, 200, 200), BF
10. LINE (0, 7)-(_WIDTH(brickpat&) - 1, 8), _RGB32(200, 200, 200), BF
11. LINE (0, 15)-(_WIDTH(brickpat&) - 1, 15), _RGB32(200, 200, 200), BF
12. LINE (0, 0)-(1, 8), _RGB32(200, 200, 200), BF
13. LINE (7, 8)-(8, 15), _RGB32(200, 200, 200), BF
14.  
15. DIM SHARED BC AS _UNSIGNED LONG
16. BC = _RGB32(119, 17, 2)
17. _DEST 0
18. WHILE _KEYDOWN(27) = 0
19.     WHILE _MOUSEINPUT: WEND
20.     mx = _MOUSEX: my = _MOUSEY: mb = _MOUSEBUTTON(1)
21.     IF mb THEN
22.         r = r + 1
23.         IF r > 20 THEN r = 1
24.         CIRCLE (mx, my), 50, BC
25.         paintImage mx, my, BC, 0, brickpat&
26.     END IF
27.     _DISPLAY
28.     _LIMIT 60
29. WEND
30.  
31. SUB paintImage (x, y, Border~&, destHandle&, imageHandle&)
32.     d = _DEST: s = _SOURCE
33.     _DEST destHandle&
34.     PAINT (x, y), BC, Border~&
35.     FOR y = 0 TO _HEIGHT(destHandle&)
36.         FOR x = 0 TO _WIDTH(destHandle&)
37.             _SOURCE destHandle&
38.             IF POINT(x, y) = BC THEN
39.                 _SOURCE imageHandle&
40.                 PSET (x, y), POINT(x MOD _WIDTH(imageHandle&), y MOD _HEIGHT(imageHandle&))
41.             END IF
42.         NEXT
43.     NEXT
44.     _DEST d: _SOURCE s
45. END SUB
46.  
47.  
48.  

One of those dah... eureka moments. Spray paint a brickwall pattern:

[TempodiBasic]

Cool!
Go behind  the limit of BorderColor% !
Yes put away the border and paint in the limit of the area!

 

But what do you think about POINT? what is the point of POINT with alpha channell?
Do POINT read and bring back the fusion of more colors in the same pixel in alphachannel?
It is possible an empowered function _POINT that can distinguish between colors merged into the pixel? (I think no but I'm not expert and I have a poor knowledge of graphic hardware).
Thanks to read

[bplus]

Hi TempodiBasic,

I am totally confused by POINT, it reports numbers correctly but according to Steve:

One important thing will *always* keep it from existing: the visible display doesn’t allow any alpha less than 255.  At least, it hasn’t in any of my past testing.

It seems true in my test of using an Alpha (less than 255) for a border control both with PAINT and with fill routines.

So strange, it reports the right number but won't work in display???

Remember I tested it earlier in this thread when you complained about my comment about using POINT and detecting Alpha and the test said it could read alpha (over black) the same if over black, and you did have to CLS first for black background.

I don't know, another Life Mystery!