Windows Printer API

[SMcNeill]

Some old, lost code from [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there], recovered thanks to Richard, which allows us to call up the windows printer interface from within QB64.  From my testing, this works on the old SDL versions and some of the older GL versions, but I have yet to get it to work properly with the latest versions of QB64 itself.  Folks with older versions of QB64 might be interested in using this (if you can, kindly tell me what version you have that it works on, so I can trace back to which point it stopped working), and people who are familiar with DECLARE LIBRARY and the Windows API might be interested in using this as a roadmap to sort out what's wrong and get it to working for the rest of us.  (I'll dig into it myself, to see if I can sort it back out later as well.)

Code: QB64: [Select]

1. CONST PD_ALLPAGES = 0
2. CONST PD_CURRENTPAGE = &H00400000
3. CONST PD_DISABLEPRINTTOFILE = &H00080000
4. CONST PD_PAGENUMS = 2
5. CONST PD_RETURNDC = &H00000100
6. CONST PD_RETURNDEFAULT = &H00000400
7. CONST PD_SELECTION = 1
8. CONST PD_USEDEVMODECOPIESANDCOLLATE = &H00040000
9. CONST START_PAGE_GENERAL = -1
10. CONST PD_RESULT_CANCEL = 0
11. CONST PD_RESULT_PRINT = 1
12. CONST PD_RESULT_APPLY = 2
13. CONST CCHDEVICENAME = 32
14. CONST CCHFORMNAME = 32
15.  
16. CONST TA_UPDATECP = 1
17.  
18. CONST S_OK = 0
19. ' CONST E_HANDLE = &H80070006
20.  
21. CONST GDI_ERROR = -1
22.  
23.  
24. DECLARE DYNAMIC LIBRARY "kernel32"
25.     FUNCTION GlobalFree~%& (BYVAL hMem~%&)
26.     FUNCTION GetLastError~& ()
27. END DECLARE
28.  
29. DECLARE DYNAMIC LIBRARY "gdi32"
30.     FUNCTION DeleteDC& (BYVAL hdc~%&)
31.     FUNCTION SetTextAlign~& (BYVAL hdc~%&, BYVAL fMode~&)
32.     FUNCTION GetTextAlign~& (BYVAL hdc~%&)
33.     FUNCTION TextOutA& (BYVAL hdc~%&, BYVAL nXStart&, BYVAL nYStart&, BYVAL lpString~%&, BYVAL cchString&)
34.     FUNCTION StartDocA& (BYVAL hdc~%&, BYVAL lpdi~%&)
35.     FUNCTION AbortDoc& (BYVAL hdc~%&)
36.     FUNCTION StartPage& (BYVAL hDC~%&)
37.     FUNCTION EndPage& (BYVAL hdc~%&)
38.     FUNCTION EndDoc& (BYVAL hdc~%&)
39.     FUNCTION ResetDCA~%& (BYVAL hdc~%&, BYVAL lpInitData~%&)
40. END DECLARE
41.  
42. DECLARE DYNAMIC LIBRARY "user32"
43.     FUNCTION FindWindowA%& (BYVAL lpClassName%&, BYVAL lpWindowName%&)
44. END DECLARE
45.  
46. DECLARE DYNAMIC LIBRARY "comdlg32"
47.     FUNCTION PrintDlgExA~& (BYVAL lppd~%&) ' returns an HRESULT
48. END DECLARE
49.  
50. DECLARE CUSTOMTYPE LIBRARY
51. ' http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=10886.msg91583#msg91583
52.     SUB SUB_READDEVMODE (BYVAL p~%&)
53.     SUB SUB_READDEVNAMES (BYVAL p~%&)
54. END DECLARE
55.  
56. TYPE DOCINFOA
57.     cbSize AS LONG
58.     lpszDocName AS _UNSIGNED _OFFSET ' LPCSTR
59.     lpszOutput AS _UNSIGNED _OFFSET ' LPCSTR
60.     lpszDatatype AS _UNSIGNED _OFFSET ' LPCSTR
61.     fwType AS _UNSIGNED LONG
62. END TYPE
63.  
64.  
65. TYPE POINTL
66.     x AS LONG
67.     y AS LONG
68. END TYPE
69.  
70. CONST len_DEVMODEA = 156
71. TYPE DEVMODEA
72.     dmDeviceName AS STRING * CCHDEVICENAME
73.     dmSpecVersion AS _UNSIGNED INTEGER
74.     dmDriverVersion AS _UNSIGNED INTEGER
75.     dmSize AS _UNSIGNED INTEGER
76.     dmDriverExtra AS _UNSIGNED INTEGER
77.     dmFields AS _UNSIGNED LONG
78.     ' union {
79.     ' struct { comment either the following 8 lines
80.     dmOrientation AS INTEGER
81.     dmPaperSize AS INTEGER
82.     dmPaperLength AS INTEGER
83.     dmPaperWidth AS INTEGER
84.     dmScale AS INTEGER
85.     dmCopies AS INTEGER
86.     dmDefaultSource AS INTEGER
87.     dmPrintQuality AS INTEGER
88.     ' };
89.     ' struct { or the following 3 lines
90.     ' dmPosition AS POINTL
91.     ' dmDisplayOrientation AS _UNSIGNED LONG
92.     ' dmDisplayFixedOutput AS _UNSIGNED LONG
93.     ' };
94.     ' };
95.     dmColor AS INTEGER
96.     dmDuplex AS INTEGER
97.     dmYResolution AS INTEGER
98.     dmTTOption AS INTEGER
99.     dmCollate AS INTEGER
100.     dmFormName AS STRING * CCHFORMNAME
101.     dmLogPixels AS _UNSIGNED INTEGER
102.     dmBitsPerPel AS _UNSIGNED LONG
103.     dmPelsWidth AS _UNSIGNED LONG
104.     dmPelsHeight AS _UNSIGNED LONG
105.     ' union { comment exactly 1 of the following 2 lines
106.     ' dmDisplayFlags AS _UNSIGNED LONG
107.     dmNup AS _UNSIGNED LONG
108.     ' };
109.     dmDisplayFrequency AS _UNSIGNED LONG
110.     dmICMMethod AS _UNSIGNED LONG
111.     dmICMIntent AS _UNSIGNED LONG
112.     dmMediaType AS _UNSIGNED LONG
113.     dmDitherType AS _UNSIGNED LONG
114.     dmReserved1 AS _UNSIGNED LONG
115.     dmReserved2 AS _UNSIGNED LONG
116.     dmPanningWidth AS _UNSIGNED LONG
117.     dmPanningHeight AS _UNSIGNED LONG
118. END TYPE
119.  
120. TYPE DEVNAMES
121.     wDriverOffset AS _UNSIGNED INTEGER
122.     wDeviceOffset AS _UNSIGNED INTEGER
123.     wOutputOffset AS _UNSIGNED INTEGER
124.     wDefault AS _UNSIGNED INTEGER
125. END TYPE
126.  
127. TYPE PRINTPAGERANGE
128.     nFromPage AS _UNSIGNED LONG
129.     nToPage AS _UNSIGNED LONG
130. END TYPE
131.  
132. TYPE PRINTDLGEX
133.     lStructSize AS _UNSIGNED LONG
134.     hwndOwner AS _UNSIGNED _OFFSET ' HWND
135.     hDevMode AS _UNSIGNED _OFFSET ' HGLOBAL
136.     hDevNames AS _UNSIGNED _OFFSET ' HGLOBAL
137.     hDC AS _UNSIGNED _OFFSET ' HDC
138.     Flags AS _UNSIGNED LONG
139.     Flags2 AS _UNSIGNED LONG
140.     ExclusionFlags AS _UNSIGNED LONG
141.     nPageRanges AS _UNSIGNED LONG
142.     nMaxPageRanges AS _UNSIGNED LONG
143.     lpPageRanges AS _UNSIGNED _OFFSET ' LPPRINTPAGERANGE
144.     nMinPage AS _UNSIGNED LONG
145.     nMaxPage AS _UNSIGNED LONG
146.     nCopies AS _UNSIGNED LONG
147.     hInstance AS _UNSIGNED _OFFSET ' HINSTANCE
148.     lpPrintTemplateName AS _UNSIGNED _OFFSET ' LPCSTR
149.     lpCallback AS _UNSIGNED _OFFSET ' LPUNKNOWN
150.     nPropertyPages AS _UNSIGNED LONG
151.     lphPropertyPages AS _UNSIGNED _OFFSET ' HPROPSHEETPAGE *
152.     nStartPage AS _UNSIGNED LONG
153.     dwResultAction AS _UNSIGNED LONG
154. END TYPE
155.  
156. DIM pageranges(0 TO 7) AS PRINTPAGERANGE
157. DIM pde AS PRINTDLGEX
158. DIM hWnd AS _UNSIGNED _OFFSET
159. DIM hr AS _UNSIGNED LONG
160. DIM t AS STRING
161. DIM t1 AS STRING * 16
162. DIM doc AS DOCINFOA
163.  
164. _DELAY .5 ' race condition for the window's appearance.
165. t = "qb64 prn test" + STR$(TIMER) 'random title for FindWindowA
166. _TITLE t
167. t = t + CHR$(0)
168. hWnd = FindWindowA(0, _OFFSET(t))
169. _TITLE "Whatever you actually want the title to be"
170.  
171. pde.lStructSize = LEN(pde)
172. pde.hwndOwner = hWnd
173. pde.hDevMode = 0
174. pde.hDevNames = 0
175. pde.Flags = PD_ALLPAGES OR PD_RETURNDC OR PD_USEDEVMODECOPIESANDCOLLATE
176. pde.Flags2 = 0
177. pde.nPageRanges = 0
178. pde.nMaxPageRanges = 1 + UBOUND(pageranges)
179. pde.lpPageRanges = _OFFSET(pageranges(0))
180. pde.nMinPage = 1
181. pde.nMaxPage = 1
182. pde.nCopies = 1
183. pde.hInstance = 0
184. pde.lpCallback = 0
185. pde.nPropertyPages = 0
186. pde.lphPropertyPages = 0
187. pde.nStartPage = START_PAGE_GENERAL
188. pde.dwResultAction = 0
189.  
190. hr = PrintDlgExA(_OFFSET(pde))
191. IF S_OK <> hr THEN PRINT "Error. HRESULT: 0x" + LCASE$(HEX$(hr))
192. PRINT pde.dwResultAction
193.  
194. IF pde.hDevMode THEN SUB_READDEVMODE _OFFSET(pde.hDevMode)
195. IF pde.hDevNames THEN SUB_READDEVNAMES _OFFSET(pde.hDevNames)
196.  
197. IF PD_RESULT_PRINT = pde.dwResultAction THEN
198.     IF pde.hDC THEN
199.         t1 = "qb64 prn test" + CHR$(0) ' fixed len str so it won't move
200.         doc.cbSize = LEN(doc)
201.         doc.lpszDocName = _OFFSET(t1)
202.         doc.lpszOutput = 0
203.         doc.lpszDatatype = 0
204.         doc.fwType = 0
205.         IF 0 >= StartDocA(pde.hDC, _OFFSET(doc)) THEN PRINT "doc error"
206.         IF 0 >= StartPage(pde.hDC) THEN PRINT "doc error"
207.  
208.         IF GDI_ERROR = SetTextAlign(pde.hDC, GetTextAlign(pde.hDC) OR TA_UPDATECP) THEN PRINT "GDI error"
209.         t = "Hello, world!"
210.         IF 0 = TextOutA(pde.hDC, 0, 0, _OFFSET(t), LEN(t)) THEN PRINT "error"
211.  
212.         IF 0 >= EndPage(pde.hDC) THEN PRINT "doc error"
213.         IF 0 >= EndDoc(pde.hDC) THEN PRINT "doc error"
214.     END IF
215. END IF
216.  
217. IF pde.hDevMode THEN
218.     IF 0 <> GlobalFree(pde.hDevMode) THEN PRINT "Error: 0x" + LCASE$(HEX$(GetLastError))
219. END IF
220. IF pde.hDevNames THEN
221.     IF 0 <> GlobalFree(pde.hDevNames) THEN PRINT "Error: 0x" + LCASE$(HEX$(GetLastError))
222. END IF
223. IF pde.hDC THEN
224.     IF 0 = DeleteDC(pde.hDC) THEN PRINT "Error: 0x" + LCASE$(HEX$(GetLastError))
225. END IF
226. END
227.  
228.  
229. SUB readDevMode (t AS DEVMODEA)
230. PRINT t.dmDeviceName
231. ' etc...
232. END SUB
233.  
234. SUB readDevNames (t AS DEVNAMES)
235. DIM m AS _MEM
236. t$ = SPACE$(255)
237.  
238. m = _MEM(_OFFSET(t) + t.wDriverOffset, 255)
239. _MEMGET m, m.OFFSET, t$
240. PRINT t$
241.  
242. m = _MEM(_OFFSET(t) + t.wDeviceOffset, 255)
243. _MEMGET m, m.OFFSET, t$
244. PRINT t$
245.  
246. m = _MEM(_OFFSET(t) + t.wOutputOffset, 255)
247. _MEMGET m, m.OFFSET, t$
248. PRINT t$
249.  
250.  
251.  
252. 'PRINT peekstr(_OFFSET(t) + t.wDriverOffset)
253. 'PRINT peekstr(_OFFSET(t) + t.wDeviceOffset)
254. 'PRINT peekstr(_OFFSET(t) + t.wOutputOffset)
255. END SUB
256.  

