Generic Random Maze Maker

[SierraKen]

Something else I always wanted to make. Was pretty easy to make the random maze maker. But finding a maze that you can actually solve is a completely different story LOL. I tried for hours to find ways to do it but I couldn't figure it out. So, instead I just threw a bunch of blank random boxes on the maze to make it more of a chance that you can solve it. lol That's why I call it "Generic Random Maze Maker". If any of you wish to toss in some ideas on how to make a maze that someone can solve every time that would be really cool. I know they have been made before and I know there's a link to one on the thread about Maze Crawlers. But it's too much code for me to figure out. In the mean time, here is what I made. You can keep making mazes until you find one with an exit. I also added Printer support just for the fun of it. It has a white background with black lines. Also, I made it so you can choose how hard you want the maze, from hallways 20 pixels wide to 100 pixels wide. One thing I did try for a long time was re-making a background colored maze on top of the already made-maze with an IF/THEN statement of when it goes from the bottom to the top of the maze. But every time I did that, with all the possibilities I messed with, it always made just a huge CLUMP of background making the mazes way too easy. lol I know it has something to do with the way I make the maze in the first place, non-stop over-drawing lines after lines, until enough is eventually made to fill the screen. But I found out that's not the way to make a path to beat the game. lol I also tried making it so it wouldn't draw background over already drawn background, but I couldn't figure that out either.

Code: QB64: [Select]

1. _TITLE "Random Maze Maker"
2. SCREEN _NEWIMAGE(800, 600, 32)
3. begin:
4. DIM t AS LONG
5. x = 400: y = 300
6. CLS
7. PRINT: PRINT
8. PRINT "                               Generic Random Maze Maker"
9. PRINT: PRINT: PRINT
10. PRINT "                                      by Ken G."
11. PRINT: PRINT: PRINT
12. PRINT "                 This program creates a random maze using the size"
13. PRINT "                 of hallways that you enter."
14. PRINT
15. PRINT "                 The mazes this program makes are only random, so many"
16. PRINT "                 of them will not be able to solve. In order to make one"
17. PRINT "                 that has a way out, you must look at each one and keep"
18. PRINT "                 making them to find one you like that has an entrance and an exit."
19. PRINT "                 To make another maze, press the Space Bar, Esc key to quit, or P"
20. PRINT "                 to print to paper."
21. PRINT
22. INPUT "                 Type a hallway width here (20-100): "; h
23. IF h < 20 OR h > 100 OR h <> INT(h) THEN GOTO begin:
24. CLS
25. LINE (0, 0)-(800, 600), _RGB32(255, 255, 255), BF
26. DO
27.     again:
28.     t = t + 1
29.     IF t = 30000000 THEN EXIT DO
30.     oldx = x
31.     oldy = y
32.     oldd = d
33.     RANDOMIZE TIMER
34.     d = INT(RND * 4) + 1
35.     IF d = oldd THEN GOTO again:
36.     IF d = 1 THEN x = x + h
37.     IF d = 2 THEN x = x - h
38.     IF d = 3 THEN y = y + h
39.     IF d = 4 THEN y = y - h
40.     IF x > 785 OR x < 15 OR y > 585 OR y < 15 THEN x = 400: y = 300: GOTO again:
41.     IF POINT(x, y) = _RGB32(0, 0, 0) THEN GOTO again:
42.     LINE (oldx, oldy)-(x, y), _RGB32(0, 0, 0)
43. LOOP
44. t = 0
45. y = 585
46. x = 400
47. FOR tt = 1 TO INT(1000 / h)
48.     RANDOMIZE TIMER
49.     x2 = INT(RND * 800) + 1
50.     y2 = INT(RND * 600) + 1
51.     d2 = INT(RND * 2) + 1
52.     IF d2 = 1 THEN LINE (x2, y2)-(x2 + h, y2 + h), _RGB32(255, 255, 255), BF
53.     IF d2 = 2 THEN LINE (x2, y2)-(x2 + h, y2 + h), _RGB32(255, 255, 255), BF
54. NEXT tt
55.  
56.  
57. _TITLE "Esc To Quit. Or Space Bar to make another one. Or (P)rint To Printer."
58. waiting:
59. a$ = INKEY$
60. IF a$ = "p" OR a$ = "P" THEN
61.     j& = _COPYIMAGE(0)
62.     SCREEN j&
63.     _DELAY .25
64.     _PRINTIMAGE j&
65.     a$ = ""
66.     GOTO waiting:
67. END IF
68. IF a$ = CHR$(27) THEN END
69. IF a$ = "q" OR a$ = "Q" THEN END
70. IF a$ = " " THEN GOTO begin:
71. GOTO waiting:
72.  

