Author Topic: Scroll Bar (Read 16109 times)

Erum · « **Reply #45 on:** September 23, 2019, 11:57:29 am »

To all the respected QB64 team,
Thank you for all those who helped me so much once again. However, I have one last dumb question.
I am done with the whole software, all I need is to add colours. My software is a bit crowded, so I thought adding colours would make the data vivid and easy to read.
I know how to add colours to each line using RGB mixing, but I want to know if it is possible to add more than one colour on one line (text colour only).
I would be grateful to anyone who takes precious time to answer this dumb question.
Regards.

bplus · « **Reply #46 on:** September 23, 2019, 12:43:20 pm »

Here is an example:

Code: QB64: [Select]

SCREEN _NEWIMAGE(800, 600, 32) 'for _rgb32 colors
_SCREENMOVE 300, 60 'to get the screen out of B+ title and tool bars
 
txt$ = "Hello world, let me show you a multi-colored string, in just one longish line."
 
'the MID$ function takes portions of a string
FOR i = 1 TO LEN(txt$) STEP 5 'print txt$ 5 chars at a time
    'reset the ink of print
    COLOR _RGB32(RND * 255, RND * 255, RND * 155 + 100)
    PRINT MID$(txt$, i, 5);
NEXT
 
 

PS It is not dumb to ask questions, neither dumb intellectually nor dumb in speech.

SMcNeill · « **Reply #47 on:** September 23, 2019, 01:04:05 pm »

Quote from: bplus on September 23, 2019, 12:43:20 pm

It is not dumb to ask questions, neither dumb intellectually nor dumb in speech.

I couldn’t agree more! All software, and new experiences, require a learning curve. By asking questions, and finding friendly folks who will take the time to answer them, you can reduce that learning curve immensely. It’s not dumb to ask questions; and the only people who thinks it is, are the true idiots. ;)

Erum · « **Reply #48 on:** September 23, 2019, 02:37:00 pm »

Respected QB64 members,
Thank you for making me feel confident for asking questions, you truly are friendly folks. As for the reply, I understood it, and I’ll use it. Thank you!
My queries are officially over. Thanks once more to everyone.
Regards.

TempodiBasic · « **Reply #49 on:** September 23, 2019, 03:02:23 pm »

about

Quote

PS It is not dumb to ask questions, neither dumb intellectually nor dumb in speech.

in my country there is a phrase from the XIX/XX century : "Chi tene a lengua va in Sardegna!"
translating from Dialect to Italian and from italian to English literally "if you have the tongue you can go to Sardegna !" but for the sense is better "You can go anywhere also to a difficult country to reach like the isle Sardegna if you use your tongue to talk, to ask, to thank"

about developing a scrollbar function
what do you like to do? Complete or stop the developing?

Petr · « **Reply #50 on:** September 23, 2019, 03:04:18 pm »

Hi again.

Finally, I finished what I promised. So ... I tried it for 256 colors only, I will add support for truecolor hexadecimal colors (now must be writed as unsigned long number) . So far, it works like this:

(Added support for PgUP, PgDn, Up, Dn)

Despite the fact that Erum will probably no use it, because as she write, is done, i add to this thread the promised second type of textbox + third with a shift in all axes. It will certainly be useful to someone later. (And I enjoy it).

Best joke from testing this program? Hell, why is text not show? Why it works not if use colors? Yeah, man. 32 bit screen and used 8 bit colors...

Code: QB64: [Select]

'promise: Textbox with use as PRINT. NEED GRAPHIC SCREEN!
 
'this is future "TextBox.BI"
TYPE Colored
    onpos AS INTEGER
    clr AS _UNSIGNED LONG
    flag AS INTEGER
END TYPE
REDIM SHARED k(0) AS Colored
 
TYPE TB
    X AS INTEGER '   X position graphic coord
    Y AS INTEGER '   Y position graphic coord
    L AS INTEGER '   TextBox lenght
    T AS STRING '    TextBox text
    B AS INTEGER '   Text begin in textbox  (for shift)
    Arrow AS LONG
    D AS SINGLE 'for time delay between click to arrows
END TYPE
REDIM SHARED TBA(0) AS TB
SCREEN _NEWIMAGE(800, 600, 256) 'screen must be initialized before PutArrow& is run.
 
TBA(0).Arrow = PutArrow&
'real textboxes starting from 1
 
'end of future "TextBox.BI"
 
 
DIM test(10) AS LONG
 