[SMcNeill]

Modified code which works on QB64 v1.3 -- 32-bit version.   Offsets or padding needs to change something somewhere to work in QB64-64bit versions, but what I have here is working as it should for the 32-bit version of QB64:

Code: QB64: [Select]

1. CONST PD_ALLPAGES = 0
2. CONST PD_CURRENTPAGE = &H00400000
3. CONST PD_DISABLEPRINTTOFILE = &H00080000
4. CONST PD_PAGENUMS = 2
5. CONST PD_RETURNDC = &H00000100
6. CONST PD_RETURNDEFAULT = &H00000400
7. CONST PD_SELECTION = 1
8. CONST PD_USEDEVMODECOPIESANDCOLLATE = &H00040000
9. CONST START_PAGE_GENERAL = -1
10. CONST PD_RESULT_CANCEL = 0
11. CONST PD_RESULT_PRINT = 1
12. CONST PD_RESULT_APPLY = 2
13. CONST CCHDEVICENAME = 32
14. CONST CCHFORMNAME = 32
15.  
16. CONST TA_UPDATECP = 1
17.  
18. CONST S_OK = 0
19. ' CONST E_HANDLE = &H80070006
20.  
21. CONST GDI_ERROR = -1
22.  
23.  
24. DECLARE DYNAMIC LIBRARY "kernel32"
25.     FUNCTION GlobalFree~%& (BYVAL hMem~%&)
26.     FUNCTION GetLastError~& ()
27. END DECLARE
28.  
29. DECLARE DYNAMIC LIBRARY "gdi32"
30.     FUNCTION DeleteDC& (BYVAL hdc~%&)
31.     FUNCTION SetTextAlign~& (BYVAL hdc~%&, BYVAL fMode~&)
32.     FUNCTION GetTextAlign~& (BYVAL hdc~%&)
33.     FUNCTION TextOutA& (BYVAL hdc~%&, BYVAL nXStart&, BYVAL nYStart&, BYVAL lpString~%&, BYVAL cchString&)
34.     FUNCTION StartDocA& (BYVAL hdc~%&, BYVAL lpdi~%&)
35.     FUNCTION AbortDoc& (BYVAL hdc~%&)
36.     FUNCTION StartPage& (BYVAL hDC~%&)
37.     FUNCTION EndPage& (BYVAL hdc~%&)
38.     FUNCTION EndDoc& (BYVAL hdc~%&)
39.     FUNCTION ResetDCA~%& (BYVAL hdc~%&, BYVAL lpInitData~%&)
40. END DECLARE
41.  
42. DECLARE DYNAMIC LIBRARY "user32"
43.     FUNCTION FindWindowA%& (BYVAL lpClassName%&, BYVAL lpWindowName%&)
44. END DECLARE
45.  
46. DECLARE DYNAMIC LIBRARY "comdlg32"
47.     FUNCTION PrintDlgExA~& (BYVAL lppd~%&) ' returns an HRESULT
48. END DECLARE
49.  
50. DECLARE CUSTOMTYPE LIBRARY
51.     ' http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=10886.msg91583#msg91583
52.     SUB SUB_READDEVMODE (BYVAL p~%&)
53.     SUB SUB_READDEVNAMES (BYVAL p~%&)
54. END DECLARE
55.  
56. TYPE DOCINFOA
57.     cbSize AS LONG
58.     lpszDocName AS _UNSIGNED _OFFSET ' LPCSTR
59.     lpszOutput AS _UNSIGNED _OFFSET ' LPCSTR
60.     lpszDatatype AS _UNSIGNED _OFFSET ' LPCSTR
61.     fwType AS _UNSIGNED LONG
62. END TYPE
63.  
64.  
65. TYPE POINTL
66.     x AS LONG
67.     y AS LONG
68. END TYPE
69.  
70. CONST len_DEVMODEA = 156
71. TYPE DEVMODEA
72.     dmDeviceName AS STRING * CCHDEVICENAME
73.     dmSpecVersion AS _UNSIGNED INTEGER
74.     dmDriverVersion AS _UNSIGNED INTEGER
75.     dmSize AS _UNSIGNED INTEGER
76.     dmDriverExtra AS _UNSIGNED INTEGER
77.     dmFields AS _UNSIGNED LONG
78.     ' union {
79.     ' struct { comment either the following 8 lines
80.     dmOrientation AS INTEGER
81.     dmPaperSize AS INTEGER
82.     dmPaperLength AS INTEGER
83.     dmPaperWidth AS INTEGER
84.     dmScale AS INTEGER
85.     dmCopies AS INTEGER
86.     dmDefaultSource AS INTEGER
87.     dmPrintQuality AS INTEGER
88.     ' };
89.     ' struct { or the following 3 lines
90.     ' dmPosition AS POINTL
91.     ' dmDisplayOrientation AS _UNSIGNED LONG
92.     ' dmDisplayFixedOutput AS _UNSIGNED LONG
93.     ' };
94.     ' };
95.     dmColor AS INTEGER
96.     dmDuplex AS INTEGER
97.     dmYResolution AS INTEGER
98.     dmTTOption AS INTEGER
99.     dmCollate AS INTEGER
100.     dmFormName AS STRING * CCHFORMNAME
101.     dmLogPixels AS _UNSIGNED INTEGER
102.     dmBitsPerPel AS _UNSIGNED LONG
103.     dmPelsWidth AS _UNSIGNED LONG
104.     dmPelsHeight AS _UNSIGNED LONG
105.     ' union { comment exactly 1 of the following 2 lines
106.     ' dmDisplayFlags AS _UNSIGNED LONG
107.     dmNup AS _UNSIGNED LONG
108.     ' };
109.     dmDisplayFrequency AS _UNSIGNED LONG
110.     dmICMMethod AS _UNSIGNED LONG
111.     dmICMIntent AS _UNSIGNED LONG
112.     dmMediaType AS _UNSIGNED LONG
113.     dmDitherType AS _UNSIGNED LONG
114.     dmReserved1 AS _UNSIGNED LONG
115.     dmReserved2 AS _UNSIGNED LONG
116.     dmPanningWidth AS _UNSIGNED LONG
117.     dmPanningHeight AS _UNSIGNED LONG
118. END TYPE
119.  
120. TYPE DEVNAMES
121.     wDriverOffset AS _UNSIGNED INTEGER
122.     wDeviceOffset AS _UNSIGNED INTEGER
123.     wOutputOffset AS _UNSIGNED INTEGER
124.     wDefault AS _UNSIGNED INTEGER
125. END TYPE
126.  
127. TYPE PRINTPAGERANGE
128.     nFromPage AS _UNSIGNED LONG
129.     nToPage AS _UNSIGNED LONG
130. END TYPE
131.  
132. TYPE PRINTDLGEX
133.     lStructSize AS _UNSIGNED LONG
134.     hwndOwner AS _UNSIGNED _OFFSET ' HWND
135.     hDevMode AS _UNSIGNED _OFFSET ' HGLOBAL
136.     hDevNames AS _UNSIGNED _OFFSET ' HGLOBAL
137.     hDC AS _UNSIGNED _OFFSET ' HDC
138.     Flags AS _UNSIGNED LONG
139.     Flags2 AS _UNSIGNED LONG
140.     ExclusionFlags AS _UNSIGNED LONG
141.     nPageRanges AS _UNSIGNED LONG
142.     nMaxPageRanges AS _UNSIGNED LONG
143.     lpPageRanges AS _UNSIGNED _OFFSET ' LPPRINTPAGERANGE
144.     nMinPage AS _UNSIGNED LONG
145.     nMaxPage AS _UNSIGNED LONG
146.     nCopies AS _UNSIGNED LONG
147.     hInstance AS _UNSIGNED _OFFSET ' HINSTANCE
148.     lpPrintTemplateName AS _UNSIGNED _OFFSET ' LPCSTR
149.     lpCallback AS _UNSIGNED _OFFSET ' LPUNKNOWN
150.     nPropertyPages AS _UNSIGNED LONG
151.     lphPropertyPages AS _UNSIGNED _OFFSET ' HPROPSHEETPAGE *
152.     nStartPage AS _UNSIGNED LONG
153.     dwResultAction AS _UNSIGNED LONG
154. END TYPE
155.  
156. DIM pageranges(0 TO 7) AS PRINTPAGERANGE
157. DIM pde AS PRINTDLGEX
158. DIM hWnd AS _UNSIGNED _OFFSET
159. DIM hr AS _UNSIGNED LONG
160. DIM t AS STRING
161. DIM t1 AS STRING * 16
162. DIM doc AS DOCINFOA
163.  
164. hWnd = _WINDOWHANDLE 'FindWindowA(0, _OFFSET(t))
165. _TITLE "Printer API demo"
166.  
167. pde.lStructSize = LEN(pde)
168. pde.hwndOwner = hWnd
169. pde.hDevMode = 0
170. pde.hDevNames = 0
171. pde.Flags = PD_ALLPAGES OR PD_RETURNDC OR PD_USEDEVMODECOPIESANDCOLLATE
172. pde.Flags2 = 0
173. pde.nPageRanges = 0
174. pde.nMaxPageRanges = 1 + UBOUND(pageranges)
175. pde.lpPageRanges = _OFFSET(pageranges(0))
176. pde.nMinPage = 1
177. pde.nMaxPage = 1
178. pde.nCopies = 1
179. pde.hInstance = 0
180. pde.lpCallback = 0
181. pde.nPropertyPages = 0
182. pde.lphPropertyPages = 0
183. pde.nStartPage = START_PAGE_GENERAL
184. pde.dwResultAction = 0
185.  
186. hr = PrintDlgExA(_OFFSET(pde))
187. IF S_OK <> hr THEN PRINT "ZZError. HRESULT: 0x" + LCASE$(HEX$(hr))
188. PRINT pde.dwResultAction
189.  
190. IF pde.hDevMode THEN SUB_READDEVMODE _OFFSET(pde.hDevMode)
191. IF pde.hDevNames THEN SUB_READDEVNAMES _OFFSET(pde.hDevNames)
192.  
193. IF PD_RESULT_PRINT = pde.dwResultAction THEN
194.     IF pde.hDC THEN
195.         t1 = "qb64 prn test" + CHR$(0) ' fixed len str so it won't move
196.         doc.cbSize = LEN(doc)
197.         doc.lpszDocName = _OFFSET(t1)
198.         doc.lpszOutput = 0
199.         doc.lpszDatatype = 0
200.         doc.fwType = 0
201.         IF 0 >= StartDocA(pde.hDC, _OFFSET(doc)) THEN PRINT "doc error"
202.         IF 0 >= StartPage(pde.hDC) THEN PRINT "doc error"
203.  
204.         IF GDI_ERROR = SetTextAlign(pde.hDC, GetTextAlign(pde.hDC) OR TA_UPDATECP) THEN PRINT "GDI error"
205.         t = "Hello, world!"
206.         IF 0 = TextOutA(pde.hDC, 0, 0, _OFFSET(t), LEN(t)) THEN PRINT "error"
207.  
208.         IF 0 >= EndPage(pde.hDC) THEN PRINT "doc error"
209.         IF 0 >= EndDoc(pde.hDC) THEN PRINT "doc error"
210.     END IF
211. END IF
212.  
213. IF pde.hDevMode THEN
214.     IF 0 <> GlobalFree(pde.hDevMode) THEN PRINT "Error: 0x" + LCASE$(HEX$(GetLastError))
215. END IF
216. IF pde.hDevNames THEN
217.     IF 0 <> GlobalFree(pde.hDevNames) THEN PRINT "Error: 0x" + LCASE$(HEX$(GetLastError))
218. END IF
219. IF pde.hDC THEN
220.     IF 0 = DeleteDC(pde.hDC) THEN PRINT "Error: 0x" + LCASE$(HEX$(GetLastError))
221. END IF
222. END
223.  
224.  
225. SUB readDevMode (t AS DEVMODEA)
226.     PRINT t.dmDeviceName
227.     ' etc...
228. END SUB
229.  
230. SUB readDevNames (t AS DEVNAMES)
231.     DIM m AS _MEM
232.     t$ = SPACE$(255)
233.  
234.     m = _MEM(_OFFSET(t) + t.wDriverOffset, 255)
235.     _MEMGET m, m.OFFSET, t$
236.     PRINT t$
237.  
238.     m = _MEM(_OFFSET(t) + t.wDeviceOffset, 255)
239.     _MEMGET m, m.OFFSET, t$
240.     PRINT t$
241.  
242.     m = _MEM(_OFFSET(t) + t.wOutputOffset, 255)
243.     _MEMGET m, m.OFFSET, t$
244.     PRINT t$
245.  
246.  
247.  
248.     'PRINT peekstr(_OFFSET(t) + t.wDriverOffset)
249.     'PRINT peekstr(_OFFSET(t) + t.wDeviceOffset)
250.     'PRINT peekstr(_OFFSET(t) + t.wOutputOffset)
251. END SUB
252.  