[bplus]

This code generates a maze that is completely connected:
https://www.qb64.org/forum/index.php?topic=277.msg1598#msg1598

[SierraKen]

That's incredible B+! Beyond what I can do for sure. But I will keep working on mine.

[bplus]

That's incredible B+! Beyond what I can do for sure. But I will keep working on mine.

And you will come up with something very interesting, I am sure! looking forward to seeing what :)

Oh hey! talk about amazing fun:
https://easylang.online/apps/monster-maze.html

[Jack002]

If you have a commodore 64 and need a maze in one line (that does not have a clear path probably) try this

10 PRINT CHR$(205.5+RND(1)); : GOTO 10

[SierraKen]

I'm working on a game using most of this code called Search-Man. Don't expect too much lol. So far you can move a little green square guy around the maze with the arrow keys and collect dots. I really like how it chooses a random maze for every level. But it's nothing like Pac-Man. It's more of a "search the maze" game. I hope to be done within a few days or less. Next I have to figure out how to make the bad guy or some way to lose. lol

[johnno56]

Bplus,

Thanks for the link to the maze... Fired it up, hand poised over the cursor keys, NO... Mouse controlled... Finally got the hang of it and successfully got through... Cool game.

[bplus]

Bplus,

Thanks for the link to the maze... Fired it up, hand poised over the cursor keys, NO... Mouse controlled... Finally got the hang of it and successfully got through... Cool game.

Yeah, I was considering cloning a QB64 version, hadn't gotten around to it, so offered it up to Ken. But you do need to get code for generating a maze worked out, the reason for the link to Amazing Mouse which has that already in QB64.

[petoro]

Amazing mazes... I've been fiddling with the B + version. I reduced the second occurrence of _DELAY to .002 to turn the little mouse into a Speedy Gonzales superhero!

[bplus]

Ken, you've got me studying maze making but first I had to settle a question about collision detection with the walls.

What are walls but simple blocks that won't let our hero at the mouse position pass through, need a detector not based on POINT.

so I found and modified code to stop hero from entering box (thanks again Johnno) :

Code: QB64: [Select]