FOR t = 1 TO 10
    test(t) = INITBOX(100 + 250 * RND, 40 * t - 27, "/5Hi, /14I'm working on it./1 This /2is the /15test/14 text/15 of the program for /78longitudinal scrolling /14in the /90window./14 Color capabilities will be added soon. /8The program uses arrays because program need to remember the shift values for more than one /50b/60o/20x.", 15 + RND * 40)
NEXT
Demo = INITBOX(150, 500, "/17T/18h/19i/20s /21i/22s/23 s/24m/25a/26l/27l /28t/29e/30x/31t", 9)
 
 
DO
 
    FOR p = 1 TO 10
        PRINTBOX p
    NEXT
    PRINTBOX Demo
 
    _DISPLAY
LOOP
 
'this is future "TextBox.BM"
 
FUNCTION INITBOX (X AS INTEGER, Y AS INTEGER, Text AS STRING, BoxLenght AS INTEGER) 'X, Y are GRAPHIC coordinates
    UTB = UBOUND(tba)
    REDIM _PRESERVE TBA(UTB + 1) AS TB
    TBA(UTB + 1).X = X
    TBA(UTB + 1).Y = Y
    TBA(UTB + 1).L = BoxLenght
    CString Text, text2$, k(), UTB + 1
    k(UBOUND(k) - 1).flag = UTB + 1
    TBA(UTB + 1).T = text2$
    TBA(UTB + 1).B = 1
    INITBOX = UTB + 1