[SMcNeill]

This version appears to work for me with both the latest 32-bit and 64-bit versions of QB64.  Test it out guys and tell me if it works as you'd expect.

Code: QB64: [Select]

1. CONST PD_ALLPAGES = 0
2. CONST PD_CURRENTPAGE = &H00400000
3. CONST PD_DISABLEPRINTTOFILE = &H00080000
4. CONST PD_PAGENUMS = 2
5. CONST PD_RETURNDC = &H00000100
6. CONST PD_RETURNDEFAULT = &H00000400
7. CONST PD_SELECTION = 1
8. CONST PD_USEDEVMODECOPIESANDCOLLATE = &H00040000
9. CONST START_PAGE_GENERAL = -1
10. CONST PD_RESULT_CANCEL = 0
11. CONST PD_RESULT_PRINT = 1
12. CONST PD_RESULT_APPLY = 2
13. CONST CCHDEVICENAME = 32
14. CONST CCHFORMNAME = 32
15.  
16. CONST TA_UPDATECP = 1
17.  
18. CONST S_OK = 0
19. ' CONST E_HANDLE = &H80070006
20.  
21. CONST GDI_ERROR = -1
22.  
23.  
24. DECLARE DYNAMIC LIBRARY "kernel32"
25.     FUNCTION GlobalFree~%& (BYVAL hMem~%&)
26.     FUNCTION GetLastError~& ()
27. END DECLARE
28.  
29. DECLARE DYNAMIC LIBRARY "gdi32"
30.     FUNCTION DeleteDC& (BYVAL hdc~%&)
31.     FUNCTION SetTextAlign~& (BYVAL hdc~%&, BYVAL fMode~&)
32.     FUNCTION GetTextAlign~& (BYVAL hdc~%&)
33.     FUNCTION TextOutA& (BYVAL hdc~%&, BYVAL nXStart&, BYVAL nYStart&, BYVAL lpString~%&, BYVAL cchString&)
34.     FUNCTION StartDocA& (BYVAL hdc~%&, BYVAL lpdi~%&)
35.     FUNCTION AbortDoc& (BYVAL hdc~%&)
36.     FUNCTION StartPage& (BYVAL hDC~%&)
37.     FUNCTION EndPage& (BYVAL hdc~%&)
38.     FUNCTION EndDoc& (BYVAL hdc~%&)
39.     FUNCTION ResetDCA~%& (BYVAL hdc~%&, BYVAL lpInitData~%&)
40. END DECLARE
41.  
42. DECLARE DYNAMIC LIBRARY "user32"
43.     FUNCTION FindWindowA%& (BYVAL lpClassName%&, BYVAL lpWindowName%&)
44. END DECLARE
45.  
46. DECLARE DYNAMIC LIBRARY "comdlg32"
47.     FUNCTION PrintDlgExA~& (BYVAL lppd~%&) ' returns an HRESULT
48. END DECLARE
49.  
50. DECLARE CUSTOMTYPE LIBRARY
51.     ' http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=10886.msg91583#msg91583
52.     SUB SUB_READDEVMODE (BYVAL p~%&)
53.     SUB SUB_READDEVNAMES (BYVAL p~%&)
54. END DECLARE
55.  
56. TYPE DOCINFOA
57.     cbSize AS LONG
58.     lpszDocName AS _UNSIGNED _OFFSET ' LPCSTR
59.     lpszOutput AS _UNSIGNED _OFFSET ' LPCSTR
60.     lpszDatatype AS _UNSIGNED _OFFSET ' LPCSTR
61.     fwType AS _UNSIGNED LONG
62. END TYPE
63.  
64.  
65. TYPE POINTL
66.     x AS LONG
67.     y AS LONG
68. END TYPE
69.  
70. CONST len_DEVMODEA = 156
71. TYPE DEVMODEA
72.     dmDeviceName AS STRING * CCHDEVICENAME
73.     dmSpecVersion AS _UNSIGNED INTEGER
74.     dmDriverVersion AS _UNSIGNED INTEGER
75.     dmSize AS _UNSIGNED INTEGER
76.     dmDriverExtra AS _UNSIGNED INTEGER
77.     dmFields AS _UNSIGNED LONG
78.     ' union {
79.     ' struct { comment either the following 8 lines
80.     dmOrientation AS INTEGER
81.     dmPaperSize AS INTEGER
82.     dmPaperLength AS INTEGER
83.     dmPaperWidth AS INTEGER
84.     dmScale AS INTEGER
85.     dmCopies AS INTEGER
86.     dmDefaultSource AS INTEGER
87.     dmPrintQuality AS INTEGER
88.     ' };
89.     ' struct { or the following 3 lines
90.     ' dmPosition AS POINTL
91.     ' dmDisplayOrientation AS _UNSIGNED LONG
92.     ' dmDisplayFixedOutput AS _UNSIGNED LONG
93.     ' };
94.     ' };
95.     dmColor AS INTEGER
96.     dmDuplex AS INTEGER
97.     dmYResolution AS INTEGER
98.     dmTTOption AS INTEGER
99.     dmCollate AS INTEGER
100.     dmFormName AS STRING * CCHFORMNAME
101.     dmLogPixels AS _UNSIGNED INTEGER
102.     dmBitsPerPel AS _UNSIGNED LONG
103.     dmPelsWidth AS _UNSIGNED LONG
104.     dmPelsHeight AS _UNSIGNED LONG
105.     ' union { comment exactly 1 of the following 2 lines
106.     ' dmDisplayFlags AS _UNSIGNED LONG
107.     dmNup AS _UNSIGNED LONG
108.     ' };
109.     dmDisplayFrequency AS _UNSIGNED LONG
110.     dmICMMethod AS _UNSIGNED LONG
111.     dmICMIntent AS _UNSIGNED LONG
112.     dmMediaType AS _UNSIGNED LONG
113.     dmDitherType AS _UNSIGNED LONG
114.     dmReserved1 AS _UNSIGNED LONG
115.     dmReserved2 AS _UNSIGNED LONG
116.     dmPanningWidth AS _UNSIGNED LONG
117.     dmPanningHeight AS _UNSIGNED LONG
118. END TYPE
119.  
120. TYPE DEVNAMES
121.     wDriverOffset AS _UNSIGNED INTEGER
122.     wDeviceOffset AS _UNSIGNED INTEGER
123.     wOutputOffset AS _UNSIGNED INTEGER
124.     wDefault AS _UNSIGNED INTEGER
125. END TYPE
126.  
127. TYPE PRINTPAGERANGE
128.     nFromPage AS _UNSIGNED LONG
129.     nToPage AS _UNSIGNED LONG
130. END TYPE
131.  
132. $IF 32BIT THEN
133.     TYPE PRINTDLGEX
134.     lStructSize AS _UNSIGNED LONG
135.     hwndOwner AS _UNSIGNED _OFFSET ' HWND
136.     hDevMode AS _UNSIGNED _OFFSET ' HGLOBAL
137.     hDevNames AS _UNSIGNED _OFFSET ' HGLOBAL
138.     hDC AS _UNSIGNED _OFFSET ' HDC
139.     Flags AS _UNSIGNED LONG
140.     Flags2 AS _UNSIGNED LONG
141.     ExclusionFlags AS _UNSIGNED LONG
142.     nPageRanges AS _UNSIGNED LONG
143.     nMaxPageRanges AS _UNSIGNED LONG
144.     lpPageRanges AS _UNSIGNED _OFFSET ' LPPRINTPAGERANGE
145.     nMinPage AS _UNSIGNED LONG
146.     nMaxPage AS _UNSIGNED LONG
147.     nCopies AS _UNSIGNED LONG
148.     hInstance AS _UNSIGNED _OFFSET ' HINSTANCE
149.     lpPrintTemplateName AS _UNSIGNED _OFFSET ' LPCSTR
150.     lpCallback AS _UNSIGNED _OFFSET ' LPUNKNOWN
151.     nPropertyPages AS _UNSIGNED LONG
152.     lphPropertyPages AS _UNSIGNED _OFFSET ' HPROPSHEETPAGE *
153.     nStartPage AS _UNSIGNED LONG
154.     dwResultAction AS _UNSIGNED LONG
155.     END TYPE
156. $ELSE
157.     TYPE PRINTDLGEX
158.         lStructSize AS _UNSIGNED _INTEGER64
159.         hwndOwner AS _UNSIGNED _OFFSET ' HWND
160.         hDevMode AS _UNSIGNED _OFFSET ' HGLOBAL
161.         hDevNames AS _UNSIGNED _OFFSET ' HGLOBAL
162.         hDC AS _UNSIGNED _OFFSET ' HDC
163.         Flags AS _UNSIGNED LONG
164.         Flags2 AS _UNSIGNED LONG
165.         ExclusionFlags AS _UNSIGNED LONG
166.         nPageRanges AS _UNSIGNED LONG
167.         nMaxPageRanges AS _UNSIGNED _INTEGER64
168.         lpPageRanges AS _UNSIGNED _OFFSET ' LPPRINTPAGERANGE
169.         nMinPage AS _UNSIGNED LONG
170.         nMaxPage AS _UNSIGNED LONG
171.         nCopies AS _UNSIGNED _INTEGER64 'LONG
172.         hInstance AS _UNSIGNED _OFFSET ' HINSTANCE
173.         lpPrintTemplateName AS _UNSIGNED _OFFSET ' LPCSTR
174.         lpCallback AS _UNSIGNED _OFFSET ' LPUNKNOWN
175.         nPropertyPages AS _UNSIGNED _INTEGER64 'LONG
176.         lphPropertyPages AS _UNSIGNED _OFFSET ' HPROPSHEETPAGE *
177.         nStartPage AS _UNSIGNED LONG
178.         dwResultAction AS _UNSIGNED LONG
179.     END TYPE
180. $END IF
181.  
182. DIM pageranges(0 TO 7) AS PRINTPAGERANGE
183. DIM pde AS PRINTDLGEX
184. DIM hWnd AS _UNSIGNED _OFFSET
185. DIM hr AS _UNSIGNED LONG
186. DIM t AS STRING
187. DIM t1 AS STRING * 16
188. DIM doc AS DOCINFOA
189.  
190. hWnd = _WINDOWHANDLE 'FindWindowA(0, _OFFSET(t))
191. _TITLE "Printer API demo"
192. pde.lStructSize = LEN(pde)
193. pde.hwndOwner = hWnd
194. pde.hDevMode = 0
195. pde.hDevNames = 0
196. pde.Flags = PD_ALLPAGES OR PD_RETURNDC OR PD_USEDEVMODECOPIESANDCOLLATE
197. pde.Flags2 = 0
198. pde.nPageRanges = 0
199. pde.nMaxPageRanges = 1 + UBOUND(pageranges)
200. pde.lpPageRanges = _OFFSET(pageranges(0))
201. pde.nMinPage = 1
202. pde.nMaxPage = 1
203. pde.nCopies = 1
204. pde.hInstance = 0
205. pde.lpCallback = 0
206. pde.nPropertyPages = 0
207. pde.lphPropertyPages = 0
208. pde.nStartPage = START_PAGE_GENERAL
209. pde.dwResultAction = 0
210.  
211. hr = PrintDlgExA(_OFFSET(pde))
212. IF S_OK <> hr THEN PRINT "ZZError. HRESULT: 0x" + LCASE$(HEX$(hr))
213. PRINT pde.dwResultAction
214.  
215. IF pde.hDevMode THEN SUB_READDEVMODE _OFFSET(pde.hDevMode)
216. IF pde.hDevNames THEN SUB_READDEVNAMES _OFFSET(pde.hDevNames)
217.  
218. IF PD_RESULT_PRINT = pde.dwResultAction THEN
219.     IF pde.hDC THEN
220.         t1 = "qb64 prn test" + CHR$(0) ' fixed len str so it won't move
221.         doc.cbSize = LEN(doc)
222.         doc.lpszDocName = _OFFSET(t1)
223.         doc.lpszOutput = 0
224.         doc.lpszDatatype = 0
225.         doc.fwType = 0
226.         IF 0 >= StartDocA(pde.hDC, _OFFSET(doc)) THEN PRINT "doc error"
227.         IF 0 >= StartPage(pde.hDC) THEN PRINT "doc error"
228.  
229.         IF GDI_ERROR = SetTextAlign(pde.hDC, GetTextAlign(pde.hDC) OR TA_UPDATECP) THEN PRINT "GDI error"
230.         t = "Hello, world!"
231.         IF 0 = TextOutA(pde.hDC, 0, 0, _OFFSET(t), LEN(t)) THEN PRINT "error"
232.  
233.         IF 0 >= EndPage(pde.hDC) THEN PRINT "doc error"
234.         IF 0 >= EndDoc(pde.hDC) THEN PRINT "doc error"
235.     END IF
236. END IF
237.  
238. IF pde.hDevMode THEN
239.     IF 0 <> GlobalFree(pde.hDevMode) THEN PRINT "Error: 0x" + LCASE$(HEX$(GetLastError))
240. END IF
241. IF pde.hDevNames THEN
242.     IF 0 <> GlobalFree(pde.hDevNames) THEN PRINT "Error: 0x" + LCASE$(HEX$(GetLastError))
243. END IF
244. IF pde.hDC THEN
245.     IF 0 = DeleteDC(pde.hDC) THEN PRINT "Error: 0x" + LCASE$(HEX$(GetLastError))
246. END IF
247. END
248.  
249.  
250. SUB readDevMode (t AS DEVMODEA)
251.     PRINT t.dmDeviceName
252.     ' etc...
253. END SUB
254.  
255. SUB readDevNames (t AS DEVNAMES)
256.     DIM m AS _MEM
257.     t$ = SPACE$(255)
258.  
259.     m = _MEM(_OFFSET(t) + t.wDriverOffset, 255)
260.     _MEMGET m, m.OFFSET, t$
261.     PRINT t$
262.  
263.     m = _MEM(_OFFSET(t) + t.wDeviceOffset, 255)
264.     _MEMGET m, m.OFFSET, t$
265.     PRINT t$
266.  
267.     m = _MEM(_OFFSET(t) + t.wOutputOffset, 255)
268.     _MEMGET m, m.OFFSET, t$
269.     PRINT t$
270.  
271.  
272.  
273.     'PRINT peekstr(_OFFSET(t) + t.wDriverOffset)
274.     'PRINT peekstr(_OFFSET(t) + t.wDeviceOffset)
275.     'PRINT peekstr(_OFFSET(t) + t.wOutputOffset)
276. END SUB
277.  