1. _TITLE "Bounding Box Collision Detection"
2. ' 2019-08-30 rewrite this so mouse box never gets inside the sides of box for maze study
3.  
4. '
5. '   Collision - Test 1  orig by johnno copied and mod b+ 2018-06-10
6. '
7. '   Bounding Box
8. '
9. ' 2018-06-10 mod by B+ change for x, y, w, h of images
10. ' by readjusting all the variables and use STEP for box drawing
11. ' Generalize the specific gosub routine from this one app so can reuse IN ANY APP using sprites / tiles / images
12.  
13. SCREEN _NEWIMAGE(800, 600, 32) '<<< something more standard center is 400, 300
14.  
15. ' sprites / tiles / images are typically referred to by their left top corner ie X, Y  and their width and height
16.  
17. 'lets do the height and width first
18. box1Width = 400 '<<< mod add this instead of above
19. box1Height = 100 '<<< mod add this instead of above
20.  
21. 'now center box
22. box1Left = 400 - box1Width / 2 'same as box1X
23. box1Top = 300 - box1Height / 2 'same as box1Y
24.  
25. mouseboxWidth = 50 '<<< mod add these constants
26. mouseboxHeight = 40 '<<< mod add these constants
27.  
28. f& = _RGB32(255, 255, 255)
29. b& = _RGB32(0, 0, 0)
30.  
31. DIM hey$(10)
32. hey$(0) = "Hey!"
33. hey$(1) = "I beg your pardon."
34. hey$(2) = "Bang!"
35. hey$(3) = "Yikes!"
36. hey$(4) = "Ouch!"
37. hey$(5) = "Watch where you are going."
38. DO
39.     k$ = INKEY$
40.     WHILE _MOUSEINPUT: WEND '<<< this is all the loop needed for mouse input
41.     CLS
42.     LINE (box1Left, box1Top)-STEP(box1Width, box1Height), _RGB32(255, 255, 255), BF
43.  
44.     ombx = mouseboxX: omby = mouseboxy
45.  
46.     mouseboxX = _MOUSEX - mouseboxWidth / 2
47.     mouseboxy = _MOUSEY - mouseboxHeight / 2
48.  
49.     IF collision%(box1Left, box1Top, box1Width, box1Height, mouseboxX, mouseboxy, mouseboxWidth, mouseboxHeight) = 1 THEN
50.         COLOR _RGB32(100, 0, 85), _RGB32(255, 255, 255)
51.         r$ = hey$(INT(RND * 6))
52.         _PRINTSTRING (box1Left + (box1Width - LEN(r$) * 8) / 2, 292), r$
53.         COLOR f&, b&
54.         mouseboxX = ombx: mouseboxy = omby
55.         lim = 1
56.     ELSE
57.         lim = 200
58.     END IF
59.     LINE (mouseboxX, mouseboxy)-STEP(mouseboxWidth, mouseboxHeight), _RGB32(255, 128, 0), BF '<<< use step with width and height
60.     _DISPLAY
61.     _LIMIT lim '<<< save the fan
62. LOOP UNTIL k$ = CHR$(27)
63.  
64. FUNCTION collision% (b1x, b1y, b1w, b1h, b2x, b2y, b2w, b2h)
65.     ' x, y represent the box left most x and top most y
66.     ' w, h represent the box width and height which is the usual way sprites / tiles / images are described
67.     ' such that boxbottom = by + bh
68.     '        and boxright = bx + bw
69.     'so the specific gosub above is gerealized to a function procedure here!
70.     IF (b1y + b1h < b2y) OR (b1y > b2y + b2h) OR (b1x > b2x + b2w) OR (b1x + b1w < b2x) THEN
71.         collision% = 0
72.     ELSE
73.         collision% = 1
74.     END IF
75. END FUNCTION
76.  

[bplus]