END FUNCTION
 
 
SUB PRINTBOX (nr AS LONG)
    IF nr < 1 OR nr > UBOUND(tba) THEN EXIT SUB 'subscript out of range prevention
    '256/32 color support:
    SELECT CASE _PIXELSIZE
        CASE 0: BEEP: PRINT "Text mode not supported by PRINTBOX!": _DISPLAY: SLEEP 3: END
        CASE 1
            Black~& = 0
            White~& = 15
            Grey~& = 24
            Grey2~& = 19
        CASE 4
            Black~& = &HFF000000
            White~& = &HFFFFFFFF
            Grey~& = &HFF6666666
            Grey2~& = &HFF221122
    END SELECT
 
 
 
 
    TextBoxArrow& = TBA(0).Arrow
    TextLenght = _PRINTWIDTH(TBA(nr).T)
    B = TBA(nr).B
    TextHeight = _FONTHEIGHT
    X = TBA(nr).X
    Y = TBA(nr).Y
    BoxLenght = TBA(nr).L
    T$ = MID$(TBA(nr).T, TBA(nr).B, TBA(nr).L) 'text loader
 
 
    WHILE _MOUSEINPUT:
        mwh = mwh + _MOUSEWHEEL
        IF mwh THEN EXIT WHILE
    WEND
 
    IF _MOUSEX >= X - 30 AND _MOUSEX <= X + 30 + BoxLenght * _FONTWIDTH THEN
        IF _MOUSEY >= Y - 3 AND _MOUSEY <= Y + 3 + 2 * TextHeight THEN
            B = B + mwh * 4
        END IF
    END IF
 
 
    '
    MB1 = _MOUSEBUTTON(1)
    MX = _MOUSEX
    MY = _MOUSEY
 
    LINE (X - 30, Y - 3)-(X + 30 + BoxLenght * _FONTWIDTH, Y + TextHeight * 2), Black~&, BF
 
 
    LINE (X - 30, Y + TextHeight)-(X + 30 + BoxLenght * _FONTWIDTH, Y + TextHeight * 2), Grey~&, BF
    LINE (X - 30, Y - 3)-(X + 30 + BoxLenght * _FONTWIDTH, Y + 2 * TextHeight), White~&, B
 
    LINE (X - 28, Y - 1)-(X + 28 + BoxLenght * _FONTWIDTH, Y + TextHeight), White~&, B
 
    TL = B / LEN(TBA(nr).T) * 100 'pocatecni poloha pruhu v procentech       begining position for bottom box (perecentually)
    L = TBA(nr).L * _FONTWIDTH
    Actual = _CEIL(X + (TL / 100 * L)) '                                     graphic position for bottom box
    boxl = BoxLenght * _FONTWIDTH
    BL = boxl / (TextLenght / 100) 'delka posuvneho boxiku  v procentech     box on bottom lenght
    BBL = boxl / 100 * BL
 
    'posuvnik
    LINE (Actual, Y + TextHeight + 5)-(Actual + BBL, Y + TextHeight * 2 - 3), White~&, BF
    LINE (Actual, Y + TextHeight + 5)-(Actual + BBL, Y + TextHeight * 2 - 3), Grey2~&, B
 
 
    IF MX >= Actual AND MX <= Actual + BBL THEN
        IF MY >= Y + TextHeight + 5 AND MY <= Y + TextHeight * 2 - 3 THEN
            IF MB1 THEN
                omx = MX
                DO UNTIL _MOUSEX <> MX
                    WHILE _MOUSEINPUT: WEND
                    MB1 = _MOUSEBUTTON(1)
                    B = B + _MOUSEX - omx
                LOOP
            END IF
        END IF
    END IF
 
 
    _PUTIMAGE (X + 15 + BoxLenght * _FONTWIDTH, Y + TextHeight + 1), TextBoxArrow&
    _PUTIMAGE (X - 15, Y + TextHeight + 1)-(X - 27, Y + TextHeight + 1 + 12), TextBoxArrow&
 
    IF TIMER < 1 THEN TBA(nr).D = 0
 
    IF MX >= X + 15 + BoxLenght * _FONTWIDTH AND MX <= X + 15 + BoxLenght * _FONTWIDTH + 12 THEN
        IF MY >= Y + 1 + TextHeight AND MY <= Y + TextHeight * 2 THEN
            IF TBA(nr).D < TIMER THEN
                IF _PIXELSIZE = 4 THEN
                    LINE (X + 15 + BoxLenght * _FONTWIDTH, Y + TextHeight + 1)-(X + 15 + BoxLenght * _FONTWIDTH + 11, Y + TextHeight * 2), &H44FFFFFF, BF
                ELSE
                    LINE (X + 15 + BoxLenght * _FONTWIDTH, Y + TextHeight + 1)-(X + 15 + BoxLenght * _FONTWIDTH + 11, Y + TextHeight * 2), 14, B
                END IF
                IF MB1 THEN
                    B = B + 1
                END IF
                TBA(nr).D = TIMER + .01
            END IF
        END IF
    END IF
 
    IF MX >= X - 26 AND MX <= X - 15 THEN
        ' IF MY >= Y + 1 AND MY <= Y + 13 THEN
        IF MY >= Y + 1 + TextHeight AND MY <= Y + TextHeight * 2 THEN
 
            SELECT CASE _KEYHIT
                CASE 18176: B = 1
                CASE 20224: B = LEN(TBA(nr).T) - TBA(nr).L + 1
                CASE 18688: B = B - TBA(nr).L
                CASE 20736: B = B + TBA(nr).L
            END SELECT
 
 
            IF TBA(nr).D < TIMER THEN
                IF _PIXELSIZE = 4 THEN
                    LINE (X - 26, Y + TextHeight + 1)-(X - 15, Y + TextHeight * 2), &H44FFFFFF, BF
                ELSE
                    LINE (X - 26, Y + TextHeight + 1)-(X - 15, Y + TextHeight * 2), 14, B
                END IF
                IF MB1 THEN
                    B = B - 1
                END IF
                TBA(nr).D = TIMER + .01
            END IF
        END IF
    END IF
    IF B < 1 THEN B = 1
    IF B > LEN(TBA(nr).T) - TBA(nr).L + 1 THEN B = LEN(TBA(nr).T) - TBA(nr).L + 1
    TBA(nr).B = B
 
    IF _PIXELSIZE = 4 THEN COLOR &HFFFFFFFF ELSE COLOR 15
 
 
    FOR V = 1 TO LEN(TBA(nr).T)
        FOR t = LBOUND(k) + 1 TO UBOUND(k)
            IF k(t).flag = nr THEN
                IF V = k(t).onpos + 1 THEN COLOR k(t).clr: EXIT FOR
            END IF
        NEXT
 
        IF V >= B AND V <= B + TBA(nr).L THEN
            _PRINTSTRING (X + (W * _FONTWIDTH), Y), MID$(TBA(nr).T, V, 1)
            W = W + 1
        END IF
    NEXT
 
END SUB
 
 
FUNCTION PutArrow&
    IF _PIXELSIZE = 4 THEN
        PutArrow& = _NEWIMAGE(12, 12, 32)
    ELSE
        PutArrow& = _NEWIMAGE(12, 12, 256)
    END IF
 
    D = _DEST
    _DEST PutArrow&
 
    LINE (1, 4)-(6, 4) '  ------------     up
    LINE (1, 8)-(6, 8) '  ------------     down
    LINE (1, 4)-(1, 8) '  I                arrow back
    LINE (6, 4)-(6, 1)
    LINE (6, 8)-(6, 11)
    LINE (6, 11)-(11, 6)
    LINE (6, 1)-(11, 6)
 
    IF _PIXELSIZE(D) = 4 THEN PAINT (6, 6), &HFF777777, &HFFFFFFFF ELSE PAINT (6, 6), 10, 15
    IF _PIXELSIZE(D) = 4 THEN _CLEARCOLOR &HFF000000, PutArrow& ELSE _CLEARCOLOR 0, PutArrow&
    _DEST D