[Dimster]

Thanks very much Steve and Richard. I ran the code for 64 bit and was so happy to see "Hello,world!" on top left corner of my printed page. I am trying to do more with this code but I'm a little lost (well maybe a lot lost). To print a screen of text, I would use "select all" to highlight it but how then would I change Line 230, where Hello world is located to send the highlighted screen text to the printer. And to print a file from line 230 is it just a matter of " t = "d:FileName" ?? doesn't seem to be working for me at moment.

[SMcNeill]

I've really got to get a printer hooked back up to my PC sometime soonish, and then I can test it and sort out how to make it all work once again, Dimster.  ;)

This poor old code was written back in Oct 2013, and disappeared with the old [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there] forums went down, and I'll need some time to sort out where/how it is supposed to work once again, before I can really answer many questions for it.  At the moment, I'm just happy to have it popping up the printer selection screen and letting me choose from the list of printers for my machine. 

My initial thinking is that the best way to use this would be to incorporate it into a set of SUB/FUNCTIONS.

Currently, if I remember correctly, this only prints a single test line of code, and that's basically from these lines:

        t = "Hello, world!"
        IF 0 = TextOutA(pde.hDC, 0, 0, _OFFSET(t), LEN(t)) THEN PRINT "error"

If you want to print more text, you can use the TextOutA command to tell the printer to print something for you, such as:

        t = "This would be the first line of text to print out!"
        IF 0 = TextOutA(pde.hDC, 0, 0, _OFFSET(t), LEN(t)) THEN PRINT "error"
        t = "This would be the second line of text to print out!"
        IF 0 = TextOutA(pde.hDC, 0, 0, _OFFSET(t), LEN(t)) THEN PRINT "error"
        t = "This would be the final line of text to print out!"
        IF 0 = TextOutA(pde.hDC, 0, 0, _OFFSET(t), LEN(t)) THEN PRINT "error"