Collision detection in a maze without POINT:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Study Maze Making" 'B+ 2019-08-30
3. CONST sw = 800, sh = 600
4. SCREEN _NEWIMAGE(sw, sh, 32)
5. _SCREENMOVE 300, 60
6.  
7. TYPE box
8.     x AS INTEGER
9.     y AS INTEGER
10.     w AS INTEGER
11.     h AS INTEGER
12. END TYPE
13. REDIM SHARED mazeBoxes(1 TO 1) AS box
14. DIM SHARED vCells AS INTEGER, hCells AS INTEGER, wallThk AS INTEGER, xl, yl
15. hCells = 28: vCells = 15
16. DIM SHARED maze(hCells + 1, vCells + 1) AS INTEGER 'walls always +1 than cells to surround them
17. DIM x, y, mx, my, mw, mh, oldx, oldy
18. xl = sw / (hCells + 2)
19. yl = sh / (vCells + 2)
20. wallThk = 10
21. mw = .7 * xl
22. mh = .7 * yl
23.  
24. FOR y = 1 TO vCells 'read in data for maze
25.     FOR x = 1 TO hCells
26.         READ maze(x, y)
27.     NEXT
28. NEXT
29. mx = xl + 5 + mw / 2: my = yl + 5 + mh / 2
30. WHILE 1
31.     CLS
32.     drawMaze
33.     oldx = mx: oldy = my
34.     WHILE _MOUSEINPUT: WEND
35.     mx = _MOUSEX - mw / 2: my = _MOUSEY - mh / 2
36.     IF MazeCollision(mx, my, mw, mh) THEN
37.         mx = oldx: my = oldy: BEEP
38.     END IF
39.     LINE (mx, my)-STEP(mw, mh), &HFF0000FF, BF
40.     _DISPLAY
41.     _LIMIT 100
42. WEND
43. END
44.  
45. 'test maze
46. DATA 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
47. DATA 1,0,0,0,0,0,1,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,1
48. DATA 1,0,1,1,1,1,1,1,1,1,1,1,0,1,1,0,1,1,0,1,1,1,1,1,0,1,1,1
49. DATA 1,0,0,0,1,0,0,0,0,0,0,1,0,0,0,0,0,1,0,0,0,0,0,1,0,0,0,1
50. DATA 1,0,1,1,1,0,1,1,1,0,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,0,1
51. DATA 1,0,1,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1
52. DATA 1,0,1,0,1,1,1,1,1,0,1,1,1,1,1,1,1,1,1,1,1,1,0,1,1,1,1,1
53. DATA 1,0,1,0,1,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,1
54. DATA 1,0,1,0,1,0,0,0,1,0,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
55. DATA 1,0,1,1,1,1,1,0,1,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,1
56. DATA 1,0,1,0,0,0,1,0,1,1,1,1,1,0,1,1,1,1,0,1,1,1,1,1,1,1,1,1
57. DATA 1,0,1,0,1,0,1,0,1,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,1
58. DATA 1,0,1,0,1,0,1,0,1,1,1,1,1,0,1,0,1,1,1,1,1,1,1,1,1,1,0,1
59. DATA 1,0,0,0,1,0,1,0,1,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,1
60. DATA 1,0,1,1,1,0,1,0,1,1,1,1,1,1,1,0,1,1,1,1,1,1,1,1,1,1,1,1
61.  
62. FUNCTION collision% (b1x, b1y, b1w, b1h, b2x, b2y, b2w, b2h)
63.     ' x, y represent the box left most x and top most y
64.     ' w, h represent the box width and height which is the usual way sprites / tiles / images are described
65.     ' such that boxbottom = by + bh
66.     '        and boxright = bx + bw
67.     'so the specific gosub above is gerealized to a function procedure here!
68.     IF (b1y + b1h < b2y) OR (b1y > b2y + b2h) OR (b1x > b2x + b2w) OR (b1x + b1w < b2x) THEN
69.         collision% = 0
70.     ELSE
71.         collision% = 1
72.     END IF
73. END FUNCTION
74.  
75. SUB drawMaze 'while drawing maze build mazeBoxes array for detecting collisions
76.     DIM x, y, cnt AS INTEGER
77.     FOR y = 1 TO vCells
78.         FOR x = 1 TO hCells
79.             IF maze(x, y) AND maze(x, y + 1) THEN
80.                 LINE (x * xl, y * yl)-STEP(wallThk, yl + wallThk), , BF
81.                 cnt = cnt + 1
82.                 REDIM _PRESERVE mazeBoxes(1 TO cnt) AS box
83.                 mazeBoxes(cnt).x = x * xl
84.                 mazeBoxes(cnt).y = y * yl
85.                 mazeBoxes(cnt).w = wallThk
86.                 mazeBoxes(cnt).h = yl + wallThk
87.             END IF
88.             IF maze(x, y) AND maze(x + 1, y) THEN
89.                 LINE (x * xl, y * yl)-STEP(xl + wallThk, wallThk), , BF
90.                 cnt = cnt + 1
91.                 REDIM _PRESERVE mazeBoxes(1 TO cnt) AS box
92.                 mazeBoxes(cnt).x = x * xl
93.                 mazeBoxes(cnt).y = y * yl
94.                 mazeBoxes(cnt).w = xl + wallThk
95.                 mazeBoxes(cnt).h = wallThk
96.             END IF
97.         NEXT
98.     NEXT
99. END SUB
100.  
101. FUNCTION MazeCollision% (mx, my, mw, mh)
102.     DIM i
103.     MazeCollision% = -1 'assume true
104.     FOR i = 1 TO UBOUND(mazeBoxes)
105.         IF collision%(mx, my, mw, mh, mazeBoxes(i).x, mazeBoxes(i).y, mazeBoxes(i).w, mazeBoxes(i).h) THEN EXIT FUNCTION
106.     NEXT
107.     MazeCollision% = 0
108. END FUNCTION
109.  
110.  

[SierraKen]