END FUNCTION
 
SUB CString (source AS STRING, text AS STRING, K() AS Colored, index AS INTEGER)
    FOR S = 1 TO LEN(source$)
        t$ = MID$(source$, S, 1)
        IF ASC(t$) >= 48 AND ASC(t$) <= 57 AND incolor THEN colornr$ = colornr$ + t$
        IF incolor AND ASC(t$) < 48 OR incolor AND ASC(t$) > 57 THEN K(kk).clr = VAL(colornr$): D = D + LEN(colornr$): colornr$ = "": incolor = 0
        IF t$ = "/" THEN
            D = D + 1
            incolor = 1
            REDIM _PRESERVE K(UBOUND(k) + 1) AS Colored
            kk = UBOUND(k)
            K(kk).onpos = S - D
            K(kk).flag = index
        END IF
        IF incolor = 0 THEN text$ = text$ + t$
    NEXT
END SUB
 
'End of future "TextBox.BM"
 
 
 
 

EDIT: Myself found critical bug: Colors from previous call was used also for next call, for next string. REPAIRED in this version. Now all strings use colors as expected. (Bug is also visible on attached image - word's "This" expected color was white. Now it is ok.

[ You are not allowed to view this attachment ]

TempodiBasic · « **Reply #51 on:** September 23, 2019, 03:13:37 pm »

Hi Bplus
I find your version of scrollbar fine and working.
[ You are not allowed to view this attachment ]

Hi Petr
very fine multicolor on the same raw of text...

bplus · « **Reply #52 on:** September 23, 2019, 03:48:13 pm »

Quote

about developing a scrollbar function
what do you like to do? Complete or stop the developing?

I am glad we could eventually help Erum. But she has sort of opened a can of worms with this scrollbar(s) thing.

Petr's and TempodiBasic's interest along with mine have been peaked, I think. I confess I was not particularly interested in a horizontal text scroller but having finished a pretty nice one, I am curious about doing text with a double scrollbar vertical and horizontal. Now Steve has sort of started that topic but also speaks of resizeable programs?? here https://www.qb64.org/forum/index.php?topic=1719.msg109557#msg109557
WTH resizeable programs??? I think he just tapped this section of code out of something bigger that makes more sense as a whole.

So I am wondering should we continue discussion here with the horizontal text conquered or should we move to Steve's thread and try and improve on his double scrollbars by connecting up mouse and normal keys arrows, home. end, pgUp, pgDn... mouse Clicks, mouse dragging, mouse wheel to the scrollers?

There is one other underlying issue to consider, the control of mouse and key inputs over the whole screen which might contain several scrollbars, mouse click or drag areas, say for buttons or lists or text boxes... going this far in thinking ahead, I see we have arrived at on InForm like GUI! (I arrived at this central mouse and key controller problem with Tiny Navigator trying to do 2 Lists to select from Files or Directories.) So now I wonder is it worth the time for working out double scrollbars for giant text which will likely mean a central controller for all mouse and key activity in order to actually use it in an app. ???

Now my head hurts ;-))

Well we are in the Discussion board, so let's continue discussion here if it pleases Petr and TempodiBasic and anyone else interested in this coding problem.

Bert22306 · « **Reply #53 on:** September 23, 2019, 03:59:05 pm »

Yeah, Bplus, Tempo, Steve, and Petr, this discussion started by Erum has been great. Very educational. Always nice to find ways to make QB64 programs look more modern and less DOS-like.

SMcNeill · « **Reply #54 on:** September 23, 2019, 04:17:12 pm »

An upgraded version of my scroll bar system, now that I have a few moments free to flesh it out:

Code: QB64: [Select]

DIM SHARED WorkScreen AS LONG, DisplayScreen AS LONG
$RESIZE:ON
 
WorkScreen = _NEWIMAGE(3600, 2400, 32) ' a nice large screen so we can scroll like crazy
DisplayScreen = _NEWIMAGE(640, 480, 32) 'a nice small display screen
 