Substitute those lines in place of the original 2 there, and you should be able to print all 3 lines on a single sheet of paper sequentially.  (Which is why I said making a SUB to handle that would probably be the best way to go...)

All of this was really more of a "proof of concept" set of code back in the day, just to mainly change printers and prove that we could interact with the windows API commands inside QB64, than something which was ever fully developed and fleshed out to make it super useful.   

Now that it's been recovered, maybe somebody will be inspired by it to expand upon it and make it a truly useful library for us.  (Heck, I might even do that, if I can just find a few extra hours in the day somewhere.)  ;)

[SierraKen]

If you just want simple text, you can just use it the old fashion way and use LPRINT. Like in this example.
I think this will only work in Windows. There's another command to print images which I've used a few times on my printer.
I just tested this and it works. But for some reason it prints after you close the program. This is USB Printer compatible.

You can read more here: https://qb64.org/wiki/LPRINT

Code: QB64: [Select]

1. CLS
2. INPUT "Type what you want on the printer: ",a$
3. LPRINT a$
4.  

[SMcNeill]

If you just want simple text, you can just use it the old fashion way and use LPRINT. Like in this example.
I think this will only work in Windows. There's another command to print images which I've used a few times on my printer.
I just tested this and it works. But for some reason it prints after you close the program. This is USB Printer compatible.