Pretty neat B+, but it's the same problem as before. The block can still jump the walls when the mouse is pointing it farther to the other side. It did that in both of your examples here.  It was the same thing with POINT I believe, the mouse just goes to a coordinate that has no walls and goes there. Although, these examples are better because the walls are thicker and it gives the player a feeling that he is blocked. That is if the player doesn't point it too far.

[bplus]

Pretty neat B+, but it's the same problem as before. The block can still jump the walls when the mouse is pointing it farther to the other side. It did that in both of your examples here.  It was the same thing with POINT I believe, the mouse just goes to a coordinate that has no walls and goes there. Although, these examples are better because the walls are thicker and it gives the player a feeling that he is blocked. That is if the player doesn't point it too far.

Yeah, I think there is a better way to do this, to force the square directed by the mouse to stay the course like with the arrows PLUS without collision detection!

Do you remember or even know of an old kids game called Operation?
You had to remove body parts with tweezers's and if your touch a wall BUZZZZZ! you lost the patient!

This collision detection reminded me of that game. :D

[bplus]

OK 3 ways to move mouse through maze
1 arrow keys without momentum
2 arrow keys with momentum, Ken's style (space bar toggles momentum on and off)
3 mouse magnet when mouse is close to player avatar it will attract it but avatar does NOT go through walls anymore.

Also except for arrow stepping #1, the others are clunky... ;(