SCREEN DisplayScreen
_DEST WorkScreen
PRINT "Let's print all sorts of stuff on our workscreen, and make certain that it's more than long enough so that it'll scroll quite a ways across from the normal screen."
PRINT
PRINT
LINE (400, 400)-(3000, 1200), &HFFFFFF00, BF
FOR i = 1 TO 145
    COLOR _RGB32(RND * 256, RND * 256, RND * 256), 0 'various colors for each line
    PRINT "LINE #"; i; ".  This is just a bunch of junk for testing purposes only.  As you can see, if you want to read all the text from this line, you're going to have to scroll to see it all."
NEXT
 
 
 
 
 
StartX = 0: StartY = 0: W = _WIDTH(DisplayScreen): H = _HEIGHT(DisplayScreen)
_DEST DisplayScreen
DO
    IF _RESIZE THEN
        temp = _NEWIMAGE(_RESIZEWIDTH, _RESIZEHEIGHT, 32)
        SCREEN temp
        _FREEIMAGE DisplayScreen
        DisplayScreen = temp
        W = _WIDTH(DisplayScreen): H = _HEIGHT(DisplayScreen)
        _DELAY .25
        junk = _RESIZE 'clear the resize flag after manually setting the screen to the size we specified.
    END IF
    _LIMIT 30
    CLS
    ScrollBar StartX, 2
    ScrollBar StartY, 1
 
    k = _KEYHIT
    SELECT CASE k
        CASE ASC("A"), ASC("a"), 19200: StartX = StartX - 10: IF StartX < 0 THEN StartX = 0
        CASE ASC("S"), ASC("s"), 20480: StartY = StartY + 10: IF StartY > _HEIGHT(WorkScreen) - H THEN StartY = _HEIGHT(WorkScreen) - H
        CASE ASC("D"), ASC("d"), 19712: StartX = StartX + 10: IF StartX > _WIDTH(WorkScreen) - W THEN StartX = _WIDTH(WorkScreen) - W
        CASE ASC("W"), ASC("w"), 18432: StartY = StartY - 10: IF StartY < 0 THEN StartY = 0
    END SELECT
    WHILE _MOUSEINPUT: WEND
    IF _MOUSEBUTTON(1) THEN
        IF _MOUSEX > W - 21 AND _MOUSEY < H - 20 THEN 'We're on a up/down scroll bar
            StartY = _MOUSEY / _HEIGHT(DisplayScreen) * _HEIGHT(WorkScreen)
            IF StartY > _HEIGHT(WorkScreen) - H THEN StartY = _HEIGHT(WorkScreen) - H
        END IF
        IF _MOUSEY > H - 21 AND _MOUSEX < W - 20 THEN 'we're on the left/right scroll bar
            StartX = _MOUSEX / _WIDTH(DisplayScreen) * _WIDTH(WorkScreen)
            IF StartX > _WIDTH(WorkScreen) - W THEN StartX = _WIDTH(WorkScreen) - W
        END IF
    END IF
 
    _PUTIMAGE (0, 0)-(W - 20, H - 20), WorkScreen, DisplayScreen, (StartX, StartY)-STEP(W, H)
    _DISPLAY
LOOP
 
 
 
 
 
SUB ScrollBar (Start, Direction)
    D = _DEST: _DEST DisplayScreen 'our scrollbars show on the display
    Min = 0
    MaxH = _HEIGHT(DisplayScreen)
    MaxW = _WIDTH(DisplayScreen)
    H = _HEIGHT(WorkScreen)
    W = _WIDTH(WorkScreen)
    IF Direction = 1 THEN 'up/down bar
        Box MaxW - 20, 0, 20, MaxH - 20, &HFF777777, &HFFFFFFFF
        Box MaxW - 19, Start / H * MaxH, 18, MaxH / H * MaxH - 20, &HFFFF0000, 0 'Red with transparent
    ELSE 'left/right bar
        Box Min, MaxH - 20, MaxW - 20, 20, &HFF777777, &HFFFFFFFF 'Gray with white border
        Box Start / W * MaxW, MaxH - 19, MaxW / W * MaxW - 20, 18, &HFFFF0000, 0 'Red with transparent
    END IF
    _DEST D
END SUB
 
 
SUB Box (x, y, wide, high, kolor AS _UNSIGNED LONG, border AS _UNSIGNED LONG)
    LINE (x, y)-STEP(wide, high), kolor, BF
    LINE (x, y)-STEP(wide, high), border, B
END SUB
 