You can read more here: https://qb64.org/wiki/LPRINT

Code: QB64: [Select]

1. CLS
2. INPUT "Type what you want on the printer: ",a$
3. LPRINT a$
4.  

LPRINT works, but you can't change which printer it uses, or any of the other settings with it, and it doesn't support any of the formatting options which you can use with the windows API, such as aligning the text, changing fonts or fontsizes, and all those things... 

The demo here is mainly to showcase how to pull up the printer options, moreso than it is to print the "Hello World" to your printer.  ;)

[Dimster]

I got a little over excited there - thanks for resetting my perspective Steve - with everything you have on your plate, this one can wait it's turn, if it's turn ever tickles your fancy. I'm over my head in memory coding and watching your videos faithfully, one day "TextOutA(pde.hDC, 0, 0, _OFFSET(t), LEN(t)" will make sense to me.

Thanks SierraKen - LPRINT I am familiar with and will mess around with it.

[SMcNeill]

I got a little over excited there - thanks for resetting my perspective Steve - with everything you have on your plate, this one can wait it's turn, if it's turn ever tickles your fancy. I'm over my head in memory coding and watching your videos faithfully, one day "TextOutA(pde.hDC, 0, 0, _OFFSET(t), LEN(t)" will make sense to me.

Thanks SierraKen - LPRINT I am familiar with and will mess around with it.