But look ma! no numbers crunching collision code to wade through! ;-))

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Study Maze Making 2 mouse navigation" 'B+ 2019-08-30 Collision detection
3. CONST sw = 800, sh = 600
4. SCREEN _NEWIMAGE(sw, sh, 32)
5. _SCREENMOVE 300, 60
6.  
7. '        GLOBALs
8. DIM SHARED vCells AS INTEGER, hCells AS INTEGER, wallThk AS INTEGER, xl, yl, xwo, ywo
9. hCells = 28: vCells = 15
10. DIM SHARED maze(hCells + 1, vCells + 1) AS INTEGER 'walls always +1 than cells to surround them
11.  
12. '        Locals for Main module code
13. DIM x, y, px, py, pw, ph, mx, my, k$, d, a, dist, momentum, lastD
14.  
15. 'set globals and locals
16. wallThk = 10 '          maze wall thickness shared
17. xl = (sw - wallThk) / (hCells + 2) 'horz length of cell shared
18. yl = (sh - wallThk) / (vCells + 2) 'vert length of cell shared
19.  
20. pw = xl '               player avatar width
21. ph = yl '               player avatar height
22. xwo = (xl - wallThk) / 2 'x wall offset  ' horz ofset of walls so player has space on each side between it and walls
23. ywo = (yl - wallThk) / 2 'y wall offset  ' vert offset of walls
24.  
25. FOR y = 1 TO vCells 'read in data for maze
26.     FOR x = 1 TO hCells
27.         READ maze(x, y)
28.     NEXT
29. NEXT
30. px = 2: py = 2
31. WHILE 1
32.     CLS
33.     drawMaze
34.  
35.  
36.     d = lastD
37.     WHILE _MOUSEINPUT: WEND
38.     mx = _MOUSEX - xl: my = _MOUSEY - yl 'offset by 1/2 character size
39.     'if the mouse is near the player then it will act as magnet drawing player to it unless wall in way
40.     dist = (mx - px * xl + xwo + wallThk / 2) ^ 2 + (my - py * yl + ywo + wallThk / 2) ^ 2
41.     IF dist <= 9 * xl * yl AND dist >= .1 * xl * yl THEN 'mouse over char
42.         a = _R2D(_ATAN2(my - py * yl + ywo + wallThk / 2, mx - px * xl + xwo + wallThk / 2))
43.         IF a < 0 THEN a = a + 360
44.         'LOCATE 1, 1: PRINT SPACE$(10)
45.         'LOCATE 1, 1: PRINT a
46.         'END
47.         IF a > 250 AND a < 290 THEN d = 1
48.         IF a > 70 AND a < 110 THEN d = 2
49.         IF (a >= 0 AND a < 20) OR (a > 340 AND a <= 360) THEN d = 3
50.         IF a > 160 AND a < 200 THEN d = 4
51.     END IF
52.  
53.     k$ = INKEY$ 'key press takes precedence over mouse
54.     IF k$ = " " THEN momentum = 1 - momentum
55.  
56.     IF LEN(k$) = 2 THEN
57.         SELECT CASE ASC(k$, 2)
58.             CASE 72: d = 1 'up
59.             CASE 80: d = 2 'down
60.             CASE 77: d = 3 'right
61.             CASE 75: d = 4 'left
62.         END SELECT
63.     END IF
64.     SELECT CASE d
65.         CASE 1 'up
66.             IF py - 1 >= 0 THEN
67.                 IF maze(px, py - 1) = 0 THEN py = py - 1
68.             END IF
69.         CASE 2 'down
70.             IF py + 1 <= vCells + 1 THEN
71.                 IF maze(px, py + 1) = 0 THEN py = py + 1
72.             END IF
73.         CASE 3 'right
74.             IF px + 1 <= hCells + 1 THEN
75.                 IF maze(px + 1, py) = 0 THEN px = px + 1
76.             END IF
77.         CASE 4 'left
78.             IF px - 1 >= 0 THEN
79.                 IF maze(px - 1, py) = 0 THEN px = px - 1
80.             END IF
81.     END SELECT
82.     LINE (px * xl + wallThk / 2, py * yl + wallThk / 2)-STEP(pw, ph), &HFF0000FF, BF 'draw player
83.     IF momentum THEN
84.         lastD = d: _TITLE "Mouse in amazement: spaceBar toggles momentum: ON"
85.     ELSE
86.         lastD = 0: _TITLE "Mouse in amazement: spaceBar toogles momentum: OFF"
87.     END IF
88.     _DISPLAY
89.     _LIMIT 5
90. WEND
91. END
92.  
93. 'test maze
94. DATA 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
95. DATA 1,0,0,0,0,0,1,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,1
96. DATA 1,0,1,1,1,1,1,1,1,1,1,1,0,1,1,0,1,1,0,1,1,1,1,1,0,1,1,1
97. DATA 1,0,0,0,1,0,0,0,0,0,0,1,0,0,0,0,0,1,0,0,0,0,0,1,0,0,0,1
98. DATA 1,0,1,1,1,0,1,1,1,0,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,0,1
99. DATA 1,0,1,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1
100. DATA 1,0,1,0,1,1,1,1,1,0,1,1,1,1,1,1,1,1,1,1,1,1,0,1,1,1,1,1
101. DATA 1,0,1,0,1,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,1
102. DATA 1,0,1,0,1,0,0,0,1,0,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
103. DATA 1,0,1,1,1,1,1,0,1,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,1
104. DATA 1,0,1,0,0,0,1,0,1,1,1,1,1,0,1,1,1,1,0,1,1,1,1,1,1,1,1,1
105. DATA 1,0,1,0,1,0,1,0,1,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,1
106. DATA 1,0,1,0,1,0,1,0,1,1,1,1,1,0,1,0,1,1,1,1,1,1,1,1,1,1,0,1
107. DATA 1,0,0,0,1,0,1,0,1,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,1
108. DATA 1,0,1,1,1,0,1,0,1,1,1,1,1,1,1,0,1,1,1,1,1,1,1,1,1,1,1,1
109.  
110. SUB drawMaze 'while drawing maze build mazeBoxes array for detecting collisions
111.     DIM x, y, cnt AS INTEGER
112.     FOR y = 1 TO vCells
113.         FOR x = 1 TO hCells
114.             IF maze(x, y) AND maze(x, y + 1) THEN
115.                 LINE (x * xl + xwo + wallThk / 2, y * yl + ywo + wallThk / 2)-STEP(wallThk, yl + wallThk), , BF
116.                 cnt = cnt + 1
117.             END IF
118.             IF maze(x, y) AND maze(x + 1, y) THEN
119.                 LINE (x * xl + xwo + wallThk / 2, y * yl + ywo + wallThk / 2)-STEP(xl + wallThk, wallThk), , BF
120.                 cnt = cnt + 1
121.             END IF
122.         NEXT
123.     NEXT
124. END SUB
125.  
126.  
127.  

[SierraKen]

That's neat. My mouse is very sticky but still cool.