Arrow keys scroll, and you can use the mouse to maneuver via the scroll bars if you hold the left mouse down while over one of them. The window is also resizable, with the scroll bars automatically adjusting to the new window sizes. Test it out, and see what you think of it. ;)

Petr · « **Reply #55 on:** September 23, 2019, 05:14:38 pm »

I think about it the best. :) Good work, Steve.

bplus · « **Reply #56 on:** September 23, 2019, 05:29:51 pm »

Quote from: Petr on September 23, 2019, 05:14:38 pm

I think about it the best. :) Good work, Steve.

Well I wonder if Steve or anyone can put can put N text boxes up with double scrollers on the same screen like we were doing for text hScrollers with mouse wheel and other key presses also of course! ;-))

SMcNeill · « **Reply #57 on:** September 23, 2019, 05:38:32 pm »

Quote from: bplus on September 23, 2019, 05:29:51 pm

Well I wonder if Steve or anyone can put can put N text boxes up with double scrollers on the same screen like we were doing for text hScrollers with mouse wheel and other key presses also of course! ;-))

Sure. Just make each scroll area independent, and assign them their own unique handle, like with my little text frames routines. All this demo needed was to make a screen adjustable/scrollable, but all you do is apply the same principle to any given screen regions — one screen of set size to draw/write on, a second screen to display a portion of it on via _PUTIMAGE, with the scroll bars just being X/Y incremental tools. (Which is all they do above for us.)

TempodiBasic · « **Reply #58 on:** September 23, 2019, 05:44:49 pm »

about

Quote

So I am wondering should we continue discussion here with the horizontal text conquered or should we move to Steve's thread

Here my answer to unify the threads https://www.qb64.org/forum/index.php?topic=1719.msg109796#msg109796

about this issue

Quote

So now I wonder is it worth the time for working out double scrollbars for giant text which will likely mean a central controller for all mouse and key activity in order to actually use it in an app. ???

IMHO when we go to think as objects or entities to use in our programs we have two option...
1. centered managing of mouse and keyboard and other input ways ,
so we can think about it like a pyramid that has like apex the I/O routine to be directed to the right entity at bottom,
or like a collection of areas to be activated by a flag (in Windows there are the messages among objects)
2. a plane or circular managing of I/O in which the objects/entities have the own different action that is activated by the specific
position of the mouse and by the specific comboKey

the substantial difference between them is that in the first the apex manages I/O and triggers entity's action, in the second there is a main loop in which each entity tests if position of mouse and combokey activate its action/s.

just as example about previous scrolling horizonthal
in the first kind of multi entities there is a main loop that catches I/O and activate the single scrolling bar...
in the second kind of multi entities, one at time each entity tests if it must react ot I/O so there is a main loop that cycles among all entities

so in the first kind each entity has a value or code to be activated and disactivated
while in the second kind each entity has an entry of parameters and a routine to activate itself.

Waiting your opinion
Thanks to read

Petr · « **Reply #59 on:** September 23, 2019, 05:56:22 pm »

Quote

Sure. Just make each scroll area independent, and assign them their own unique handle, like with my little text frames routines. All this demo needed was to make a screen adjustable/scrollable, but all you do is apply the same principle to any given screen regions — one screen of set size to draw/write on, a second screen to display a portion of it on via _PUTIMAGE, with the scroll bars just being X/Y incremental tools. (Which is all they do above for us.)

I'll do it differently. I'll do it with PRINTSTRING (none PUTIMAGE). Yeah, if I wanted to make a slider for pictures with text, that would be harder. To solve the text flow around the picture .... I can think of several possibilities, but I will stay with the text. Of course it will take a while, but it won't be a problem. Of course there will be an unlimited number (according to RAM) of these dialogs on the monitor. I think, i need 2 or 3 days for it (i have very limited time for programming now).

So far, I say goodbye because here is midnight.

News:

Author Topic: Scroll Bar (Read 16109 times)

Erum

Re: Scroll Bar

bplus

Re: Scroll Bar

SMcNeill

Re: Scroll Bar

Erum

Re: Scroll Bar

TempodiBasic

Re: Scroll Bar

Petr

Re: Scroll Bar

TempodiBasic

Re: Scroll Bar

bplus

Re: Scroll Bar

Bert22306

Re: Scroll Bar

SMcNeill

Re: Scroll Bar

Petr

Re: Scroll Bar

bplus

Re: Scroll Bar

SMcNeill

Re: Scroll Bar

TempodiBasic

Re: Scroll Bar

Petr

Re: Scroll Bar