I had to look it up to sort out what all those parameters stand for once again, and if I'm reading the documentation correctly, TextOutA is more versitile than I'd first thought -- it's basically like _PRINTSTRING, except it prints to various places and not just the screen.

TextOutA(pde.hDC, 0, 0, _OFFSET(t), LEN(t)) --- let's break this down step by step for you:

TextOutA -- the name of the FUNCTION we're calling.  It should return an OK code, or an ERROR code if it screws up.
pde.h -- this is the handle of the device that we're sending text out to.  In this case, we're sending it to our printer which we initialized earlier.
0, 0 -- these are X,Y coordinates of where the text should print, inside the boundaries of our page.
_OFFSET(t) -- the offset of the string which we want to print out.
LEN(t) -- the length of the string which we want to print out.

I'll need to so some testing to see if it works as intended, but according to the documention, that's how it works.  :P

https://docs.microsoft.com/en-us/windows/win32/api/wingdi/nf-wingdi-textouta

[SMcNeill]

I was playing around with this again a bit today, and had some interesting results which I thought I'd share for folks:

Code: QB64: [Select]

1. CONST PD_ALLPAGES = 0
2. CONST PD_CURRENTPAGE = &H00400000
3. CONST PD_DISABLEPRINTTOFILE = &H00080000
4. CONST PD_PAGENUMS = 2
5. CONST PD_RETURNDC = &H00000100
6. CONST PD_RETURNDEFAULT = &H00000400
7. CONST PD_SELECTION = 1
8. CONST PD_USEDEVMODECOPIESANDCOLLATE = &H00040000
9. CONST START_PAGE_GENERAL = -1
10. CONST PD_RESULT_CANCEL = 0
11. CONST PD_RESULT_PRINT = 1
12. CONST PD_RESULT_APPLY = 2
13. CONST CCHDEVICENAME = 32
14. CONST CCHFORMNAME = 32
15.  
16. CONST TA_UPDATECP = 1
17.  
18. CONST S_OK = 0
19. ' CONST E_HANDLE = &H80070006
20.  
21. CONST GDI_ERROR = -1
22.  
23.  
24. DECLARE DYNAMIC LIBRARY "kernel32"
25.     FUNCTION GlobalFree~%& (BYVAL hMem~%&)
26.     FUNCTION GetLastError~& ()
27. END DECLARE
28.  
29. DECLARE DYNAMIC LIBRARY "gdi32"
30.     FUNCTION DeleteDC& (BYVAL hdc~%&)
31.     FUNCTION SetTextAlign~& (BYVAL hdc~%&, BYVAL fMode~&)
32.     FUNCTION GetTextAlign~& (BYVAL hdc~%&)
33.     FUNCTION TextOutA& (BYVAL hdc~%&, BYVAL nXStart&, BYVAL nYStart&, BYVAL lpString~%&, BYVAL cchString&)
34.     FUNCTION StartDocA& (BYVAL hdc~%&, BYVAL lpdi~%&)
35.     FUNCTION AbortDoc& (BYVAL hdc~%&)
36.     FUNCTION StartPage& (BYVAL hDC~%&)
37.     FUNCTION EndPage& (BYVAL hdc~%&)
38.     FUNCTION EndDoc& (BYVAL hdc~%&)
39.     FUNCTION ResetDCA~%& (BYVAL hdc~%&, BYVAL lpInitData~%&)
40. END DECLARE
41.  
42. DECLARE DYNAMIC LIBRARY "comdlg32"
43.     FUNCTION PrintDlgExA~& (BYVAL lppd~%&) ' returns an HRESULT
44. END DECLARE
45.  
46. TYPE DOCINFOA
47.     cbSize AS LONG
48.     lpszDocName AS _UNSIGNED _OFFSET ' LPCSTR
49.     lpszOutput AS _UNSIGNED _OFFSET ' LPCSTR
50.     lpszDatatype AS _UNSIGNED _OFFSET ' LPCSTR
51.     fwType AS _UNSIGNED LONG
52. END TYPE
53.  
54.  
55. TYPE POINTL
56.     x AS LONG
57.     y AS LONG
58. END TYPE
59.  
60. CONST len_DEVMODEA = 156
61. TYPE DEVMODEA
62.     dmDeviceName AS STRING * CCHDEVICENAME
63.     dmSpecVersion AS _UNSIGNED INTEGER
64.     dmDriverVersion AS _UNSIGNED INTEGER
65.     dmSize AS _UNSIGNED INTEGER
66.     dmDriverExtra AS _UNSIGNED INTEGER
67.     dmFields AS _UNSIGNED LONG
68.     ' union {
69.     ' struct { comment either the following 8 lines
70.     dmOrientation AS INTEGER
71.     dmPaperSize AS INTEGER
72.     dmPaperLength AS INTEGER
73.     dmPaperWidth AS INTEGER
74.     dmScale AS INTEGER
75.     dmCopies AS INTEGER
76.     dmDefaultSource AS INTEGER
77.     dmPrintQuality AS INTEGER
78.     ' };
79.     ' struct { or the following 3 lines
80.     ' dmPosition AS POINTL
81.     ' dmDisplayOrientation AS _UNSIGNED LONG
82.     ' dmDisplayFixedOutput AS _UNSIGNED LONG
83.     ' };
84.     ' };
85.     dmColor AS INTEGER
86.     dmDuplex AS INTEGER
87.     dmYResolution AS INTEGER
88.     dmTTOption AS INTEGER
89.     dmCollate AS INTEGER
90.     dmFormName AS STRING * CCHFORMNAME
91.     dmLogPixels AS _UNSIGNED INTEGER
92.     dmBitsPerPel AS _UNSIGNED LONG
93.     dmPelsWidth AS _UNSIGNED LONG
94.     dmPelsHeight AS _UNSIGNED LONG
95.     ' union { comment exactly 1 of the following 2 lines
96.     ' dmDisplayFlags AS _UNSIGNED LONG
97.     dmNup AS _UNSIGNED LONG
98.     ' };
99.     dmDisplayFrequency AS _UNSIGNED LONG
100.     dmICMMethod AS _UNSIGNED LONG
101.     dmICMIntent AS _UNSIGNED LONG
102.     dmMediaType AS _UNSIGNED LONG
103.     dmDitherType AS _UNSIGNED LONG
104.     dmReserved1 AS _UNSIGNED LONG
105.     dmReserved2 AS _UNSIGNED LONG
106.     dmPanningWidth AS _UNSIGNED LONG
107.     dmPanningHeight AS _UNSIGNED LONG
108. END TYPE
109.  
110. TYPE DEVNAMES
111.     wDriverOffset AS _UNSIGNED INTEGER
112.     wDeviceOffset AS _UNSIGNED INTEGER
113.     wOutputOffset AS _UNSIGNED INTEGER
114.     wDefault AS _UNSIGNED INTEGER
115. END TYPE
116.  
117. TYPE PRINTPAGERANGE
118.     nFromPage AS _UNSIGNED LONG
119.     nToPage AS _UNSIGNED LONG
120. END TYPE
121.  
122. $IF 32BIT THEN
123.     TYPE PRINTDLGEX
124.     lStructSize AS _UNSIGNED LONG
125.     hwndOwner AS _UNSIGNED _OFFSET ' HWND
126.     hDevMode AS _UNSIGNED _OFFSET ' HGLOBAL
127.     hDevNames AS _UNSIGNED _OFFSET ' HGLOBAL
128.     hDC AS _UNSIGNED _OFFSET ' HDC
129.     Flags AS _UNSIGNED LONG
130.     Flags2 AS _UNSIGNED LONG
131.     ExclusionFlags AS _UNSIGNED LONG
132.     nPageRanges AS _UNSIGNED LONG
133.     nMaxPageRanges AS _UNSIGNED LONG
134.     lpPageRanges AS _UNSIGNED _OFFSET ' LPPRINTPAGERANGE
135.     nMinPage AS _UNSIGNED LONG
136.     nMaxPage AS _UNSIGNED LONG
137.     nCopies AS _UNSIGNED LONG
138.     hInstance AS _UNSIGNED _OFFSET ' HINSTANCE
139.     lpPrintTemplateName AS _UNSIGNED _OFFSET ' LPCSTR
140.     lpCallback AS _UNSIGNED _OFFSET ' LPUNKNOWN
141.     nPropertyPages AS _UNSIGNED LONG
142.     lphPropertyPages AS _UNSIGNED _OFFSET ' HPROPSHEETPAGE *
143.     nStartPage AS _UNSIGNED LONG
144.     dwResultAction AS _UNSIGNED LONG
145.     END TYPE
146. $ELSE
147.     TYPE PRINTDLGEX
148.         lStructSize AS _UNSIGNED _INTEGER64
149.         hwndOwner AS _UNSIGNED _OFFSET ' HWND
150.         hDevMode AS _UNSIGNED _OFFSET ' HGLOBAL
151.         hDevNames AS _UNSIGNED _OFFSET ' HGLOBAL
152.         hDC AS _UNSIGNED _OFFSET ' HDC
153.         Flags AS _UNSIGNED LONG
154.         Flags2 AS _UNSIGNED LONG
155.         ExclusionFlags AS _UNSIGNED LONG
156.         nPageRanges AS _UNSIGNED LONG
157.         nMaxPageRanges AS _UNSIGNED _INTEGER64
158.         lpPageRanges AS _UNSIGNED _OFFSET ' LPPRINTPAGERANGE
159.         nMinPage AS _UNSIGNED LONG
160.         nMaxPage AS _UNSIGNED LONG
161.         nCopies AS _UNSIGNED _INTEGER64 'LONG
162.         hInstance AS _UNSIGNED _OFFSET ' HINSTANCE
163.         lpPrintTemplateName AS _UNSIGNED _OFFSET ' LPCSTR
164.         lpCallback AS _UNSIGNED _OFFSET ' LPUNKNOWN
165.         nPropertyPages AS _UNSIGNED _INTEGER64 'LONG
166.         lphPropertyPages AS _UNSIGNED _OFFSET ' HPROPSHEETPAGE *
167.         nStartPage AS _UNSIGNED LONG
168.         dwResultAction AS _UNSIGNED LONG
169.     END TYPE
170. $END IF
171.  
172. DIM pageranges(0 TO 7) AS PRINTPAGERANGE
173. DIM pde AS PRINTDLGEX
174. DIM hWnd AS _UNSIGNED _OFFSET
175. DIM hr AS _UNSIGNED LONG
176. DIM t AS STRING
177. DIM t1 AS STRING * 16
178. DIM doc AS DOCINFOA
179.  
180. hWnd = _WINDOWHANDLE 'FindWindowA(0, _OFFSET(t))
181. _TITLE "Printer API demo"
182. pde.lStructSize = LEN(pde)
183. pde.hwndOwner = hWnd
184. pde.hDevMode = 0
185. pde.hDevNames = 0
186. pde.Flags = PD_ALLPAGES OR PD_RETURNDC OR PD_USEDEVMODECOPIESANDCOLLATE
187. pde.Flags2 = 0
188. pde.nPageRanges = 0
189. pde.nMaxPageRanges = 1 + UBOUND(pageranges)
190. pde.lpPageRanges = _OFFSET(pageranges(0))
191. pde.nMinPage = 1
192. pde.nMaxPage = 1
193. pde.nCopies = 1
194. pde.hInstance = 0
195. pde.lpCallback = 0
196. pde.nPropertyPages = 0
197. pde.lphPropertyPages = 0
198. pde.nStartPage = START_PAGE_GENERAL
199. pde.dwResultAction = 0
200.  
201. hr = PrintDlgExA(_OFFSET(pde))
202. IF S_OK <> hr THEN PRINT "ZZError. HRESULT: 0x" + LCASE$(HEX$(hr))
203.  
204. IF PD_RESULT_PRINT = pde.dwResultAction THEN
205.     IF pde.hDC THEN
206.         t1 = "qb64 prn test" + CHR$(0) ' fixed len str so it won't move
207.         doc.cbSize = LEN(doc)
208.         doc.lpszDocName = _OFFSET(t1)
209.         doc.lpszOutput = 0
210.         doc.lpszDatatype = 0
211.         doc.fwType = 0
212.         IF 0 >= StartDocA(pde.hDC, _OFFSET(doc)) THEN PRINT "doc error"
213.         IF 0 >= StartPage(pde.hDC) THEN PRINT "doc error"
214.  
215.         LPRINT "Foo"
216.         LPRINT "poo"
217.         LPRINT "snoo"
218.  
219.         IF 0 >= EndPage(pde.hDC) THEN PRINT "doc error"
220.         IF 0 >= EndDoc(pde.hDC) THEN PRINT "doc error"
221.     END IF
222. END IF
223.  
224. PRINT "Printed!!"
225.  
226.  
227. IF pde.hDevMode THEN
228.     IF 0 <> GlobalFree(pde.hDevMode) THEN PRINT "Error: 0x" + LCASE$(HEX$(GetLastError))
229. END IF
230. IF pde.hDevNames THEN
231.     IF 0 <> GlobalFree(pde.hDevNames) THEN PRINT "Error: 0x" + LCASE$(HEX$(GetLastError))
232. END IF
233. IF pde.hDC THEN
234.     IF 0 = DeleteDC(pde.hDC) THEN PRINT "Error: 0x" + LCASE$(HEX$(GetLastError))
235. END IF
236. END
237.  

Run this and it'll pop up a print selection window for you, and then print 3 lines to whatever you tell it to print to: "Foo Poo Shoo"  (or something equally nonsensical). 

By itself, this demo really isn't all that impressive, but once you play with it just a bit, you can see why I was interested in resurrecting this old bit of code.  Change from your default printer to "Microsoft Print To PDF" and then Print.  At this point, you'll now be asked for a filename to save to your drive under, and if you enter one, you''ll generate a PDF file PRESTO-MAGICO!!  (Example PDF created from this process and posted below...)

If you look at the code, you'll see that I took out several of the windows library calls and replaced them with the old standard LPRINT which we all know and loved from back in the QBASIC days of the language...

Code: [Select]

        LPRINT "Foo"
        LPRINT "poo"
        LPRINT "snoo"

If you're interested in making PDFs (as was posted about in other topics), this seems like an awfully easy way to make and create them in Windows.  (Won't work for Linux or Mac, but what can I say.. I don't have a Linux or Mac machine for testing/development, so I can't really sort out how to make things like this work on those systems very readily.  Sorry.)

Code has been cleaned up quite a bit and should be easier to follow at this point in time, so people can make it a library and plug it into their own projects if they want.  I wouldn't say it's 100% perfect yet, as there's a lot of options which haven't been incorporated into it such as font changes, alignment, or any such thing, but it basically does what it's supposed to do:  It allows us to access the windows printer selection GUI, choose a printer, and then print stuff to it -- even if what we choose is the "Print To PDF", or "Print To Fax" options....

And that alone, seems like it's enough of a worthwhile accomplishment by itself to make me happy that Richard could help me find and recover this lost bit of code. 

MANY THANKS RICHARD!!